src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU GPLv3 license.
   7
   8 #include "config.h"
   9
  10 #define PROTECTED_MODE_CS (2 << 3) // 0x10
  11 #define PROTECTED_MODE_DS (3 << 3) // 0x18
  12 #define REAL_MODE_CS      (4 << 3) // 0x20
  13 #define REAL_MODE_DS      (5 << 3) // 0x28
  14
  15         .code16gcc
  16
  17
  18 /****************************************************************
  19  * Include of 16bit C code
  20  ****************************************************************/
  21
  22         .globl bios16c_start, bios16c_end
  23 bios16c_start:
  24 .include "out/blob.proc.16.s"
  25         .text
  26 bios16c_end:
  27
  28
  29 /****************************************************************
  30  * POST handler
  31  ****************************************************************/
  32
  33         // Macro to reset the 16bit stack
  34         // Clobbers %ax
  35         .macro RESET_STACK
  36         xorw %ax, %ax
  37         movw %ax, %ss
  38         movl $ CONFIG_STACK_OFFSET , %esp
  39         .endm
  40
  41         .org 0xe05b
  42         .globl post16
  43 post16:
  44         // init the stack pointer
  45         RESET_STACK
  46
  47         // Set entry point of rombios32 code - the actual address
  48         // is altered later in the build process.
  49         .globl set_entry32
  50 set_entry32:
  51         pushl $0xf0000000
  52
  53         // Fall through to transition32 function below
  54
  55
  56 /****************************************************************
  57  * Call trampolines
  58  ****************************************************************/
  59
  60 // Place CPU into 32bit mode from 16bit mode.
  61 // Clobbers: %eax, flags, stack registers, cr0, idt/gdt
  62 transition32:
  63         // Disable irqs
  64         cli
  65
  66         // enable a20
  67         inb $0x92, %al
  68         orb $0x02, %al
  69         outb %al, $0x92
  70
  71         // Set segment descriptors
  72         lidt %cs:pmode_IDT_info
  73         lgdt %cs:rombios32_gdt_48
  74
  75         // set PE bit in CR0
  76         movl  %cr0, %eax
  77         orb   $0x01, %al
  78         movl  %eax, %cr0
  79
  80         // start protected mode code
  81         // ljmpl $PROTECTED_MODE_CS, $(1f | 0xf0000)
  82         .word 0xea66, 1f, 0x000f, PROTECTED_MODE_CS
  83
  84         .code32
  85 1:
  86         // init data segments
  87         movl $PROTECTED_MODE_DS, %eax
  88         movw %ax, %ds
  89         movw %ax, %es
  90         movw %ax, %ss
  91         xorl %eax, %eax
  92         movw %ax, %fs
  93         movw %ax, %gs
  94
  95         cld
  96
  97         retl
  98
  99 // Call a 16bit function from 32bit mode.
 100 // %eax = address of struct bregs
 101 // Clobbers: all gp registers, flags, stack registers, cr0, idt/gdt
 102         .globl __call16_from32
 103 __call16_from32:
 104         pushl %eax
 105
 106         // Jump to 16bit mode
 107         ljmp $REAL_MODE_CS, $1f
 108
 109         .code16gcc
 110 1:
 111         // restore data segment limits to 0xffff
 112         movw $REAL_MODE_DS, %ax
 113         movw %ax, %ds
 114         movw %ax, %es
 115         movw %ax, %ss
 116         movw %ax, %fs
 117         movw %ax, %gs
 118
 119         // reset PE bit in CR0
 120         movl %cr0, %eax
 121         andb $0xfe, %al
 122         movl %eax, %cr0
 123
 124         // far jump to flush CPU queue after transition to real mode
 125         ljmpw $0xf000, $2f
 126
 127 2:
 128         // restore IDT to normal real-mode defaults
 129         lidt %cs:rmode_IDT_info
 130
 131         // Clear segment registers
 132         xorw %ax, %ax
 133         movw %ax, %fs
 134         movw %ax, %gs
 135         movw %ax, %es
 136         movw %ax, %ds
 137         movw %ax, %ss  // Assume stack is in segment 0
 138
 139         popl %eax
 140         pushl $transition32
 141
 142         // Fall through to __call16
 143
 144
 145 // Call a 16bit function from 16bit mode with a specified cpu register state
 146 // %eax = address of struct bregs
 147 // Clobbers: all gp registers, es
 148         .globl __call16
 149 __call16:
 150         // Save eax
 151         pushl %eax
 152
 153         // Setup for iretw call
 154         pushw $0xf000
 155         pushw $1f               // return point
 156         pushw 0x28(%eax)        // flags
 157         pushl 0x24(%eax)        // CS:IP
 158
 159         // Load calling registers.
 160         movl 0x04(%eax), %edi
 161         movl 0x08(%eax), %esi
 162         movl 0x0c(%eax), %ebp
 163         movl 0x14(%eax), %ebx
 164         movl 0x18(%eax), %edx
 165         movl 0x1c(%eax), %ecx
 166         movw 0x02(%eax), %es    // XXX - should load %ds too
 167         movl 0x20(%eax), %eax
 168
 169         // Invoke call
 170         iretw                   // XXX - just do a lcalll
 171 1:
 172         // Store flags, eax, ecx
 173         pushfw
 174         pushl %eax
 175         movl 0x06(%esp), %eax
 176         movl %ecx, 0x1c(%eax)   // Save %ecx
 177         popl %ecx
 178         movl %ecx, 0x20(%eax)   // Save %eax
 179         popw %cx
 180         movw %cx, 0x28(%eax)    // Save flags
 181
 182         // Store remaining registers
 183         movw %es, 0x02(%eax)
 184         movl %edi, 0x04(%eax)
 185         movl %esi, 0x08(%eax)
 186         movl %ebp, 0x0c(%eax)
 187         movl %ebx, 0x14(%eax)
 188         movl %edx, 0x18(%eax)
 189
 190         // Remove %eax
 191         popl %eax
 192
 193         retl
 194
 195
 196 /****************************************************************
 197  * GDT and IDT tables
 198  ****************************************************************/
 199
 200 // Protected mode IDT descriptor
 201 //
 202 // I just make the limit 0, so the machine will shutdown
 203 // if an exception occurs during protected mode memory
 204 // transfers.
 205 //
 206 // Set base to f0000 to correspond to beginning of BIOS,
 207 // in case I actually define an IDT later
 208 // Set limit to 0
 209 pmode_IDT_info:
 210         .word 0x0000  // limit 15:00
 211         .long 0xf0000 // base 16:47
 212
 213 // Real mode IDT descriptor
 214 //
 215 // Set to typical real-mode values.
 216 // base  = 000000
 217 // limit =   03ff
 218 rmode_IDT_info:
 219         .word 0x03ff  // limit 15:00
 220         .long 0       // base 16:47
 221
 222 rombios32_gdt_48:
 223         .word 0x30
 224         .word rombios32_gdt
 225         .word 0x000f
 226
 227         .balign 8
 228 rombios32_gdt:
 229         .word 0, 0, 0, 0
 230         .word 0, 0, 0, 0
 231         // 32 bit flat code segment (PROTECTED_MODE_CS)
 232         .word 0xffff, 0, 0x9b00, 0x00cf
 233         // 32 bit flat data segment (PROTECTED_MODE_DS)
 234         .word 0xffff, 0, 0x9300, 0x00cf
 235         // 16 bit code segment base=0xf0000 limit=0xffff (REAL_MODE_CS)
 236         .word 0xffff, 0, 0x9b0f, 0x0000
 237         // 16 bit data segment base=0x0 limit=0xffff (REAL_MODE_DS)
 238         .word 0xffff, 0, 0x9300, 0x0000
 239
 240
 241 /****************************************************************
 242  * Interrupt entry points
 243  ****************************************************************/
 244
 245         .macro ENTRY cfunc
 246         pushal
 247         pushw %es
 248         pushw %ds
 249         movw %ss, %ax
 250         movw %ax, %ds
 251         movzwl %sp, %esp
 252         movl %esp, %eax
 253         calll \cfunc
 254         popw %ds
 255         popw %es
 256         popal
 257         .endm
 258
 259         .macro IRQ_ENTRY num
 260         .globl entry_\num
 261         entry_\num :
 262         cli         // In case something far-calls instead of using "int"
 263         ENTRY handle_\num
 264         iretw
 265         .endm
 266
 267         // APM trampolines
 268         .globl apm16protected_entry
 269 apm16protected_entry:
 270         ENTRY handle_1553
 271         lretw
 272
 273         .code32
 274         .globl apm32protected_entry
 275 apm32protected_entry:
 276         pushw %cs
 277         incw (%esp)
 278         pushw apm16protected_entry
 279         lcallw *(%esp)
 280         lretl
 281         .code16gcc
 282
 283         .org 0xe2c3
 284         IRQ_ENTRY nmi
 285
 286         IRQ_ENTRY 13
 287         IRQ_ENTRY 12
 288         IRQ_ENTRY 11
 289         IRQ_ENTRY 76
 290         IRQ_ENTRY 1c
 291         IRQ_ENTRY 70
 292         IRQ_ENTRY 74
 293         IRQ_ENTRY 75
 294
 295         .globl entry_19
 296 entry_19:
 297         RESET_STACK
 298         calll handle_19
 299
 300         .globl entry_18
 301 entry_18:
 302         RESET_STACK
 303         calll handle_18
 304
 305
 306         // IRQ trampolines
 307         .macro IRQ_TRAMPOLINE num
 308         .globl irq_trampoline_0x\num
 309         irq_trampoline_0x\num :
 310         int $0x\num
 311         lretw
 312         .endm
 313
 314         IRQ_TRAMPOLINE 02
 315         IRQ_TRAMPOLINE 10
 316         IRQ_TRAMPOLINE 13
 317         IRQ_TRAMPOLINE 15
 318         IRQ_TRAMPOLINE 18
 319         IRQ_TRAMPOLINE 19
 320         IRQ_TRAMPOLINE 1c
 321         IRQ_TRAMPOLINE 4a
 322
 323         .org 0xe3fe
 324         jmp entry_13
 325
 326         .org 0xe401
 327         // XXX - Fixed Disk Parameter Table
 328
 329         .org 0xe6f2
 330         jmp entry_19
 331
 332         .org 0xe6f5
 333 .include "out/cbt.proc.16.s"
 334         .text
 335
 336         .org 0xe729
 337         // XXX - Baud Rate Generator Table
 338
 339         .org 0xe739
 340         IRQ_ENTRY 14
 341
 342         .org 0xe82e
 343         IRQ_ENTRY 16
 344
 345         .org 0xe987
 346         IRQ_ENTRY 09
 347
 348         .org 0xec59
 349         IRQ_ENTRY 40
 350
 351         .org 0xef57
 352         IRQ_ENTRY 0e
 353
 354         .org 0xefc7
 355 .include "out/floppy_dbt.proc.16.s"
 356         .text
 357
 358         .org 0xefd2
 359         IRQ_ENTRY 17
 360
 361         .org 0xf045
 362         // XXX int 10
 363         iretw
 364
 365         .org 0xf065
 366         IRQ_ENTRY 10
 367
 368         .org 0xf0a4
 369         // XXX int 1D
 370         iretw
 371
 372         .globl freespace2_start, freespace2_end
 373 freespace2_start:
 374
 375         .org 0xf841
 376 freespace2_end:
 377         jmp entry_12
 378
 379         .org 0xf84d
 380         jmp entry_11
 381
 382         .org 0xf859
 383         IRQ_ENTRY 15
 384
 385         .org 0xfa6e
 386 .include "out/font.proc.16.s"
 387         .text
 388
 389         .org 0xfe6e
 390         IRQ_ENTRY 1a
 391
 392         .org 0xfea5
 393         IRQ_ENTRY 08
 394
 395         .org 0xfef3
 396         // XXX - Initial Interrupt Vector Offsets Loaded by POST
 397
 398         .org 0xff00
 399         // XXX - BIOS_COPYRIGHT_STRING
 400         .ascii "(c) 2002 MandrakeSoft S.A. Written by Kevin Lawton & the Bochs team."
 401
 402         .org 0xff53
 403         .globl dummy_iret_handler
 404 dummy_iret_handler:
 405         iretw
 406
 407         .org 0xff54
 408         IRQ_ENTRY 05
 409
 410         .org 0xfff0 // Power-up Entry Point
 411         ljmpw $0xf000, $post16
 412
 413         .org 0xfff5
 414         // BIOS build date
 415         .ascii "06/23/99"
 416
 417         .org 0xfffe
 418         .byte CONFIG_MODEL_ID
 419         .byte 0x00
 420
 421         .end