src/vm/jit/x86_64/asmpart.S

   1 /* src/vm/jit/x86_64/asmpart.S - Java-C interface functions for x86_64
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29             Christian Thalinger
  30
  31    Changes: Edwin Steiner
  32
  33    $Id: asmpart.S 4713 2006-03-30 12:01:50Z twisti $
  34
  35 */
  36
  37
  38 #include "config.h"
  39
  40 #include "vm/jit/x86_64/arch.h"
  41 #include "vm/jit/x86_64/md-abi.h"
  42 #include "vm/jit/x86_64/md-asm.h"
  43 #include "vm/jit/x86_64/offsets.h"
  44
  45 #include "vm/jit/abi-asm.h"
  46 #include "vm/jit/methodheader.h"
  47
  48
  49         .text
  50
  51
  52 /* export functions ***********************************************************/
  53
  54         .globl asm_vm_call_method
  55         .globl asm_vm_call_method_int
  56         .globl asm_vm_call_method_long
  57         .globl asm_vm_call_method_float
  58         .globl asm_vm_call_method_double
  59         .globl asm_vm_call_method_exception_handler
  60
  61         .globl asm_call_jit_compiler
  62         .globl asm_handle_exception
  63         .globl asm_handle_nat_exception
  64
  65         .globl asm_wrapper_patcher
  66
  67         .globl asm_replacement_out
  68         .globl asm_replacement_in
  69
  70         .globl asm_builtin_f2i
  71         .globl asm_builtin_f2l
  72         .globl asm_builtin_d2i
  73         .globl asm_builtin_d2l
  74
  75         .globl asm_perform_threadswitch
  76         .globl asm_initialize_thread_stack
  77         .globl asm_switchstackandcall
  78         .globl asm_criticalsections
  79         .globl asm_getclassvalues_atomic
  80
  81
  82 /********************* function asm_calljavafunction ***************************
  83 *                                                                              *
  84 *   This function calls a Java-method (which possibly needs compilation)       *
  85 *   with up to 4 address parameters.                                           *
  86 *                                                                              *
  87 *   This functions calls the JIT-compiler which eventually translates the      *
  88 *   method into machine code.                                                  *
  89 *                                                                              *
  90 *   C-prototype:                                                               *
  91 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  92 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  93 *                                                                              *
  94 *******************************************************************************/
  95
  96         .align  8
  97
  98         .quad   0                           /* catch type all                     */
  99         .quad   0                           /* handler pc                         */
 100         .quad   0                           /* end pc                             */
 101         .quad   0                           /* start pc                           */
 102         .long   1                           /* extable size                       */
 103         .long   0
 104         .quad   0                           /* line number table  start           */
 105         .quad   0                           /* line number table  size            */
 106         .long   0
 107         .long   0                           /* fltsave                            */
 108         .long   0                           /* intsave                            */
 109         .long   0                           /* isleaf                             */
 110         .long   0                           /* IsSync                             */
 111         .long   0                           /* frame size                         */
 112         .quad   0                           /* method pointer (pointer to name)   */
 113
 114 asm_vm_call_method:
 115 asm_vm_call_method_int:
 116 asm_vm_call_method_long:
 117 asm_vm_call_method_float:
 118 asm_vm_call_method_double:
 119         sub     $(7*8),sp                   /* keep stack 16-byte aligned         */
 120         mov     %rbx,0*8(sp)                /* %rbx is not a callee saved in cacao*/
 121         mov     s0,1*8(sp)
 122         mov     s1,2*8(sp)
 123         mov     s2,3*8(sp)
 124         mov     s3,4*8(sp)
 125         mov     s4,5*8(sp)
 126
 127         mov     a0,itmp1                    /* move method pointer for compiler   */
 128         xor     %rbp,%rbp                   /* set argument stack frame to zero   */
 129
 130         test    a1,a1                       /* maybe we have no args...           */
 131         jle     L_copy_done
 132
 133         mov     a1,itmp3                    /* arg count                          */
 134         mov     a2,itmp2                    /* pointer to arg block               */
 135
 136         mov     itmp2,%r14                  /* save argument block pointer        */
 137         mov     itmp3,%r15                  /* save argument count                */
 138
 139         sub     $sizevmarg,itmp2            /* initialize pointer (smaller code)  */
 140         add     $1,itmp3                    /* initialize argument count          */
 141         xor     %r12,%r12                   /* initialize integer argument counter*/
 142         xor     %r13,%r13                   /* initialize float argument counter  */
 143
 144 L_register_copy:
 145         add     $sizevmarg,itmp2            /* goto next argument block           */
 146         dec     itmp3                       /* argument count - 1                 */
 147         jz      L_register_copy_done
 148         andb    $0x02,offvmargtype(itmp2)   /* is this a float/double type?       */
 149         jnz     L_register_handle_float     /* yes, handle it                     */
 150
 151         cmp     $INT_ARG_CNT,%r12           /* are we out of integer argument     */
 152         je      L_register_copy             /* register? yes, next loop           */
 153
 154         lea     jumptable_integer(%rip),%rbp
 155         mov     0(%rbp,%r12,8),%rbx
 156         inc     %r12                      /* integer argument counter + 1         */
 157         jmp     *%rbx
 158
 159 L_register_handle_float:
 160         cmp     $FLT_ARG_CNT,%r13         /* are we out of float argument         */
 161         je      L_register_copy           /* register? yes, next loop             */
 162
 163         lea     jumptable_float(%rip),%rbp
 164         mov     0(%rbp,%r13,8),%rbx
 165         inc     %r13                      /* float argument counter + 1           */
 166         jmp     *%rbx
 167
 168 L_register_copy_done:
 169         mov     %r15,%rbp                 /* calculate remaining arguments        */
 170         sub     %r12,%rbp                 /* - integer arguments in registers     */
 171         sub     %r13,%rbp                 /* - float arguments in registers       */
 172         jle     L_copy_done               /* are all assigned to registers?       */
 173
 174         and     $0xfffffffffffffffe,%rbp  /* keep stack 16-byte aligned           */
 175         shl     $3,%rbp                   /* calculate stack size                 */
 176         sub     %rbp,sp                   /* stack frame for arguments            */
 177         mov     sp,%rbx                   /* use %rbx as temp sp                  */
 178
 179         sub     $sizevmarg,%r14           /* initialize pointer (smaller code)    */
 180         add     $1,%r15                   /* initialize argument count            */
 181
 182 L_stack_copy_loop:
 183         add     $sizevmarg,%r14           /* goto next argument block             */
 184         dec     %r15                      /* are there any arguments left?        */
 185         jz      L_copy_done               /* no test needed after dec             */
 186
 187         andb    $0x02,offvmargtype(%r14)    /* is this a float/double type?       */
 188         jnz     L_stack_handle_float
 189         dec     %r12                        /* arguments assigned to registers    */
 190         jge     L_stack_copy_loop
 191         jmp     L_stack_copy
 192
 193 L_stack_handle_float:
 194         dec     %r13                        /* arguments assigned to registers    */
 195         jge     L_stack_copy_loop
 196
 197 L_stack_copy:
 198         mov     offvmargdata(%r14),itmp3    /* copy s8 argument onto stack        */
 199         mov     itmp3,0(%rbx)
 200         add     $8,%rbx                     /* increase sp to next argument       */
 201         jmp     L_stack_copy_loop
 202
 203 L_copy_done:
 204                                             /* itmp1 still contains method pointer*/
 205         lea     L_asm_call_jit_compiler(%rip),itmp3
 206         call    *itmp3                      /* call JIT compiler                  */
 207
 208         add     bp,sp                       /* remove argument stack frame if any */
 209
 210 L_asm_vm_call_method_return:
 211         mov     0*8(sp),%rbx                /* restore callee saved registers     */
 212         mov     1*8(sp),s0
 213         mov     2*8(sp),s1
 214         mov     3*8(sp),s2
 215         mov     4*8(sp),s3
 216         mov     5*8(sp),s4
 217         add     $(7*8),sp                   /* free stack space                   */
 218         ret
 219
 220 asm_vm_call_method_exception_handler:
 221 #if !defined(NDEBUG)
 222         mov     xptr,a0                     /* pass exception pointer             */
 223         call    builtin_throw_exception@PLT
 224 #endif
 225         xor     v0,v0                       /* return NULL                        */
 226         jmp     L_asm_vm_call_method_return
 227
 228
 229 jumptable_integer:
 230         .quad   handle_a0
 231         .quad   handle_a1
 232         .quad   handle_a2
 233         .quad   handle_a3
 234         .quad   handle_a4
 235         .quad   handle_a5
 236
 237 handle_a0:
 238         mov     offvmargdata(itmp2),a0
 239         jmp     L_register_copy
 240 handle_a1:
 241         mov     offvmargdata(itmp2),a1
 242         jmp     L_register_copy
 243 handle_a2:
 244         mov     offvmargdata(itmp2),a2
 245         jmp     L_register_copy
 246 handle_a3:
 247         mov     offvmargdata(itmp2),a3
 248         jmp     L_register_copy
 249 handle_a4:
 250         mov     offvmargdata(itmp2),a4
 251         jmp     L_register_copy
 252 handle_a5:
 253         mov     offvmargdata(itmp2),a5
 254         jmp     L_register_copy
 255
 256
 257 jumptable_float:
 258         .quad   handle_fa0
 259         .quad   handle_fa1
 260         .quad   handle_fa2
 261         .quad   handle_fa3
 262         .quad   handle_fa4
 263         .quad   handle_fa5
 264         .quad   handle_fa6
 265         .quad   handle_fa7
 266
 267 handle_fa0:
 268         movq    offvmargdata(itmp2),fa0
 269         jmp     L_register_copy
 270 handle_fa1:
 271         movq    offvmargdata(itmp2),fa1
 272         jmp     L_register_copy
 273 handle_fa2:
 274         movq    offvmargdata(itmp2),fa2
 275         jmp     L_register_copy
 276 handle_fa3:
 277         movq    offvmargdata(itmp2),fa3
 278         jmp     L_register_copy
 279 handle_fa4:
 280         movq    offvmargdata(itmp2),fa4
 281         jmp     L_register_copy
 282 handle_fa5:
 283         movq    offvmargdata(itmp2),fa5
 284         jmp     L_register_copy
 285 handle_fa6:
 286         movq    offvmargdata(itmp2),fa6
 287         jmp     L_register_copy
 288 handle_fa7:
 289         movq    offvmargdata(itmp2),fa7
 290         jmp     L_register_copy
 291
 292
 293 /****************** function asm_call_jit_compiler *****************************
 294 *                                                                              *
 295 *   invokes the compiler for untranslated JavaVM methods.                      *
 296 *                                                                              *
 297 *   Register R0 contains a pointer to the method info structure (prepared      *
 298 *   by createcompilerstub). Using the return address in R26 and the            *
 299 *   offset in the LDA instruction or using the value in methodptr R28 the      *
 300 *   patching address for storing the method address can be computed:           *
 301 *                                                                              *
 302 *   method address was either loaded using                                     *
 303 *                                                                              *
 304 *   i386_mov_imm_reg(a, REG_ITMP2)                ; invokestatic/special       *
 305 *   i386_call_reg(REG_ITMP2)                                                   *
 306 *                                                                              *
 307 *   or                                                                         *
 308 *                                                                              *
 309 *   i386_mov_membase_reg(REG_SP, 0, REG_ITMP2)    ; invokevirtual/interface    *
 310 *   i386_mov_membase_reg(REG_ITMP2, OFFSET(, vftbl), REG_ITMP3)                *
 311 *   i386_mov_membase_reg(REG_ITMP3, OFFSET(vftbl, table[0]) + \                *
 312 *       sizeof(methodptr) * m->vftblindex, REG_ITMP1)                          *
 313 *   i386_call_reg(REG_ITMP1)                                                   *
 314 *                                                                              *
 315 *   in the static case the method pointer can be computed using the            *
 316 *   return address and the lda function following the jmp instruction          *
 317 *                                                                              *
 318 *******************************************************************************/
 319
 320 asm_call_jit_compiler:
 321 L_asm_call_jit_compiler:                /* required for PIC code              */
 322                                             /* keep stack 16-byte aligned         */
 323         sub     $((3+ARG_CNT)*8+sizestackframeinfo),sp
 324
 325         mov     t0,0*8(sp)                  /* save register                      */
 326
 327         mov     (3+ARG_CNT)*8+sizestackframeinfo(sp),itmp3 /* get return address  */
 328         mov     -1(itmp3),%bl               /* get function code                  */
 329         cmp     $0xd2,%bl                   /* called with `call *REG_ITMP2'?     */
 330         jne     L_not_static_special
 331
 332         sub     $11,itmp3                   /* calculate address of immediate     */
 333         jmp     L_call_jit_compile
 334
 335 L_not_static_special:
 336         cmp     $0xd0,%bl                   /* called with `call *REG_ITMP1'      */
 337         jne     L_not_virtual_interface
 338
 339         sub     $7,itmp3                    /* calculate address of offset        */
 340         mov     (itmp3),itmp3l              /* get offset (32-bit)                */
 341         add     itmp2,itmp3                 /* add base address to get method addr*/
 342         jmp     L_call_jit_compile
 343
 344 L_not_virtual_interface:                /* a call from asm_calljavamethod     */
 345         xor     itmp3,itmp3
 346
 347 L_call_jit_compile:
 348         mov     0*8(sp),t0                  /* restore register                   */
 349         mov     itmp3,0*8(sp)               /* save address for method pointer    */
 350         mov     itmp1,1*8(sp)               /* save method pointer                */
 351
 352         SAVE_ARGUMENT_REGISTERS(3)
 353
 354         mov     sp,a0                       /* create stackframe info             */
 355         add     $((3+ARG_CNT)*8),a0         /* pass sfi                           */
 356         xor     a1,a1                       /* if pv is NULL, use findmethod      */
 357         mov     sp,a2                       /* pass java sp                       */
 358         add     $((1+3+ARG_CNT)*8+sizestackframeinfo),a2
 359                                             /* pass ra to java function           */
 360         mov     ((3+ARG_CNT)*8+sizestackframeinfo)(sp),a3
 361         mov     a3,a4                       /* xpc is equal to ra                 */
 362         call    stacktrace_create_extern_stackframeinfo@PLT
 363
 364         mov     1*8(sp),a0                  /* pass method pointer                */
 365         call    jit_compile@PLT
 366         mov     v0,1*8(sp)                  /* save return value                  */
 367
 368         mov     sp,a0                       /* remove stackframe info             */
 369         add     $((3+ARG_CNT)*8),a0         /* pass sfi                           */
 370         call    stacktrace_remove_stackframeinfo@PLT
 371
 372         mov     0*8(sp),itmp3               /* restore address for method pointer */
 373         mov     1*8(sp),v0                  /* restore return value               */
 374
 375         RESTORE_ARGUMENT_REGISTERS(3)
 376
 377         add     $((3+ARG_CNT)*8+sizestackframeinfo),sp /* remove stack frame      */
 378
 379         test    v0,v0                       /* check for exception                */
 380         je      L_asm_call_jit_compiler_exception
 381
 382         test    itmp3,itmp3                 /* is address == 0 (asm_calljavamethod*/
 383         je      L_call_method
 384
 385         mov     v0,(itmp3)                  /* and now save the new pointer       */
 386
 387 L_call_method:
 388         jmp     *v0                         /* ...and now call the new method     */
 389
 390 L_asm_call_jit_compiler_exception:
 391 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 392         call    builtin_asm_get_exceptionptrptr@PLT
 393         mov     v0,itmp2                    /* v0 == xptr                         */
 394 #else
 395         lea     _no_threads_exceptionptr(%rip),itmp2
 396 #endif
 397         mov     (itmp2),xptr                /* get the exception pointer          */
 398         movl    $0,(itmp2)                  /* clear exception pointer            */
 399
 400         pop     xpc                         /* delete return address              */
 401         sub     $5,xpc                      /* faulting address is ra - 5         */
 402         jmp     L_asm_handle_exception
 403
 404
 405 /* asm_handle_exception ********************************************************
 406 *                                                                              *
 407 *   This function handles an exception. It does not use the usual calling      *
 408 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 409 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 410 *   the local exception table for a handler. If no one is found, it unwinds    *
 411 *   stacks and continues searching the callers.                                *
 412 *                                                                              *
 413 *******************************************************************************/
 414
 415 asm_handle_nat_exception:
 416         add     $8,sp                       /* clear return address of native stub*/
 417
 418 asm_handle_exception:
 419 L_asm_handle_exception:                 /* required for PIC code              */
 420         sub     $((ARG_CNT+TMP_CNT)*8),sp   /* create maybe-leaf stackframe       */
 421
 422         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 423         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 424
 425         mov     $((ARG_CNT+TMP_CNT)*8),a3   /* prepare a3 for handle_exception    */
 426         mov     $1,t0                       /* set maybe-leaf flag                */
 427
 428 L_asm_handle_exception_stack_loop:
 429         sub     $(6*8),sp
 430         mov     xptr,0*8(sp)                /* save exception pointer             */
 431         mov     xpc,1*8(sp)                 /* save exception pc                  */
 432         add     sp,a3                       /* calculate Java sp into a3...       */
 433         add     $(6*8),a3
 434         mov     a3,3*8(sp)                  /* ...and save it                     */
 435         mov     t0,4*8(sp)                  /* save maybe-leaf flag               */
 436
 437         mov     xpc,a0                      /* exception pc                       */
 438         call    codegen_findmethod@PLT
 439         mov     v0,2*8(sp)                  /* save data segment pointer          */
 440
 441         mov     0*8(sp),a0                  /* pass exception pointer             */
 442         mov     1*8(sp),a1                  /* pass exception pc                  */
 443         mov     v0,a2                       /* pass data segment pointer          */
 444         mov     3*8(sp),a3                  /* pass Java stack pointer            */
 445         call    exceptions_handle_exception@PLT
 446
 447         test    v0,v0
 448         jz      L_asm_handle_exception_not_catched
 449
 450         mov     v0,xpc                      /* move handlerpc into xpc            */
 451         mov     0*8(sp),xptr                /* restore exception pointer          */
 452         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 453         add     $(6*8),sp                   /* free stack frame                   */
 454
 455         test    t0,t0                       /* test for maybe-leaf flag           */
 456         jz      L_asm_handle_exception_no_leaf
 457
 458         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 459         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 460
 461         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 462
 463 L_asm_handle_exception_no_leaf:
 464         jmp     *xpc                        /* jump to the handler                */
 465
 466 L_asm_handle_exception_not_catched:
 467         mov     0*8(sp),xptr                /* restore exception pointer          */
 468         mov     2*8(sp),itmp3               /* restore data segment pointer       */
 469         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 470         add     $(6*8),sp
 471
 472         test    t0,t0
 473         jz      L_asm_handle_exception_no_leaf_stack
 474
 475         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 476         xor     t0,t0                       /* clear the isleaf flags             */
 477
 478 L_asm_handle_exception_no_leaf_stack:
 479         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 480         add     sp,itmp2                    /* pointer to save area               */
 481
 482         mov     IntSave(itmp3),a0l          /* a0l = saved int register count     */
 483         test    a0l,a0l
 484         je      noint
 485
 486         cmp     $1,a0l
 487         je      int1
 488         cmp     $2,a0l
 489         je      int2
 490         cmp     $3,a0l
 491         je      int3
 492         cmp     $4,a0l
 493         je      int4
 494
 495         mov     -5*8(itmp2),s0
 496 int4:
 497         mov     -4*8(itmp2),s1
 498 int3:
 499         mov     -3*8(itmp2),s2
 500 int2:
 501         mov     -2*8(itmp2),s3
 502 int1:
 503         mov     -1*8(itmp2),s4
 504
 505         shl     $3,a0l                      /* multiply by 8 bytes                */
 506         sub     a0,itmp2
 507
 508 noint:
 509 #if 0
 510         mov     FltSave(itmp3),a0l          /* a0l = saved flt register count     */
 511         test    a0l,a0l
 512         je      noflt
 513
 514         cmpl    $1,a0l
 515         je      flt1
 516         cmpl    $2,a0l
 517         je      flt2
 518         cmpl    $3,a0l
 519         je      flt3
 520         cmpl    $4,a0l
 521         je      flt4
 522
 523         movq    -5*8(itmp2),%xmm11
 524 flt4:
 525         movq    -4*8(itmp2),%xmm12
 526 flt3:
 527         movq    -3*8(itmp2),%xmm13
 528 flt2:
 529         movq    -2*8(itmp2),%xmm14
 530 flt1:
 531         movq    -1*8(itmp2),%xmm15
 532
 533 noflt:
 534 #endif
 535         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 536         add     itmp2,sp                    /* unwind stack                       */
 537
 538                                             /* exception pointer is still set     */
 539         pop     xpc                         /* the new xpc is return address      */
 540         sub     $3,xpc                      /* subtract 3 bytes for call          */
 541
 542         xor     a3,a3                       /* prepare a3 for handle_exception    */
 543
 544         jmp             L_asm_handle_exception_stack_loop
 545
 546
 547 /* asm_wrapper_patcher *********************************************************
 548
 549    XXX
 550
 551    Stack layout:
 552      40   return address
 553      32   pointer to virtual java_objectheader
 554      24   machine code (which is patched back later)
 555      16   unresolved class/method/field reference
 556       8   data segment displacement from load instructions
 557       0   pointer to patcher function
 558      -8   bp
 559
 560 *******************************************************************************/
 561
 562 asm_wrapper_patcher:
 563         push    bp                          /* save base pointer                  */
 564         mov     sp,bp                       /* move actual sp to bp               */
 565         sub     $((3+ARG_CNT+TMP_CNT)*8+sizestackframeinfo),sp
 566         and     $0xfffffffffffffff0,sp      /* align sp to 16-byte (this is for   */
 567                                             /* leaf functions)                    */
 568
 569         SAVE_ARGUMENT_REGISTERS(3)
 570         SAVE_TEMPORARY_REGISTERS(3+ARG_CNT)
 571
 572         mov     itmp1,0*8(sp)               /* save itmp1 and itmp2               */
 573         mov     itmp2,1*8(sp)               /* can be used by some instructions   */
 574
 575         mov     sp,a0                       /* create stackframe info             */
 576         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 577         xor     a1,a1                       /* if pv is NULL, use findmethod      */
 578         mov     bp,a2                       /* pass java sp                       */
 579         add     $((6+1)*8),a2
 580         mov     ((5+1)*8)(bp),a3            /* pass ra to java function           */
 581         mov     a3,a4                       /* xpc is equal to ra                 */
 582         call    stacktrace_create_extern_stackframeinfo@PLT
 583
 584         mov     bp,a0                       /* pass stack pointer                 */
 585         add     $((1+1)*8),a0               /* skip function pointer              */
 586         mov     1*8(bp),itmp3               /* get function pointer               */
 587         call    *itmp3                      /* call the patcher function          */
 588         mov     v0,2*8(sp)                  /* save return value                  */
 589
 590         mov     sp,a0                       /* remove stackframe info             */
 591         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 592         call    stacktrace_remove_stackframeinfo@PLT
 593
 594         RESTORE_ARGUMENT_REGISTERS(3)
 595         RESTORE_TEMPORARY_REGISTERS(3+ARG_CNT)
 596
 597         mov     0*8(sp),itmp1               /* restore itmp1 and itmp2            */
 598         mov     1*8(sp),itmp2               /* can be used by some instructions   */
 599         mov     2*8(sp),itmp3               /* restore return value               */
 600
 601         mov     bp,sp                       /* restore original sp                */
 602         pop     bp                          /* restore bp                         */
 603         add     $(5*8),sp                   /* remove patcher stackframe, keep ra */
 604
 605         test    itmp3,itmp3                 /* exception thrown?                  */
 606         jz      L_asm_wrapper_patcher_exception
 607         ret                                 /* call new patched code              */
 608
 609 L_asm_wrapper_patcher_exception:
 610 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 611         call    builtin_asm_get_exceptionptrptr@PLT
 612         mov     v0,itmp2                    /* v0 == xptr                         */
 613 #else
 614         mov     _no_threads_exceptionptr,itmp2
 615 #endif
 616         mov     (itmp2),xptr                /* get the exception pointer          */
 617         movl    $0,(itmp2)                  /* clear exception pointer            */
 618
 619         pop     xpc                         /* get and remove return address      */
 620         jmp     L_asm_handle_exception
 621
 622
 623 /* asm_replacement_out *********************************************************
 624
 625    This code is jumped to from the replacement-out stubs that are executed
 626    when a thread reaches an activated replacement point.
 627
 628    The purpose of asm_replacement_out is to read out the parts of the
 629    execution state that cannot be accessed from C code, store this state,
 630    and then call the C function replace_me.
 631
 632    Stack layout:
 633       8                 start of stack inside method to replace
 634       0   rplpoint *    info on the replacement point that was reached
 635
 636 *******************************************************************************/
 637
 638 /* some room to accomodate changes of the stack frame size during replacement */
 639         /* XXX we should find a cleaner solution here */
 640 #define REPLACEMENT_ROOM  512
 641
 642 asm_replacement_out:
 643     /* create stack frame */
 644         sub     $(sizeexecutionstate + REPLACEMENT_ROOM),sp
 645
 646         /* save registers in execution state */
 647         mov     %rax,(RAX*8+offes_intregs)(sp)
 648         mov     %rbx,(RBX*8+offes_intregs)(sp)
 649         mov     %rcx,(RCX*8+offes_intregs)(sp)
 650         mov     %rdx,(RDX*8+offes_intregs)(sp)
 651         mov     %rsi,(RSI*8+offes_intregs)(sp)
 652         mov     %rdi,(RDI*8+offes_intregs)(sp)
 653         mov     %rbp,(RBP*8+offes_intregs)(sp)
 654         movq    $0  ,(RSP*8+offes_intregs)(sp) /* not used */
 655         mov     %r8 ,(R8 *8+offes_intregs)(sp)
 656         mov     %r9 ,(R9 *8+offes_intregs)(sp)
 657         mov     %r10,(R10*8+offes_intregs)(sp)
 658         mov     %r11,(R11*8+offes_intregs)(sp)
 659         mov     %r12,(R12*8+offes_intregs)(sp)
 660         mov     %r13,(R13*8+offes_intregs)(sp)
 661         mov     %r14,(R14*8+offes_intregs)(sp)
 662         mov     %r15,(R15*8+offes_intregs)(sp)
 663
 664         movq    %xmm0 ,(XMM0 *8+offes_fltregs)(sp)
 665         movq    %xmm1 ,(XMM1 *8+offes_fltregs)(sp)
 666         movq    %xmm2 ,(XMM2 *8+offes_fltregs)(sp)
 667         movq    %xmm3 ,(XMM3 *8+offes_fltregs)(sp)
 668         movq    %xmm4 ,(XMM4 *8+offes_fltregs)(sp)
 669         movq    %xmm5 ,(XMM5 *8+offes_fltregs)(sp)
 670         movq    %xmm6 ,(XMM6 *8+offes_fltregs)(sp)
 671         movq    %xmm7 ,(XMM7 *8+offes_fltregs)(sp)
 672         movq    %xmm8 ,(XMM8 *8+offes_fltregs)(sp)
 673         movq    %xmm9 ,(XMM9 *8+offes_fltregs)(sp)
 674         movq    %xmm10,(XMM10*8+offes_fltregs)(sp)
 675         movq    %xmm11,(XMM11*8+offes_fltregs)(sp)
 676         movq    %xmm12,(XMM12*8+offes_fltregs)(sp)
 677         movq    %xmm13,(XMM13*8+offes_fltregs)(sp)
 678         movq    %xmm14,(XMM14*8+offes_fltregs)(sp)
 679         movq    %xmm15,(XMM15*8+offes_fltregs)(sp)
 680
 681         /* calculate sp of method */
 682         mov     sp,itmp1
 683         add     $(sizeexecutionstate + REPLACEMENT_ROOM + 8),itmp1
 684         mov     itmp1,(offes_sp)(sp)
 685
 686         /* pv must be looked up via AVL tree */
 687         movq    $0,(offes_pv)(sp)
 688
 689         /* call replace_me */
 690         mov     -8(itmp1),a0                /* rplpoint *                         */
 691     mov     sp,a1                       /* arg1: execution state              */
 692     call    replace_me@PLT              /* call C function replace_me         */
 693     call    abort@PLT                   /* NEVER REACHED                      */
 694
 695 /* asm_replacement_in **********************************************************
 696
 697    This code writes the given execution state and jumps to the replacement
 698    code.
 699
 700    This function never returns!
 701
 702    C prototype:
 703       void asm_replacement_in(executionstate *es);
 704
 705 *******************************************************************************/
 706
 707 asm_replacement_in:
 708         mov     a0,%rbp                     /* executionstate *es                 */
 709
 710         /* set new sp */
 711         mov     (offes_sp)(%rbp),%rsp
 712
 713         /* store address of new code */
 714         push    (offes_pc)(%rbp)
 715
 716         /* copy registers from execution state */
 717         movq    (XMM0 *8+offes_fltregs)(%rbp),%xmm0
 718         movq    (XMM1 *8+offes_fltregs)(%rbp),%xmm1
 719         movq    (XMM2 *8+offes_fltregs)(%rbp),%xmm2
 720         movq    (XMM3 *8+offes_fltregs)(%rbp),%xmm3
 721         movq    (XMM4 *8+offes_fltregs)(%rbp),%xmm4
 722         movq    (XMM5 *8+offes_fltregs)(%rbp),%xmm5
 723         movq    (XMM6 *8+offes_fltregs)(%rbp),%xmm6
 724         movq    (XMM7 *8+offes_fltregs)(%rbp),%xmm7
 725         movq    (XMM8 *8+offes_fltregs)(%rbp),%xmm8
 726         movq    (XMM9 *8+offes_fltregs)(%rbp),%xmm9
 727         movq    (XMM10*8+offes_fltregs)(%rbp),%xmm10
 728         movq    (XMM11*8+offes_fltregs)(%rbp),%xmm11
 729         movq    (XMM12*8+offes_fltregs)(%rbp),%xmm12
 730         movq    (XMM13*8+offes_fltregs)(%rbp),%xmm13
 731         movq    (XMM14*8+offes_fltregs)(%rbp),%xmm14
 732         movq    (XMM15*8+offes_fltregs)(%rbp),%xmm15
 733
 734         mov     (RAX*8+offes_intregs)(%rbp),%rax
 735         mov     (RBX*8+offes_intregs)(%rbp),%rbx
 736         mov     (RCX*8+offes_intregs)(%rbp),%rcx
 737         mov     (RDX*8+offes_intregs)(%rbp),%rdx
 738         mov     (RSI*8+offes_intregs)(%rbp),%rsi
 739         mov     (RDI*8+offes_intregs)(%rbp),%rdi
 740         mov     (R8 *8+offes_intregs)(%rbp),%r8
 741         mov     (R9 *8+offes_intregs)(%rbp),%r9
 742         mov     (R10*8+offes_intregs)(%rbp),%r10
 743         mov     (R11*8+offes_intregs)(%rbp),%r11
 744         mov     (R12*8+offes_intregs)(%rbp),%r12
 745         mov     (R13*8+offes_intregs)(%rbp),%r13
 746         mov     (R14*8+offes_intregs)(%rbp),%r14
 747         mov     (R15*8+offes_intregs)(%rbp),%r15
 748
 749         mov     (RBP*8+offes_intregs)(%rbp),%rbp
 750
 751         /* jump to new code */
 752         ret
 753
 754 /* asm_builtin_x2x *************************************************************
 755 *                                                                              *
 756 *   Wrapper functions for float to int corner cases                            *
 757 *                                                                              *
 758 *******************************************************************************/
 759
 760 asm_builtin_f2i:
 761         sub     $(ARG_CNT*8),sp
 762
 763         SAVE_ARGUMENT_REGISTERS(0)
 764
 765         movq    ftmp1,fa0
 766         call    builtin_f2i@PLT
 767
 768         RESTORE_ARGUMENT_REGISTERS(0)
 769
 770         add     $(ARG_CNT*8),sp
 771         ret
 772
 773
 774 asm_builtin_f2l:
 775         sub     $(ARG_CNT*8),sp
 776
 777         SAVE_ARGUMENT_REGISTERS(0)
 778
 779         movq    ftmp1,fa0
 780         call    builtin_f2l@PLT
 781
 782         RESTORE_ARGUMENT_REGISTERS(0)
 783
 784         add     $(ARG_CNT*8),sp
 785         ret
 786
 787
 788 asm_builtin_d2i:
 789         sub     $(ARG_CNT*8),sp
 790
 791         SAVE_ARGUMENT_REGISTERS(0)
 792
 793         movq    ftmp1,fa0
 794         call    builtin_d2i@PLT
 795
 796         RESTORE_ARGUMENT_REGISTERS(0)
 797
 798         add     $(ARG_CNT*8),sp
 799         ret
 800
 801
 802 asm_builtin_d2l:
 803         sub     $(ARG_CNT*8),sp
 804
 805         SAVE_ARGUMENT_REGISTERS(0)
 806
 807         movq    ftmp1,fa0
 808         call    builtin_d2l@PLT
 809
 810         RESTORE_ARGUMENT_REGISTERS(0)
 811
 812         add     $(ARG_CNT*8),sp
 813         ret
 814
 815
 816 /******************* function asm_initialize_thread_stack **********************
 817 *                                                                              *
 818 * initialized a thread stack                                                   *
 819 * (to)->restorePoint = asm_initialize_thread_stack((u1*)(func), (to)->stackEnd)*
 820 *                                                                              *
 821 *******************************************************************************/
 822
 823 asm_initialize_thread_stack:
 824         sub     $(7*8),%rsi
 825
 826         xor     %r10,%r10
 827         mov     %r10,0*8(%rsi)
 828         mov     %r10,1*8(%rsi)
 829         mov     %r10,2*8(%rsi)
 830         mov     %r10,3*8(%rsi)
 831         mov     %r10,4*8(%rsi)
 832         mov     %r10,5*8(%rsi)
 833
 834         mov     %rdi,6*8(%rsi)          /* save (u1*) (func)                  */
 835         mov     %rsi,%rax               /* return restorepoint in %rax        */
 836         ret
 837
 838
 839 /******************* function asm_perform_threadswitch *************************
 840 *                                                                              *
 841 *   void asm_perform_threadswitch (u1 **from, u1 **to, u1 **stackTop);         *
 842 *                                                                              *
 843 *   performs a threadswitch                                                    *
 844 *                                                                              *
 845 *******************************************************************************/
 846
 847 asm_perform_threadswitch:
 848         sub     $(7*8),%rsp             /* allocate stack frame               */
 849
 850         mov     %rbx,0*8(%rsp)
 851         mov     %rbp,1*8(%rsp)
 852         mov     %r12,2*8(%rsp)
 853         mov     %r13,3*8(%rsp)
 854         mov     %r14,4*8(%rsp)
 855         mov     %r15,5*8(%rsp)
 856
 857         mov     7*8(%rsp),%rax                  /* save current return address        */
 858         mov     %rax,6*8(%rsp)
 859
 860         mov     %rsp,(%rdi)                     /* first argument **from              */
 861         mov     %rsp,(%rdx)                     /* third argument **stackTop          */
 862
 863         mov     (%rsi),%rsp                     /* load new stack pointer             */
 864
 865         mov     0*8(%rsp),%rbx
 866         mov     1*8(%rsp),%rbp
 867         mov     2*8(%rsp),%r12
 868         mov     3*8(%rsp),%r13
 869         mov     4*8(%rsp),%r14
 870         mov     5*8(%rsp),%r15
 871
 872         mov     6*8(%rsp),%rax          /* restore return address             */
 873         add     $(7*8),%rsp             /* free stack frame                   */
 874         mov     %rax,(%rsp)
 875         ret
 876
 877
 878 /********************* function asm_switchstackandcall *************************
 879 *                                                                              *
 880 *  int asm_switchstackandcall (void *stack, void *func, void **stacktopsave,   *
 881 *                                      void *p);                                       *
 882 *                                                                              *
 883 *   Switches to a new stack, calls a function and switches back.               *
 884 *       a0 (%rdi)     new stack pointer                                        *
 885 *       a1 (%rsi)     function pointer                                         *
 886 *               a2 (%rdx)     pointer to variable where stack top should be stored     *
 887 *       a3 (%rcx)     pointer to user data, is passed to the function          *
 888 *                                                                              *
 889 *******************************************************************************/
 890
 891 asm_switchstackandcall:
 892         sub     $(1*8),%rsp             /* keep stack 16-byte aligned         */
 893         sub     $16,%rdi                                /* allocate new stack                 */
 894
 895         mov     8(%rsp),%rax                    /* save return address on new stack   */
 896         mov     %rax,(%rdi)
 897         mov     %rsp,8(%rdi)                    /* save old stack pointer on new stack*/
 898         mov     %rsp,(%rdx)                             /* save old stack pointer to variable */
 899
 900         mov     %rdi,%rsp                               /* switch to new stack                */
 901
 902         mov     %rcx,%rdi                       /* pass pointer                       */
 903         call    *%rsi                                   /* and call function                  */
 904
 905         mov     (%rsp),%r10                             /* load return address                */
 906         mov     8(%rsp),%rsp                    /* switch to old stack                */
 907         add     $(1*8),%rsp             /* free stack space                   */
 908         mov     %r10,(%rsp)             /* write return adress                */
 909         ret
 910
 911
 912 asm_getclassvalues_atomic:
 913 _crit_restart:
 914 _crit_begin:
 915         movl    offbaseval(a0),itmp1l
 916         movl    offdiffval(a0),itmp2l
 917         movl    offbaseval(a1),itmp3l
 918 _crit_end:
 919         movl    itmp1l,offcast_super_baseval(a2)
 920         movl    itmp2l,offcast_super_diffval(a2)
 921         movl    itmp3l,offcast_sub_baseval(a2)
 922         ret
 923
 924         .data
 925
 926 asm_criticalsections:
 927 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 928         .quad   _crit_begin
 929         .quad   _crit_end
 930         .quad   _crit_restart
 931 #endif
 932         .quad 0
 933
 934
 935 /* Disable exec-stacks, required for Gentoo ***********************************/
 936
 937 #if defined(__GCC__) && defined(__ELF__)
 938         .section .note.GNU-stack,"",@progbits
 939 #endif
 940
 941
 942 /*
 943  * These are local overrides for various environment variables in Emacs.
 944  * Please do not remove this and leave it at the end of the file, where
 945  * Emacs will automagically detect them.
 946  * ---------------------------------------------------------------------
 947  * Local variables:
 948  * mode: asm
 949  * indent-tabs-mode: t
 950  * c-basic-offset: 4
 951  * tab-width: 4
 952  * End:
 953  * vim:noexpandtab:sw=4:ts=4:
 954  */