src/vm/jit/x86_64/asmpart.S

   1 /* src/vm/jit/x86_64/asmpart.S - Java-C interface functions for x86_64
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29             Christian Thalinger
  30
  31    Changes: Edwin Steiner
  32
  33    $Id: asmpart.S 4749 2006-04-11 10:20:18Z twisti $
  34
  35 */
  36
  37
  38 #include "config.h"
  39
  40 #include "vm/jit/x86_64/arch.h"
  41 #include "vm/jit/x86_64/md-abi.h"
  42 #include "vm/jit/x86_64/md-asm.h"
  43 #include "vm/jit/x86_64/offsets.h"
  44
  45 #include "vm/jit/abi-asm.h"
  46 #include "vm/jit/methodheader.h"
  47
  48
  49         .text
  50
  51
  52 /* export functions ***********************************************************/
  53
  54         .globl asm_vm_call_method
  55         .globl asm_vm_call_method_int
  56         .globl asm_vm_call_method_long
  57         .globl asm_vm_call_method_float
  58         .globl asm_vm_call_method_double
  59         .globl asm_vm_call_method_exception_handler
  60
  61         .globl asm_call_jit_compiler
  62         .globl asm_handle_exception
  63         .globl asm_handle_nat_exception
  64
  65         .globl asm_wrapper_patcher
  66
  67         .globl asm_replacement_out
  68         .globl asm_replacement_in
  69
  70         .globl asm_builtin_f2i
  71         .globl asm_builtin_f2l
  72         .globl asm_builtin_d2i
  73         .globl asm_builtin_d2l
  74
  75         .globl asm_perform_threadswitch
  76         .globl asm_initialize_thread_stack
  77         .globl asm_switchstackandcall
  78         .globl asm_criticalsections
  79         .globl asm_getclassvalues_atomic
  80
  81
  82 /********************* function asm_calljavafunction ***************************
  83 *                                                                              *
  84 *   This function calls a Java-method (which possibly needs compilation)       *
  85 *   with up to 4 address parameters.                                           *
  86 *                                                                              *
  87 *   This functions calls the JIT-compiler which eventually translates the      *
  88 *   method into machine code.                                                  *
  89 *                                                                              *
  90 *   C-prototype:                                                               *
  91 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  92 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  93 *                                                                              *
  94 *******************************************************************************/
  95
  96         .align  8
  97
  98         .quad   0                           /* catch type all                     */
  99         .quad   0                           /* handler pc                         */
 100         .quad   0                           /* end pc                             */
 101         .quad   0                           /* start pc                           */
 102         .long   1                           /* extable size                       */
 103         .long   0
 104         .quad   0                           /* line number table  start           */
 105         .quad   0                           /* line number table  size            */
 106         .long   0
 107         .long   0                           /* fltsave                            */
 108         .long   0                           /* intsave                            */
 109         .long   0                           /* isleaf                             */
 110         .long   0                           /* IsSync                             */
 111         .long   0                           /* frame size                         */
 112         .quad   0                           /* method pointer (pointer to name)   */
 113
 114 asm_vm_call_method:
 115 asm_vm_call_method_int:
 116 asm_vm_call_method_long:
 117 asm_vm_call_method_float:
 118 asm_vm_call_method_double:
 119         sub     $(7*8),sp                   /* keep stack 16-byte aligned         */
 120         mov     %rbx,0*8(sp)                /* %rbx is not a callee saved in cacao*/
 121         mov     s0,1*8(sp)
 122         mov     s1,2*8(sp)
 123         mov     s2,3*8(sp)
 124         mov     s3,4*8(sp)
 125         mov     s4,5*8(sp)
 126
 127         mov     a0,itmp1                    /* move method pointer for compiler   */
 128         xor     %rbp,%rbp                   /* set argument stack frame to zero   */
 129
 130         test    a1,a1                       /* maybe we have no args...           */
 131         jle     L_copy_done
 132
 133         mov     a1,itmp3                    /* arg count                          */
 134         mov     a2,itmp2                    /* pointer to arg block               */
 135
 136         mov     itmp2,%r14                  /* save argument block pointer        */
 137         mov     itmp3,%r15                  /* save argument count                */
 138
 139         sub     $sizevmarg,itmp2            /* initialize pointer (smaller code)  */
 140         add     $1,itmp3                    /* initialize argument count          */
 141         xor     %r12,%r12                   /* initialize integer argument counter*/
 142         xor     %r13,%r13                   /* initialize float argument counter  */
 143
 144 L_register_copy:
 145         add     $sizevmarg,itmp2            /* goto next argument block           */
 146         dec     itmp3                       /* argument count - 1                 */
 147         jz      L_register_copy_done
 148         andb    $0x02,offvmargtype(itmp2)   /* is this a float/double type?       */
 149         jnz     L_register_handle_float     /* yes, handle it                     */
 150
 151         cmp     $INT_ARG_CNT,%r12           /* are we out of integer argument     */
 152         je      L_register_copy             /* register? yes, next loop           */
 153
 154         lea     jumptable_integer(%rip),%rbp
 155         mov     0(%rbp,%r12,8),%rbx
 156         inc     %r12                      /* integer argument counter + 1         */
 157         jmp     *%rbx
 158
 159 L_register_handle_float:
 160         cmp     $FLT_ARG_CNT,%r13         /* are we out of float argument         */
 161         je      L_register_copy           /* register? yes, next loop             */
 162
 163         lea     jumptable_float(%rip),%rbp
 164         mov     0(%rbp,%r13,8),%rbx
 165         inc     %r13                      /* float argument counter + 1           */
 166         jmp     *%rbx
 167
 168 L_register_copy_done:
 169         mov     %r15,%rbp                 /* calculate remaining arguments        */
 170         sub     %r12,%rbp                 /* - integer arguments in registers     */
 171         sub     %r13,%rbp                 /* - float arguments in registers       */
 172         jle     L_copy_done               /* are all assigned to registers?       */
 173
 174         and     $0xfffffffffffffffe,%rbp  /* keep stack 16-byte aligned           */
 175         shl     $3,%rbp                   /* calculate stack size                 */
 176         sub     %rbp,sp                   /* stack frame for arguments            */
 177         mov     sp,%rbx                   /* use %rbx as temp sp                  */
 178
 179         sub     $sizevmarg,%r14           /* initialize pointer (smaller code)    */
 180         add     $1,%r15                   /* initialize argument count            */
 181
 182 L_stack_copy_loop:
 183         add     $sizevmarg,%r14           /* goto next argument block             */
 184         dec     %r15                      /* are there any arguments left?        */
 185         jz      L_copy_done               /* no test needed after dec             */
 186
 187         andb    $0x02,offvmargtype(%r14)    /* is this a float/double type?       */
 188         jnz     L_stack_handle_float
 189         dec     %r12                        /* arguments assigned to registers    */
 190         jge     L_stack_copy_loop
 191         jmp     L_stack_copy
 192
 193 L_stack_handle_float:
 194         dec     %r13                        /* arguments assigned to registers    */
 195         jge     L_stack_copy_loop
 196
 197 L_stack_copy:
 198         mov     offvmargdata(%r14),itmp3    /* copy s8 argument onto stack        */
 199         mov     itmp3,0(%rbx)
 200         add     $8,%rbx                     /* increase sp to next argument       */
 201         jmp     L_stack_copy_loop
 202
 203 L_copy_done:
 204                                             /* itmp1 still contains method pointer*/
 205         lea     L_asm_call_jit_compiler(%rip),itmp3
 206         call    *itmp3                      /* call JIT compiler                  */
 207
 208         add     bp,sp                       /* remove argument stack frame if any */
 209
 210 L_asm_vm_call_method_return:
 211         mov     0*8(sp),%rbx                /* restore callee saved registers     */
 212         mov     1*8(sp),s0
 213         mov     2*8(sp),s1
 214         mov     3*8(sp),s2
 215         mov     4*8(sp),s3
 216         mov     5*8(sp),s4
 217         add     $(7*8),sp                   /* free stack space                   */
 218         ret
 219
 220 asm_vm_call_method_exception_handler:
 221         mov     xptr,a0                     /* pass exception pointer             */
 222         call    builtin_throw_exception@PLT
 223         jmp     L_asm_vm_call_method_return
 224
 225
 226 jumptable_integer:
 227         .quad   handle_a0
 228         .quad   handle_a1
 229         .quad   handle_a2
 230         .quad   handle_a3
 231         .quad   handle_a4
 232         .quad   handle_a5
 233
 234 handle_a0:
 235         mov     offvmargdata(itmp2),a0
 236         jmp     L_register_copy
 237 handle_a1:
 238         mov     offvmargdata(itmp2),a1
 239         jmp     L_register_copy
 240 handle_a2:
 241         mov     offvmargdata(itmp2),a2
 242         jmp     L_register_copy
 243 handle_a3:
 244         mov     offvmargdata(itmp2),a3
 245         jmp     L_register_copy
 246 handle_a4:
 247         mov     offvmargdata(itmp2),a4
 248         jmp     L_register_copy
 249 handle_a5:
 250         mov     offvmargdata(itmp2),a5
 251         jmp     L_register_copy
 252
 253
 254 jumptable_float:
 255         .quad   handle_fa0
 256         .quad   handle_fa1
 257         .quad   handle_fa2
 258         .quad   handle_fa3
 259         .quad   handle_fa4
 260         .quad   handle_fa5
 261         .quad   handle_fa6
 262         .quad   handle_fa7
 263
 264 handle_fa0:
 265         movq    offvmargdata(itmp2),fa0
 266         jmp     L_register_copy
 267 handle_fa1:
 268         movq    offvmargdata(itmp2),fa1
 269         jmp     L_register_copy
 270 handle_fa2:
 271         movq    offvmargdata(itmp2),fa2
 272         jmp     L_register_copy
 273 handle_fa3:
 274         movq    offvmargdata(itmp2),fa3
 275         jmp     L_register_copy
 276 handle_fa4:
 277         movq    offvmargdata(itmp2),fa4
 278         jmp     L_register_copy
 279 handle_fa5:
 280         movq    offvmargdata(itmp2),fa5
 281         jmp     L_register_copy
 282 handle_fa6:
 283         movq    offvmargdata(itmp2),fa6
 284         jmp     L_register_copy
 285 handle_fa7:
 286         movq    offvmargdata(itmp2),fa7
 287         jmp     L_register_copy
 288
 289
 290 /****************** function asm_call_jit_compiler *****************************
 291 *                                                                              *
 292 *   invokes the compiler for untranslated JavaVM methods.                      *
 293 *                                                                              *
 294 *   Register R0 contains a pointer to the method info structure (prepared      *
 295 *   by createcompilerstub). Using the return address in R26 and the            *
 296 *   offset in the LDA instruction or using the value in methodptr R28 the      *
 297 *   patching address for storing the method address can be computed:           *
 298 *                                                                              *
 299 *   method address was either loaded using                                     *
 300 *                                                                              *
 301 *   i386_mov_imm_reg(a, REG_ITMP2)                ; invokestatic/special       *
 302 *   i386_call_reg(REG_ITMP2)                                                   *
 303 *                                                                              *
 304 *   or                                                                         *
 305 *                                                                              *
 306 *   i386_mov_membase_reg(REG_SP, 0, REG_ITMP2)    ; invokevirtual/interface    *
 307 *   i386_mov_membase_reg(REG_ITMP2, OFFSET(, vftbl), REG_ITMP3)                *
 308 *   i386_mov_membase_reg(REG_ITMP3, OFFSET(vftbl, table[0]) + \                *
 309 *       sizeof(methodptr) * m->vftblindex, REG_ITMP1)                          *
 310 *   i386_call_reg(REG_ITMP1)                                                   *
 311 *                                                                              *
 312 *   in the static case the method pointer can be computed using the            *
 313 *   return address and the lda function following the jmp instruction          *
 314 *                                                                              *
 315 *******************************************************************************/
 316
 317 asm_call_jit_compiler:
 318 L_asm_call_jit_compiler:                /* required for PIC code              */
 319                                             /* keep stack 16-byte aligned         */
 320         sub     $((3+ARG_CNT)*8+sizestackframeinfo),sp
 321
 322         mov     t0,0*8(sp)                  /* save register                      */
 323
 324         mov     (3+ARG_CNT)*8+sizestackframeinfo(sp),itmp3 /* get return address  */
 325         mov     -1(itmp3),%bl               /* get function code                  */
 326         cmp     $0xd2,%bl                   /* called with `call *REG_ITMP2'?     */
 327         jne     L_not_static_special
 328
 329         sub     $11,itmp3                   /* calculate address of immediate     */
 330         jmp     L_call_jit_compile
 331
 332 L_not_static_special:
 333         cmp     $0xd0,%bl                   /* called with `call *REG_ITMP1'      */
 334         jne     L_not_virtual_interface
 335
 336         sub     $7,itmp3                    /* calculate address of offset        */
 337         mov     (itmp3),itmp3l              /* get offset (32-bit)                */
 338         add     itmp2,itmp3                 /* add base address to get method addr*/
 339         jmp     L_call_jit_compile
 340
 341 L_not_virtual_interface:                /* a call from asm_calljavamethod     */
 342         xor     itmp3,itmp3
 343
 344 L_call_jit_compile:
 345         mov     0*8(sp),t0                  /* restore register                   */
 346         mov     itmp3,0*8(sp)               /* save address for method pointer    */
 347         mov     itmp1,1*8(sp)               /* save method pointer                */
 348
 349         SAVE_ARGUMENT_REGISTERS(3)
 350
 351         mov     sp,a0                       /* create stackframe info             */
 352         add     $((3+ARG_CNT)*8),a0         /* pass sfi                           */
 353         xor     a1,a1                       /* if pv is NULL, use findmethod      */
 354         mov     sp,a2                       /* pass java sp                       */
 355         add     $((1+3+ARG_CNT)*8+sizestackframeinfo),a2
 356                                             /* pass ra to java function           */
 357         mov     ((3+ARG_CNT)*8+sizestackframeinfo)(sp),a3
 358         mov     a3,a4                       /* xpc is equal to ra                 */
 359         call    stacktrace_create_extern_stackframeinfo@PLT
 360
 361         mov     1*8(sp),a0                  /* pass method pointer                */
 362         call    jit_compile@PLT
 363         mov     v0,1*8(sp)                  /* save return value                  */
 364
 365         mov     sp,a0                       /* remove stackframe info             */
 366         add     $((3+ARG_CNT)*8),a0         /* pass sfi                           */
 367         call    stacktrace_remove_stackframeinfo@PLT
 368
 369         mov     0*8(sp),itmp3               /* restore address for method pointer */
 370         mov     1*8(sp),v0                  /* restore return value               */
 371
 372         RESTORE_ARGUMENT_REGISTERS(3)
 373
 374         add     $((3+ARG_CNT)*8+sizestackframeinfo),sp /* remove stack frame      */
 375
 376         test    v0,v0                       /* check for exception                */
 377         je      L_asm_call_jit_compiler_exception
 378
 379         test    itmp3,itmp3                 /* is address == 0 (asm_calljavamethod*/
 380         je      L_call_method
 381
 382         mov     v0,(itmp3)                  /* and now save the new pointer       */
 383
 384 L_call_method:
 385         jmp     *v0                         /* ...and now call the new method     */
 386
 387 L_asm_call_jit_compiler_exception:
 388 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 389         call    builtin_asm_get_exceptionptrptr@PLT
 390         mov     v0,itmp2                    /* v0 == xptr                         */
 391 #else
 392         lea     _no_threads_exceptionptr(%rip),itmp2
 393 #endif
 394         mov     (itmp2),xptr                /* get the exception pointer          */
 395         movl    $0,(itmp2)                  /* clear exception pointer            */
 396
 397         pop     xpc                         /* delete return address              */
 398         sub     $5,xpc                      /* faulting address is ra - 5         */
 399         jmp     L_asm_handle_exception
 400
 401
 402 /* asm_handle_exception ********************************************************
 403 *                                                                              *
 404 *   This function handles an exception. It does not use the usual calling      *
 405 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 406 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 407 *   the local exception table for a handler. If no one is found, it unwinds    *
 408 *   stacks and continues searching the callers.                                *
 409 *                                                                              *
 410 *******************************************************************************/
 411
 412 asm_handle_nat_exception:
 413         add     $8,sp                       /* clear return address of native stub*/
 414
 415 asm_handle_exception:
 416 L_asm_handle_exception:                 /* required for PIC code              */
 417         sub     $((ARG_CNT+TMP_CNT)*8),sp   /* create maybe-leaf stackframe       */
 418
 419         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 420         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 421
 422         mov     $((ARG_CNT+TMP_CNT)*8),a3   /* prepare a3 for handle_exception    */
 423         mov     $1,t0                       /* set maybe-leaf flag                */
 424
 425 L_asm_handle_exception_stack_loop:
 426         sub     $(6*8),sp
 427         mov     xptr,0*8(sp)                /* save exception pointer             */
 428         mov     xpc,1*8(sp)                 /* save exception pc                  */
 429         add     sp,a3                       /* calculate Java sp into a3...       */
 430         add     $(6*8),a3
 431         mov     a3,3*8(sp)                  /* ...and save it                     */
 432         mov     t0,4*8(sp)                  /* save maybe-leaf flag               */
 433
 434         mov     xpc,a0                      /* exception pc                       */
 435         call    codegen_findmethod@PLT
 436         mov     v0,2*8(sp)                  /* save data segment pointer          */
 437
 438         mov     0*8(sp),a0                  /* pass exception pointer             */
 439         mov     1*8(sp),a1                  /* pass exception pc                  */
 440         mov     v0,a2                       /* pass data segment pointer          */
 441         mov     3*8(sp),a3                  /* pass Java stack pointer            */
 442         call    exceptions_handle_exception@PLT
 443
 444         test    v0,v0
 445         jz      L_asm_handle_exception_not_catched
 446
 447         mov     v0,xpc                      /* move handlerpc into xpc            */
 448         mov     0*8(sp),xptr                /* restore exception pointer          */
 449         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 450         add     $(6*8),sp                   /* free stack frame                   */
 451
 452         test    t0,t0                       /* test for maybe-leaf flag           */
 453         jz      L_asm_handle_exception_no_leaf
 454
 455         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 456         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 457
 458         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 459
 460 L_asm_handle_exception_no_leaf:
 461         jmp     *xpc                        /* jump to the handler                */
 462
 463 L_asm_handle_exception_not_catched:
 464         mov     0*8(sp),xptr                /* restore exception pointer          */
 465         mov     2*8(sp),itmp3               /* restore data segment pointer       */
 466         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 467         add     $(6*8),sp
 468
 469         test    t0,t0
 470         jz      L_asm_handle_exception_no_leaf_stack
 471
 472         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 473         xor     t0,t0                       /* clear the isleaf flags             */
 474
 475 L_asm_handle_exception_no_leaf_stack:
 476         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 477         add     sp,itmp2                    /* pointer to save area               */
 478
 479         mov     IntSave(itmp3),a0l          /* a0l = saved int register count     */
 480         test    a0l,a0l
 481         je      noint
 482
 483         cmp     $1,a0l
 484         je      int1
 485         cmp     $2,a0l
 486         je      int2
 487         cmp     $3,a0l
 488         je      int3
 489         cmp     $4,a0l
 490         je      int4
 491
 492         mov     -5*8(itmp2),s0
 493 int4:
 494         mov     -4*8(itmp2),s1
 495 int3:
 496         mov     -3*8(itmp2),s2
 497 int2:
 498         mov     -2*8(itmp2),s3
 499 int1:
 500         mov     -1*8(itmp2),s4
 501
 502         shl     $3,a0l                      /* multiply by 8 bytes                */
 503         sub     a0,itmp2
 504
 505 noint:
 506 #if 0
 507         mov     FltSave(itmp3),a0l          /* a0l = saved flt register count     */
 508         test    a0l,a0l
 509         je      noflt
 510
 511         cmpl    $1,a0l
 512         je      flt1
 513         cmpl    $2,a0l
 514         je      flt2
 515         cmpl    $3,a0l
 516         je      flt3
 517         cmpl    $4,a0l
 518         je      flt4
 519
 520         movq    -5*8(itmp2),%xmm11
 521 flt4:
 522         movq    -4*8(itmp2),%xmm12
 523 flt3:
 524         movq    -3*8(itmp2),%xmm13
 525 flt2:
 526         movq    -2*8(itmp2),%xmm14
 527 flt1:
 528         movq    -1*8(itmp2),%xmm15
 529
 530 noflt:
 531 #endif
 532         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 533         add     itmp2,sp                    /* unwind stack                       */
 534
 535                                             /* exception pointer is still set     */
 536         pop     xpc                         /* the new xpc is return address      */
 537         sub     $3,xpc                      /* subtract 3 bytes for call          */
 538
 539         xor     a3,a3                       /* prepare a3 for handle_exception    */
 540
 541         jmp             L_asm_handle_exception_stack_loop
 542
 543
 544 /* asm_wrapper_patcher *********************************************************
 545
 546    XXX
 547
 548    Stack layout:
 549      40   return address
 550      32   pointer to virtual java_objectheader
 551      24   machine code (which is patched back later)
 552      16   unresolved class/method/field reference
 553       8   data segment displacement from load instructions
 554       0   pointer to patcher function
 555      -8   bp
 556
 557 *******************************************************************************/
 558
 559 asm_wrapper_patcher:
 560         push    bp                          /* save base pointer                  */
 561         mov     sp,bp                       /* move actual sp to bp               */
 562         sub     $((3+ARG_CNT+TMP_CNT)*8+sizestackframeinfo),sp
 563         and     $0xfffffffffffffff0,sp      /* align sp to 16-byte (this is for   */
 564                                             /* leaf functions)                    */
 565
 566         SAVE_ARGUMENT_REGISTERS(3)
 567         SAVE_TEMPORARY_REGISTERS(3+ARG_CNT)
 568
 569         mov     itmp1,0*8(sp)               /* save itmp1 and itmp2               */
 570         mov     itmp2,1*8(sp)               /* can be used by some instructions   */
 571
 572         mov     sp,a0                       /* create stackframe info             */
 573         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 574         xor     a1,a1                       /* if pv is NULL, use findmethod      */
 575         mov     bp,a2                       /* pass java sp                       */
 576         add     $((6+1)*8),a2
 577         mov     ((5+1)*8)(bp),a3            /* pass ra to java function           */
 578         mov     a3,a4                       /* xpc is equal to ra                 */
 579         call    stacktrace_create_extern_stackframeinfo@PLT
 580
 581         mov     bp,a0                       /* pass stack pointer                 */
 582         add     $((1+1)*8),a0               /* skip function pointer              */
 583         mov     1*8(bp),itmp3               /* get function pointer               */
 584         call    *itmp3                      /* call the patcher function          */
 585         mov     v0,2*8(sp)                  /* save return value                  */
 586
 587         mov     sp,a0                       /* remove stackframe info             */
 588         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 589         call    stacktrace_remove_stackframeinfo@PLT
 590
 591         RESTORE_ARGUMENT_REGISTERS(3)
 592         RESTORE_TEMPORARY_REGISTERS(3+ARG_CNT)
 593
 594         mov     0*8(sp),itmp1               /* restore itmp1 and itmp2            */
 595         mov     1*8(sp),itmp2               /* can be used by some instructions   */
 596         mov     2*8(sp),itmp3               /* restore return value               */
 597
 598         mov     bp,sp                       /* restore original sp                */
 599         pop     bp                          /* restore bp                         */
 600         add     $(5*8),sp                   /* remove patcher stackframe, keep ra */
 601
 602         test    itmp3,itmp3                 /* exception thrown?                  */
 603         jz      L_asm_wrapper_patcher_exception
 604         ret                                 /* call new patched code              */
 605
 606 L_asm_wrapper_patcher_exception:
 607 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 608         call    builtin_asm_get_exceptionptrptr@PLT
 609         mov     v0,itmp2                    /* v0 == xptr                         */
 610 #else
 611         mov     _no_threads_exceptionptr,itmp2
 612 #endif
 613         mov     (itmp2),xptr                /* get the exception pointer          */
 614         movl    $0,(itmp2)                  /* clear exception pointer            */
 615
 616         pop     xpc                         /* get and remove return address      */
 617         jmp     L_asm_handle_exception
 618
 619
 620 /* asm_replacement_out *********************************************************
 621
 622    This code is jumped to from the replacement-out stubs that are executed
 623    when a thread reaches an activated replacement point.
 624
 625    The purpose of asm_replacement_out is to read out the parts of the
 626    execution state that cannot be accessed from C code, store this state,
 627    and then call the C function replace_me.
 628
 629    Stack layout:
 630       8                 start of stack inside method to replace
 631       0   rplpoint *    info on the replacement point that was reached
 632
 633 *******************************************************************************/
 634
 635 /* some room to accomodate changes of the stack frame size during replacement */
 636         /* XXX we should find a cleaner solution here */
 637 #define REPLACEMENT_ROOM  512
 638
 639 asm_replacement_out:
 640     /* create stack frame */
 641         sub     $(sizeexecutionstate + REPLACEMENT_ROOM),sp
 642
 643         /* save registers in execution state */
 644         mov     %rax,(RAX*8+offes_intregs)(sp)
 645         mov     %rbx,(RBX*8+offes_intregs)(sp)
 646         mov     %rcx,(RCX*8+offes_intregs)(sp)
 647         mov     %rdx,(RDX*8+offes_intregs)(sp)
 648         mov     %rsi,(RSI*8+offes_intregs)(sp)
 649         mov     %rdi,(RDI*8+offes_intregs)(sp)
 650         mov     %rbp,(RBP*8+offes_intregs)(sp)
 651         movq    $0  ,(RSP*8+offes_intregs)(sp) /* not used */
 652         mov     %r8 ,(R8 *8+offes_intregs)(sp)
 653         mov     %r9 ,(R9 *8+offes_intregs)(sp)
 654         mov     %r10,(R10*8+offes_intregs)(sp)
 655         mov     %r11,(R11*8+offes_intregs)(sp)
 656         mov     %r12,(R12*8+offes_intregs)(sp)
 657         mov     %r13,(R13*8+offes_intregs)(sp)
 658         mov     %r14,(R14*8+offes_intregs)(sp)
 659         mov     %r15,(R15*8+offes_intregs)(sp)
 660
 661         movq    %xmm0 ,(XMM0 *8+offes_fltregs)(sp)
 662         movq    %xmm1 ,(XMM1 *8+offes_fltregs)(sp)
 663         movq    %xmm2 ,(XMM2 *8+offes_fltregs)(sp)
 664         movq    %xmm3 ,(XMM3 *8+offes_fltregs)(sp)
 665         movq    %xmm4 ,(XMM4 *8+offes_fltregs)(sp)
 666         movq    %xmm5 ,(XMM5 *8+offes_fltregs)(sp)
 667         movq    %xmm6 ,(XMM6 *8+offes_fltregs)(sp)
 668         movq    %xmm7 ,(XMM7 *8+offes_fltregs)(sp)
 669         movq    %xmm8 ,(XMM8 *8+offes_fltregs)(sp)
 670         movq    %xmm9 ,(XMM9 *8+offes_fltregs)(sp)
 671         movq    %xmm10,(XMM10*8+offes_fltregs)(sp)
 672         movq    %xmm11,(XMM11*8+offes_fltregs)(sp)
 673         movq    %xmm12,(XMM12*8+offes_fltregs)(sp)
 674         movq    %xmm13,(XMM13*8+offes_fltregs)(sp)
 675         movq    %xmm14,(XMM14*8+offes_fltregs)(sp)
 676         movq    %xmm15,(XMM15*8+offes_fltregs)(sp)
 677
 678         /* calculate sp of method */
 679         mov     sp,itmp1
 680         add     $(sizeexecutionstate + REPLACEMENT_ROOM + 8),itmp1
 681         mov     itmp1,(offes_sp)(sp)
 682
 683         /* pv must be looked up via AVL tree */
 684         movq    $0,(offes_pv)(sp)
 685
 686         /* call replace_me */
 687         mov     -8(itmp1),a0                /* rplpoint *                         */
 688     mov     sp,a1                       /* arg1: execution state              */
 689     call    replace_me@PLT              /* call C function replace_me         */
 690     call    abort@PLT                   /* NEVER REACHED                      */
 691
 692 /* asm_replacement_in **********************************************************
 693
 694    This code writes the given execution state and jumps to the replacement
 695    code.
 696
 697    This function never returns!
 698
 699    C prototype:
 700       void asm_replacement_in(executionstate *es);
 701
 702 *******************************************************************************/
 703
 704 asm_replacement_in:
 705         mov     a0,%rbp                     /* executionstate *es                 */
 706
 707         /* set new sp */
 708         mov     (offes_sp)(%rbp),%rsp
 709
 710         /* store address of new code */
 711         push    (offes_pc)(%rbp)
 712
 713         /* copy registers from execution state */
 714         movq    (XMM0 *8+offes_fltregs)(%rbp),%xmm0
 715         movq    (XMM1 *8+offes_fltregs)(%rbp),%xmm1
 716         movq    (XMM2 *8+offes_fltregs)(%rbp),%xmm2
 717         movq    (XMM3 *8+offes_fltregs)(%rbp),%xmm3
 718         movq    (XMM4 *8+offes_fltregs)(%rbp),%xmm4
 719         movq    (XMM5 *8+offes_fltregs)(%rbp),%xmm5
 720         movq    (XMM6 *8+offes_fltregs)(%rbp),%xmm6
 721         movq    (XMM7 *8+offes_fltregs)(%rbp),%xmm7
 722         movq    (XMM8 *8+offes_fltregs)(%rbp),%xmm8
 723         movq    (XMM9 *8+offes_fltregs)(%rbp),%xmm9
 724         movq    (XMM10*8+offes_fltregs)(%rbp),%xmm10
 725         movq    (XMM11*8+offes_fltregs)(%rbp),%xmm11
 726         movq    (XMM12*8+offes_fltregs)(%rbp),%xmm12
 727         movq    (XMM13*8+offes_fltregs)(%rbp),%xmm13
 728         movq    (XMM14*8+offes_fltregs)(%rbp),%xmm14
 729         movq    (XMM15*8+offes_fltregs)(%rbp),%xmm15
 730
 731         mov     (RAX*8+offes_intregs)(%rbp),%rax
 732         mov     (RBX*8+offes_intregs)(%rbp),%rbx
 733         mov     (RCX*8+offes_intregs)(%rbp),%rcx
 734         mov     (RDX*8+offes_intregs)(%rbp),%rdx
 735         mov     (RSI*8+offes_intregs)(%rbp),%rsi
 736         mov     (RDI*8+offes_intregs)(%rbp),%rdi
 737         mov     (R8 *8+offes_intregs)(%rbp),%r8
 738         mov     (R9 *8+offes_intregs)(%rbp),%r9
 739         mov     (R10*8+offes_intregs)(%rbp),%r10
 740         mov     (R11*8+offes_intregs)(%rbp),%r11
 741         mov     (R12*8+offes_intregs)(%rbp),%r12
 742         mov     (R13*8+offes_intregs)(%rbp),%r13
 743         mov     (R14*8+offes_intregs)(%rbp),%r14
 744         mov     (R15*8+offes_intregs)(%rbp),%r15
 745
 746         mov     (RBP*8+offes_intregs)(%rbp),%rbp
 747
 748         /* jump to new code */
 749         ret
 750
 751 /* asm_builtin_x2x *************************************************************
 752 *                                                                              *
 753 *   Wrapper functions for float to int corner cases                            *
 754 *                                                                              *
 755 *******************************************************************************/
 756
 757 asm_builtin_f2i:
 758         sub     $(ARG_CNT*8),sp
 759
 760         SAVE_ARGUMENT_REGISTERS(0)
 761
 762         movq    ftmp1,fa0
 763         call    builtin_f2i@PLT
 764
 765         RESTORE_ARGUMENT_REGISTERS(0)
 766
 767         add     $(ARG_CNT*8),sp
 768         ret
 769
 770
 771 asm_builtin_f2l:
 772         sub     $(ARG_CNT*8),sp
 773
 774         SAVE_ARGUMENT_REGISTERS(0)
 775
 776         movq    ftmp1,fa0
 777         call    builtin_f2l@PLT
 778
 779         RESTORE_ARGUMENT_REGISTERS(0)
 780
 781         add     $(ARG_CNT*8),sp
 782         ret
 783
 784
 785 asm_builtin_d2i:
 786         sub     $(ARG_CNT*8),sp
 787
 788         SAVE_ARGUMENT_REGISTERS(0)
 789
 790         movq    ftmp1,fa0
 791         call    builtin_d2i@PLT
 792
 793         RESTORE_ARGUMENT_REGISTERS(0)
 794
 795         add     $(ARG_CNT*8),sp
 796         ret
 797
 798
 799 asm_builtin_d2l:
 800         sub     $(ARG_CNT*8),sp
 801
 802         SAVE_ARGUMENT_REGISTERS(0)
 803
 804         movq    ftmp1,fa0
 805         call    builtin_d2l@PLT
 806
 807         RESTORE_ARGUMENT_REGISTERS(0)
 808
 809         add     $(ARG_CNT*8),sp
 810         ret
 811
 812
 813 /******************* function asm_initialize_thread_stack **********************
 814 *                                                                              *
 815 * initialized a thread stack                                                   *
 816 * (to)->restorePoint = asm_initialize_thread_stack((u1*)(func), (to)->stackEnd)*
 817 *                                                                              *
 818 *******************************************************************************/
 819
 820 asm_initialize_thread_stack:
 821         sub     $(7*8),%rsi
 822
 823         xor     %r10,%r10
 824         mov     %r10,0*8(%rsi)
 825         mov     %r10,1*8(%rsi)
 826         mov     %r10,2*8(%rsi)
 827         mov     %r10,3*8(%rsi)
 828         mov     %r10,4*8(%rsi)
 829         mov     %r10,5*8(%rsi)
 830
 831         mov     %rdi,6*8(%rsi)          /* save (u1*) (func)                  */
 832         mov     %rsi,%rax               /* return restorepoint in %rax        */
 833         ret
 834
 835
 836 /******************* function asm_perform_threadswitch *************************
 837 *                                                                              *
 838 *   void asm_perform_threadswitch (u1 **from, u1 **to, u1 **stackTop);         *
 839 *                                                                              *
 840 *   performs a threadswitch                                                    *
 841 *                                                                              *
 842 *******************************************************************************/
 843
 844 asm_perform_threadswitch:
 845         sub     $(7*8),%rsp             /* allocate stack frame               */
 846
 847         mov     %rbx,0*8(%rsp)
 848         mov     %rbp,1*8(%rsp)
 849         mov     %r12,2*8(%rsp)
 850         mov     %r13,3*8(%rsp)
 851         mov     %r14,4*8(%rsp)
 852         mov     %r15,5*8(%rsp)
 853
 854         mov     7*8(%rsp),%rax                  /* save current return address        */
 855         mov     %rax,6*8(%rsp)
 856
 857         mov     %rsp,(%rdi)                     /* first argument **from              */
 858         mov     %rsp,(%rdx)                     /* third argument **stackTop          */
 859
 860         mov     (%rsi),%rsp                     /* load new stack pointer             */
 861
 862         mov     0*8(%rsp),%rbx
 863         mov     1*8(%rsp),%rbp
 864         mov     2*8(%rsp),%r12
 865         mov     3*8(%rsp),%r13
 866         mov     4*8(%rsp),%r14
 867         mov     5*8(%rsp),%r15
 868
 869         mov     6*8(%rsp),%rax          /* restore return address             */
 870         add     $(7*8),%rsp             /* free stack frame                   */
 871         mov     %rax,(%rsp)
 872         ret
 873
 874
 875 /********************* function asm_switchstackandcall *************************
 876 *                                                                              *
 877 *  int asm_switchstackandcall (void *stack, void *func, void **stacktopsave,   *
 878 *                                      void *p);                                       *
 879 *                                                                              *
 880 *   Switches to a new stack, calls a function and switches back.               *
 881 *       a0 (%rdi)     new stack pointer                                        *
 882 *       a1 (%rsi)     function pointer                                         *
 883 *               a2 (%rdx)     pointer to variable where stack top should be stored     *
 884 *       a3 (%rcx)     pointer to user data, is passed to the function          *
 885 *                                                                              *
 886 *******************************************************************************/
 887
 888 asm_switchstackandcall:
 889         sub     $(1*8),%rsp             /* keep stack 16-byte aligned         */
 890         sub     $16,%rdi                                /* allocate new stack                 */
 891
 892         mov     8(%rsp),%rax                    /* save return address on new stack   */
 893         mov     %rax,(%rdi)
 894         mov     %rsp,8(%rdi)                    /* save old stack pointer on new stack*/
 895         mov     %rsp,(%rdx)                             /* save old stack pointer to variable */
 896
 897         mov     %rdi,%rsp                               /* switch to new stack                */
 898
 899         mov     %rcx,%rdi                       /* pass pointer                       */
 900         call    *%rsi                                   /* and call function                  */
 901
 902         mov     (%rsp),%r10                             /* load return address                */
 903         mov     8(%rsp),%rsp                    /* switch to old stack                */
 904         add     $(1*8),%rsp             /* free stack space                   */
 905         mov     %r10,(%rsp)             /* write return adress                */
 906         ret
 907
 908
 909 asm_getclassvalues_atomic:
 910 _crit_restart:
 911 _crit_begin:
 912         movl    offbaseval(a0),itmp1l
 913         movl    offdiffval(a0),itmp2l
 914         movl    offbaseval(a1),itmp3l
 915 _crit_end:
 916         movl    itmp1l,offcast_super_baseval(a2)
 917         movl    itmp2l,offcast_super_diffval(a2)
 918         movl    itmp3l,offcast_sub_baseval(a2)
 919         ret
 920
 921         .data
 922
 923 asm_criticalsections:
 924 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 925         .quad   _crit_begin
 926         .quad   _crit_end
 927         .quad   _crit_restart
 928 #endif
 929         .quad 0
 930
 931
 932 /* Disable exec-stacks, required for Gentoo ***********************************/
 933
 934 #if defined(__GCC__) && defined(__ELF__)
 935         .section .note.GNU-stack,"",@progbits
 936 #endif
 937
 938
 939 /*
 940  * These are local overrides for various environment variables in Emacs.
 941  * Please do not remove this and leave it at the end of the file, where
 942  * Emacs will automagically detect them.
 943  * ---------------------------------------------------------------------
 944  * Local variables:
 945  * mode: asm
 946  * indent-tabs-mode: t
 947  * c-basic-offset: 4
 948  * tab-width: 4
 949  * End:
 950  * vim:noexpandtab:sw=4:ts=4:
 951  */