src/cpu/via/car/cache_as_ram.inc

   1 /*
   2  * This file is part of the coreboot project.
   3  *
   4  * Copyright (C) 2000,2007 Ronald G. Minnich <rminnich@gmail.com>
   5  * Copyright (C) 2005 Eswar Nallusamy, LANL
   6  * Copyright (C) 2005 Tyan
   7  * (Written by Yinghai Lu <yhlu@tyan.com> for Tyan)
   8  * Copyright (C) 2007 coresystems GmbH
   9  * (Written by Stefan Reinauer <stepan@coresystems.de> for coresystems GmbH)
  10  * Copyright (C) 2007,2008 Carl-Daniel Hailfinger
  11  * Copyright (C) 2008 VIA Technologies, Inc.
  12  * (Written by Jason Zhao <jasonzhao@viatech.com.cn> for VIA)
  13  *
  14  * This program is free software; you can redistribute it and/or modify
  15  * it under the terms of the GNU General Public License as published by
  16  * the Free Software Foundation; version 2 of the License.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  26  */
  27
  28 #include <cpu/x86/stack.h>
  29 #include <cpu/x86/mtrr.h>
  30 #include <console/post_codes.h>
  31
  32 #define CacheSize               CONFIG_DCACHE_RAM_SIZE
  33 #define CacheBase               CONFIG_DCACHE_RAM_BASE
  34
  35         /* Save the BIST result. */
  36         movl    %eax, %ebp
  37
  38 CacheAsRam:
  39
  40         /* Disable cache. */
  41         movl    %cr0, %eax
  42         orl     $(1 << 30), %eax
  43         movl    %eax, %cr0
  44         invd
  45
  46         /* Set the default memory type and enable fixed and variable MTRRs. */
  47         movl    $MTRRdefType_MSR, %ecx
  48         xorl    %edx, %edx
  49         movl    $(MTRRdefTypeEn | MTRRdefTypeFixEn), %eax
  50         wrmsr
  51
  52         /* Clear all MTRRs. */
  53         xorl    %edx, %edx
  54         movl    $all_mtrr_msrs, %esi
  55
  56 clear_fixed_var_mtrr:
  57         lodsl   (%esi), %eax
  58         testl   %eax, %eax
  59         jz      clear_fixed_var_mtrr_out
  60
  61         movl    %eax, %ecx
  62         xorl    %eax, %eax
  63         wrmsr
  64
  65         jmp     clear_fixed_var_mtrr
  66
  67 all_mtrr_msrs:
  68         /* fixed MTRR MSRs */
  69         .long   MTRRfix64K_00000_MSR
  70         .long   MTRRfix16K_80000_MSR
  71         .long   MTRRfix16K_A0000_MSR
  72         .long   MTRRfix4K_C0000_MSR
  73         .long   MTRRfix4K_C8000_MSR
  74         .long   MTRRfix4K_D0000_MSR
  75         .long   MTRRfix4K_D8000_MSR
  76         .long   MTRRfix4K_E0000_MSR
  77         .long   MTRRfix4K_E8000_MSR
  78         .long   MTRRfix4K_F0000_MSR
  79         .long   MTRRfix4K_F8000_MSR
  80
  81         /* var MTRR MSRs */
  82         .long   MTRRphysBase_MSR(0)
  83         .long   MTRRphysMask_MSR(0)
  84         .long   MTRRphysBase_MSR(1)
  85         .long   MTRRphysMask_MSR(1)
  86         .long   MTRRphysBase_MSR(2)
  87         .long   MTRRphysMask_MSR(2)
  88         .long   MTRRphysBase_MSR(3)
  89         .long   MTRRphysMask_MSR(3)
  90         .long   MTRRphysBase_MSR(4)
  91         .long   MTRRphysMask_MSR(4)
  92         .long   MTRRphysBase_MSR(5)
  93         .long   MTRRphysMask_MSR(5)
  94         .long   MTRRphysBase_MSR(6)
  95         .long   MTRRphysMask_MSR(6)
  96         .long   MTRRphysBase_MSR(7)
  97         .long   MTRRphysMask_MSR(7)
  98
  99         .long   0x000 /* NULL, end of table */
 100
 101 clear_fixed_var_mtrr_out:
 102         movl    $MTRRphysBase_MSR(0), %ecx
 103         xorl    %edx, %edx
 104         movl    $(CacheBase | MTRR_TYPE_WRBACK), %eax
 105         wrmsr
 106
 107         movl    $MTRRphysMask_MSR(0), %ecx
 108         /* This assumes we never access addresses above 2^36 in CAR. */
 109         movl    $0x0000000f, %edx
 110         movl    $(~(CacheSize - 1) | MTRRphysMaskValid), %eax
 111         wrmsr
 112
 113         /*
 114          * Enable write base caching so we can do execute in place (XIP)
 115          * on the flash ROM.
 116          */
 117         movl    $MTRRphysBase_MSR(1), %ecx
 118         xorl    %edx, %edx
 119         /*
 120          * IMPORTANT: The following calculation _must_ be done at runtime. See
 121          * http://www.coreboot.org/pipermail/coreboot/2010-October/060855.html
 122          */
 123         movl    $copy_and_run, %eax
 124         andl    $(~(CONFIG_XIP_ROM_SIZE - 1)), %eax
 125         orl     $MTRR_TYPE_WRBACK, %eax
 126         wrmsr
 127
 128         movl    $MTRRphysMask_MSR(1), %ecx
 129         movl    $0x0000000f, %edx
 130         movl    $(~(CONFIG_XIP_ROM_SIZE - 1) | MTRRphysMaskValid), %eax
 131         wrmsr
 132
 133         /* Set the default memory type and enable fixed and variable MTRRs. */
 134         /* TODO: Or also enable fixed MTRRs? Bug in the code? */
 135         movl    $MTRRdefType_MSR, %ecx
 136         xorl    %edx, %edx
 137         movl    $(MTRRdefTypeEn), %eax
 138         wrmsr
 139
 140         /* Enable cache. */
 141         movl    %cr0, %eax
 142         andl    $(~((1 << 30) | (1 << 29))), %eax
 143         movl    %eax, %cr0
 144
 145         /* Read the range with lodsl. */
 146         cld
 147         movl    $CacheBase, %esi
 148         movl    %esi, %edi
 149         movl    $(CacheSize >> 2), %ecx
 150         rep     lodsl
 151
 152         movl    $CacheBase, %esi
 153         movl    %esi, %edi
 154         movl    $(CacheSize >> 2), %ecx
 155
 156         /*
 157          * 0x5c5c5c5c is a memory test pattern.
 158          * TODO: Check if everything works with the zero pattern as well.
 159          */
 160         /* xorl %eax, %eax */
 161         xorl    $0x5c5c5c5c, %eax
 162         rep     stosl
 163
 164 #ifdef CARTEST
 165         /*
 166          * IMPORTANT: The following calculation _must_ be done at runtime. See
 167          * http://www.coreboot.org/pipermail/coreboot/2010-October/060855.html
 168          */
 169         movl    $copy_and_run, %esi
 170         andl    $(~(CONFIG_XIP_ROM_SIZE - 1)), %ei
 171         movl    %esi, %edi
 172         movl    $(CONFIG_XIP_ROM_SIZE >> 2), %ecx
 173         rep     lodsl
 174 #endif
 175
 176         /*
 177          * The key point of this CAR code is C7 cache does not turn into
 178          * "no fill" mode, which is not compatible with general CAR code.
 179          */
 180
 181         movl    $(CacheBase + CacheSize - 4), %eax
 182         movl    %eax, %esp
 183
 184 #ifdef CARTEST
 185 testok:
 186         post_code(0x40)
 187         xorl    %edx, %edx
 188         xorl    %eax, %eax
 189         movl    $0x5c5c, %edx
 190         pushl   %edx
 191         pushl   %edx
 192         pushl   %edx
 193         pushl   %edx
 194         pushl   %edx
 195         popl    %esi
 196         popl    %esi
 197         popl    %eax
 198         popl    %eax
 199         popl    %eax
 200         cmpl    %edx, %eax
 201         jne     stackerr
 202 #endif
 203
 204         /* Restore the BIST result. */
 205         movl    %ebp, %eax
 206
 207         /* We need to set EBP? No need. */
 208         movl    %esp, %ebp
 209         pushl   %eax    /* BIST */
 210         call    main
 211
 212         /*
 213          * TODO: Backup stack in CACHE_AS_RAM into MMX and SSE and after we
 214          *       get STACK up, we restore that. It is only needed if we
 215          *       want to go back.
 216          */
 217
 218         /* We don't need CAR from now on. */
 219
 220         /* Disable cache. */
 221         movl    %cr0, %eax
 222         orl     $(1 << 30), %eax
 223         movl    %eax, %cr0
 224
 225         /* Set the default memory type and enable variable MTRRs. */
 226         /* TODO: Or also enable fixed MTRRs? Bug in the code? */
 227         movl    $MTRRdefType_MSR, %ecx
 228         xorl    %edx, %edx
 229         movl    $(MTRRdefTypeEn), %eax
 230         wrmsr
 231
 232         /* Enable caching for CONFIG_RAMBASE..CONFIG_RAMTOP. */
 233         movl    $MTRRphysBase_MSR(0), %ecx
 234         xorl    %edx, %edx
 235         movl    $(CONFIG_RAMBASE | MTRR_TYPE_WRBACK), %eax
 236         wrmsr
 237
 238         movl    $MTRRphysMask_MSR(0), %ecx
 239         movl    $0x0000000f, %edx       /* AMD 40 bit 0xff */
 240         movl    $(~(CONFIG_RAMTOP - CONFIG_RAMBASE - 1) | MTRRphysMaskValid), %eax
 241         wrmsr
 242
 243         /* Cache XIP_ROM area to speedup coreboot code. */
 244         movl    $MTRRphysBase_MSR(1), %ecx
 245         xorl    %edx, %edx
 246         /*
 247          * IMPORTANT: The following calculation _must_ be done at runtime. See
 248          * http://www.coreboot.org/pipermail/coreboot/2010-October/060855.html
 249          */
 250         movl    $copy_and_run, %eax
 251         andl    $(~(CONFIG_XIP_ROM_SIZE - 1)), %eax
 252         orl     $MTRR_TYPE_WRBACK, %eax
 253         wrmsr
 254
 255         movl    $MTRRphysMask_MSR(1), %ecx
 256         xorl    %edx, %edx
 257         movl    $(~(CONFIG_XIP_ROM_SIZE - 1) | MTRRphysMaskValid), %eax
 258         wrmsr
 259
 260         /* Enable cache. */
 261         movl    %cr0, %eax
 262         andl    $(~((1 << 30) | (1 << 29))), %eax
 263         movl    %eax, %cr0
 264         invd
 265
 266         /* Clear boot_complete flag. */
 267         xorl    %ebp, %ebp
 268 __main:
 269         post_code(POST_PREPARE_RAMSTAGE)
 270         cld                     /* Clear direction flag. */
 271
 272         movl    %ebp, %esi
 273
 274         movl    $ROMSTAGE_STACK, %esp
 275         movl    %esp, %ebp
 276         pushl   %esi
 277         call    copy_and_run
 278
 279 .Lhlt:
 280         post_code(POST_DEAD_CODE)
 281         hlt
 282         jmp     .Lhlt
 283