eglib/configure.ac

   1 AC_INIT(eglib, [0.3],
   2         [http://bugzilla.novell.com/enter_bug.cgi?product=mono])
   3
   4 AC_CONFIG_SRCDIR([README])
   5 #AC_CONFIG_MACRO_DIR([m4])
   6 AC_CANONICAL_SYSTEM
   7 AC_CANONICAL_HOST
   8
   9 AM_INIT_AUTOMAKE([1.9 dist-bzip2 tar-ustar no-dist-gzip foreign])
  10 AM_CONFIG_HEADER([config.h])
  11 AM_MAINTAINER_MODE
  12
  13 AC_PROG_CC
  14 AM_PROG_LIBTOOL
  15 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
  16 DOLT
  17 CFLAGS="$CFLAGS -O0"
  18 GNUC_PRETTY=
  19 GNUC_UNUSED=
  20 BREAKPOINT="G_STMT_START { raise (SIGTRAP); } G_STMT_END"
  21 if test x$GCC = xyes; then
  22    GNUC_UNUSED='__attribute__((__unused__))'
  23    GNUC_NORETURN='__attribute__((__noreturn__))'
  24    case $host_cpu in
  25      i*86|x86_64) BREAKPOINT="G_STMT_START { __asm__ (\"int \$03\"); } G_STMT_END" ;;
  26    esac
  27 fi
  28 AC_SUBST(GNUC_PRETTY)
  29 AC_SUBST(GNUC_UNUSED)
  30 AC_SUBST(GNUC_NORETURN)
  31 AC_SUBST(BREAKPOINT)
  32
  33 # We use a separate variable to pass down CPPFLAGS and CFLAGS from the main mono
  34 # configure, because of autoconf brokeness
  35 if test "x$CPPFLAGS_FOR_EGLIB" != "x"; then
  36    CPPFLAGS=$CPPFLAGS_FOR_EGLIB
  37 fi
  38 if test "x$CFLAGS_FOR_EGLIB" != "x"; then
  39    CFLAGS=$CFLAGS_FOR_EGLIB
  40 fi
  41
  42 CFLAGS="$CFLAGS -g -D_GNU_SOURCE"
  43
  44 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
  45 AC_C_BIGENDIAN([ORDER=G_BIG_ENDIAN],[ORDER=G_LITTLE_ENDIAN])
  46
  47 platform_darwin=no
  48
  49 case $host in
  50 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  51     PATHSEP='\\'
  52     SEARCHSEP=';'
  53     OS="WIN32"
  54     PIDTYPE='void *'
  55     ;;
  56 *-*darwin*)
  57     platform_darwin=yes
  58     PATHSEP='/'
  59     SEARCHSEP=':'
  60     OS="UNIX"
  61     PIDTYPE='int'
  62     ;;
  63 *)
  64     PATHSEP='/'
  65     SEARCHSEP=':'
  66     OS="UNIX"
  67     PIDTYPE='int'
  68     ;;
  69 esac
  70
  71 case $host in
  72         *-*-solaris*)
  73         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  74         ;;
  75 esac
  76
  77 case $target in
  78 arm*-darwin*)
  79     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE"
  80     ;;
  81 i*86-*-darwin*)
  82     ORDER=G_LITTLE_ENDIAN
  83     ;;
  84 *-*-openbsd*)
  85     CFLAGS="$CFLAGS -pthread"
  86     LDFLAGS="$LDFLAGS -pthread"
  87     ;;
  88 esac
  89
  90 AC_SUBST(ORDER)
  91 AC_SUBST(CFLAGS)
  92 AC_SUBST(PATHSEP)
  93 AC_SUBST(SEARCHSEP)
  94 AC_SUBST(OS)
  95 AC_SUBST(PIDTYPE)
  96 AM_CONDITIONAL(HOST_WIN32, test x$OS = xWIN32)
  97 AM_CONDITIONAL(TARGET_WIN32, test x$OS = xWIN32)
  98 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
  99
 100 AC_CHECK_SIZEOF(int)
 101 AC_CHECK_SIZEOF(void *)
 102 AC_CHECK_SIZEOF(long)
 103 AC_CHECK_SIZEOF(long long)
 104 AC_CHECK_FUNCS(strndup strlcpy stpcpy getpwuid_r strtok_r rewinddir vasprintf)
 105 AM_CONDITIONAL(NEED_VASPRINTF, test x$have_vasprintf = x )
 106 AM_ICONV()
 107 AC_SEARCH_LIBS(sqrtf, m)
 108
 109 # nanosleep may not be part of libc, also search it in other libraries
 110 AC_SEARCH_LIBS(nanosleep, rt)
 111
 112 AC_SEARCH_LIBS(dlopen, dl)
 113 old_ldflags="${LDFLAGS}"
 114 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 115 AC_TRY_LINK(, [int i;], found_export_dynamic=yes, found_export_dynamic=no)
 116 if test $found_export_dynamic = no; then
 117         LDFLAGS="${old_ldflags}"
 118 fi
 119
 120 AC_MSG_CHECKING(for varargs macros)
 121 AC_TRY_COMPILE([],[
 122 int foo (int i, int j);
 123 #define bar(...) foo (1, __VA_ARGS__)
 124 void main () {
 125          bar (2);
 126 }
 127 ],have_iso_varargs=yes,have_iso_varargs=no)
 128 AC_MSG_RESULT($have_iso_varargs)
 129 G_HAVE_ISO_VARARGS=0
 130 if test "x$have_iso_varargs" = "xyes"; then
 131    G_HAVE_ISO_VARARGS=1
 132 fi
 133 AC_SUBST(G_HAVE_ISO_VARARGS)
 134
 135 AC_CHECK_HEADERS(getopt.h sys/time.h sys/wait.h pwd.h langinfo.h iconv.h localcharset.h sys/types.h)
 136 AC_CHECK_HEADER(alloca.h, [HAVE_ALLOCA_H=1], [HAVE_ALLOCA_H=0])
 137 AC_SUBST(HAVE_ALLOCA_H)
 138
 139 if test $ac_cv_sizeof_void_p = $ac_cv_sizeof_int; then
 140    GPOINTER_TO_INT="((gint) (ptr))"
 141    GPOINTER_TO_UINT="((guint) (ptr))"
 142    GINT_TO_POINTER="((gpointer) (v))"
 143    GUINT_TO_POINTER="((gpointer) (v))"
 144    GSIZE="int"
 145    GSIZE_FORMAT='"u"'
 146    G_GUINT64_FORMAT='"llu"'
 147    G_GINT64_FORMAT='"lld"'
 148 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long; then
 149    GPOINTER_TO_INT="((gint)(long) (ptr))"
 150    GPOINTER_TO_UINT="((guint)(long) (ptr))"
 151    GINT_TO_POINTER="((gpointer)(glong) (v))"
 152    GUINT_TO_POINTER="((gpointer)(gulong) (v))"
 153    GSIZE="long"
 154    GSIZE_FORMAT='"lu"'
 155    G_GUINT64_FORMAT='"lu"'
 156    G_GINT64_FORMAT='"ld"'
 157 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long_long; then
 158    GPOINTER_TO_INT="((gint)(long long) (ptr))"
 159    GPOINTER_TO_UINT="((guint)(unsigned long long) (ptr))"
 160    GINT_TO_POINTER="((gpointer)(long long) (v))"
 161    GUINT_TO_POINTER="((gpointer)(unsigned long long) (v))"
 162    GSIZE="long long"
 163    GSIZE_FORMAT='"I64u"'
 164    G_GUINT64_FORMAT='"I64u"'
 165    G_GINT64_FORMAT='"I64i"'
 166 else
 167    AC_MSG_ERROR([unsupported pointer size])
 168 fi
 169
 170 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 171
 172 pkg_config_path=
 173 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir      Change pkg-config dir to custom dir],
 174         if test x$with_crosspkgdir = "x"; then
 175                 if test -s $PKG_CONFIG_PATH; then
 176                         pkg_config_path=$PKG_CONFIG_PATH
 177                 fi
 178         else
 179                 pkg_config_path=$with_crosspkgdir
 180                 PKG_CONFIG_PATH=$pkg_config_path
 181                 export PKG_CONFIG_PATH
 182         fi
 183 )
 184
 185 dnl
 186 dnl No, you can not replace the call below with a pkg.m4 macro
 187 dnl
 188 have_glib=false
 189 if test "x$PKG_CONFIG" != "xno"; then
 190     if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
 191         have_glib=true;
 192     else
 193         have_glib=false;
 194     fi
 195 fi
 196 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 197
 198 AC_ARG_ENABLE(quiet-build, [  --enable-quiet-build  Enable quiet runtime build (on by default)], enable_quiet_build=$enableval, enable_quiet_build=yes)
 199 AC_SUBST(GPOINTER_TO_INT)
 200 AC_SUBST(GPOINTER_TO_UINT)
 201 AC_SUBST(GINT_TO_POINTER)
 202 AC_SUBST(GUINT_TO_POINTER)
 203 AC_SUBST(GSIZE)
 204 AC_SUBST(GSIZE_FORMAT)
 205 AC_SUBST(G_GUINT64_FORMAT)
 206 AC_SUBST(G_GINT64_FORMAT)
 207
 208 if test x$enable_quiet_build = xyes; then
 209    AC_CONFIG_COMMANDS([quiet], [for i in `find src test -name Makefile.in | sed -e 's/Makefile.in/Makefile/g'`; do if test -f $i; then $srcdir/../scripts/patch-quiet.sh $i; fi; done], [shell=$SHELL])
 210    AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool; sed -e 's/$ECHO "copying selected/# "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
 211 fi
 212
 213 AC_OUTPUT([
 214 Makefile
 215 src/Makefile
 216 src/eglib-config.h
 217 test/Makefile
 218 ])