src/rombios16.lds.S

   1 // Linker definitions for 16bit code
   2 //
   3 // Copyright (C) 2008  Kevin O'Connor <kevin@koconnor.net>
   4 //
   5 // This file may be distributed under the terms of the GNU LGPLv3 license.
   6
   7 #include "config.h"
   8
   9 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  10 OUTPUT_ARCH("i386")
  11 SECTIONS
  12 {
  13         . = ( _code32_code32_end - BUILD_BIOS_ADDR ) ;
  14         code16_start = . ;
  15         .text16 : {
  16                 *(.text)
  17                 code16_rodata = . ;
  18                 *(.rodata*)
  19                 *(.data.var16)
  20                 }
  21         freespace1_start = . ;
  22         code16_end = . ;
  23
  24         . = BUILD_START_FIXED ;
  25         code16_fixed_start = . ;
  26         freespace1_end = . ;
  27         .text16.fixed.addr : {
  28                 *(.text.fixed.addr)
  29                 }
  30         code16_fixed_end = . ;
  31
  32         // Discard regular data sections to force a link error if
  33         // 16bit code attempts to access data not marked with VAR16.
  34         /DISCARD/ : { *(.data) *(.bss) *(COMMON) }
  35 }