src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU GPLv3 license.
   7
   8 #include "config.h" // CONFIG_*
   9 #include "ioport.h" // PORT_A20
  10 #include "bregs.h" // CR0_*
  11 #include "cmos.h" // CMOS_RESET_CODE
  12 #include "../out/asm-offsets.h" // BREGS_*
  13
  14
  15 /****************************************************************
  16  * Include of 16bit C code
  17  ****************************************************************/
  18
  19         .code16gcc
  20 .include "out/ccode.16.s"
  21
  22
  23 /****************************************************************
  24  * Entry macros
  25  ****************************************************************/
  26
  27         // Call a C function - this does the minimal work necessary to
  28         // call into C.  It sets up %ds, backs up %es, and backs up
  29         // those registers that are call clobbered by the C compiler.
  30         .macro ENTRY cfunc
  31         cld
  32         pushl %eax              // Save registers clobbered by C code
  33         pushl %ecx
  34         pushl %edx
  35         pushw %es
  36         pushw %ds
  37         movw %ss, %ax           // Move %ss to %ds
  38         movw %ax, %ds
  39         pushl %esp              // Backup %esp, then clear high bits
  40         movzwl %sp, %esp
  41         calll \cfunc
  42         popl %esp               // Restore %esp (including high bits)
  43         popw %ds                // Restore registers saved above
  44         popw %es
  45         popl %edx
  46         popl %ecx
  47         popl %eax
  48         .endm
  49
  50         // Call a C function with current register list as an
  51         // argument.  This backs up the registers and sets %eax
  52         // to point to the backup.  On return, the registers are
  53         // restored from the structure.
  54         .macro ENTRY_ARG cfunc
  55         cld
  56         pushl %eax              // Save registers (matches struct bregs)
  57         pushl %ecx
  58         pushl %edx
  59         pushl %ebx
  60         pushl %esi
  61         pushl %edi
  62         pushw %es
  63         pushw %ds
  64         movw %ss, %ax           // Move %ss to %ds
  65         movw %ax, %ds
  66         movl %esp, %ebx         // Backup %esp, then zero high bits
  67         movzwl %sp, %esp
  68         movl %esp, %eax         // First arg is pointer to struct bregs
  69         calll \cfunc
  70         movl %ebx, %esp         // Restore %esp (including high bits)
  71         popw %ds                // Restore registers (from struct bregs)
  72         popw %es
  73         popl %edi
  74         popl %esi
  75         popl %ebx
  76         popl %edx
  77         popl %ecx
  78         popl %eax
  79         .endm
  80
  81         // As above, but don't mangle %esp
  82         .macro ENTRY_ARG_ESP cfunc
  83         cld
  84         pushl %eax              // Save registers (matches struct bregs)
  85         pushl %ecx
  86         pushl %edx
  87         pushl %ebx
  88         pushl %esi
  89         pushl %edi
  90         pushw %es
  91         pushw %ds
  92         movw %ss, %ax           // Move %ss to %ds
  93         movw %ax, %ds
  94         movl %esp, %eax         // First arg is pointer to struct bregs
  95         calll \cfunc
  96         popw %ds                // Restore registers (from struct bregs)
  97         popw %es
  98         popl %edi
  99         popl %esi
 100         popl %ebx
 101         popl %edx
 102         popl %ecx
 103         popl %eax
 104         .endm
 105
 106         // Macro to reset the 16bit stack
 107         // Clobbers %ax
 108         .macro RESET_STACK
 109         xorw %ax, %ax
 110         movw %ax, %ss
 111         movl $ BUILD_STACK_ADDR , %esp
 112         cld
 113         .endm
 114
 115         // Specify a location in the fixed part of bios area.
 116         .macro ORG addr
 117         .section .text.fixed.addr
 118         .org \addr - BUILD_START_FIXED
 119         .endm
 120
 121
 122 /****************************************************************
 123  * POST handler
 124  ****************************************************************/
 125
 126         ORG 0xe05b
 127 post16:
 128         // enable cache
 129         movl %cr0, %eax
 130         andl $~(CR0_CD|CR0_NW), %eax
 131         movl %eax, %cr0
 132
 133         // Check for restart indicator.
 134         movl $CMOS_RESET_CODE, %eax
 135         outb %al, $PORT_CMOS_INDEX
 136         inb $PORT_CMOS_DATA, %al
 137         cmpb $0x0, %al
 138         jnz entry_resume
 139
 140         // Normal entry point
 141         RESET_STACK
 142
 143         pushl $_code32__start
 144
 145         // Fall through to transition32 function below
 146
 147
 148 /****************************************************************
 149  * Call trampolines
 150  ****************************************************************/
 151
 152 // Place CPU into 32bit mode from 16bit mode.
 153 // Clobbers: %eax, flags, stack registers, cr0, idt/gdt
 154 transition32:
 155         // Disable irqs
 156         cli
 157
 158         // enable a20
 159         inb $PORT_A20, %al
 160         orb $A20_ENABLE_BIT, %al
 161         outb %al, $PORT_A20
 162
 163         // Set segment descriptors
 164         lidtw %cs:pmode_IDT_info
 165         lgdtw %cs:rombios32_gdt_48
 166
 167         // Enable protected mode
 168         movl %cr0, %eax
 169         orl $CR0_PE, %eax
 170         movl %eax, %cr0
 171
 172         // start 32bit protected mode code
 173         ljmpl $SEG32_MODE32_CS, $(BUILD_BIOS_ADDR + 1f)
 174
 175         .code32
 176 1:
 177         // init data segments
 178         movl $SEG32_MODE32_DS, %eax
 179         movw %ax, %ds
 180         movw %ax, %es
 181         movw %ax, %ss
 182         movw %ax, %fs
 183         movw %ax, %gs
 184
 185         retl
 186
 187 // Call a 16bit function from 32bit mode.
 188 // %eax = address of struct bregs
 189 // Clobbers: all gp registers, flags, stack registers, cr0, idt/gdt
 190         .global __call16_from32, __call16big_from32
 191 __call16_from32:
 192         pushl %eax
 193
 194         // restore data segment limits to 0xffff
 195         movl $SEG32_MODE16_DS, %eax
 196         movw %ax, %ds
 197         movw %ax, %es
 198         movw %ax, %ss
 199         movw %ax, %fs
 200         movw %ax, %gs
 201
 202         // disable a20
 203         inb $PORT_A20, %al
 204         andb $~A20_ENABLE_BIT, %al
 205         outb %al, $PORT_A20
 206
 207         // Jump to 16bit mode
 208         ljmpw $SEG32_MODE16_CS, $1f
 209
 210 __call16big_from32:
 211         pushl %eax
 212
 213         movl $SEG32_MODE16BIG_DS, %eax
 214         movw %ax, %ds
 215         movw %ax, %es
 216         movw %ax, %ss
 217         movw %ax, %fs
 218         movw %ax, %gs
 219
 220         ljmpl $SEG32_MODE16BIG_CS, $(BUILD_BIOS_ADDR + 1f)
 221
 222         .code16gcc
 223 1:
 224         // Disable protected mode
 225         movl %cr0, %eax
 226         andl $~CR0_PE, %eax
 227         movl %eax, %cr0
 228
 229         // far jump to flush CPU queue after transition to real mode
 230         ljmpw $SEG_BIOS, $2f
 231
 232 2:
 233         // restore IDT to normal real-mode defaults
 234         lidtw %cs:rmode_IDT_info
 235
 236         // Clear segment registers
 237         xorw %ax, %ax
 238         movw %ax, %fs
 239         movw %ax, %gs
 240         movw %ax, %es
 241         movw %ax, %ds
 242         movw %ax, %ss  // Assume stack is in segment 0
 243
 244         popl %eax
 245
 246         // Set __call16 return address to be transition32
 247         pushl $transition32
 248
 249         // Fall through to __call16
 250
 251
 252 // Call a 16bit function from 16bit mode with a specified cpu register state
 253 // %eax = address of struct bregs
 254 // Clobbers: all gp registers, es
 255         .global __call16
 256 __call16:
 257         // Save eax
 258         pushl %eax
 259
 260         // Setup for iretw call
 261         pushw $SEG_BIOS
 262         pushw $1f               // return point
 263         pushw BREGS_flags(%eax) // flags
 264         pushl BREGS_ip(%eax)    // CS:IP
 265
 266         // Load calling registers.
 267         movl BREGS_edi(%eax), %edi
 268         movl BREGS_esi(%eax), %esi
 269         movl BREGS_ebx(%eax), %ebx
 270         movl BREGS_edx(%eax), %edx
 271         movl BREGS_ecx(%eax), %ecx
 272         movw BREGS_es(%eax), %es
 273         movw BREGS_ds(%eax), %ds
 274         movl %ss:BREGS_eax(%eax), %eax
 275
 276         // Invoke call
 277         iretw                   // XXX - just do a lcalll
 278 1:
 279         // Store flags, eax, ecx
 280         pushfw
 281         pushl %eax
 282         movl 0x06(%esp), %eax
 283         movl %ecx, %ss:BREGS_ecx(%eax)
 284         movw %ds, %ss:BREGS_ds(%eax)
 285         movw %ss, %cx
 286         movw %cx, %ds           // Restore %ds == %ss
 287         popl %ecx
 288         movl %ecx, BREGS_eax(%eax)
 289         popw %cx
 290         movw %cx, BREGS_flags(%eax)
 291
 292         // Store remaining registers
 293         movw %es, BREGS_es(%eax)
 294         movl %edi, BREGS_edi(%eax)
 295         movl %esi, BREGS_esi(%eax)
 296         movl %ebx, BREGS_ebx(%eax)
 297         movl %edx, BREGS_edx(%eax)
 298
 299         // Remove %eax
 300         popl %eax
 301
 302         cld
 303
 304         retl
 305
 306 // Entry point when a post call looks like a resume.
 307 // %eax = shutdown status from cmos
 308 entry_resume:
 309         // Save old shutdown status.
 310         movl %eax, %ebx
 311
 312         // Clear shutdown status register.
 313         movl $CMOS_RESET_CODE, %eax
 314         outb %al, $PORT_CMOS_INDEX
 315         xorl %eax, %eax
 316         outb %al, $PORT_CMOS_DATA
 317
 318         // Use a stack in EBDA
 319         movw $SEG_BDA, %ax
 320         movw %ax, %ds
 321         movw BDA_ebda_seg, %ax
 322         movw %ax, %ss
 323         movw %ax, %ds
 324         movl $EBDA_resume_stack_top, %esp
 325
 326         // Call handler.
 327         movl %ebx, %eax
 328         cld
 329         cli
 330         jmp handle_resume
 331
 332 // APM trampolines
 333         .global apm16protected_entry
 334 apm16protected_entry:
 335         pushfw          // save flags
 336         pushl %eax      // dummy
 337         ENTRY_ARG handle_1553
 338         addw $4, %sp    // pop dummy
 339         popfw           // restore flags
 340         lretw
 341
 342         .code32
 343         .global apm32protected_entry
 344 apm32protected_entry:
 345         pushfw
 346         pushw %cs       // Setup for long jump to 16bit mode
 347         pushw $1f
 348         addw $8, 2(%esp)
 349         ljmpw *(%esp)
 350         .code16gcc
 351 1:
 352         ENTRY_ARG_ESP handle_1553
 353
 354         movw $2f,(%esp) // Setup for long jump back to 32bit mode
 355         subw $8, 2(%esp)
 356         ljmpw *(%esp)
 357         .code32
 358 2:
 359         addl $4, %esp   // pop call address
 360         popfw
 361         lretl
 362
 363 // 32bit elf entry point
 364         .global post32
 365 post32:
 366         cli
 367         cld
 368         lidtl (BUILD_BIOS_ADDR + pmode_IDT_info)
 369         lgdtl (BUILD_BIOS_ADDR + rombios32_gdt_48)
 370         movl $BUILD_STACK_ADDR, %esp
 371         ljmpl $SEG32_MODE32_CS, $_code32__start
 372
 373         .code16gcc
 374
 375 // Shutdown a CPU.  We want this in the 0xf000 section to ensure that
 376 // the code wont be overwritten with something else.  (Should
 377 // something spurious wake up the CPU, we want to be sure that the hlt
 378 // insn will still be present and will shutdown the CPU.)
 379         .global permanent_halt
 380 permanent_halt:
 381         cli
 382 1:      hlt
 383         jmp 1b
 384
 385         // IRQ trampolines
 386         .macro IRQ_TRAMPOLINE num
 387         .global irq_trampoline_0x\num
 388         irq_trampoline_0x\num :
 389         int $0x\num
 390         lretw
 391         .endm
 392
 393         IRQ_TRAMPOLINE 02
 394         IRQ_TRAMPOLINE 10
 395         IRQ_TRAMPOLINE 13
 396         IRQ_TRAMPOLINE 15
 397         IRQ_TRAMPOLINE 16
 398         IRQ_TRAMPOLINE 18
 399         IRQ_TRAMPOLINE 19
 400         IRQ_TRAMPOLINE 1c
 401         IRQ_TRAMPOLINE 4a
 402
 403
 404 /****************************************************************
 405  * Interrupt entry points
 406  ****************************************************************/
 407
 408         // Define an entry point for an interrupt (no args passed).
 409         .macro IRQ_ENTRY num
 410         .global entry_\num
 411         entry_\num :
 412         cli         // In case something far-calls instead of using "int"
 413         ENTRY handle_\num
 414         iretw
 415         .endm
 416
 417         // Define an entry point for an interrupt (can read/modify args).
 418         .macro IRQ_ENTRY_ARG num
 419         .global entry_\num
 420         entry_\num :
 421         cli         // In case something far-calls instead of using "int"
 422         ENTRY_ARG handle_\num
 423         iretw
 424         .endm
 425
 426         ORG 0xe2c3
 427         IRQ_ENTRY nmi
 428
 429 /****************************************************************
 430  * GDT and IDT tables (between 0xe2c3 - 0xe3fe)
 431  ****************************************************************/
 432
 433 // Protected mode IDT descriptor
 434 //
 435 // I just make the limit 0, so the machine will shutdown
 436 // if an exception occurs during protected mode memory
 437 // transfers.
 438 //
 439 // Set base to f0000 to correspond to beginning of BIOS,
 440 // in case I actually define an IDT later
 441 // Set limit to 0
 442         .type pmode_IDT_info, @object
 443 pmode_IDT_info:
 444         .word 0x0000  // limit 15:00
 445         .long 0xf0000 // base 16:47
 446
 447 // Real mode IDT descriptor
 448 //
 449 // Set to typical real-mode values.
 450 // base  = 000000
 451 // limit =   03ff
 452         .type rmode_IDT_info, @object
 453 rmode_IDT_info:
 454         .word 0x03ff  // limit 15:00
 455         .long 0       // base 16:47
 456
 457         .type rombios32_gdt_48, @object
 458 rombios32_gdt_48:
 459         .word (rombios32_gdt_end - rombios32_gdt)
 460         .long (BUILD_BIOS_ADDR + rombios32_gdt)
 461
 462         .balign 8
 463         .type rombios32_gdt, @object
 464 rombios32_gdt:
 465         .word 0, 0, 0, 0
 466         .word 0, 0, 0, 0
 467         // 32 bit flat code segment (SEG32_MODE32_CS)
 468         .word 0xffff, 0, 0x9b00, 0x00cf
 469         // 32 bit flat data segment (SEG32_MODE32_DS)
 470         .word 0xffff, 0, 0x9300, 0x00cf
 471         // 16 bit code segment base=0xf0000 limit=0xffff (SEG32_MODE16_CS)
 472         .word 0xffff, 0, 0x9b0f, 0x0000
 473         // 16 bit data segment base=0x0 limit=0xffff (SEG32_MODE16_DS)
 474         .word 0xffff, 0, 0x9300, 0x0000
 475         // 16 bit code segment base=0 limit=0xffffffff (SEG32_MODE16BIG_CS)
 476         .word 0xffff, 0, 0x9b00, 0x008f
 477         // 16 bit data segment base=0 limit=0xffffffff (SEG32_MODE16BIG_DS)
 478         .word 0xffff, 0, 0x9300, 0x008f
 479 rombios32_gdt_end:
 480
 481 // We need a copy of this string in the 0xf000 segment, but we are not
 482 // actually a PnP BIOS, so make sure it is *not* aligned, so OSes will
 483 // not see it if they scan.
 484         .global pnp_string
 485         .type pnp_string, @object
 486         .balign 2
 487         .byte 0
 488 pnp_string:
 489         .ascii "$PnP"
 490
 491
 492 /****************************************************************
 493  * Interrupt entry points (continued)
 494  ****************************************************************/
 495
 496         ORG 0xe3fe
 497         .global entry_13_official
 498 entry_13_official:
 499         jmp entry_13
 500
 501         ORG 0xe401
 502         .type __fdpt, @object
 503 __fdpt:
 504         // XXX - Fixed Disk Parameter Table
 505
 506         ORG 0xe6f2
 507         .global entry_19_official
 508 entry_19_official:
 509         jmp entry_19
 510
 511         ORG 0xe6f5
 512 .include "out/cbt.proc.16.s"
 513         .text
 514
 515         ORG 0xe729
 516         .type __brgt, @object
 517 __brgt:
 518         // XXX - Baud Rate Generator Table
 519
 520         ORG 0xe739
 521         IRQ_ENTRY_ARG 14
 522
 523         ORG 0xe82e
 524         IRQ_ENTRY_ARG 16
 525
 526         ORG 0xe987
 527         IRQ_ENTRY 09
 528
 529         ORG 0xec59
 530         IRQ_ENTRY_ARG 40
 531
 532         ORG 0xef57
 533         IRQ_ENTRY 0e
 534
 535         ORG 0xefc7
 536 .include "out/floppy_dbt.proc.16.s"
 537         .text
 538
 539         ORG 0xefd2
 540         IRQ_ENTRY_ARG 17
 541
 542         ORG 0xf045
 543 __int10_0x0f:
 544         // XXX - INT 10 Functions 0-Fh Entry Point
 545         iretw
 546
 547         ORG 0xf065
 548         IRQ_ENTRY_ARG 10
 549
 550         ORG 0xf0a4
 551         .type __int1d, @object
 552 __int1d:
 553         // XXX - INT 1D - SYSTEM DATA - VIDEO PARAMETER TABLES
 554         .space 0x58
 555
 556         .global freespace2_start, freespace2_end
 557 freespace2_start:
 558
 559         ORG 0xf841
 560 freespace2_end:
 561         .global entry_12_official
 562 entry_12_official:
 563         jmp entry_12
 564
 565         ORG 0xf84d
 566         .global entry_11_official
 567 entry_11_official:
 568         jmp entry_11
 569
 570         ORG 0xf859
 571         IRQ_ENTRY_ARG 15
 572
 573         // Fit other misc defs if the freespace between 0xf859-0xfa6e
 574
 575         IRQ_ENTRY_ARG 13
 576         IRQ_ENTRY_ARG 12
 577         IRQ_ENTRY_ARG 11
 578         IRQ_ENTRY 76
 579         IRQ_ENTRY 1c
 580         IRQ_ENTRY 70
 581         IRQ_ENTRY 74
 582         IRQ_ENTRY 75
 583         IRQ_ENTRY hwpic1
 584         IRQ_ENTRY hwpic2
 585
 586         // int 18/19 are special - they reset the stack and do not return.
 587 entry_19:
 588         RESET_STACK
 589         pushl $_code32_handle_19
 590         jmp transition32
 591
 592         .global entry_18
 593 entry_18:
 594         RESET_STACK
 595         pushl $_code32_handle_18
 596         jmp transition32
 597
 598         ORG 0xfa6e
 599 .include "out/font.proc.16.s"
 600         .text
 601
 602         ORG 0xfe6e
 603         IRQ_ENTRY_ARG 1a
 604
 605         ORG 0xfea5
 606         IRQ_ENTRY 08
 607
 608         ORG 0xfef3
 609 __initvector:
 610         // XXX - Initial Interrupt Vector Offsets Loaded by POST
 611
 612         ORG 0xff00
 613         .type __copyright, @object
 614 __copyright:
 615         // XXX - BIOS_COPYRIGHT_STRING
 616         .asciz "(c) 2002 MandrakeSoft S.A. Written by Kevin Lawton & the Bochs team."
 617
 618         ORG 0xff53
 619         .global dummy_iret_handler
 620 dummy_iret_handler:
 621         iretw
 622
 623         ORG 0xff54
 624         IRQ_ENTRY_ARG 05
 625
 626         ORG 0xfff0 // Power-up Entry Point
 627         .global reset_vector
 628 reset_vector:
 629         ljmpw $SEG_BIOS, $post16
 630
 631         ORG 0xfff5
 632         .type __biosdate, @object
 633 __biosdate:
 634         // BIOS build date
 635         .ascii "06/23/99"
 636
 637         ORG 0xfffe
 638         .type __model_id, @object
 639 __model_id:
 640         .byte CONFIG_MODEL_ID
 641
 642         .global bios_checksum
 643         .type bios_checksum, @object
 644 bios_checksum:
 645         .byte 0x00
 646
 647         .end