payloads/libpayload/arch/i386/head.S

   1 /*
   2  * This file is part of the libpayload project.
   3  *
   4  * Copyright (C) 2008 Advanced Micro Devices, Inc.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. The name of the author may not be used to endorse or promote products
  15  *    derived from this software without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30         .code32
  31         .global _entry, _leave
  32         .text
  33         .align 4
  34
  35 /*
  36  * Our entry point - assume that the CPU is in 32 bit protected mode and
  37  * all segments are in a flat model. That's our operating mode, so we won't
  38  * change anything.
  39  */
  40 _entry:
  41         jmp _init
  42
  43         .align 4
  44
  45 #define MB_MAGIC 0x1BADB002
  46 #define MB_FLAGS 0x00010003
  47
  48 mb_header:
  49         .long MB_MAGIC
  50         .long MB_FLAGS
  51         .long -(MB_MAGIC + MB_FLAGS)
  52         .long mb_header
  53         .long _start
  54         .long _edata
  55         .long _end
  56         .long _init
  57
  58 /*
  59  * This function saves off the previous stack and switches us to our
  60  * own execution environment.
  61  */
  62 _init:
  63         /* No interrupts, please. */
  64         cli
  65
  66         /* There is a bunch of stuff missing here to take arguments on the stack
  67          * See http://www.coreboot.org/Payload_API and exec.S.
  68          */
  69         /* Store current stack pointer. */
  70         movl %esp, %esi
  71
  72         /* Store EAX and EBX */
  73         movl %eax,loader_eax
  74         movl %ebx,loader_ebx
  75
  76         /* Clear the bss */
  77         cld
  78         movl $.bss, %edi
  79         movl $_end, %ecx
  80         subl %edi, %ecx
  81         xor %ax, %ax
  82         rep stosb
  83
  84         /* Setup new stack. */
  85         movl $_stack, %ebx
  86
  87         movl %ebx, %esp
  88
  89         /* Save old stack pointer. */
  90         pushl %esi
  91
  92         /* Let's rock. */
  93         call start_main
  94
  95         /* %eax has the return value - pass it on unmolested */
  96 _leave:
  97         /* Get old stack pointer. */
  98         popl %ebx
  99
 100         /* Restore old stack. */
 101         movl %ebx, %esp
 102
 103         /* Return to the original context. */
 104         ret