src/cpu/intel/model_6ex/cache_as_ram.inc

   1 /*
   2  * This file is part of the coreboot project.
   3  *
   4  * Copyright (C) 2000,2007 Ronald G. Minnich <rminnich@gmail.com>
   5  * Copyright (C) 2007-2008 coresystems GmbH
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License as published by
   9  * the Free Software Foundation; version 2 of the License.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19  */
  20
  21 #include <cpu/x86/stack.h>
  22 #include <cpu/x86/mtrr.h>
  23 #include <cpu/x86/post_code.h>
  24
  25 #define CACHE_AS_RAM_SIZE CONFIG_DCACHE_RAM_SIZE
  26 #define CACHE_AS_RAM_BASE CONFIG_DCACHE_RAM_BASE
  27
  28         /* Save the BIST result. */
  29         movl    %eax, %ebp
  30
  31 cache_as_ram:
  32         post_code(0x20)
  33
  34         /* Send INIT IPI to all excluding ourself. */
  35         movl    $0x000C4500, %eax
  36         movl    $0xFEE00300, %esi
  37         movl    %eax, (%esi)
  38
  39         /* Zero out all fixed range and variable range MTRRs. */
  40         movl    $mtrr_table, %esi
  41         movl    $((mtrr_table_end - mtrr_table) / 2), %edi
  42         xorl    %eax, %eax
  43         xorl    %edx, %edx
  44 clear_mtrrs:
  45         movw    (%esi), %bx
  46         movzx   %bx, %ecx
  47         wrmsr
  48         add     $2, %esi
  49         dec     %edi
  50         jnz     clear_mtrrs
  51
  52         /* Configure the default memory type to uncacheable. */
  53         movl    $MTRRdefType_MSR, %ecx
  54         rdmsr
  55         andl    $(~0x00000cff), %eax
  56         wrmsr
  57
  58         /* Set Cache-as-RAM base address. */
  59         movl    $(MTRRphysBase_MSR(0)), %ecx
  60         movl    $(CACHE_AS_RAM_BASE | MTRR_TYPE_WRBACK), %eax
  61         xorl    %edx, %edx
  62         wrmsr
  63
  64         /* Set Cache-as-RAM mask. */
  65         movl    $(MTRRphysMask_MSR(0)), %ecx
  66         movl    $(~(CACHE_AS_RAM_SIZE - 1) | MTRRphysMaskValid), %eax
  67         movl    $0x0000000f, %edx
  68         wrmsr
  69
  70         /* Enable MTRR. */
  71         movl    $MTRRdefType_MSR, %ecx
  72         rdmsr
  73         orl     $MTRRdefTypeEn, %eax
  74         wrmsr
  75
  76         /* Enable L2 cache. */
  77         movl    $0x11e, %ecx
  78         rdmsr
  79         orl     $(1 << 8), %eax
  80         wrmsr
  81
  82         /* Enable cache (CR0.CD = 0, CR0.NW = 0). */
  83         movl    %cr0, %eax
  84         andl    $(~((1 << 30) | (1 << 29))), %eax
  85         invd
  86         movl    %eax, %cr0
  87
  88         /* Clear the cache memory reagion. */
  89         movl    $CACHE_AS_RAM_BASE, %esi
  90         movl    %esi, %edi
  91         movl    $(CACHE_AS_RAM_SIZE / 4), %ecx
  92         // movl $0x23322332, %eax
  93         xorl    %eax, %eax
  94         rep     stosl
  95
  96         /* Enable Cache-as-RAM mode by disabling cache. */
  97         movl    %cr0, %eax
  98         orl     $(1 << 30), %eax
  99         movl    %eax, %cr0
 100
 101 #if defined(CONFIG_XIP_ROM_SIZE) && defined(CONFIG_XIP_ROM_BASE)
 102         /* Enable cache for our code in Flash because we do XIP here */
 103         movl    $MTRRphysBase_MSR(1), %ecx
 104         xorl    %edx, %edx
 105 #if CONFIG_TINY_BOOTBLOCK
 106 #define REAL_XIP_ROM_BASE AUTO_XIP_ROM_BASE
 107 #else
 108 #define REAL_XIP_ROM_BASE CONFIG_XIP_ROM_BASE
 109 #endif
 110         /*
 111          * IMPORTANT: The two lines below can _not_ be written like this:
 112          *   movl $(REAL_XIP_ROM_BASE | MTRR_TYPE_WRBACK), %eax
 113          * http://www.coreboot.org/pipermail/coreboot/2010-October/060855.html
 114          */
 115         movl    $REAL_XIP_ROM_BASE, %eax
 116         orl     $MTRR_TYPE_WRBACK, %eax
 117         wrmsr
 118
 119         movl    $MTRRphysMask_MSR(1), %ecx
 120         movl    $0x0000000f, %edx
 121         movl    $(~(CONFIG_XIP_ROM_SIZE - 1) | MTRRphysMaskValid), %eax
 122         wrmsr
 123 #endif /* CONFIG_XIP_ROM_SIZE && CONFIG_XIP_ROM_BASE */
 124
 125         /* Enable cache. */
 126         movl    %cr0, %eax
 127         andl    $(~((1 << 30) | (1 << 29))), %eax
 128         movl    %eax, %cr0
 129
 130         /* Set up the stack pointer. */
 131 #if CONFIG_USBDEBUG
 132         /* Leave some space for the struct ehci_debug_info. */
 133         movl    $(CACHE_AS_RAM_BASE + CACHE_AS_RAM_SIZE - 4 - 128), %eax
 134 #else
 135         movl    $(CACHE_AS_RAM_BASE + CACHE_AS_RAM_SIZE - 4), %eax
 136 #endif
 137         movl    %eax, %esp
 138
 139         /* Restore the BIST result. */
 140         movl    %ebp, %eax
 141         movl    %esp, %ebp
 142         pushl   %eax
 143
 144         post_code(0x23)
 145
 146         /* Call romstage.c main function. */
 147         call    main
 148
 149         post_code(0x2f)
 150
 151         post_code(0x30)
 152
 153         /* Disable cache. */
 154         movl    %cr0, %eax
 155         orl     $(1 << 30), %eax
 156         movl    %eax, %cr0
 157
 158         post_code(0x31)
 159
 160         /* Disable MTRR. */
 161         movl    $MTRRdefType_MSR, %ecx
 162         rdmsr
 163         andl    $(~MTRRdefTypeEn), %eax
 164         wrmsr
 165
 166         post_code(0x31)
 167
 168         invd
 169 #if 0
 170         xorl    %eax, %eax
 171         xorl    %edx, %edx
 172         movl    $MTRRphysBase_MSR(0), %ecx
 173         wrmsr
 174         movl    $MTRRphysMask_MSR(0), %ecx
 175         wrmsr
 176         movl    $MTRRphysBase_MSR(1), %ecx
 177         wrmsr
 178         movl    $MTRRphysMask_MSR(1), %ecx
 179         wrmsr
 180 #endif
 181
 182         post_code(0x33)
 183
 184         /* Enable cache. */
 185         movl    %cr0, %eax
 186         andl    $~((1 << 30) | (1 << 29)), %eax
 187         movl    %eax, %cr0
 188
 189         post_code(0x36)
 190
 191         /* Disable cache. */
 192         movl    %cr0, %eax
 193         orl     $(1 << 30), %eax
 194         movl    %eax, %cr0
 195
 196         post_code(0x38)
 197
 198         /* Enable Write Back and Speculative Reads for the first 1MB. */
 199         movl    $MTRRphysBase_MSR(0), %ecx
 200         movl    $(0x00000000 | MTRR_TYPE_WRBACK), %eax
 201         xorl    %edx, %edx
 202         wrmsr
 203         movl    $MTRRphysMask_MSR(0), %ecx
 204         movl    $(~(1024 * 1024 - 1) | MTRRphysMaskValid), %eax
 205         movl    $0x0000000f, %edx       // 36bit address space
 206         wrmsr
 207
 208         post_code(0x39)
 209
 210         /* And enable cache again after setting MTRRs. */
 211         movl    %cr0, %eax
 212         andl    $~((1 << 30) | (1 << 29)), %eax
 213         movl    %eax, %cr0
 214
 215         post_code(0x3a)
 216
 217         /* Enable MTRR. */
 218         movl    $MTRRdefType_MSR, %ecx
 219         rdmsr
 220         orl     $MTRRdefTypeEn, %eax
 221         wrmsr
 222
 223         post_code(0x3b)
 224
 225         /* Invalidate the cache again. */
 226         invd
 227
 228         post_code(0x3c)
 229
 230         /* Clear boot_complete flag. */
 231         xorl    %ebp, %ebp
 232 __main:
 233         post_code(POST_PREPARE_RAMSTAGE)
 234         cld                     /* Clear direction flag. */
 235
 236         movl    %ebp, %esi
 237
 238         movl    $ROMSTAGE_STACK, %esp
 239         movl    %esp, %ebp
 240         pushl   %esi
 241         call    copy_and_run
 242
 243 .Lhlt:
 244         post_code(POST_DEAD_CODE)
 245         hlt
 246         jmp     .Lhlt
 247
 248 mtrr_table:
 249         /* Fixed MTRRs */
 250         .word 0x250, 0x258, 0x259
 251         .word 0x268, 0x269, 0x26A
 252         .word 0x26B, 0x26C, 0x26D
 253         .word 0x26E, 0x26F
 254         /* Variable MTRRs */
 255         .word 0x200, 0x201, 0x202, 0x203
 256         .word 0x204, 0x205, 0x206, 0x207
 257         .word 0x208, 0x209, 0x20A, 0x20B
 258         .word 0x20C, 0x20D, 0x20E, 0x20F
 259 mtrr_table_end:
 260