src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU GPLv3 license.
   7
   8 #include "config.h"
   9
  10 #define PROTECTED_MODE_CS (2 << 3) // 0x10
  11 #define PROTECTED_MODE_DS (3 << 3) // 0x18
  12 #define REAL_MODE_CS      (4 << 3) // 0x20
  13 #define REAL_MODE_DS      (5 << 3) // 0x28
  14
  15         .code16gcc
  16
  17
  18 /****************************************************************
  19  * Include of 16bit C code
  20  ****************************************************************/
  21
  22         .globl bios16c_start, bios16c_end
  23 bios16c_start:
  24 .include "out/blob.proc.16.s"
  25         .text
  26 bios16c_end:
  27
  28
  29 /****************************************************************
  30  * POST handler
  31  ****************************************************************/
  32
  33         // Macro to reset the 16bit stack
  34         // Clobbers %ax
  35         .macro RESET_STACK
  36         xorw %ax, %ax
  37         movw %ax, %ss
  38         movl $ CONFIG_STACK_OFFSET , %esp
  39         .endm
  40
  41         .org 0xe05b
  42         .globl post16
  43 post16:
  44         // init the stack pointer
  45         RESET_STACK
  46
  47         // Set entry point of rombios32 code - the actual address
  48         // is altered later in the build process.
  49         .globl set_entry32
  50 set_entry32:
  51         pushl $0xf0000000
  52
  53         // Fall through to transition32 function below
  54
  55
  56 /****************************************************************
  57  * Call trampolines
  58  ****************************************************************/
  59
  60 // Place CPU into 32bit mode from 16bit mode.
  61 // Clobbers: %eax, flags, stack registers, cr0, idt/gdt
  62 transition32:
  63         // Disable irqs
  64         cli
  65
  66         // enable a20
  67         inb $0x92, %al
  68         orb $0x02, %al
  69         outb %al, $0x92
  70
  71         // Set segment descriptors
  72         lidt %cs:pmode_IDT_info
  73         lgdt %cs:rombios32_gdt_48
  74
  75         // set PE bit in CR0
  76         movl  %cr0, %eax
  77         orb   $0x01, %al
  78         movl  %eax, %cr0
  79
  80         // start protected mode code
  81         // ljmpl $PROTECTED_MODE_CS, $(1f | 0xf0000)
  82         .word 0xea66, 1f, 0x000f, PROTECTED_MODE_CS
  83
  84         .code32
  85 1:
  86         // init data segments
  87         movl $PROTECTED_MODE_DS, %eax
  88         movw %ax, %ds
  89         movw %ax, %es
  90         movw %ax, %ss
  91         xorl %eax, %eax
  92         movw %ax, %fs
  93         movw %ax, %gs
  94
  95         cld
  96
  97         retl
  98
  99 // Call a 16bit function from 32bit mode.
 100 // %eax = address of struct bregs
 101 // Clobbers: all gp registers, flags, stack registers, cr0, idt/gdt
 102         .globl __call16_from32
 103 __call16_from32:
 104         pushl %eax
 105
 106         // Jump to 16bit mode
 107         ljmp $REAL_MODE_CS, $1f
 108
 109         .code16gcc
 110 1:
 111         // restore data segment limits to 0xffff
 112         movw $REAL_MODE_DS, %ax
 113         movw %ax, %ds
 114         movw %ax, %es
 115         movw %ax, %ss
 116         movw %ax, %fs
 117         movw %ax, %gs
 118
 119         // reset PE bit in CR0
 120         movl %cr0, %eax
 121         andb $0xfe, %al
 122         movl %eax, %cr0
 123
 124         // far jump to flush CPU queue after transition to real mode
 125         ljmpw $0xf000, $2f
 126
 127 2:
 128         // restore IDT to normal real-mode defaults
 129         lidt %cs:rmode_IDT_info
 130
 131         // Clear segment registers
 132         xorw %ax, %ax
 133         movw %ax, %fs
 134         movw %ax, %gs
 135         movw %ax, %es
 136         movw %ax, %ds
 137         movw %ax, %ss  // Assume stack is in segment 0
 138
 139         popl %eax
 140         pushl $transition32
 141
 142         // Fall through to __call16
 143
 144
 145 // Call a 16bit function from 16bit mode with a specified cpu register state
 146 // %eax = address of struct bregs
 147 // Clobbers: all gp registers, es
 148         .globl __call16
 149 __call16:
 150         // Save eax
 151         pushl %eax
 152
 153         // Setup for iretw call
 154         pushw $0xf000
 155         pushw $1f               // return point
 156         pushw 0x28(%eax)        // flags
 157         pushl 0x24(%eax)        // CS:IP
 158
 159         // Load calling registers.
 160         movl 0x04(%eax), %edi
 161         movl 0x08(%eax), %esi
 162         movl 0x0c(%eax), %ebp
 163         movl 0x14(%eax), %ebx
 164         movl 0x18(%eax), %edx
 165         movl 0x1c(%eax), %ecx
 166         movw 0x02(%eax), %es    // XXX - should load %ds too
 167         movl 0x20(%eax), %eax
 168
 169         // Invoke call
 170         iretw                   // XXX - just do a lcalll
 171 1:
 172         // Store flags, eax, ecx
 173         pushfw
 174         pushl %eax
 175         movl 0x06(%esp), %eax
 176         movl %ecx, %ss:0x1c(%eax)       // Save %ecx
 177         movw %ss, %cx
 178         movw %cx, %ds                   // Restore %ds == %ss
 179         popl %ecx
 180         movl %ecx, 0x20(%eax)           // Save %eax
 181         popw %cx
 182         movw %cx, 0x28(%eax)            // Save flags
 183
 184         // Store remaining registers
 185         movw %es, 0x02(%eax)
 186         movl %edi, 0x04(%eax)
 187         movl %esi, 0x08(%eax)
 188         movl %ebp, 0x0c(%eax)
 189         movl %ebx, 0x14(%eax)
 190         movl %edx, 0x18(%eax)
 191
 192         // Remove %eax
 193         popl %eax
 194
 195         retl
 196
 197
 198 /****************************************************************
 199  * GDT and IDT tables
 200  ****************************************************************/
 201
 202 // Protected mode IDT descriptor
 203 //
 204 // I just make the limit 0, so the machine will shutdown
 205 // if an exception occurs during protected mode memory
 206 // transfers.
 207 //
 208 // Set base to f0000 to correspond to beginning of BIOS,
 209 // in case I actually define an IDT later
 210 // Set limit to 0
 211 pmode_IDT_info:
 212         .word 0x0000  // limit 15:00
 213         .long 0xf0000 // base 16:47
 214
 215 // Real mode IDT descriptor
 216 //
 217 // Set to typical real-mode values.
 218 // base  = 000000
 219 // limit =   03ff
 220 rmode_IDT_info:
 221         .word 0x03ff  // limit 15:00
 222         .long 0       // base 16:47
 223
 224 rombios32_gdt_48:
 225         .word 0x30
 226         .word rombios32_gdt
 227         .word 0x000f
 228
 229         .balign 8
 230 rombios32_gdt:
 231         .word 0, 0, 0, 0
 232         .word 0, 0, 0, 0
 233         // 32 bit flat code segment (PROTECTED_MODE_CS)
 234         .word 0xffff, 0, 0x9b00, 0x00cf
 235         // 32 bit flat data segment (PROTECTED_MODE_DS)
 236         .word 0xffff, 0, 0x9300, 0x00cf
 237         // 16 bit code segment base=0xf0000 limit=0xffff (REAL_MODE_CS)
 238         .word 0xffff, 0, 0x9b0f, 0x0000
 239         // 16 bit data segment base=0x0 limit=0xffff (REAL_MODE_DS)
 240         .word 0xffff, 0, 0x9300, 0x0000
 241
 242
 243 /****************************************************************
 244  * Interrupt entry points
 245  ****************************************************************/
 246
 247         .macro ENTRY cfunc
 248         pushal
 249         pushw %es
 250         pushw %ds
 251         movw %ss, %ax
 252         movw %ax, %ds
 253         movzwl %sp, %esp
 254         movl %esp, %eax
 255         calll \cfunc
 256         popw %ds
 257         popw %es
 258         popal
 259         .endm
 260
 261         .macro IRQ_ENTRY num
 262         .globl entry_\num
 263         entry_\num :
 264         cli         // In case something far-calls instead of using "int"
 265         ENTRY handle_\num
 266         iretw
 267         .endm
 268
 269         // APM trampolines
 270         .globl apm16protected_entry
 271 apm16protected_entry:
 272         pushfw          // save flags
 273         pushl %eax      // dummy
 274         ENTRY handle_1553
 275         addw $4, %sp    // pop dummy
 276         popfw           // restore flags
 277         lretw
 278
 279         .code32
 280         .globl apm32protected_entry
 281 apm32protected_entry:
 282         pushfw          // save flags
 283         pushw %cs       // Setup for long jump to 16bitmode
 284         incw (%esp)
 285         pushw 1f
 286         lcallw *(%esp)
 287         addl $4, %esp   // pop call address
 288         popfw
 289         lretl
 290         .code16gcc
 291 1:                      // 16bit entry point for apm32 code.
 292         ENTRY handle_1553
 293         lretw
 294
 295         .org 0xe2c3
 296         IRQ_ENTRY nmi
 297
 298         IRQ_ENTRY 13
 299         IRQ_ENTRY 12
 300         IRQ_ENTRY 11
 301         IRQ_ENTRY 76
 302         IRQ_ENTRY 1c
 303         IRQ_ENTRY 70
 304         IRQ_ENTRY 74
 305         IRQ_ENTRY 75
 306
 307         .globl entry_19
 308 entry_19:
 309         RESET_STACK
 310         calll handle_19
 311
 312         .globl entry_18
 313 entry_18:
 314         RESET_STACK
 315         calll handle_18
 316
 317
 318         // IRQ trampolines
 319         .macro IRQ_TRAMPOLINE num
 320         .globl irq_trampoline_0x\num
 321         irq_trampoline_0x\num :
 322         int $0x\num
 323         lretw
 324         .endm
 325
 326         IRQ_TRAMPOLINE 02
 327         IRQ_TRAMPOLINE 10
 328         IRQ_TRAMPOLINE 13
 329         IRQ_TRAMPOLINE 15
 330         IRQ_TRAMPOLINE 18
 331         IRQ_TRAMPOLINE 19
 332         IRQ_TRAMPOLINE 1c
 333         IRQ_TRAMPOLINE 4a
 334
 335         .org 0xe3fe
 336         jmp entry_13
 337
 338         .org 0xe401
 339         // XXX - Fixed Disk Parameter Table
 340
 341         .org 0xe6f2
 342         jmp entry_19
 343
 344         .org 0xe6f5
 345 .include "out/cbt.proc.16.s"
 346         .text
 347
 348         .org 0xe729
 349         // XXX - Baud Rate Generator Table
 350
 351         .org 0xe739
 352         IRQ_ENTRY 14
 353
 354         .org 0xe82e
 355         IRQ_ENTRY 16
 356
 357         .org 0xe987
 358         IRQ_ENTRY 09
 359
 360         .org 0xec59
 361         IRQ_ENTRY 40
 362
 363         .org 0xef57
 364         IRQ_ENTRY 0e
 365
 366         .org 0xefc7
 367 .include "out/floppy_dbt.proc.16.s"
 368         .text
 369
 370         .org 0xefd2
 371         IRQ_ENTRY 17
 372
 373         .org 0xf045
 374         // XXX int 10
 375         iretw
 376
 377         .org 0xf065
 378         IRQ_ENTRY 10
 379
 380         .org 0xf0a4
 381         // XXX int 1D
 382         iretw
 383
 384         .globl freespace2_start, freespace2_end
 385 freespace2_start:
 386
 387         .org 0xf841
 388 freespace2_end:
 389         jmp entry_12
 390
 391         .org 0xf84d
 392         jmp entry_11
 393
 394         .org 0xf859
 395         IRQ_ENTRY 15
 396
 397         .org 0xfa6e
 398 .include "out/font.proc.16.s"
 399         .text
 400
 401         .org 0xfe6e
 402         IRQ_ENTRY 1a
 403
 404         .org 0xfea5
 405         IRQ_ENTRY 08
 406
 407         .org 0xfef3
 408         // XXX - Initial Interrupt Vector Offsets Loaded by POST
 409
 410         .org 0xff00
 411         // XXX - BIOS_COPYRIGHT_STRING
 412         .ascii "(c) 2002 MandrakeSoft S.A. Written by Kevin Lawton & the Bochs team."
 413
 414         .org 0xff53
 415         .globl dummy_iret_handler
 416 dummy_iret_handler:
 417         iretw
 418
 419         .org 0xff54
 420         IRQ_ENTRY 05
 421
 422         .org 0xfff0 // Power-up Entry Point
 423         ljmpw $0xf000, $post16
 424
 425         .org 0xfff5
 426         // BIOS build date
 427         .ascii "06/23/99"
 428
 429         .org 0xfffe
 430         .byte CONFIG_MODEL_ID
 431         .byte 0x00
 432
 433         .end