src/vm/jit/x86_64/asmpart.S

   1 /* src/vm/jit/x86_64/asmpart.S - Java-C interface functions for x86_64
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29             Christian Thalinger
  30
  31    Changes: Edwin Steiner
  32
  33    $Id: asmpart.S 5041 2006-06-20 09:10:05Z twisti $
  34
  35 */
  36
  37
  38 #include "config.h"
  39
  40 #include "vm/jit/x86_64/arch.h"
  41 #include "vm/jit/x86_64/md-abi.h"
  42 #include "vm/jit/x86_64/md-asm.h"
  43 #include "vm/jit/x86_64/offsets.h"
  44
  45 #include "vm/jit/abi-asm.h"
  46 #include "vm/jit/methodheader.h"
  47
  48
  49         .text
  50
  51
  52 /* export functions ***********************************************************/
  53
  54         .globl asm_vm_call_method
  55         .globl asm_vm_call_method_int
  56         .globl asm_vm_call_method_long
  57         .globl asm_vm_call_method_float
  58         .globl asm_vm_call_method_double
  59         .globl asm_vm_call_method_exception_handler
  60
  61         .globl asm_call_jit_compiler
  62         .globl asm_handle_exception
  63         .globl asm_handle_nat_exception
  64
  65         .globl asm_wrapper_patcher
  66
  67         .globl asm_replacement_out
  68         .globl asm_replacement_in
  69
  70         .globl asm_builtin_f2i
  71         .globl asm_builtin_f2l
  72         .globl asm_builtin_d2i
  73         .globl asm_builtin_d2l
  74
  75         .globl asm_criticalsections
  76         .globl asm_getclassvalues_atomic
  77
  78
  79 /********************* function asm_calljavafunction ***************************
  80 *                                                                              *
  81 *   This function calls a Java-method (which possibly needs compilation)       *
  82 *   with up to 4 address parameters.                                           *
  83 *                                                                              *
  84 *   This functions calls the JIT-compiler which eventually translates the      *
  85 *   method into machine code.                                                  *
  86 *                                                                              *
  87 *   C-prototype:                                                               *
  88 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  89 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  90 *                                                                              *
  91 *******************************************************************************/
  92
  93         .align  8
  94
  95         .quad   0                           /* catch type all                     */
  96         .quad   0                           /* handler pc                         */
  97         .quad   0                           /* end pc                             */
  98         .quad   0                           /* start pc                           */
  99         .long   1                           /* extable size                       */
 100         .long   0                           /* ALIGNMENT PADDING                  */
 101         .quad   0                           /* line number table  start           */
 102         .quad   0                           /* line number table  size            */
 103         .long   0                           /* ALIGNMENT PADDING                  */
 104         .long   0                           /* fltsave                            */
 105         .long   0                           /* intsave                            */
 106         .long   0                           /* isleaf                             */
 107         .long   0                           /* IsSync                             */
 108         .long   0                           /* frame size                         */
 109         .quad   0                           /* codeinfo pointer                   */
 110
 111 asm_vm_call_method:
 112 asm_vm_call_method_int:
 113 asm_vm_call_method_long:
 114 asm_vm_call_method_float:
 115 asm_vm_call_method_double:
 116         sub     $(7*8),sp                   /* keep stack 16-byte aligned         */
 117         mov     %rbx,0*8(sp)                /* %rbx is not a callee saved in cacao*/
 118         mov     s0,1*8(sp)
 119         mov     s1,2*8(sp)
 120         mov     s2,3*8(sp)
 121         mov     s3,4*8(sp)
 122         mov     s4,5*8(sp)
 123
 124         mov     a0,itmp1                    /* move method pointer for compiler   */
 125         xor     %rbp,%rbp                   /* set argument stack frame to zero   */
 126
 127         test    a1,a1                       /* maybe we have no args...           */
 128         jle     L_copy_done
 129
 130         mov     a1,itmp3                    /* arg count                          */
 131         mov     a2,itmp2                    /* pointer to arg block               */
 132
 133         mov     itmp2,%r14                  /* save argument block pointer        */
 134         mov     itmp3,%r15                  /* save argument count                */
 135
 136         sub     $sizevmarg,itmp2            /* initialize pointer (smaller code)  */
 137         add     $1,itmp3                    /* initialize argument count          */
 138         xor     %r12,%r12                   /* initialize integer argument counter*/
 139         xor     %r13,%r13                   /* initialize float argument counter  */
 140
 141 L_register_copy:
 142         add     $sizevmarg,itmp2            /* goto next argument block           */
 143         dec     itmp3                       /* argument count - 1                 */
 144         jz      L_register_copy_done
 145         andb    $0x02,offvmargtype(itmp2)   /* is this a float/double type?       */
 146         jnz     L_register_handle_float     /* yes, handle it                     */
 147
 148         cmp     $INT_ARG_CNT,%r12           /* are we out of integer argument     */
 149         je      L_register_copy             /* register? yes, next loop           */
 150
 151         lea     jumptable_integer(%rip),%rbp
 152         mov     0(%rbp,%r12,8),%rbx
 153         inc     %r12                      /* integer argument counter + 1         */
 154         jmp     *%rbx
 155
 156 L_register_handle_float:
 157         cmp     $FLT_ARG_CNT,%r13         /* are we out of float argument         */
 158         je      L_register_copy           /* register? yes, next loop             */
 159
 160         lea     jumptable_float(%rip),%rbp
 161         mov     0(%rbp,%r13,8),%rbx
 162         inc     %r13                      /* float argument counter + 1           */
 163         jmp     *%rbx
 164
 165 L_register_copy_done:
 166         mov     %r15,%rbp                 /* calculate remaining arguments        */
 167         sub     %r12,%rbp                 /* - integer arguments in registers     */
 168         sub     %r13,%rbp                 /* - float arguments in registers       */
 169         jle     L_copy_done               /* are all assigned to registers?       */
 170
 171         and     $0xfffffffffffffffe,%rbp  /* keep stack 16-byte aligned           */
 172         shl     $3,%rbp                   /* calculate stack size                 */
 173         sub     %rbp,sp                   /* stack frame for arguments            */
 174         mov     sp,%rbx                   /* use %rbx as temp sp                  */
 175
 176         sub     $sizevmarg,%r14           /* initialize pointer (smaller code)    */
 177         add     $1,%r15                   /* initialize argument count            */
 178
 179 L_stack_copy_loop:
 180         add     $sizevmarg,%r14           /* goto next argument block             */
 181         dec     %r15                      /* are there any arguments left?        */
 182         jz      L_copy_done               /* no test needed after dec             */
 183
 184         andb    $0x02,offvmargtype(%r14)    /* is this a float/double type?       */
 185         jnz     L_stack_handle_float
 186         dec     %r12                        /* arguments assigned to registers    */
 187         jge     L_stack_copy_loop
 188         jmp     L_stack_copy
 189
 190 L_stack_handle_float:
 191         dec     %r13                        /* arguments assigned to registers    */
 192         jge     L_stack_copy_loop
 193
 194 L_stack_copy:
 195         mov     offvmargdata(%r14),itmp3    /* copy s8 argument onto stack        */
 196         mov     itmp3,0(%rbx)
 197         add     $8,%rbx                     /* increase sp to next argument       */
 198         jmp     L_stack_copy_loop
 199
 200 L_copy_done:
 201                                             /* itmp1 still contains method pointer*/
 202         lea     L_asm_call_jit_compiler(%rip),mptr
 203         mov     sp,itmp3                    /* calculate the old stack pointer    */
 204         add     bp,itmp3
 205         mov     mptr,6*8(itmp3)
 206         lea     (6*8-256)(itmp3),mptr       /* We subtract 256 to force the next  */
 207                                             /* move instruction to have a 32-bit  */
 208                                             /* offset.                            */
 209
 210         mov     (0*8+256)(mptr),itmp3       /* method call as in Java             */
 211         call    *itmp3                      /* call JIT compiler                  */
 212
 213         add     bp,sp                       /* remove argument stack frame if any */
 214
 215 L_asm_vm_call_method_return:
 216         mov     0*8(sp),%rbx                /* restore callee saved registers     */
 217         mov     1*8(sp),s0
 218         mov     2*8(sp),s1
 219         mov     3*8(sp),s2
 220         mov     4*8(sp),s3
 221         mov     5*8(sp),s4
 222         add     $(7*8),sp                   /* free stack space                   */
 223         ret
 224
 225 asm_vm_call_method_exception_handler:
 226         mov     xptr,a0                     /* pass exception pointer             */
 227         call    builtin_throw_exception@PLT
 228         jmp     L_asm_vm_call_method_return
 229
 230
 231 jumptable_integer:
 232         .quad   handle_a0
 233         .quad   handle_a1
 234         .quad   handle_a2
 235         .quad   handle_a3
 236         .quad   handle_a4
 237         .quad   handle_a5
 238
 239 handle_a0:
 240         mov     offvmargdata(itmp2),a0
 241         jmp     L_register_copy
 242 handle_a1:
 243         mov     offvmargdata(itmp2),a1
 244         jmp     L_register_copy
 245 handle_a2:
 246         mov     offvmargdata(itmp2),a2
 247         jmp     L_register_copy
 248 handle_a3:
 249         mov     offvmargdata(itmp2),a3
 250         jmp     L_register_copy
 251 handle_a4:
 252         mov     offvmargdata(itmp2),a4
 253         jmp     L_register_copy
 254 handle_a5:
 255         mov     offvmargdata(itmp2),a5
 256         jmp     L_register_copy
 257
 258
 259 jumptable_float:
 260         .quad   handle_fa0
 261         .quad   handle_fa1
 262         .quad   handle_fa2
 263         .quad   handle_fa3
 264         .quad   handle_fa4
 265         .quad   handle_fa5
 266         .quad   handle_fa6
 267         .quad   handle_fa7
 268
 269 handle_fa0:
 270         movq    offvmargdata(itmp2),fa0
 271         jmp     L_register_copy
 272 handle_fa1:
 273         movq    offvmargdata(itmp2),fa1
 274         jmp     L_register_copy
 275 handle_fa2:
 276         movq    offvmargdata(itmp2),fa2
 277         jmp     L_register_copy
 278 handle_fa3:
 279         movq    offvmargdata(itmp2),fa3
 280         jmp     L_register_copy
 281 handle_fa4:
 282         movq    offvmargdata(itmp2),fa4
 283         jmp     L_register_copy
 284 handle_fa5:
 285         movq    offvmargdata(itmp2),fa5
 286         jmp     L_register_copy
 287 handle_fa6:
 288         movq    offvmargdata(itmp2),fa6
 289         jmp     L_register_copy
 290 handle_fa7:
 291         movq    offvmargdata(itmp2),fa7
 292         jmp     L_register_copy
 293
 294
 295 /****************** function asm_call_jit_compiler *****************************
 296 *                                                                              *
 297 *   invokes the compiler for untranslated JavaVM methods.                      *
 298 *                                                                              *
 299 *   Register R0 contains a pointer to the method info structure (prepared      *
 300 *   by createcompilerstub). Using the return address in R26 and the            *
 301 *   offset in the LDA instruction or using the value in methodptr R28 the      *
 302 *   patching address for storing the method address can be computed:           *
 303 *                                                                              *
 304 *   method address was either loaded using                                     *
 305 *                                                                              *
 306 *   i386_mov_imm_reg(a, REG_ITMP2)                ; invokestatic/special       *
 307 *   i386_call_reg(REG_ITMP2)                                                   *
 308 *                                                                              *
 309 *   or                                                                         *
 310 *                                                                              *
 311 *   i386_mov_membase_reg(REG_SP, 0, REG_ITMP2)    ; invokevirtual/interface    *
 312 *   i386_mov_membase_reg(REG_ITMP2, OFFSET(, vftbl), REG_ITMP3)                *
 313 *   i386_mov_membase_reg(REG_ITMP3, OFFSET(vftbl, table[0]) + \                *
 314 *       sizeof(methodptr) * m->vftblindex, REG_ITMP1)                          *
 315 *   i386_call_reg(REG_ITMP1)                                                   *
 316 *                                                                              *
 317 *   in the static case the method pointer can be computed using the            *
 318 *   return address and the lda function following the jmp instruction          *
 319 *                                                                              *
 320 *******************************************************************************/
 321
 322 asm_call_jit_compiler:
 323 L_asm_call_jit_compiler:                /* required for PIC code              */
 324         sub     $(ARG_CNT+1)*8,sp           /* +1: keep stack 16-byte aligned     */
 325
 326         SAVE_ARGUMENT_REGISTERS(0)
 327
 328         mov     itmp1,a0                    /* pass methodinfo pointer            */
 329         mov     mptr,a1                     /* pass method pointer                */
 330         mov     sp,a2                       /* pass java sp                       */
 331         add     $(1+ARG_CNT+1)*8,a2
 332         mov     (ARG_CNT+1)*8(sp),a3        /* pass ra to java function           */
 333         call    jit_asm_compile@PLT
 334
 335         RESTORE_ARGUMENT_REGISTERS(0)
 336
 337         add     $(ARG_CNT+1)*8,sp           /* remove stack frame                 */
 338
 339         test    v0,v0                       /* check for exception                */
 340         je      L_asm_call_jit_compiler_exception
 341
 342         jmp     *v0                         /* ...and now call the new method     */
 343
 344 L_asm_call_jit_compiler_exception:
 345 #if defined(ENABLE_THREADS)
 346         call    builtin_asm_get_exceptionptrptr@PLT
 347         mov     v0,itmp2                    /* v0 == xptr                         */
 348 #else
 349         lea     _no_threads_exceptionptr(%rip),itmp2
 350 #endif
 351         mov     (itmp2),xptr                /* get the exception pointer          */
 352         movl    $0,(itmp2)                  /* clear exception pointer            */
 353
 354         pop     xpc                         /* delete return address              */
 355         sub     $5,xpc                      /* faulting address is ra - 5         */
 356         jmp     L_asm_handle_exception
 357
 358
 359 /* asm_handle_exception ********************************************************
 360 *                                                                              *
 361 *   This function handles an exception. It does not use the usual calling      *
 362 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 363 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 364 *   the local exception table for a handler. If no one is found, it unwinds    *
 365 *   stacks and continues searching the callers.                                *
 366 *                                                                              *
 367 *******************************************************************************/
 368
 369 asm_handle_nat_exception:
 370         add     $8,sp                       /* clear return address of native stub*/
 371
 372 asm_handle_exception:
 373 L_asm_handle_exception:                 /* required for PIC code              */
 374         sub     $((ARG_CNT+TMP_CNT)*8),sp   /* create maybe-leaf stackframe       */
 375
 376         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 377         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 378
 379         mov     $((ARG_CNT+TMP_CNT)*8),a3   /* prepare a3 for handle_exception    */
 380         mov     $1,t0                       /* set maybe-leaf flag                */
 381
 382 L_asm_handle_exception_stack_loop:
 383         sub     $(6*8),sp
 384         mov     xptr,0*8(sp)                /* save exception pointer             */
 385         mov     xpc,1*8(sp)                 /* save exception pc                  */
 386         add     sp,a3                       /* calculate Java sp into a3...       */
 387         add     $(6*8),a3
 388         mov     a3,3*8(sp)                  /* ...and save it                     */
 389         mov     t0,4*8(sp)                  /* save maybe-leaf flag               */
 390
 391         mov     xpc,a0                      /* exception pc                       */
 392         call    codegen_findmethod@PLT
 393         mov     v0,2*8(sp)                  /* save data segment pointer          */
 394
 395         mov     0*8(sp),a0                  /* pass exception pointer             */
 396         mov     1*8(sp),a1                  /* pass exception pc                  */
 397         mov     v0,a2                       /* pass data segment pointer          */
 398         mov     3*8(sp),a3                  /* pass Java stack pointer            */
 399         call    exceptions_handle_exception@PLT
 400
 401         test    v0,v0
 402         jz      L_asm_handle_exception_not_catched
 403
 404         mov     v0,xpc                      /* move handlerpc into xpc            */
 405         mov     0*8(sp),xptr                /* restore exception pointer          */
 406         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 407         add     $(6*8),sp                   /* free stack frame                   */
 408
 409         test    t0,t0                       /* test for maybe-leaf flag           */
 410         jz      L_asm_handle_exception_no_leaf
 411
 412         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 413         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 414
 415         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 416
 417 L_asm_handle_exception_no_leaf:
 418         jmp     *xpc                        /* jump to the handler                */
 419
 420 L_asm_handle_exception_not_catched:
 421         mov     0*8(sp),xptr                /* restore exception pointer          */
 422         mov     2*8(sp),itmp3               /* restore data segment pointer       */
 423         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 424         add     $(6*8),sp
 425
 426         test    t0,t0
 427         jz      L_asm_handle_exception_no_leaf_stack
 428
 429         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 430         xor     t0,t0                       /* clear the isleaf flags             */
 431
 432 L_asm_handle_exception_no_leaf_stack:
 433         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 434         add     sp,itmp2                    /* pointer to save area               */
 435
 436         mov     IntSave(itmp3),a0l          /* a0l = saved int register count     */
 437         test    a0l,a0l
 438         je      noint
 439
 440         cmp     $1,a0l
 441         je      int1
 442         cmp     $2,a0l
 443         je      int2
 444         cmp     $3,a0l
 445         je      int3
 446         cmp     $4,a0l
 447         je      int4
 448
 449         mov     -5*8(itmp2),s0
 450 int4:
 451         mov     -4*8(itmp2),s1
 452 int3:
 453         mov     -3*8(itmp2),s2
 454 int2:
 455         mov     -2*8(itmp2),s3
 456 int1:
 457         mov     -1*8(itmp2),s4
 458
 459         shl     $3,a0l                      /* multiply by 8 bytes                */
 460         sub     a0,itmp2
 461
 462 noint:
 463 #if 0
 464         mov     FltSave(itmp3),a0l          /* a0l = saved flt register count     */
 465         test    a0l,a0l
 466         je      noflt
 467
 468         cmpl    $1,a0l
 469         je      flt1
 470         cmpl    $2,a0l
 471         je      flt2
 472         cmpl    $3,a0l
 473         je      flt3
 474         cmpl    $4,a0l
 475         je      flt4
 476
 477         movq    -5*8(itmp2),%xmm11
 478 flt4:
 479         movq    -4*8(itmp2),%xmm12
 480 flt3:
 481         movq    -3*8(itmp2),%xmm13
 482 flt2:
 483         movq    -2*8(itmp2),%xmm14
 484 flt1:
 485         movq    -1*8(itmp2),%xmm15
 486
 487 noflt:
 488 #endif
 489         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 490         add     itmp2,sp                    /* unwind stack                       */
 491
 492                                             /* exception pointer is still set     */
 493         pop     xpc                         /* the new xpc is return address      */
 494         sub     $3,xpc                      /* subtract 3 bytes for call          */
 495
 496         xor     a3,a3                       /* prepare a3 for handle_exception    */
 497
 498         jmp             L_asm_handle_exception_stack_loop
 499
 500
 501 /* asm_wrapper_patcher *********************************************************
 502
 503    XXX
 504
 505    Stack layout:
 506      40   return address
 507      32   pointer to virtual java_objectheader
 508      24   machine code (which is patched back later)
 509      16   unresolved class/method/field reference
 510       8   data segment displacement from load instructions
 511       0   pointer to patcher function
 512      -8   bp
 513
 514 *******************************************************************************/
 515
 516 asm_wrapper_patcher:
 517         push    bp                          /* save base pointer                  */
 518         mov     sp,bp                       /* move actual sp to bp               */
 519         sub     $((3+ARG_CNT+TMP_CNT)*8+sizestackframeinfo),sp
 520         and     $0xfffffffffffffff0,sp      /* align sp to 16-byte (this is for   */
 521                                             /* leaf functions)                    */
 522
 523         SAVE_ARGUMENT_REGISTERS(3)
 524         SAVE_TEMPORARY_REGISTERS(3+ARG_CNT)
 525
 526         mov     itmp1,0*8(sp)               /* save itmp1 and itmp2               */
 527         mov     itmp2,1*8(sp)               /* can be used by some instructions   */
 528
 529         mov     sp,a0                       /* create stackframe info             */
 530         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 531         xor     a1,a1                       /* if pv is NULL, use findmethod      */
 532         mov     bp,a2                       /* pass java sp                       */
 533         add     $((6+1)*8),a2
 534         mov     ((5+1)*8)(bp),a3            /* pass ra to java function           */
 535         mov     a3,a4                       /* xpc is equal to ra                 */
 536         call    stacktrace_create_extern_stackframeinfo@PLT
 537
 538         mov     bp,a0                       /* pass stack pointer                 */
 539         add     $((1+1)*8),a0               /* skip function pointer              */
 540         mov     1*8(bp),itmp3               /* get function pointer               */
 541         call    *itmp3                      /* call the patcher function          */
 542         mov     v0,2*8(sp)                  /* save return value                  */
 543
 544         mov     sp,a0                       /* remove stackframe info             */
 545         add     $((3+ARG_CNT+TMP_CNT)*8),a0
 546         call    stacktrace_remove_stackframeinfo@PLT
 547
 548         RESTORE_ARGUMENT_REGISTERS(3)
 549         RESTORE_TEMPORARY_REGISTERS(3+ARG_CNT)
 550
 551         mov     0*8(sp),itmp1               /* restore itmp1 and itmp2            */
 552         mov     1*8(sp),itmp2               /* can be used by some instructions   */
 553         mov     2*8(sp),itmp3               /* restore return value               */
 554
 555         mov     bp,sp                       /* restore original sp                */
 556         pop     bp                          /* restore bp                         */
 557         add     $(5*8),sp                   /* remove patcher stackframe, keep ra */
 558
 559         test    itmp3,itmp3                 /* exception thrown?                  */
 560         jz      L_asm_wrapper_patcher_exception
 561         ret                                 /* call new patched code              */
 562
 563 L_asm_wrapper_patcher_exception:
 564 #if defined(ENABLE_THREADS)
 565         call    builtin_asm_get_exceptionptrptr@PLT
 566         mov     v0,itmp2                    /* v0 == xptr                         */
 567 #else
 568         mov     _no_threads_exceptionptr,itmp2
 569 #endif
 570         mov     (itmp2),xptr                /* get the exception pointer          */
 571         movl    $0,(itmp2)                  /* clear exception pointer            */
 572
 573         pop     xpc                         /* get and remove return address      */
 574         jmp     L_asm_handle_exception
 575
 576
 577 /* asm_replacement_out *********************************************************
 578
 579    This code is jumped to from the replacement-out stubs that are executed
 580    when a thread reaches an activated replacement point.
 581
 582    The purpose of asm_replacement_out is to read out the parts of the
 583    execution state that cannot be accessed from C code, store this state,
 584    and then call the C function replace_me.
 585
 586    Stack layout:
 587       8                 start of stack inside method to replace
 588       0   rplpoint *    info on the replacement point that was reached
 589
 590 *******************************************************************************/
 591
 592 /* some room to accomodate changes of the stack frame size during replacement */
 593         /* XXX we should find a cleaner solution here */
 594 #define REPLACEMENT_ROOM  512
 595
 596 asm_replacement_out:
 597     /* create stack frame */
 598         sub     $(sizeexecutionstate + REPLACEMENT_ROOM),sp
 599
 600         /* save registers in execution state */
 601         mov     %rax,(RAX*8+offes_intregs)(sp)
 602         mov     %rbx,(RBX*8+offes_intregs)(sp)
 603         mov     %rcx,(RCX*8+offes_intregs)(sp)
 604         mov     %rdx,(RDX*8+offes_intregs)(sp)
 605         mov     %rsi,(RSI*8+offes_intregs)(sp)
 606         mov     %rdi,(RDI*8+offes_intregs)(sp)
 607         mov     %rbp,(RBP*8+offes_intregs)(sp)
 608         movq    $0  ,(RSP*8+offes_intregs)(sp) /* not used */
 609         mov     %r8 ,(R8 *8+offes_intregs)(sp)
 610         mov     %r9 ,(R9 *8+offes_intregs)(sp)
 611         mov     %r10,(R10*8+offes_intregs)(sp)
 612         mov     %r11,(R11*8+offes_intregs)(sp)
 613         mov     %r12,(R12*8+offes_intregs)(sp)
 614         mov     %r13,(R13*8+offes_intregs)(sp)
 615         mov     %r14,(R14*8+offes_intregs)(sp)
 616         mov     %r15,(R15*8+offes_intregs)(sp)
 617
 618         movq    %xmm0 ,(XMM0 *8+offes_fltregs)(sp)
 619         movq    %xmm1 ,(XMM1 *8+offes_fltregs)(sp)
 620         movq    %xmm2 ,(XMM2 *8+offes_fltregs)(sp)
 621         movq    %xmm3 ,(XMM3 *8+offes_fltregs)(sp)
 622         movq    %xmm4 ,(XMM4 *8+offes_fltregs)(sp)
 623         movq    %xmm5 ,(XMM5 *8+offes_fltregs)(sp)
 624         movq    %xmm6 ,(XMM6 *8+offes_fltregs)(sp)
 625         movq    %xmm7 ,(XMM7 *8+offes_fltregs)(sp)
 626         movq    %xmm8 ,(XMM8 *8+offes_fltregs)(sp)
 627         movq    %xmm9 ,(XMM9 *8+offes_fltregs)(sp)
 628         movq    %xmm10,(XMM10*8+offes_fltregs)(sp)
 629         movq    %xmm11,(XMM11*8+offes_fltregs)(sp)
 630         movq    %xmm12,(XMM12*8+offes_fltregs)(sp)
 631         movq    %xmm13,(XMM13*8+offes_fltregs)(sp)
 632         movq    %xmm14,(XMM14*8+offes_fltregs)(sp)
 633         movq    %xmm15,(XMM15*8+offes_fltregs)(sp)
 634
 635         /* calculate sp of method */
 636         mov     sp,itmp1
 637         add     $(sizeexecutionstate + REPLACEMENT_ROOM + 8),itmp1
 638         mov     itmp1,(offes_sp)(sp)
 639
 640         /* pv must be looked up via AVL tree */
 641         movq    $0,(offes_pv)(sp)
 642
 643         /* call replace_me */
 644         mov     -8(itmp1),a0                /* rplpoint *                         */
 645     mov     sp,a1                       /* arg1: execution state              */
 646     call    replace_me@PLT              /* call C function replace_me         */
 647     call    abort@PLT                   /* NEVER REACHED                      */
 648
 649 /* asm_replacement_in **********************************************************
 650
 651    This code writes the given execution state and jumps to the replacement
 652    code.
 653
 654    This function never returns!
 655
 656    C prototype:
 657       void asm_replacement_in(executionstate *es);
 658
 659 *******************************************************************************/
 660
 661 asm_replacement_in:
 662         mov     a0,%rbp                     /* executionstate *es                 */
 663
 664         /* set new sp */
 665         mov     (offes_sp)(%rbp),%rsp
 666
 667         /* store address of new code */
 668         push    (offes_pc)(%rbp)
 669
 670         /* copy registers from execution state */
 671         movq    (XMM0 *8+offes_fltregs)(%rbp),%xmm0
 672         movq    (XMM1 *8+offes_fltregs)(%rbp),%xmm1
 673         movq    (XMM2 *8+offes_fltregs)(%rbp),%xmm2
 674         movq    (XMM3 *8+offes_fltregs)(%rbp),%xmm3
 675         movq    (XMM4 *8+offes_fltregs)(%rbp),%xmm4
 676         movq    (XMM5 *8+offes_fltregs)(%rbp),%xmm5
 677         movq    (XMM6 *8+offes_fltregs)(%rbp),%xmm6
 678         movq    (XMM7 *8+offes_fltregs)(%rbp),%xmm7
 679         movq    (XMM8 *8+offes_fltregs)(%rbp),%xmm8
 680         movq    (XMM9 *8+offes_fltregs)(%rbp),%xmm9
 681         movq    (XMM10*8+offes_fltregs)(%rbp),%xmm10
 682         movq    (XMM11*8+offes_fltregs)(%rbp),%xmm11
 683         movq    (XMM12*8+offes_fltregs)(%rbp),%xmm12
 684         movq    (XMM13*8+offes_fltregs)(%rbp),%xmm13
 685         movq    (XMM14*8+offes_fltregs)(%rbp),%xmm14
 686         movq    (XMM15*8+offes_fltregs)(%rbp),%xmm15
 687
 688         mov     (RAX*8+offes_intregs)(%rbp),%rax
 689         mov     (RBX*8+offes_intregs)(%rbp),%rbx
 690         mov     (RCX*8+offes_intregs)(%rbp),%rcx
 691         mov     (RDX*8+offes_intregs)(%rbp),%rdx
 692         mov     (RSI*8+offes_intregs)(%rbp),%rsi
 693         mov     (RDI*8+offes_intregs)(%rbp),%rdi
 694         mov     (R8 *8+offes_intregs)(%rbp),%r8
 695         mov     (R9 *8+offes_intregs)(%rbp),%r9
 696         mov     (R10*8+offes_intregs)(%rbp),%r10
 697         mov     (R11*8+offes_intregs)(%rbp),%r11
 698         mov     (R12*8+offes_intregs)(%rbp),%r12
 699         mov     (R13*8+offes_intregs)(%rbp),%r13
 700         mov     (R14*8+offes_intregs)(%rbp),%r14
 701         mov     (R15*8+offes_intregs)(%rbp),%r15
 702
 703         mov     (RBP*8+offes_intregs)(%rbp),%rbp
 704
 705         /* jump to new code */
 706         ret
 707
 708
 709 /* asm_builtin_x2x *************************************************************
 710 *                                                                              *
 711 *   Wrapper functions for float to int corner cases                            *
 712 *                                                                              *
 713 *******************************************************************************/
 714
 715 asm_builtin_f2i:
 716         sub     $(ARG_CNT*8),sp
 717
 718         SAVE_ARGUMENT_REGISTERS(0)
 719
 720         movq    ftmp1,fa0
 721         call    builtin_f2i@PLT
 722
 723         RESTORE_ARGUMENT_REGISTERS(0)
 724
 725         add     $(ARG_CNT*8),sp
 726         ret
 727
 728
 729 asm_builtin_f2l:
 730         sub     $(ARG_CNT*8),sp
 731
 732         SAVE_ARGUMENT_REGISTERS(0)
 733
 734         movq    ftmp1,fa0
 735         call    builtin_f2l@PLT
 736
 737         RESTORE_ARGUMENT_REGISTERS(0)
 738
 739         add     $(ARG_CNT*8),sp
 740         ret
 741
 742
 743 asm_builtin_d2i:
 744         sub     $(ARG_CNT*8),sp
 745
 746         SAVE_ARGUMENT_REGISTERS(0)
 747
 748         movq    ftmp1,fa0
 749         call    builtin_d2i@PLT
 750
 751         RESTORE_ARGUMENT_REGISTERS(0)
 752
 753         add     $(ARG_CNT*8),sp
 754         ret
 755
 756
 757 asm_builtin_d2l:
 758         sub     $(ARG_CNT*8),sp
 759
 760         SAVE_ARGUMENT_REGISTERS(0)
 761
 762         movq    ftmp1,fa0
 763         call    builtin_d2l@PLT
 764
 765         RESTORE_ARGUMENT_REGISTERS(0)
 766
 767         add     $(ARG_CNT*8),sp
 768         ret
 769
 770
 771 asm_getclassvalues_atomic:
 772 _crit_restart:
 773 _crit_begin:
 774         movl    offbaseval(a0),itmp1l
 775         movl    offdiffval(a0),itmp2l
 776         movl    offbaseval(a1),itmp3l
 777 _crit_end:
 778         movl    itmp1l,offcast_super_baseval(a2)
 779         movl    itmp2l,offcast_super_diffval(a2)
 780         movl    itmp3l,offcast_sub_baseval(a2)
 781         ret
 782
 783         .data
 784
 785 asm_criticalsections:
 786 #if defined(ENABLE_THREADS)
 787         .quad   _crit_begin
 788         .quad   _crit_end
 789         .quad   _crit_restart
 790 #endif
 791         .quad 0
 792
 793
 794 /* Disable exec-stacks, required for Gentoo ***********************************/
 795
 796 #if defined(__GCC__) && defined(__ELF__)
 797         .section .note.GNU-stack,"",@progbits
 798 #endif
 799
 800
 801 /*
 802  * These are local overrides for various environment variables in Emacs.
 803  * Please do not remove this and leave it at the end of the file, where
 804  * Emacs will automagically detect them.
 805  * ---------------------------------------------------------------------
 806  * Local variables:
 807  * mode: asm
 808  * indent-tabs-mode: t
 809  * c-basic-offset: 4
 810  * tab-width: 4
 811  * End:
 812  * vim:noexpandtab:sw=4:ts=4:
 813  */