src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU GPLv3 license.
   7
   8 #include "config.h" // CONFIG_*
   9 #include "ioport.h" // PORT_A20
  10 #include "bregs.h" // CR0_*
  11 #include "cmos.h" // CMOS_RESET_CODE
  12 #include "../out/asm-offsets.h" // BREGS_*
  13
  14
  15 /****************************************************************
  16  * Include of 16bit C code
  17  ****************************************************************/
  18
  19         .code16gcc
  20 .include "out/ccode.16.s"
  21
  22
  23 /****************************************************************
  24  * Entry macros
  25  ****************************************************************/
  26
  27         // Call a C function - this does the minimal work necessary to
  28         // call into C.  It sets up %ds, backs up %es, and backs up
  29         // those registers that are call clobbered by the C compiler.
  30         .macro ENTRY cfunc
  31         cld
  32         pushl %eax              // Save registers clobbered by C code
  33         pushl %ecx
  34         pushl %edx
  35         pushw %es
  36         pushw %ds
  37         movw %ss, %ax           // Move %ss to %ds
  38         movw %ax, %ds
  39         pushl %esp              // Backup %esp, then clear high bits
  40         movzwl %sp, %esp
  41         calll \cfunc
  42         popl %esp               // Restore %esp (including high bits)
  43         popw %ds                // Restore registers saved above
  44         popw %es
  45         popl %edx
  46         popl %ecx
  47         popl %eax
  48         .endm
  49
  50         // Call a C function with current register list as an
  51         // argument.  This backs up the registers and sets %eax
  52         // to point to the backup.  On return, the registers are
  53         // restored from the structure.
  54         .macro ENTRY_ARG cfunc
  55         cld
  56         pushl %eax              // Save registers (matches struct bregs)
  57         pushl %ecx
  58         pushl %edx
  59         pushl %ebx
  60         pushl %esi
  61         pushl %edi
  62         pushw %es
  63         pushw %ds
  64         movw %ss, %ax           // Move %ss to %ds
  65         movw %ax, %ds
  66         movl %esp, %ebx         // Backup %esp, then zero high bits
  67         movzwl %sp, %esp
  68         movl %esp, %eax         // First arg is pointer to struct bregs
  69         calll \cfunc
  70         movl %ebx, %esp         // Restore %esp (including high bits)
  71         popw %ds                // Restore registers (from struct bregs)
  72         popw %es
  73         popl %edi
  74         popl %esi
  75         popl %ebx
  76         popl %edx
  77         popl %ecx
  78         popl %eax
  79         .endm
  80
  81         // As above, but don't mangle %esp
  82         .macro ENTRY_ARG_ESP cfunc
  83         cld
  84         pushl %eax              // Save registers (matches struct bregs)
  85         pushl %ecx
  86         pushl %edx
  87         pushl %ebx
  88         pushl %esi
  89         pushl %edi
  90         pushw %es
  91         pushw %ds
  92         movw %ss, %ax           // Move %ss to %ds
  93         movw %ax, %ds
  94         movl %esp, %eax         // First arg is pointer to struct bregs
  95         calll \cfunc
  96         popw %ds                // Restore registers (from struct bregs)
  97         popw %es
  98         popl %edi
  99         popl %esi
 100         popl %ebx
 101         popl %edx
 102         popl %ecx
 103         popl %eax
 104         .endm
 105
 106         // Macro to reset the 16bit stack
 107         // Clobbers %ax
 108         .macro RESET_STACK
 109         xorw %ax, %ax
 110         movw %ax, %ss
 111         movl $ BUILD_STACK_ADDR , %esp
 112         cld
 113         .endm
 114
 115         // Specify a location in the fixed part of bios area.
 116         .macro ORG addr
 117         .section .text.fixed.addr
 118         .org \addr - BUILD_START_FIXED
 119         .endm
 120
 121
 122 /****************************************************************
 123  * POST handler
 124  ****************************************************************/
 125
 126         ORG 0xe05b
 127 post16:
 128         // enable cache
 129         movl %cr0, %eax
 130         andl $~(CR0_CD|CR0_NW), %eax
 131         movl %eax, %cr0
 132
 133         // Check for restart indicator.
 134         movl $CMOS_RESET_CODE, %eax
 135         outb %al, $PORT_CMOS_INDEX
 136         inb $PORT_CMOS_DATA, %al
 137         cmpb $0x0, %al
 138         jnz entry_resume
 139
 140         // Normal entry point
 141         RESET_STACK
 142
 143         pushl $_code32__start
 144
 145         // Fall through to transition32 function below
 146
 147
 148 /****************************************************************
 149  * Call trampolines
 150  ****************************************************************/
 151
 152 // Place CPU into 32bit mode from 16bit mode.
 153 // Clobbers: %eax, flags, stack registers, cr0, idt/gdt
 154 transition32:
 155         // Disable irqs
 156         cli
 157
 158         // enable a20
 159         inb $PORT_A20, %al
 160         orb $A20_ENABLE_BIT, %al
 161         outb %al, $PORT_A20
 162
 163         // Set segment descriptors
 164         lidtw %cs:pmode_IDT_info
 165         lgdtw %cs:rombios32_gdt_48
 166
 167         // Enable protected mode
 168         movl %cr0, %eax
 169         orl $CR0_PE, %eax
 170         movl %eax, %cr0
 171
 172         // start 32bit protected mode code
 173         ljmpl $SEG32_MODE32_CS, $(BUILD_BIOS_ADDR + 1f)
 174
 175         .code32
 176 1:
 177         // init data segments
 178         movl $SEG32_MODE32_DS, %eax
 179         movw %ax, %ds
 180         movw %ax, %es
 181         movw %ax, %ss
 182         movw %ax, %fs
 183         movw %ax, %gs
 184
 185         retl
 186
 187 // Call a 16bit function from 32bit mode.
 188 // %eax = address of struct bregs
 189 // Clobbers: all gp registers, flags, stack registers, cr0, idt/gdt
 190         .global __call16_from32, __call16big_from32
 191 __call16_from32:
 192         pushl %eax
 193
 194         // restore data segment limits to 0xffff
 195         movl $SEG32_MODE16_DS, %eax
 196         movw %ax, %ds
 197         movw %ax, %es
 198         movw %ax, %ss
 199         movw %ax, %fs
 200         movw %ax, %gs
 201
 202         // disable a20
 203         inb $PORT_A20, %al
 204         andb $~A20_ENABLE_BIT, %al
 205         outb %al, $PORT_A20
 206
 207         // Jump to 16bit mode
 208         ljmpw $SEG32_MODE16_CS, $1f
 209
 210 __call16big_from32:
 211         pushl %eax
 212
 213         movl $SEG32_MODE16BIG_DS, %eax
 214         movw %ax, %ds
 215         movw %ax, %es
 216         movw %ax, %ss
 217         movw %ax, %fs
 218         movw %ax, %gs
 219
 220         ljmpl $SEG32_MODE16BIG_CS, $(BUILD_BIOS_ADDR + 1f)
 221
 222         .code16gcc
 223 1:
 224         // Disable protected mode
 225         movl %cr0, %eax
 226         andl $~CR0_PE, %eax
 227         movl %eax, %cr0
 228
 229         // far jump to flush CPU queue after transition to real mode
 230         ljmpw $SEG_BIOS, $2f
 231
 232 2:
 233         // restore IDT to normal real-mode defaults
 234         lidtw %cs:rmode_IDT_info
 235
 236         // Clear segment registers
 237         xorw %ax, %ax
 238         movw %ax, %fs
 239         movw %ax, %gs
 240         movw %ax, %es
 241         movw %ax, %ds
 242         movw %ax, %ss  // Assume stack is in segment 0
 243
 244         popl %eax
 245
 246         // Set __call16 return address to be transition32
 247         pushl $transition32
 248
 249         // Fall through to __call16
 250
 251
 252 // Call a 16bit function from 16bit mode with a specified cpu register state
 253 // %eax = address of struct bregs
 254 // Clobbers: all gp registers, es
 255         .global __call16
 256 __call16:
 257         // Save eax
 258         pushl %eax
 259
 260         // Setup for iretw call
 261         pushw $SEG_BIOS
 262         pushw $1f               // return point
 263         pushw BREGS_flags(%eax) // flags
 264         pushl BREGS_ip(%eax)    // CS:IP
 265
 266         // Load calling registers.
 267         movl BREGS_edi(%eax), %edi
 268         movl BREGS_esi(%eax), %esi
 269         movl BREGS_ebx(%eax), %ebx
 270         movl BREGS_edx(%eax), %edx
 271         movl BREGS_ecx(%eax), %ecx
 272         movw BREGS_es(%eax), %es
 273         movw BREGS_ds(%eax), %ds
 274         movl %ss:BREGS_eax(%eax), %eax
 275
 276         // Invoke call
 277         iretw                   // XXX - just do a lcalll
 278 1:
 279         // Store flags, eax, ecx
 280         pushfw
 281         pushl %eax
 282         movl 0x06(%esp), %eax
 283         movl %ecx, %ss:BREGS_ecx(%eax)
 284         movw %ds, %ss:BREGS_ds(%eax)
 285         movw %ss, %cx
 286         movw %cx, %ds           // Restore %ds == %ss
 287         popl %ecx
 288         movl %ecx, BREGS_eax(%eax)
 289         popw %cx
 290         movw %cx, BREGS_flags(%eax)
 291
 292         // Store remaining registers
 293         movw %es, BREGS_es(%eax)
 294         movl %edi, BREGS_edi(%eax)
 295         movl %esi, BREGS_esi(%eax)
 296         movl %ebx, BREGS_ebx(%eax)
 297         movl %edx, BREGS_edx(%eax)
 298
 299         // Remove %eax
 300         popl %eax
 301
 302         cld
 303
 304         retl
 305
 306 // Entry point when a post call looks like a resume.
 307 entry_resume:
 308         // Save old shutdown status.
 309         movl %eax, %ebx
 310
 311         // Clear shutdown status register.
 312         movl $CMOS_RESET_CODE, %eax
 313         outb %al, $PORT_CMOS_INDEX
 314         xorl %eax, %eax
 315         outb %al, $PORT_CMOS_DATA
 316
 317         // Use a stack in EBDA
 318         movw $SEG_BDA, %ax
 319         movw %ax, %ds
 320         movw BDA_ebda_seg, %ss
 321         movl $EBDA_resume_stack_top, %esp
 322
 323         // Call handler.
 324         movl %ebx, %eax
 325         cld
 326         cli
 327         jmp handle_resume
 328
 329 // APM trampolines
 330         .global apm16protected_entry
 331 apm16protected_entry:
 332         pushfw          // save flags
 333         pushl %eax      // dummy
 334         ENTRY_ARG handle_1553
 335         addw $4, %sp    // pop dummy
 336         popfw           // restore flags
 337         lretw
 338
 339         .code32
 340         .global apm32protected_entry
 341 apm32protected_entry:
 342         pushfw
 343         pushw %cs       // Setup for long jump to 16bit mode
 344         pushw $1f
 345         addw $8, 2(%esp)
 346         ljmpw *(%esp)
 347         .code16gcc
 348 1:
 349         ENTRY_ARG_ESP handle_1553
 350
 351         movw $2f,(%esp) // Setup for long jump back to 32bit mode
 352         subw $8, 2(%esp)
 353         ljmpw *(%esp)
 354         .code32
 355 2:
 356         addl $4, %esp   // pop call address
 357         popfw
 358         lretl
 359
 360 // 32bit elf entry point
 361         .global post32
 362 post32:
 363         cli
 364         cld
 365         lidtl (BUILD_BIOS_ADDR + pmode_IDT_info)
 366         lgdtl (BUILD_BIOS_ADDR + rombios32_gdt_48)
 367         movl $BUILD_STACK_ADDR, %esp
 368         ljmpl $SEG32_MODE32_CS, $_code32__start
 369
 370         .code16gcc
 371
 372 // Shutdown a CPU.  We want this in the 0xf000 section to ensure that
 373 // the code wont be overwritten with something else.  (Should
 374 // something spurious wake up the CPU, we want to be sure that the hlt
 375 // insn will still be present and will shutdown the CPU.)
 376         .global permanent_halt
 377 permanent_halt:
 378         cli
 379 1:      hlt
 380         jmp 1b
 381
 382
 383 /****************************************************************
 384  * GDT and IDT tables
 385  ****************************************************************/
 386
 387 // Protected mode IDT descriptor
 388 //
 389 // I just make the limit 0, so the machine will shutdown
 390 // if an exception occurs during protected mode memory
 391 // transfers.
 392 //
 393 // Set base to f0000 to correspond to beginning of BIOS,
 394 // in case I actually define an IDT later
 395 // Set limit to 0
 396 pmode_IDT_info:
 397         .word 0x0000  // limit 15:00
 398         .long 0xf0000 // base 16:47
 399
 400 // Real mode IDT descriptor
 401 //
 402 // Set to typical real-mode values.
 403 // base  = 000000
 404 // limit =   03ff
 405 rmode_IDT_info:
 406         .word 0x03ff  // limit 15:00
 407         .long 0       // base 16:47
 408
 409 rombios32_gdt_48:
 410         .word (rombios32_gdt_end - rombios32_gdt)
 411         .long (BUILD_BIOS_ADDR + rombios32_gdt)
 412
 413         .balign 8
 414 rombios32_gdt:
 415         .word 0, 0, 0, 0
 416         .word 0, 0, 0, 0
 417         // 32 bit flat code segment (SEG32_MODE32_CS)
 418         .word 0xffff, 0, 0x9b00, 0x00cf
 419         // 32 bit flat data segment (SEG32_MODE32_DS)
 420         .word 0xffff, 0, 0x9300, 0x00cf
 421         // 16 bit code segment base=0xf0000 limit=0xffff (SEG32_MODE16_CS)
 422         .word 0xffff, 0, 0x9b0f, 0x0000
 423         // 16 bit data segment base=0x0 limit=0xffff (SEG32_MODE16_DS)
 424         .word 0xffff, 0, 0x9300, 0x0000
 425         // 16 bit code segment base=0 limit=0xffffffff (SEG32_MODE16BIG_CS)
 426         .word 0xffff, 0, 0x9b00, 0x008f
 427         // 16 bit data segment base=0 limit=0xffffffff (SEG32_MODE16BIG_DS)
 428         .word 0xffff, 0, 0x9300, 0x008f
 429 rombios32_gdt_end:
 430
 431 // We need a copy of this string in the 0xf000 segment, but we are not
 432 // actually a PnP BIOS, so make sure it is *not* aligned, so OSes will
 433 // not see it if they scan.
 434         .global pnp_string
 435         .balign 2
 436         .byte 0
 437 pnp_string:
 438         .ascii "$PnP"
 439
 440
 441 /****************************************************************
 442  * Interrupt entry points
 443  ****************************************************************/
 444
 445         // Define an entry point for an interrupt (no args passed).
 446         .macro IRQ_ENTRY num
 447         .global entry_\num
 448         entry_\num :
 449         cli         // In case something far-calls instead of using "int"
 450         ENTRY handle_\num
 451         iretw
 452         .endm
 453
 454         // Define an entry point for an interrupt (can read/modify args).
 455         .macro IRQ_ENTRY_ARG num
 456         .global entry_\num
 457         entry_\num :
 458         cli         // In case something far-calls instead of using "int"
 459         ENTRY_ARG handle_\num
 460         iretw
 461         .endm
 462
 463         ORG 0xe2c3
 464         IRQ_ENTRY nmi
 465
 466         IRQ_ENTRY_ARG 13
 467         IRQ_ENTRY_ARG 12
 468         IRQ_ENTRY_ARG 11
 469         IRQ_ENTRY 76
 470         IRQ_ENTRY 1c
 471         IRQ_ENTRY 70
 472
 473         ORG 0xe3fe
 474         jmp entry_13
 475
 476         ORG 0xe401
 477         // XXX - Fixed Disk Parameter Table
 478
 479         ORG 0xe6f2
 480         jmp entry_19
 481
 482         ORG 0xe6f5
 483 .include "out/cbt.proc.16.s"
 484         .text
 485
 486         ORG 0xe729
 487         // XXX - Baud Rate Generator Table
 488
 489         ORG 0xe739
 490         IRQ_ENTRY_ARG 14
 491
 492         IRQ_ENTRY 74
 493         IRQ_ENTRY 75
 494
 495         // int 18/19 are special - they reset the stack and do not return.
 496         .global entry_19
 497 entry_19:
 498         RESET_STACK
 499         pushl $_code32_handle_19
 500         jmp transition32
 501
 502         .global entry_18
 503 entry_18:
 504         RESET_STACK
 505         pushl $_code32_handle_18
 506         jmp transition32
 507
 508         // IRQ trampolines
 509         .macro IRQ_TRAMPOLINE num
 510         .global irq_trampoline_0x\num
 511         irq_trampoline_0x\num :
 512         int $0x\num
 513         lretw
 514         .endm
 515
 516         IRQ_TRAMPOLINE 02
 517         IRQ_TRAMPOLINE 10
 518         IRQ_TRAMPOLINE 13
 519         IRQ_TRAMPOLINE 15
 520         IRQ_TRAMPOLINE 16
 521         IRQ_TRAMPOLINE 18
 522         IRQ_TRAMPOLINE 19
 523         IRQ_TRAMPOLINE 1c
 524         IRQ_TRAMPOLINE 4a
 525
 526         ORG 0xe82e
 527         IRQ_ENTRY_ARG 16
 528
 529         .global entry_hwirq
 530 entry_hwirq:
 531         ENTRY handle_hwirq
 532
 533         ORG 0xe987
 534         IRQ_ENTRY 09
 535
 536         ORG 0xec59
 537         IRQ_ENTRY_ARG 40
 538
 539         ORG 0xef57
 540         IRQ_ENTRY 0e
 541
 542         ORG 0xefc7
 543 .include "out/floppy_dbt.proc.16.s"
 544         .text
 545
 546         ORG 0xefd2
 547         IRQ_ENTRY_ARG 17
 548
 549         ORG 0xf045
 550         // XXX int 10
 551         iretw
 552
 553         ORG 0xf065
 554         IRQ_ENTRY_ARG 10
 555
 556         ORG 0xf0a4
 557         // XXX int 1D
 558         iretw
 559
 560         .global freespace2_start, freespace2_end
 561 freespace2_start:
 562
 563         ORG 0xf841
 564 freespace2_end:
 565         jmp entry_12
 566
 567         ORG 0xf84d
 568         jmp entry_11
 569
 570         ORG 0xf859
 571         IRQ_ENTRY_ARG 15
 572
 573         ORG 0xfa6e
 574 .include "out/font.proc.16.s"
 575         .text
 576
 577         ORG 0xfe6e
 578         IRQ_ENTRY_ARG 1a
 579
 580         ORG 0xfea5
 581         IRQ_ENTRY 08
 582
 583         ORG 0xfef3
 584         // XXX - Initial Interrupt Vector Offsets Loaded by POST
 585
 586         ORG 0xff00
 587         // XXX - BIOS_COPYRIGHT_STRING
 588         .ascii "(c) 2002 MandrakeSoft S.A. Written by Kevin Lawton & the Bochs team."
 589
 590         ORG 0xff53
 591         .global dummy_iret_handler
 592 dummy_iret_handler:
 593         iretw
 594
 595         ORG 0xff54
 596         IRQ_ENTRY_ARG 05
 597
 598         ORG 0xfff0 // Power-up Entry Point
 599         .global reset_vector
 600 reset_vector:
 601         ljmpw $SEG_BIOS, $post16
 602
 603         ORG 0xfff5
 604         // BIOS build date
 605         .ascii "06/23/99"
 606
 607         ORG 0xfffe
 608         .byte CONFIG_MODEL_ID
 609
 610         .global bios_checksum
 611 bios_checksum:
 612         .byte 0x00
 613
 614         .end