payloads/libpayload/libpayload.ldscript

   1 /*
   2  This file is part of the libpayload project.
   3
   4  Copyright (C) 2008 Advanced Micro Devices, Inc.
   5
   6  Redistribution and use in source and binary forms, with or without
   7  modification, are permitted provided that the following conditions
   8  are met:
   9  1. Redistributions of source code must retain the above copyright
  10     notice, this list of conditions and the following disclaimer.
  11  2. Redistributions in binary form must reproduce the above copyright
  12     notice, this list of conditions and the following disclaimer in the
  13     documentation and/or other materials provided with the distribution.
  14  3. The name of the author may not be used to endorse or promote products
  15     derived from this software without specific prior written permission.
  16
  17  THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  SUCH DAMAGE.
  28 */
  29
  30 BASE_ADDRESS = 0x100000;
  31
  32 OUTPUT_FORMAT(elf32-i386)
  33 OUTPUT_ARCH(i386)
  34
  35 ENTRY(_entry)
  36
  37 HEAP_SIZE = 16384;
  38 STACK_SIZE = 16384;
  39
  40 SECTIONS
  41 {
  42         . = BASE_ADDRESS;
  43
  44         . = ALIGN(16);
  45         _start = .;
  46
  47         .text : {
  48                 *(.text._entry)
  49                 *(.text)
  50                 *(.text.*)
  51         }
  52
  53         .rodata : {
  54                 *(.rodata)
  55                 *(.rodata.*)
  56         }
  57
  58         .data : {
  59                 *(.data)
  60                 *(.data.*)
  61         }
  62
  63         .bss : {
  64                 *(.bss)
  65                 *(.bss.*)
  66                 *(COMMON)
  67
  68                 /* Stack and heap */
  69
  70                 . = ALIGN(16);
  71                 _heap = .;
  72                 . += HEAP_SIZE;
  73                 . = ALIGN(16);
  74                 _eheap = .;
  75
  76                 _stack = .;
  77                 . += STACK_SIZE;
  78                 . = ALIGN(16);
  79                 _stack = .;
  80         }
  81
  82         /* Put the static bits of our inital stack at the bottom */
  83         .istack : {
  84                 *(.istack)
  85         }
  86
  87         _end = .;
  88
  89         /DISCARD/ : { *(.comment) *(.note) *(.note.*) }
  90 }