src/romlayout.S

   1 // Rom layout and bios assembler to C interface.
   2 //
   3 // Copyright (C) 2008,2009  Kevin O'Connor <kevin@koconnor.net>
   4 // Copyright (C) 2002  MandrakeSoft S.A.
   5 //
   6 // This file may be distributed under the terms of the GNU LGPLv3 license.
   7
   8
   9 /****************************************************************
  10  * Include of 16bit C code
  11  ****************************************************************/
  12
  13         .code16gcc
  14 .include "out/ccode.16.s"
  15
  16 #include "config.h" // CONFIG_*
  17 #include "ioport.h" // PORT_A20
  18 #include "bregs.h" // CR0_*
  19 #include "cmos.h" // CMOS_RESET_CODE
  20 #include "../out/asm-offsets.h" // BREGS_*
  21 #include "entryfuncs.S" // ENTRY_*
  22
  23
  24 /****************************************************************
  25  * Call trampolines
  26  ****************************************************************/
  27
  28 // Place CPU into 32bit mode from 16bit mode.
  29 // Clobbers: flags, segment registers, cr0, idt/gdt
  30         DECLFUNC transition32
  31 transition32:
  32         pushl %eax
  33
  34         // Disable irqs (and clear direction flag)
  35         cli
  36         cld
  37
  38         // Disable nmi
  39         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
  40         outb %al, $PORT_CMOS_INDEX
  41         inb $PORT_CMOS_DATA, %al
  42
  43         // enable a20
  44         inb $PORT_A20, %al
  45         orb $A20_ENABLE_BIT, %al
  46         outb %al, $PORT_A20
  47
  48         // Set segment descriptors
  49         lidtw %cs:pmode_IDT_info
  50         lgdtw %cs:rombios32_gdt_48
  51
  52         // Enable protected mode
  53         movl %cr0, %eax
  54         orl $CR0_PE, %eax
  55         movl %eax, %cr0
  56
  57         // start 32bit protected mode code
  58         ljmpl $SEG32_MODE32_CS, $(BUILD_BIOS_ADDR + 1f)
  59
  60         .code32
  61 1:
  62         // init data segments
  63         movl $SEG32_MODE32_DS, %eax
  64         movw %ax, %ds
  65         movw %ax, %es
  66         movw %ax, %ss
  67         movw %ax, %fs
  68         movw %ax, %gs
  69
  70         popl %eax
  71         retl
  72
  73 // Call a 16bit function from 32bit mode.
  74 // %eax = address of struct bregs
  75 // Clobbers: %e[bcd]x, %e[ds]i, flags, segment registers, idt/gdt
  76         DECLFUNC __call16_from32
  77         .global __call16big_from32
  78 __call16_from32:
  79         pushl %eax
  80
  81         // restore data segment limits to 0xffff
  82         movl $SEG32_MODE16_DS, %eax
  83         movw %ax, %ds
  84         movw %ax, %es
  85         movw %ax, %ss
  86         movw %ax, %fs
  87         movw %ax, %gs
  88
  89 #if CONFIG_DISABLE_A20
  90         // disable a20
  91         inb $PORT_A20, %al
  92         andb $~A20_ENABLE_BIT, %al
  93         outb %al, $PORT_A20
  94 #endif
  95
  96         // Jump to 16bit mode
  97         ljmpw $SEG32_MODE16_CS, $1f
  98
  99 __call16big_from32:
 100         pushl %eax
 101
 102         movl $SEG32_MODE16BIG_DS, %eax
 103         movw %ax, %ds
 104         movw %ax, %es
 105         movw %ax, %ss
 106         movw %ax, %fs
 107         movw %ax, %gs
 108
 109         ljmpl $SEG32_MODE16BIG_CS, $(BUILD_BIOS_ADDR + 1f)
 110
 111         .code16gcc
 112 1:
 113         // Disable protected mode
 114         movl %cr0, %eax
 115         andl $~CR0_PE, %eax
 116         movl %eax, %cr0
 117
 118         // far jump to flush CPU queue after transition to real mode
 119         ljmpw $SEG_BIOS, $2f
 120
 121 2:
 122         // restore IDT to normal real-mode defaults
 123         lidtw %cs:rmode_IDT_info
 124
 125         // Clear segment registers
 126         xorw %ax, %ax
 127         movw %ax, %fs
 128         movw %ax, %gs
 129         movw %ax, %es
 130         movw %ax, %ds
 131         movw %ax, %ss  // Assume stack is in segment 0
 132
 133         popl %eax
 134
 135         // Make call.
 136         calll __call16
 137
 138         // Return via transition32
 139         jmp transition32
 140
 141
 142 // Call a 16bit function from 16bit mode with a specified cpu register state
 143 // %eax = address of struct bregs
 144 // Clobbers: %e[bcd]x, %e[ds]i, flags
 145         DECLFUNC __call16
 146 __call16:
 147         // Save %eax, %ebp
 148         pushl %ebp
 149         pushl %eax
 150
 151         // Setup for iretw call
 152         pushw %cs
 153         pushw $1f               // return point
 154         pushw BREGS_flags(%eax) // flags
 155         pushl BREGS_ip(%eax)    // CS:IP
 156
 157         // Load calling registers.
 158         movl BREGS_edi(%eax), %edi
 159         movl BREGS_esi(%eax), %esi
 160         movl BREGS_ebp(%eax), %ebp
 161         movl BREGS_ebx(%eax), %ebx
 162         movl BREGS_edx(%eax), %edx
 163         movl BREGS_ecx(%eax), %ecx
 164         movw BREGS_es(%eax), %es
 165         movw BREGS_ds(%eax), %ds
 166         movl %ss:BREGS_eax(%eax), %eax
 167
 168         // Invoke call
 169         iretw                   // XXX - just do a lcalll
 170 1:
 171         // Store flags, eax, ecx
 172         pushfw
 173         pushl %eax
 174         movl 0x06(%esp), %eax
 175         movl %ecx, %ss:BREGS_ecx(%eax)
 176         movw %ds, %ss:BREGS_ds(%eax)
 177         movw %ss, %cx
 178         movw %cx, %ds           // Restore %ds == %ss
 179         popl %ecx
 180         movl %ecx, BREGS_eax(%eax)
 181         popw %cx
 182         movw %cx, BREGS_flags(%eax)
 183
 184         // Store remaining registers
 185         movw %es, BREGS_es(%eax)
 186         movl %edi, BREGS_edi(%eax)
 187         movl %esi, BREGS_esi(%eax)
 188         movl %ebp, BREGS_ebp(%eax)
 189         movl %ebx, BREGS_ebx(%eax)
 190         movl %edx, BREGS_edx(%eax)
 191
 192         // Remove %eax, restore %ebp
 193         popl %eax
 194         popl %ebp
 195
 196         retl
 197
 198 // IRQ trampolines
 199         .macro IRQ_TRAMPOLINE num
 200         DECLFUNC irq_trampoline_0x\num
 201         irq_trampoline_0x\num :
 202         int $0x\num
 203         lretw
 204         .endm
 205
 206         IRQ_TRAMPOLINE 10
 207         IRQ_TRAMPOLINE 13
 208         IRQ_TRAMPOLINE 15
 209         IRQ_TRAMPOLINE 16
 210         IRQ_TRAMPOLINE 18
 211         IRQ_TRAMPOLINE 19
 212
 213
 214 /****************************************************************
 215  * POST entry point
 216  ****************************************************************/
 217
 218         DECLFUNC entry_post
 219 entry_post:
 220         // Enable cache
 221         movl %cr0, %eax
 222         andl $~(CR0_CD|CR0_NW), %eax
 223         movl %eax, %cr0
 224
 225         // Disable interrupts
 226         cli
 227         cld
 228
 229         // Check for restart indicator.
 230         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
 231         outb %al, $PORT_CMOS_INDEX
 232         inb $PORT_CMOS_DATA, %al
 233         cmpb $0x0, %al
 234         jnz 1f
 235
 236         // Normal entry point
 237         ENTRY_INTO32 _start
 238
 239         // Entry point when a post call looks like a resume.
 240 1:
 241         // Save old shutdown status.
 242         movl %eax, %ebx
 243
 244         // Clear shutdown status register.
 245         movl $CMOS_RESET_CODE|NMI_DISABLE_BIT, %eax
 246         outb %al, $PORT_CMOS_INDEX
 247         xorl %eax, %eax
 248         outb %al, $PORT_CMOS_DATA
 249
 250         // Use a stack in EBDA
 251         movw $SEG_BDA, %ax
 252         movw %ax, %ds
 253         movw BDA_ebda_seg, %ax
 254
 255         cmpw $EBDA_SEGMENT_START, %ax
 256         jle 2f
 257         // EBDA segment doesn't look valid - use startup value.
 258         movw $EBDA_SEGMENT_START, %ax
 259
 260 2:      movw %ax, %ds
 261         movw %ax, %ss
 262         movl $EBDA_OFFSET_TOP_STACK, %esp
 263
 264         // Call handler.
 265         movl %ebx, %eax
 266         jmp handle_resume
 267
 268
 269 /****************************************************************
 270  * Misc. entry points.
 271  ****************************************************************/
 272
 273 // PnP entry points
 274         DECLFUNC entry_pnp_real
 275         .global entry_pnp_prot
 276 entry_pnp_prot:
 277         pushl %esp
 278         jmp 1f
 279 entry_pnp_real:
 280         pushl %esp              // Backup %esp, then clear high bits
 281         movzwl %sp, %esp
 282 1:
 283         pushfl                  // Save registers clobbered by C code
 284         pushl %eax
 285         pushl %ecx
 286         pushl %edx
 287         pushw %es
 288         pushw %ds
 289         movw %ss, %cx           // Move %ss to %ds
 290         movw %cx, %ds
 291         lea 28(%esp), %eax      // %eax points to start of u16 args
 292         calll handle_pnp
 293         movw %ax, 12(%esp)      // Modify %eax to return %ax
 294         popw %ds
 295         popw %es
 296         popl %edx
 297         popl %ecx
 298         popl %eax
 299         popfl
 300         popl %esp
 301         lretw
 302
 303 // APM entry points
 304         DECLFUNC apm16protected_entry
 305 apm16protected_entry:
 306         pushfw          // save flags
 307         pushl %eax      // dummy
 308         ENTRY_ARG handle_1553
 309         addw $4, %sp    // pop dummy
 310         popfw           // restore flags
 311         lretw
 312
 313         .code32
 314         DECLFUNC apm32protected_entry
 315 apm32protected_entry:
 316         pushfw
 317         pushw %cs       // Setup for long jump to 16bit mode
 318         pushw $1f
 319         addw $8, 2(%esp)
 320         ljmpw *(%esp)
 321         .code16gcc
 322 1:
 323         ENTRY_ARG_ESP handle_1553
 324
 325         movw $2f,(%esp) // Setup for long jump back to 32bit mode
 326         subw $8, 2(%esp)
 327         ljmpw *(%esp)
 328         .code32
 329 2:
 330         addl $4, %esp   // pop call address
 331         popfw
 332         lretl
 333
 334 // 32bit elf entry point
 335         DECLFUNC post32
 336 post32:
 337         cli
 338         cld
 339         lidtl (BUILD_BIOS_ADDR + pmode_IDT_info)
 340         lgdtl (BUILD_BIOS_ADDR + rombios32_gdt_48)
 341         movl $SEG32_MODE32_DS, %eax
 342         movw %ax, %ds
 343         movw %ax, %es
 344         movw %ax, %fs
 345         movw %ax, %gs
 346         movw %ax, %ss
 347         movl $BUILD_STACK_ADDR, %esp
 348         ljmpl $SEG32_MODE32_CS, $_start
 349
 350         .code16gcc
 351
 352
 353 /****************************************************************
 354  * Interrupt entry points
 355  ****************************************************************/
 356
 357         // Define an entry point for an interrupt (no args passed).
 358         .macro IRQ_ENTRY num
 359         .global entry_\num
 360         entry_\num :
 361         pushl $ handle_\num
 362         jmp irqentry
 363         .endm
 364
 365         // Define an entry point for an interrupt (can read/modify args).
 366         .macro IRQ_ENTRY_ARG num
 367         .global entry_\num
 368         entry_\num :
 369         pushl $ handle_\num
 370         jmp irqentryarg
 371         .endm
 372
 373         // Macros that put each handler into its own section
 374         .macro DECL_IRQ_ENTRY num
 375         DECLFUNC entry_\num
 376         IRQ_ENTRY \num
 377         .endm
 378         .macro DECL_IRQ_ENTRY_ARG num
 379         DECLFUNC entry_\num
 380         IRQ_ENTRY_ARG \num
 381         .endm
 382
 383         // Main entry point for interrupts without args
 384         DECLFUNC irqentry
 385 irqentry:
 386         ENTRY_ST
 387         iretw
 388
 389         // Main entry point for interrupts with args
 390         DECLFUNC irqentry
 391 irqentryarg:
 392         ENTRY_ARG_ST
 393         iretw
 394
 395         DECL_IRQ_ENTRY_ARG 13
 396         DECL_IRQ_ENTRY 76
 397         DECL_IRQ_ENTRY 70
 398         DECL_IRQ_ENTRY 74
 399         DECL_IRQ_ENTRY 75
 400         DECL_IRQ_ENTRY hwpic1
 401         DECL_IRQ_ENTRY hwpic2
 402
 403         // int 18/19 are special - they reset stack and call into 32bit mode.
 404         DECLFUNC entry_19
 405 entry_19:
 406         ENTRY_INTO32 handle_19
 407
 408         DECLFUNC entry_18
 409 entry_18:
 410         ENTRY_INTO32 handle_18
 411
 412
 413 /****************************************************************
 414  * Fixed position entry points
 415  ****************************************************************/
 416
 417         // Specify a location in the fixed part of bios area.
 418         .macro ORG addr
 419         .section .fixedaddr.\addr
 420         .endm
 421
 422         ORG 0xe05b
 423 entry_post_official:
 424         jmp entry_post
 425
 426         ORG 0xe2c3
 427         IRQ_ENTRY 02
 428
 429         ORG 0xe3fe
 430         .global entry_13_official
 431 entry_13_official:
 432         jmp entry_13
 433
 434         // 0xe401 - OldFDPT in disk.c
 435
 436         ORG 0xe6f2
 437         .global entry_19_official
 438 entry_19_official:
 439         jmp entry_19
 440
 441         // 0xe6f5 - BIOS_CONFIG_TABLE in misc.c
 442
 443         // 0xe729 - BaudTable in serial.c
 444
 445         ORG 0xe739
 446         IRQ_ENTRY_ARG 14
 447
 448         ORG 0xe82e
 449         IRQ_ENTRY_ARG 16
 450
 451         ORG 0xe987
 452         IRQ_ENTRY 09
 453
 454         ORG 0xec59
 455         IRQ_ENTRY_ARG 40
 456
 457         ORG 0xef57
 458         IRQ_ENTRY 0e
 459
 460         // 0xefc7 - diskette_param_table in floppy.c
 461
 462         ORG 0xefd2
 463         IRQ_ENTRY_ARG 17
 464
 465         ORG 0xf045
 466 entry_10_0x0f:
 467         // XXX - INT 10 Functions 0-Fh Entry Point
 468         iretw
 469
 470         ORG 0xf065
 471         IRQ_ENTRY_ARG 10
 472
 473         // 0xf0a4 - VideoParams in misc.c
 474
 475         ORG 0xf841
 476         IRQ_ENTRY_ARG 12
 477
 478         ORG 0xf84d
 479         IRQ_ENTRY_ARG 11
 480
 481         ORG 0xf859
 482         IRQ_ENTRY_ARG 15
 483
 484         // 0xfa6e - vgafont8 in font.c
 485
 486         ORG 0xfe6e
 487         IRQ_ENTRY_ARG 1a
 488
 489         ORG 0xfea5
 490         IRQ_ENTRY 08
 491
 492         // 0xfef3 - InitVectors in misc.c
 493
 494         // 0xff00 - BiosCopyright in misc.c
 495
 496         ORG 0xff53
 497         .global entry_iret_official
 498 entry_iret_official:
 499         iretw
 500
 501         ORG 0xff54
 502         IRQ_ENTRY_ARG 05
 503
 504         ORG 0xfff0 // Power-up Entry Point
 505         .global reset_vector
 506 reset_vector:
 507         ljmpw $SEG_BIOS, $entry_post_official
 508
 509         // 0xfff5 - BiosDate in misc.c
 510
 511         // 0xfffe - BiosModelId in misc.c
 512
 513         // 0xffff - BiosChecksum in misc.c
 514
 515         .end