src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008,2009  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU LGPLv3 license.
   7
   8
   9 /****************************************************************
  10  * Include of 16bit C code
  11  ****************************************************************/
  12
  13         .code16gcc
  14 .include "out/ccode.16.s"
  15
  16 #include "config.h" // CONFIG_*
  17 #include "ioport.h" // PORT_A20
  18 #include "bregs.h" // CR0_*
  19 #include "cmos.h" // CMOS_RESET_CODE
  20 #include "../out/asm-offsets.h" // BREGS_*
  21 #include "entryfuncs.S" // ENTRY_*
  22
  23
  24 /****************************************************************
  25  * Call trampolines
  26  ****************************************************************/
  27
  28 // Place CPU into 32bit mode from 16bit mode.
  29 // Clobbers: flags, segment registers, cr0, idt/gdt
  30         DECLFUNC transition32
  31 transition32:
  32         pushl %eax
  33
  34         // Disable irqs (and clear direction flag)
  35         cli
  36         cld
  37
  38         // Disable nmi
  39         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
  40         outb %al, $PORT_CMOS_INDEX
  41         inb $PORT_CMOS_DATA, %al
  42
  43         // enable a20
  44         inb $PORT_A20, %al
  45         orb $A20_ENABLE_BIT, %al
  46         outb %al, $PORT_A20
  47
  48         // Set segment descriptors
  49         lidtw %cs:pmode_IDT_info
  50         lgdtw %cs:rombios32_gdt_48
  51
  52         // Enable protected mode
  53         movl %cr0, %eax
  54         orl $CR0_PE, %eax
  55         movl %eax, %cr0
  56
  57         // start 32bit protected mode code
  58         ljmpl $SEG32_MODE32_CS, $(BUILD_BIOS_ADDR + 1f)
  59
  60         .code32
  61 1:
  62         // init data segments
  63         movl $SEG32_MODE32_DS, %eax
  64         movw %ax, %ds
  65         movw %ax, %es
  66         movw %ax, %ss
  67         movw %ax, %fs
  68         movw %ax, %gs
  69
  70         popl %eax
  71         retl
  72
  73 // Call a 16bit function from 32bit mode.
  74 // %eax = address of struct bregs
  75 // Clobbers: %e[bcd]x, %e[ds]i, flags, segment registers, idt/gdt
  76         DECLFUNC __call16_from32
  77         .global __call16big_from32
  78 __call16_from32:
  79         pushl %eax
  80
  81         // restore data segment limits to 0xffff
  82         movl $SEG32_MODE16_DS, %eax
  83         movw %ax, %ds
  84         movw %ax, %es
  85         movw %ax, %ss
  86         movw %ax, %fs
  87         movw %ax, %gs
  88
  89 #if CONFIG_DISABLE_A20
  90         // disable a20
  91         inb $PORT_A20, %al
  92         andb $~A20_ENABLE_BIT, %al
  93         outb %al, $PORT_A20
  94 #endif
  95
  96         // Jump to 16bit mode
  97         ljmpw $SEG32_MODE16_CS, $1f
  98
  99 __call16big_from32:
 100         pushl %eax
 101
 102         movl $SEG32_MODE16BIG_DS, %eax
 103         movw %ax, %ds
 104         movw %ax, %es
 105         movw %ax, %ss
 106         movw %ax, %fs
 107         movw %ax, %gs
 108
 109         ljmpl $SEG32_MODE16BIG_CS, $(BUILD_BIOS_ADDR + 1f)
 110
 111         .code16gcc
 112 1:
 113         // Disable protected mode
 114         movl %cr0, %eax
 115         andl $~CR0_PE, %eax
 116         movl %eax, %cr0
 117
 118         // far jump to flush CPU queue after transition to real mode
 119         ljmpw $SEG_BIOS, $2f
 120
 121 2:
 122         // restore IDT to normal real-mode defaults
 123         lidtw %cs:rmode_IDT_info
 124
 125         // Clear segment registers
 126         xorw %ax, %ax
 127         movw %ax, %fs
 128         movw %ax, %gs
 129         movw %ax, %es
 130         movw %ax, %ds
 131         movw %ax, %ss  // Assume stack is in segment 0
 132
 133         popl %eax
 134
 135         // Make call.
 136         calll __call16
 137
 138         // Return via transition32
 139         jmp transition32
 140
 141
 142 // Call a 16bit function from 16bit mode with a specified cpu register state
 143 // %eax = address of struct bregs
 144 // Clobbers: %e[bcd]x, %e[ds]i, flags
 145         DECLFUNC __call16
 146 __call16:
 147         // Save %eax, %ebp
 148         pushl %ebp
 149         pushl %eax
 150
 151         // Setup for iretw call
 152         pushw %cs
 153         pushw $1f               // return point
 154         pushw BREGS_flags(%eax) // flags
 155         pushl BREGS_ip(%eax)    // CS:IP
 156
 157         // Load calling registers.
 158         movl BREGS_edi(%eax), %edi
 159         movl BREGS_esi(%eax), %esi
 160         movl BREGS_ebp(%eax), %ebp
 161         movl BREGS_ebx(%eax), %ebx
 162         movl BREGS_edx(%eax), %edx
 163         movl BREGS_ecx(%eax), %ecx
 164         movw BREGS_es(%eax), %es
 165         movw BREGS_ds(%eax), %ds
 166         movl %ss:BREGS_eax(%eax), %eax
 167
 168         // Invoke call
 169         iretw                   // XXX - just do a lcalll
 170 1:
 171         // Store flags, eax, ecx
 172         pushfw
 173         pushl %eax
 174         movl 0x06(%esp), %eax
 175         movl %ecx, %ss:BREGS_ecx(%eax)
 176         movw %ds, %ss:BREGS_ds(%eax)
 177         movw %ss, %cx
 178         movw %cx, %ds           // Restore %ds == %ss
 179         popl %ecx
 180         movl %ecx, BREGS_eax(%eax)
 181         popw %cx
 182         movw %cx, BREGS_flags(%eax)
 183
 184         // Store remaining registers
 185         movw %es, BREGS_es(%eax)
 186         movl %edi, BREGS_edi(%eax)
 187         movl %esi, BREGS_esi(%eax)
 188         movl %ebp, BREGS_ebp(%eax)
 189         movl %ebx, BREGS_ebx(%eax)
 190         movl %edx, BREGS_edx(%eax)
 191
 192         // Remove %eax, restore %ebp
 193         popl %eax
 194         popl %ebp
 195
 196         retl
 197
 198 // IRQ trampolines
 199         .macro IRQ_TRAMPOLINE num
 200         DECLFUNC irq_trampoline_0x\num
 201         irq_trampoline_0x\num :
 202         int $0x\num
 203         lretw
 204         .endm
 205
 206         IRQ_TRAMPOLINE 10
 207         IRQ_TRAMPOLINE 13
 208         IRQ_TRAMPOLINE 15
 209         IRQ_TRAMPOLINE 16
 210         IRQ_TRAMPOLINE 18
 211         IRQ_TRAMPOLINE 19
 212
 213
 214 /****************************************************************
 215  * POST entry point
 216  ****************************************************************/
 217
 218         DECLFUNC entry_post
 219 entry_post:
 220         // Enable cache
 221         movl %cr0, %eax
 222         andl $~(CR0_CD|CR0_NW), %eax
 223         movl %eax, %cr0
 224
 225         // Disable interrupts
 226         cli
 227         cld
 228
 229         // Check for restart indicator.
 230         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
 231         outb %al, $PORT_CMOS_INDEX
 232         inb $PORT_CMOS_DATA, %al
 233         cmpb $0x0, %al
 234         jnz 1f
 235
 236         // Normal entry point
 237         ENTRY_INTO32 _code32__start
 238
 239         // Entry point when a post call looks like a resume.
 240 1:
 241         // Save old shutdown status.
 242         movl %eax, %ebx
 243
 244         // Clear shutdown status register.
 245         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
 246         outb %al, $PORT_CMOS_INDEX
 247         xorl %eax, %eax
 248         outb %al, $PORT_CMOS_DATA
 249
 250         // Use a stack in EBDA
 251         movw $SEG_BDA, %ax
 252         movw %ax, %ds
 253         movw BDA_ebda_seg, %ax
 254         // XXX - should verify ebda_seg looks sane.
 255         movw %ax, %ds
 256         movw %ax, %ss
 257         movl $EBDA_OFFSET_TOP_STACK, %esp
 258
 259         // Call handler.
 260         movl %ebx, %eax
 261         jmp handle_resume
 262
 263
 264 /****************************************************************
 265  * Misc. entry points.
 266  ****************************************************************/
 267
 268 // PnP entry points
 269         DECLFUNC entry_pnp_real
 270         .global entry_pnp_prot
 271 entry_pnp_prot:
 272         pushl %esp
 273         jmp 1f
 274 entry_pnp_real:
 275         pushl %esp              // Backup %esp, then clear high bits
 276         movzwl %sp, %esp
 277 1:
 278         pushfl                  // Save registers clobbered by C code
 279         pushl %eax
 280         pushl %ecx
 281         pushl %edx
 282         pushw %es
 283         pushw %ds
 284         movw %ss, %cx           // Move %ss to %ds
 285         movw %cx, %ds
 286         lea 28(%esp), %eax      // %eax points to start of u16 args
 287         calll handle_pnp
 288         movw %ax, 12(%esp)      // Modify %eax to return %ax
 289         popw %ds
 290         popw %es
 291         popl %edx
 292         popl %ecx
 293         popl %eax
 294         popfl
 295         popl %esp
 296         lretw
 297
 298 // APM entry points
 299         DECLFUNC apm16protected_entry
 300 apm16protected_entry:
 301         pushfw          // save flags
 302         pushl %eax      // dummy
 303         ENTRY_ARG handle_1553
 304         addw $4, %sp    // pop dummy
 305         popfw           // restore flags
 306         lretw
 307
 308         .code32
 309         DECLFUNC apm32protected_entry
 310 apm32protected_entry:
 311         pushfw
 312         pushw %cs       // Setup for long jump to 16bit mode
 313         pushw $1f
 314         addw $8, 2(%esp)
 315         ljmpw *(%esp)
 316         .code16gcc
 317 1:
 318         ENTRY_ARG_ESP handle_1553
 319
 320         movw $2f,(%esp) // Setup for long jump back to 32bit mode
 321         subw $8, 2(%esp)
 322         ljmpw *(%esp)
 323         .code32
 324 2:
 325         addl $4, %esp   // pop call address
 326         popfw
 327         lretl
 328
 329 // 32bit elf entry point
 330         DECLFUNC post32
 331 post32:
 332         cli
 333         cld
 334         lidtl (BUILD_BIOS_ADDR + pmode_IDT_info)
 335         lgdtl (BUILD_BIOS_ADDR + rombios32_gdt_48)
 336         movl $SEG32_MODE32_DS, %eax
 337         movw %ax, %ds
 338         movw %ax, %es
 339         movw %ax, %fs
 340         movw %ax, %gs
 341         movw %ax, %ss
 342         movl $BUILD_STACK_ADDR, %esp
 343         ljmpl $SEG32_MODE32_CS, $_code32__start
 344
 345         .code16gcc
 346
 347
 348 /****************************************************************
 349  * Interrupt entry points
 350  ****************************************************************/
 351
 352         // Define an entry point for an interrupt (no args passed).
 353         .macro IRQ_ENTRY num
 354         .global entry_\num
 355         entry_\num :
 356         pushl $ handle_\num
 357         jmp irqentry
 358         .endm
 359
 360         // Define an entry point for an interrupt (can read/modify args).
 361         .macro IRQ_ENTRY_ARG num
 362         .global entry_\num
 363         entry_\num :
 364         pushl $ handle_\num
 365         jmp irqentryarg
 366         .endm
 367
 368         // Macros that put each handler into its own section
 369         .macro DECL_IRQ_ENTRY num
 370         DECLFUNC entry_\num
 371         IRQ_ENTRY \num
 372         .endm
 373         .macro DECL_IRQ_ENTRY_ARG num
 374         DECLFUNC entry_\num
 375         IRQ_ENTRY_ARG \num
 376         .endm
 377
 378         // Main entry point for interrupts without args
 379         DECLFUNC irqentry
 380 irqentry:
 381         ENTRY_ST
 382         iretw
 383
 384         // Main entry point for interrupts with args
 385         DECLFUNC irqentry
 386 irqentryarg:
 387         ENTRY_ARG_ST
 388         iretw
 389
 390         DECL_IRQ_ENTRY_ARG 13
 391         DECL_IRQ_ENTRY 76
 392         DECL_IRQ_ENTRY 70
 393         DECL_IRQ_ENTRY 74
 394         DECL_IRQ_ENTRY 75
 395         DECL_IRQ_ENTRY hwpic1
 396         DECL_IRQ_ENTRY hwpic2
 397
 398         // int 18/19 are special - they reset stack and call into 32bit mode.
 399         DECLFUNC entry_19
 400 entry_19:
 401         ENTRY_INTO32 _code32_handle_19
 402
 403         DECLFUNC entry_18
 404 entry_18:
 405         ENTRY_INTO32 _code32_handle_18
 406
 407
 408 /****************************************************************
 409  * Fixed position entry points
 410  ****************************************************************/
 411
 412         // Specify a location in the fixed part of bios area.
 413         .macro ORG addr
 414         .section .fixedaddr.\addr
 415         .endm
 416
 417         ORG 0xe05b
 418 entry_post_official:
 419         jmp entry_post
 420
 421         ORG 0xe2c3
 422         IRQ_ENTRY 02
 423
 424         ORG 0xe3fe
 425         .global entry_13_official
 426 entry_13_official:
 427         jmp entry_13
 428
 429         // 0xe401 - OldFDPT in disk.c
 430
 431         ORG 0xe6f2
 432         .global entry_19_official
 433 entry_19_official:
 434         jmp entry_19
 435
 436         // 0xe6f5 - BIOS_CONFIG_TABLE in misc.c
 437
 438         // 0xe729 - BaudTable in serial.c
 439
 440         ORG 0xe739
 441         IRQ_ENTRY_ARG 14
 442
 443         ORG 0xe82e
 444         IRQ_ENTRY_ARG 16
 445
 446         ORG 0xe987
 447         IRQ_ENTRY 09
 448
 449         ORG 0xec59
 450         IRQ_ENTRY_ARG 40
 451
 452         ORG 0xef57
 453         IRQ_ENTRY 0e
 454
 455         // 0xefc7 - diskette_param_table in floppy.c
 456
 457         ORG 0xefd2
 458         IRQ_ENTRY_ARG 17
 459
 460         ORG 0xf045
 461 entry_10_0x0f:
 462         // XXX - INT 10 Functions 0-Fh Entry Point
 463         iretw
 464
 465         ORG 0xf065
 466         IRQ_ENTRY_ARG 10
 467
 468         // 0xf0a4 - VideoParams in misc.c
 469
 470         ORG 0xf841
 471         IRQ_ENTRY_ARG 12
 472
 473         ORG 0xf84d
 474         IRQ_ENTRY_ARG 11
 475
 476         ORG 0xf859
 477         IRQ_ENTRY_ARG 15
 478
 479         // 0xfa6e - vgafont8 in font.c
 480
 481         ORG 0xfe6e
 482         IRQ_ENTRY_ARG 1a
 483
 484         ORG 0xfea5
 485         IRQ_ENTRY 08
 486
 487         // 0xfef3 - InitVectors in misc.c
 488
 489         // 0xff00 - BiosCopyright in misc.c
 490
 491         ORG 0xff53
 492         .global entry_iret_official
 493 entry_iret_official:
 494         iretw
 495
 496         ORG 0xff54
 497         IRQ_ENTRY_ARG 05
 498
 499         ORG 0xfff0 // Power-up Entry Point
 500         .global reset_vector
 501 reset_vector:
 502         ljmpw $SEG_BIOS, $entry_post_official
 503
 504         // 0xfff5 - BiosDate in misc.c
 505
 506         // 0xfffe - BiosModelId in misc.c
 507
 508         // 0xffff - BiosChecksum in misc.c
 509
 510         .end