eglib/configure.ac

   1 #
   2 # Copyright 2012 Xamarin Inc
   3 #
   4 AC_INIT(eglib, [0.3],
   5         [http://bugzilla.xamarin.com/enter_bug.cgi?classification=Mono])
   6
   7 AC_CONFIG_SRCDIR([README])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_SYSTEM
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.9 dist-bzip2 tar-ustar no-dist-gzip foreign])
  13 AC_CONFIG_HEADERS([config.h])
  14 AM_MAINTAINER_MODE
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_PROG_CC
  19 AM_PROG_LIBTOOL
  20 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
  21 DOLT
  22 GNUC_PRETTY=
  23 GNUC_UNUSED=
  24 BREAKPOINT="G_STMT_START { raise (SIGTRAP); } G_STMT_END"
  25 if test x$GCC = xyes; then
  26    GNUC_UNUSED='__attribute__((__unused__))'
  27    GNUC_NORETURN='__attribute__((__noreturn__))'
  28    case $host_cpu in
  29      i*86|x86_64) BREAKPOINT="G_STMT_START { __asm__ (\"int \$03\"); } G_STMT_END" ;;
  30    esac
  31 fi
  32 AC_SUBST(GNUC_PRETTY)
  33 AC_SUBST(GNUC_UNUSED)
  34 AC_SUBST(GNUC_NORETURN)
  35 AC_SUBST(BREAKPOINT)
  36
  37 # We use a separate variable to pass down CPPFLAGS and CFLAGS from the main mono
  38 # configure, because of autoconf brokeness
  39 if test "x$CPPFLAGS_FOR_EGLIB" != "x"; then
  40    CPPFLAGS=$CPPFLAGS_FOR_EGLIB
  41 fi
  42 if test "x$CFLAGS_FOR_EGLIB" != "x"; then
  43    CFLAGS=$CFLAGS_FOR_EGLIB
  44 fi
  45
  46 CFLAGS="$CFLAGS -g -D_GNU_SOURCE"
  47
  48 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
  49 AC_C_BIGENDIAN([ORDER=G_BIG_ENDIAN],[ORDER=G_LITTLE_ENDIAN])
  50
  51 platform_darwin=no
  52 platform_android=no
  53
  54 case $host in
  55 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  56     PATHSEP='\\'
  57     SEARCHSEP=';'
  58     OS="WIN32"
  59     PIDTYPE='void *'
  60     ;;
  61 *-*darwin*)
  62     platform_darwin=yes
  63     PATHSEP='/'
  64     SEARCHSEP=':'
  65     OS="UNIX"
  66     PIDTYPE='int'
  67     ;;
  68 *-*-linux-android*)
  69     platform_android=yes
  70         AC_DEFINE(PLATFORM_ANDROID,1,[Targeting the Android platform])
  71     PATHSEP='/'
  72     SEARCHSEP=':'
  73     OS="UNIX"
  74     PIDTYPE='int'
  75     ;;
  76 *)
  77     PATHSEP='/'
  78     SEARCHSEP=':'
  79     OS="UNIX"
  80     PIDTYPE='int'
  81     ;;
  82 esac
  83
  84 case $host in
  85         *-*-solaris*)
  86         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  87         ;;
  88 esac
  89
  90 case $target in
  91 arm*-darwin*|aarch64*-*)
  92     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE"
  93     ;;
  94 i*86-*-darwin*)
  95     ORDER=G_LITTLE_ENDIAN
  96     ;;
  97 *-*-openbsd*)
  98     CFLAGS="$CFLAGS -pthread"
  99     LDFLAGS="$LDFLAGS -pthread"
 100     ;;
 101 esac
 102
 103 target_osx=no
 104 target_ios=no
 105
 106 if test "x$platform_darwin" = "xyes"; then
 107         AC_TRY_COMPILE([#include "TargetConditionals.h"],[
 108         #if TARGET_IPHONE_SIMULATOR == 1 || TARGET_OS_IPHONE == 1
 109         #error fail this for ios
 110         #endif
 111         return 0;
 112         ], [
 113                 AC_DEFINE(TARGET_OSX,1,[The JIT/AOT targets OSX])
 114                 target_osx=yes
 115         ], [
 116                 AC_DEFINE(TARGET_IOS,1,[The JIT/AOT targets iOS])
 117                 target_ios=yes
 118         ])
 119    AC_DEFINE(TARGET_MACH,1,[The JIT/AOT targets Apple platforms])
 120 fi
 121
 122 AC_SUBST(ORDER)
 123 AC_SUBST(CFLAGS)
 124 AC_SUBST(PATHSEP)
 125 AC_SUBST(SEARCHSEP)
 126 AC_SUBST(OS)
 127 AC_SUBST(PIDTYPE)
 128 AM_CONDITIONAL(HOST_WIN32, test x$OS = xWIN32)
 129 AM_CONDITIONAL(TARGET_WIN32, test x$OS = xWIN32)
 130 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
 131 AM_CONDITIONAL(PLATFORM_ANDROID, test x$platform_android = xyes)
 132
 133 AC_CHECK_SIZEOF(int)
 134 AC_CHECK_SIZEOF(void *)
 135 AC_CHECK_SIZEOF(long)
 136 AC_CHECK_SIZEOF(long long)
 137 AC_CHECK_FUNCS(strlcpy stpcpy strtok_r rewinddir vasprintf)
 138
 139 #
 140 # Mono currently supports 10.6, but strndup is not available prior to 10.7; avoiding
 141 # the detection of strndup on OS X so Mono built on 10.7+ still runs on 10.6. This can be
 142 # removed once support for 10.6 is dropped.
 143 #
 144 # iOS detection of strndup and getpwuid_r is faulty for some reason so let's simply avoid it
 145 #
 146 if test x$target_osx = xyes; then
 147 AC_CHECK_FUNCS(getpwuid_r)
 148 elif test x$target_ios = xno; then
 149 AC_CHECK_FUNCS(strndup getpwuid_r)
 150 fi
 151
 152 AM_CONDITIONAL(NEED_VASPRINTF, test x$have_vasprintf = x )
 153 AM_ICONV()
 154 AC_SEARCH_LIBS(sqrtf, m)
 155
 156 # nanosleep may not be part of libc, also search it in other libraries
 157 AC_SEARCH_LIBS(nanosleep, rt)
 158
 159 AC_SEARCH_LIBS(dlopen, dl)
 160 old_ldflags="${LDFLAGS}"
 161 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 162 AC_TRY_LINK(, [int i;], found_export_dynamic=yes, found_export_dynamic=no)
 163 if test $found_export_dynamic = no; then
 164         LDFLAGS="${old_ldflags}"
 165 fi
 166
 167 AC_MSG_CHECKING(for varargs macros)
 168 AC_TRY_COMPILE([],[
 169 int foo (int i, int j);
 170 #define bar(...) foo (1, __VA_ARGS__)
 171 void main () {
 172          bar (2);
 173 }
 174 ],have_iso_varargs=yes,have_iso_varargs=no)
 175 AC_MSG_RESULT($have_iso_varargs)
 176 G_HAVE_ISO_VARARGS=0
 177 if test "x$have_iso_varargs" = "xyes"; then
 178    G_HAVE_ISO_VARARGS=1
 179 fi
 180 AC_SUBST(G_HAVE_ISO_VARARGS)
 181
 182 AC_CHECK_HEADERS(getopt.h sys/time.h sys/wait.h pwd.h langinfo.h iconv.h localcharset.h sys/types.h)
 183 AC_CHECK_HEADER(alloca.h, [HAVE_ALLOCA_H=1], [HAVE_ALLOCA_H=0])
 184 AC_SUBST(HAVE_ALLOCA_H)
 185
 186 if test $ac_cv_sizeof_void_p = $ac_cv_sizeof_int; then
 187    GPOINTER_TO_INT="((gint) (ptr))"
 188    GPOINTER_TO_UINT="((guint) (ptr))"
 189    GINT_TO_POINTER="((gpointer) (v))"
 190    GUINT_TO_POINTER="((gpointer) (v))"
 191    GSIZE="int"
 192    GSIZE_FORMAT='"u"'
 193    G_GUINT64_FORMAT='"llu"'
 194    G_GINT64_FORMAT='"lld"'
 195    G_GUINT32_FORMAT='"lu"'
 196    G_GINT32_FORMAT='"ld"'
 197 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long; then
 198    GPOINTER_TO_INT="((gint)(long) (ptr))"
 199    GPOINTER_TO_UINT="((guint)(long) (ptr))"
 200    GINT_TO_POINTER="((gpointer)(glong) (v))"
 201    GUINT_TO_POINTER="((gpointer)(gulong) (v))"
 202    GSIZE="long"
 203    GSIZE_FORMAT='"lu"'
 204    G_GUINT64_FORMAT='"lu"'
 205    G_GINT64_FORMAT='"ld"'
 206    G_GUINT32_FORMAT='"u"'
 207    G_GINT32_FORMAT='"d"'
 208 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long_long; then
 209    GPOINTER_TO_INT="((gint)(long long) (ptr))"
 210    GPOINTER_TO_UINT="((guint)(unsigned long long) (ptr))"
 211    GINT_TO_POINTER="((gpointer)(long long) (v))"
 212    GUINT_TO_POINTER="((gpointer)(unsigned long long) (v))"
 213    GSIZE="long long"
 214    GSIZE_FORMAT='"I64u"'
 215    G_GUINT64_FORMAT='"I64u"'
 216    G_GINT64_FORMAT='"I64i"'
 217    G_GUINT32_FORMAT='"I32u"'
 218    G_GINT32_FORMAT='"I32i"'
 219 else
 220    AC_MSG_ERROR([unsupported pointer size])
 221 fi
 222
 223 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 224
 225 pkg_config_path=
 226 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir      Change pkg-config dir to custom dir],
 227         if test x$with_crosspkgdir = "x"; then
 228                 if test -s $PKG_CONFIG_PATH; then
 229                         pkg_config_path=$PKG_CONFIG_PATH
 230                 fi
 231         else
 232                 pkg_config_path=$with_crosspkgdir
 233                 PKG_CONFIG_PATH=$pkg_config_path
 234                 export PKG_CONFIG_PATH
 235         fi
 236 )
 237
 238 dnl
 239 dnl No, you can not replace the call below with a pkg.m4 macro
 240 dnl
 241 have_glib=false
 242 if test "x$PKG_CONFIG" != "xno"; then
 243     if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
 244         have_glib=true;
 245     else
 246         have_glib=false;
 247     fi
 248 fi
 249 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 250
 251 AC_SUBST(GPOINTER_TO_INT)
 252 AC_SUBST(GPOINTER_TO_UINT)
 253 AC_SUBST(GINT_TO_POINTER)
 254 AC_SUBST(GUINT_TO_POINTER)
 255 AC_SUBST(GSIZE)
 256 AC_SUBST(GSIZE_FORMAT)
 257 AC_SUBST(G_GUINT64_FORMAT)
 258 AC_SUBST(G_GINT64_FORMAT)
 259 AC_SUBST(G_GUINT32_FORMAT)
 260 AC_SUBST(G_GINT32_FORMAT)
 261
 262 AC_OUTPUT([
 263 Makefile
 264 m4/Makefile
 265 src/Makefile
 266 src/eglib-config.h
 267 test/Makefile
 268 ])