src/vm/jit/x86_64/asmpart.S

   1 /* src/vm/jit/x86_64/asmpart.S - Java-C interface functions for x86_64
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29             Christian Thalinger
  30
  31    Changes: Edwin Steiner
  32
  33    $Id: asmpart.S 5145 2006-07-17 11:48:38Z twisti $
  34
  35 */
  36
  37
  38 #include "config.h"
  39
  40 #include "vm/jit/x86_64/arch.h"
  41 #include "vm/jit/x86_64/md-abi.h"
  42 #include "vm/jit/x86_64/md-asm.h"
  43 #include "vm/jit/x86_64/offsets.h"
  44
  45 #include "vm/jit/abi-asm.h"
  46 #include "vm/jit/methodheader.h"
  47
  48
  49         .text
  50
  51
  52 /* export functions ***********************************************************/
  53
  54         .globl asm_vm_call_method
  55         .globl asm_vm_call_method_int
  56         .globl asm_vm_call_method_long
  57         .globl asm_vm_call_method_float
  58         .globl asm_vm_call_method_double
  59         .globl asm_vm_call_method_exception_handler
  60
  61         .globl asm_call_jit_compiler
  62
  63         .globl asm_handle_exception
  64         .globl asm_handle_nat_exception
  65
  66         .globl asm_abstractmethoderror
  67
  68         .globl asm_patcher_wrapper
  69
  70         .globl asm_replacement_out
  71         .globl asm_replacement_in
  72
  73         .globl asm_builtin_f2i
  74         .globl asm_builtin_f2l
  75         .globl asm_builtin_d2i
  76         .globl asm_builtin_d2l
  77
  78         .globl asm_criticalsections
  79         .globl asm_getclassvalues_atomic
  80
  81
  82 /********************* function asm_calljavafunction ***************************
  83 *                                                                              *
  84 *   This function calls a Java-method (which possibly needs compilation)       *
  85 *   with up to 4 address parameters.                                           *
  86 *                                                                              *
  87 *   This functions calls the JIT-compiler which eventually translates the      *
  88 *   method into machine code.                                                  *
  89 *                                                                              *
  90 *   C-prototype:                                                               *
  91 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  92 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  93 *                                                                              *
  94 *******************************************************************************/
  95
  96         .align  8
  97
  98         .quad   0                           /* catch type all                     */
  99         .quad   0                           /* handler pc                         */
 100         .quad   0                           /* end pc                             */
 101         .quad   0                           /* start pc                           */
 102         .long   1                           /* extable size                       */
 103         .long   0                           /* ALIGNMENT PADDING                  */
 104         .quad   0                           /* line number table  start           */
 105         .quad   0                           /* line number table  size            */
 106         .long   0                           /* ALIGNMENT PADDING                  */
 107         .long   0                           /* fltsave                            */
 108         .long   0                           /* intsave                            */
 109         .long   0                           /* isleaf                             */
 110         .long   0                           /* IsSync                             */
 111         .long   0                           /* frame size                         */
 112         .quad   0                           /* codeinfo pointer                   */
 113
 114 asm_vm_call_method:
 115 asm_vm_call_method_int:
 116 asm_vm_call_method_long:
 117 asm_vm_call_method_float:
 118 asm_vm_call_method_double:
 119         sub     $(7*8),sp                   /* keep stack 16-byte aligned         */
 120         mov     %rbx,0*8(sp)                /* %rbx is not a callee saved in cacao*/
 121         mov     s0,1*8(sp)
 122         mov     s1,2*8(sp)
 123         mov     s2,3*8(sp)
 124         mov     s3,4*8(sp)
 125         mov     s4,5*8(sp)
 126
 127         mov     a0,itmp1                    /* move method pointer for compiler   */
 128         xor     %rbp,%rbp                   /* set argument stack frame to zero   */
 129
 130         test    a1,a1                       /* maybe we have no args...           */
 131         jle     L_copy_done
 132
 133         mov     a1,itmp3                    /* arg count                          */
 134         mov     a2,itmp2                    /* pointer to arg block               */
 135
 136         mov     itmp2,%r14                  /* save argument block pointer        */
 137         mov     itmp3,%r15                  /* save argument count                */
 138
 139         sub     $sizevmarg,itmp2            /* initialize pointer (smaller code)  */
 140         add     $1,itmp3                    /* initialize argument count          */
 141         xor     %r12,%r12                   /* initialize integer argument counter*/
 142         xor     %r13,%r13                   /* initialize float argument counter  */
 143
 144 L_register_copy:
 145         add     $sizevmarg,itmp2            /* goto next argument block           */
 146         dec     itmp3                       /* argument count - 1                 */
 147         jz      L_register_copy_done
 148         andb    $0x02,offvmargtype(itmp2)   /* is this a float/double type?       */
 149         jnz     L_register_handle_float     /* yes, handle it                     */
 150
 151         cmp     $INT_ARG_CNT,%r12           /* are we out of integer argument     */
 152         je      L_register_copy             /* register? yes, next loop           */
 153
 154         lea     jumptable_integer(%rip),%rbp
 155         mov     0(%rbp,%r12,8),%rbx
 156         inc     %r12                      /* integer argument counter + 1         */
 157         jmp     *%rbx
 158
 159 L_register_handle_float:
 160         cmp     $FLT_ARG_CNT,%r13         /* are we out of float argument         */
 161         je      L_register_copy           /* register? yes, next loop             */
 162
 163         lea     jumptable_float(%rip),%rbp
 164         mov     0(%rbp,%r13,8),%rbx
 165         inc     %r13                      /* float argument counter + 1           */
 166         jmp     *%rbx
 167
 168 L_register_copy_done:
 169         mov     %r15,%rbp                 /* calculate remaining arguments        */
 170         sub     %r12,%rbp                 /* - integer arguments in registers     */
 171         sub     %r13,%rbp                 /* - float arguments in registers       */
 172         jle     L_copy_done               /* are all assigned to registers?       */
 173
 174         and     $0xfffffffffffffffe,%rbp  /* keep stack 16-byte aligned           */
 175         shl     $3,%rbp                   /* calculate stack size                 */
 176         sub     %rbp,sp                   /* stack frame for arguments            */
 177         mov     sp,%rbx                   /* use %rbx as temp sp                  */
 178
 179         sub     $sizevmarg,%r14           /* initialize pointer (smaller code)    */
 180         add     $1,%r15                   /* initialize argument count            */
 181
 182 L_stack_copy_loop:
 183         add     $sizevmarg,%r14           /* goto next argument block             */
 184         dec     %r15                      /* are there any arguments left?        */
 185         jz      L_copy_done               /* no test needed after dec             */
 186
 187         andb    $0x02,offvmargtype(%r14)    /* is this a float/double type?       */
 188         jnz     L_stack_handle_float
 189         dec     %r12                        /* arguments assigned to registers    */
 190         jge     L_stack_copy_loop
 191         jmp     L_stack_copy
 192
 193 L_stack_handle_float:
 194         dec     %r13                        /* arguments assigned to registers    */
 195         jge     L_stack_copy_loop
 196
 197 L_stack_copy:
 198         mov     offvmargdata(%r14),itmp3    /* copy s8 argument onto stack        */
 199         mov     itmp3,0(%rbx)
 200         add     $8,%rbx                     /* increase sp to next argument       */
 201         jmp     L_stack_copy_loop
 202
 203 L_copy_done:
 204                                             /* itmp1 still contains method pointer*/
 205         lea     L_asm_call_jit_compiler(%rip),mptr
 206         mov     sp,itmp3                    /* calculate the old stack pointer    */
 207         add     bp,itmp3
 208         mov     mptr,6*8(itmp3)
 209         lea     (6*8-256)(itmp3),mptr       /* We subtract 256 to force the next  */
 210                                             /* move instruction to have a 32-bit  */
 211                                             /* offset.                            */
 212
 213         mov     (0*8+256)(mptr),itmp3       /* method call as in Java             */
 214         call    *itmp3                      /* call JIT compiler                  */
 215
 216         add     bp,sp                       /* remove argument stack frame if any */
 217
 218 L_asm_vm_call_method_return:
 219         mov     0*8(sp),%rbx                /* restore callee saved registers     */
 220         mov     1*8(sp),s0
 221         mov     2*8(sp),s1
 222         mov     3*8(sp),s2
 223         mov     4*8(sp),s3
 224         mov     5*8(sp),s4
 225         add     $(7*8),sp                   /* free stack space                   */
 226         ret
 227
 228 asm_vm_call_method_exception_handler:
 229         mov     xptr,a0                     /* pass exception pointer             */
 230         call    builtin_throw_exception@PLT
 231         jmp     L_asm_vm_call_method_return
 232
 233
 234 jumptable_integer:
 235         .quad   handle_a0
 236         .quad   handle_a1
 237         .quad   handle_a2
 238         .quad   handle_a3
 239         .quad   handle_a4
 240         .quad   handle_a5
 241
 242 handle_a0:
 243         mov     offvmargdata(itmp2),a0
 244         jmp     L_register_copy
 245 handle_a1:
 246         mov     offvmargdata(itmp2),a1
 247         jmp     L_register_copy
 248 handle_a2:
 249         mov     offvmargdata(itmp2),a2
 250         jmp     L_register_copy
 251 handle_a3:
 252         mov     offvmargdata(itmp2),a3
 253         jmp     L_register_copy
 254 handle_a4:
 255         mov     offvmargdata(itmp2),a4
 256         jmp     L_register_copy
 257 handle_a5:
 258         mov     offvmargdata(itmp2),a5
 259         jmp     L_register_copy
 260
 261
 262 jumptable_float:
 263         .quad   handle_fa0
 264         .quad   handle_fa1
 265         .quad   handle_fa2
 266         .quad   handle_fa3
 267         .quad   handle_fa4
 268         .quad   handle_fa5
 269         .quad   handle_fa6
 270         .quad   handle_fa7
 271
 272 handle_fa0:
 273         movq    offvmargdata(itmp2),fa0
 274         jmp     L_register_copy
 275 handle_fa1:
 276         movq    offvmargdata(itmp2),fa1
 277         jmp     L_register_copy
 278 handle_fa2:
 279         movq    offvmargdata(itmp2),fa2
 280         jmp     L_register_copy
 281 handle_fa3:
 282         movq    offvmargdata(itmp2),fa3
 283         jmp     L_register_copy
 284 handle_fa4:
 285         movq    offvmargdata(itmp2),fa4
 286         jmp     L_register_copy
 287 handle_fa5:
 288         movq    offvmargdata(itmp2),fa5
 289         jmp     L_register_copy
 290 handle_fa6:
 291         movq    offvmargdata(itmp2),fa6
 292         jmp     L_register_copy
 293 handle_fa7:
 294         movq    offvmargdata(itmp2),fa7
 295         jmp     L_register_copy
 296
 297
 298 /****************** function asm_call_jit_compiler *****************************
 299 *                                                                              *
 300 *   invokes the compiler for untranslated JavaVM methods.                      *
 301 *                                                                              *
 302 *   Register R0 contains a pointer to the method info structure (prepared      *
 303 *   by createcompilerstub). Using the return address in R26 and the            *
 304 *   offset in the LDA instruction or using the value in methodptr R28 the      *
 305 *   patching address for storing the method address can be computed:           *
 306 *                                                                              *
 307 *   method address was either loaded using                                     *
 308 *                                                                              *
 309 *   i386_mov_imm_reg(a, REG_ITMP2)                ; invokestatic/special       *
 310 *   i386_call_reg(REG_ITMP2)                                                   *
 311 *                                                                              *
 312 *   or                                                                         *
 313 *                                                                              *
 314 *   i386_mov_membase_reg(REG_SP, 0, REG_ITMP2)    ; invokevirtual/interface    *
 315 *   i386_mov_membase_reg(REG_ITMP2, OFFSET(, vftbl), REG_ITMP3)                *
 316 *   i386_mov_membase_reg(REG_ITMP3, OFFSET(vftbl, table[0]) + \                *
 317 *       sizeof(methodptr) * m->vftblindex, REG_ITMP1)                          *
 318 *   i386_call_reg(REG_ITMP1)                                                   *
 319 *                                                                              *
 320 *   in the static case the method pointer can be computed using the            *
 321 *   return address and the lda function following the jmp instruction          *
 322 *                                                                              *
 323 *******************************************************************************/
 324
 325 asm_call_jit_compiler:
 326 L_asm_call_jit_compiler:                /* required for PIC code              */
 327         sub     $(ARG_CNT+1)*8,sp           /* +1: keep stack 16-byte aligned     */
 328
 329         SAVE_ARGUMENT_REGISTERS(0)
 330
 331         mov     itmp1,a0                    /* pass methodinfo pointer            */
 332         mov     mptr,a1                     /* pass method pointer                */
 333         mov     sp,a2                       /* pass java sp                       */
 334         add     $(1+ARG_CNT+1)*8,a2
 335         mov     (ARG_CNT+1)*8(sp),a3        /* pass ra to java function           */
 336         call    jit_asm_compile@PLT
 337
 338         RESTORE_ARGUMENT_REGISTERS(0)
 339
 340         add     $(ARG_CNT+1)*8,sp           /* remove stack frame                 */
 341
 342         test    v0,v0                       /* check for exception                */
 343         je      L_asm_call_jit_compiler_exception
 344
 345         jmp     *v0                         /* ...and now call the new method     */
 346
 347 L_asm_call_jit_compiler_exception:
 348         call    exceptions_get_and_clear_exception@PLT
 349         pop     xpc                         /* delete return address              */
 350         sub     $3,xpc                      /* faulting address is ra - 3         */
 351         jmp     L_asm_handle_exception
 352
 353
 354 /* asm_handle_exception ********************************************************
 355 *                                                                              *
 356 *   This function handles an exception. It does not use the usual calling      *
 357 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 358 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 359 *   the local exception table for a handler. If no one is found, it unwinds    *
 360 *   stacks and continues searching the callers.                                *
 361 *                                                                              *
 362 *******************************************************************************/
 363
 364 asm_handle_nat_exception:
 365         add     $8,sp                       /* clear return address of native stub*/
 366
 367 asm_handle_exception:
 368 L_asm_handle_exception:                 /* required for PIC code              */
 369         sub     $((ARG_CNT+TMP_CNT)*8),sp   /* create maybe-leaf stackframe       */
 370
 371         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 372         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 373
 374         mov     $((ARG_CNT+TMP_CNT)*8),a3   /* prepare a3 for handle_exception    */
 375         mov     $1,t0                       /* set maybe-leaf flag                */
 376
 377 L_asm_handle_exception_stack_loop:
 378         sub     $(6*8),sp
 379         mov     xptr,0*8(sp)                /* save exception pointer             */
 380         mov     xpc,1*8(sp)                 /* save exception pc                  */
 381         add     sp,a3                       /* calculate Java sp into a3...       */
 382         add     $(6*8),a3
 383         mov     a3,3*8(sp)                  /* ...and save it                     */
 384         mov     t0,4*8(sp)                  /* save maybe-leaf flag               */
 385
 386         mov     xpc,a0                      /* exception pc                       */
 387         call    codegen_findmethod@PLT
 388         mov     v0,2*8(sp)                  /* save data segment pointer          */
 389
 390         mov     0*8(sp),a0                  /* pass exception pointer             */
 391         mov     1*8(sp),a1                  /* pass exception pc                  */
 392         mov     v0,a2                       /* pass data segment pointer          */
 393         mov     3*8(sp),a3                  /* pass Java stack pointer            */
 394         call    exceptions_handle_exception@PLT
 395
 396         test    v0,v0
 397         jz      L_asm_handle_exception_not_catched
 398
 399         mov     v0,xpc                      /* move handlerpc into xpc            */
 400         mov     0*8(sp),xptr                /* restore exception pointer          */
 401         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 402         add     $(6*8),sp                   /* free stack frame                   */
 403
 404         test    t0,t0                       /* test for maybe-leaf flag           */
 405         jz      L_asm_handle_exception_no_leaf
 406
 407         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 408         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 409
 410         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 411
 412 L_asm_handle_exception_no_leaf:
 413         jmp     *xpc                        /* jump to the handler                */
 414
 415 L_asm_handle_exception_not_catched:
 416         mov     0*8(sp),xptr                /* restore exception pointer          */
 417         mov     2*8(sp),itmp3               /* restore data segment pointer       */
 418         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 419         add     $(6*8),sp
 420
 421         test    t0,t0
 422         jz      L_asm_handle_exception_no_leaf_stack
 423
 424         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 425         xor     t0,t0                       /* clear the isleaf flags             */
 426
 427 L_asm_handle_exception_no_leaf_stack:
 428         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 429         add     sp,itmp2                    /* pointer to save area               */
 430
 431         mov     IntSave(itmp3),a0l          /* a0l = saved int register count     */
 432         test    a0l,a0l
 433         je      noint
 434
 435         cmp     $1,a0l
 436         je      int1
 437         cmp     $2,a0l
 438         je      int2
 439         cmp     $3,a0l
 440         je      int3
 441         cmp     $4,a0l
 442         je      int4
 443
 444         mov     -5*8(itmp2),s0
 445 int4:
 446         mov     -4*8(itmp2),s1
 447 int3:
 448         mov     -3*8(itmp2),s2
 449 int2:
 450         mov     -2*8(itmp2),s3
 451 int1:
 452         mov     -1*8(itmp2),s4
 453
 454         shl     $3,a0l                      /* multiply by 8 bytes                */
 455         sub     a0,itmp2
 456
 457 noint:
 458 #if 0
 459         mov     FltSave(itmp3),a0l          /* a0l = saved flt register count     */
 460         test    a0l,a0l
 461         je      noflt
 462
 463         cmpl    $1,a0l
 464         je      flt1
 465         cmpl    $2,a0l
 466         je      flt2
 467         cmpl    $3,a0l
 468         je      flt3
 469         cmpl    $4,a0l
 470         je      flt4
 471
 472         movq    -5*8(itmp2),%xmm11
 473 flt4:
 474         movq    -4*8(itmp2),%xmm12
 475 flt3:
 476         movq    -3*8(itmp2),%xmm13
 477 flt2:
 478         movq    -2*8(itmp2),%xmm14
 479 flt1:
 480         movq    -1*8(itmp2),%xmm15
 481
 482 noflt:
 483 #endif
 484         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 485         add     itmp2,sp                    /* unwind stack                       */
 486
 487                                             /* exception pointer is still set     */
 488         pop     xpc                         /* the new xpc is return address      */
 489         sub     $3,xpc                      /* subtract 3 bytes for call          */
 490
 491         xor     a3,a3                       /* prepare a3 for handle_exception    */
 492
 493         jmp             L_asm_handle_exception_stack_loop
 494
 495
 496 /* asm_abstractmethoderror *****************************************************
 497
 498    Creates and throws an AbstractMethodError.
 499
 500 *******************************************************************************/
 501
 502 asm_abstractmethoderror:
 503         mov     sp,a0                       /* pass java sp                       */
 504         add     $1*8,a0
 505         mov     0*8(sp),a1                  /* pass exception address             */
 506         sub     $3,a1
 507         call    exceptions_asm_new_abstractmethoderror@PLT
 508                                             /* exception pointer is return value  */
 509         pop     xpc                         /* get exception address              */
 510         sub     $3,xpc                      /* exception address is ra - 3        */
 511         jmp     L_asm_handle_exception
 512
 513
 514 /* asm_patcher_wrapper *********************************************************
 515
 516    XXX
 517
 518    Stack layout:
 519      40   return address
 520      32   pointer to virtual java_objectheader
 521      24   machine code (which is patched back later)
 522      16   unresolved class/method/field reference
 523       8   data segment displacement from load instructions
 524       0   pointer to patcher function
 525      -8   bp
 526
 527 *******************************************************************************/
 528
 529 asm_patcher_wrapper:
 530         push    bp                          /* save base pointer                  */
 531         mov     sp,bp                       /* move actual sp to bp               */
 532         sub     $((3+ARG_CNT+TMP_CNT)*8+sizestackframeinfo),sp
 533         and     $0xfffffffffffffff0,sp      /* align sp to 16-byte (this is for   */
 534                                             /* leaf functions)                    */
 535
 536         SAVE_ARGUMENT_REGISTERS(3)
 537         SAVE_TEMPORARY_REGISTERS(3+ARG_CNT)
 538
 539         mov     itmp1,0*8(sp)               /* save itmp1 and itmp2               */
 540         mov     itmp2,1*8(sp)               /* can be used by some instructions   */
 541
 542         mov     bp,a0                       /* pass SP of patcher stub            */
 543         add     $(1*8),a0
 544         mov     $0,a1                       /* pass PV (if NULL, use findmethod)  */
 545         mov     $0,a2                       /* pass RA (it's on the stack)        */
 546         call    patcher_wrapper@PLT
 547         mov     v0,2*8(sp)                  /* save return value                  */
 548
 549         RESTORE_ARGUMENT_REGISTERS(3)
 550         RESTORE_TEMPORARY_REGISTERS(3+ARG_CNT)
 551
 552         mov     0*8(sp),itmp1               /* restore itmp1 and itmp2            */
 553         mov     1*8(sp),itmp2               /* can be used by some instructions   */
 554         mov     2*8(sp),itmp3               /* restore return value               */
 555
 556         mov     bp,sp                       /* restore original sp                */
 557         pop     bp                          /* restore bp                         */
 558         add     $(5*8),sp                   /* remove patcher stackframe, keep RA */
 559
 560         test    itmp3,itmp3                 /* exception thrown?                  */
 561         jne     L_asm_patcher_wrapper_exception
 562         ret                                 /* call new patched code              */
 563
 564 L_asm_patcher_wrapper_exception:
 565         mov     itmp3,xptr                  /* get exception                      */
 566         pop     xpc                         /* get and remove return address      */
 567         jmp     L_asm_handle_exception
 568
 569
 570 /* asm_replacement_out *********************************************************
 571
 572    This code is jumped to from the replacement-out stubs that are executed
 573    when a thread reaches an activated replacement point.
 574
 575    The purpose of asm_replacement_out is to read out the parts of the
 576    execution state that cannot be accessed from C code, store this state,
 577    and then call the C function replace_me.
 578
 579    Stack layout:
 580       8                 start of stack inside method to replace
 581       0   rplpoint *    info on the replacement point that was reached
 582
 583 *******************************************************************************/
 584
 585 /* some room to accomodate changes of the stack frame size during replacement */
 586         /* XXX we should find a cleaner solution here */
 587 #define REPLACEMENT_ROOM  512
 588
 589 asm_replacement_out:
 590     /* create stack frame */
 591         sub     $(sizeexecutionstate + REPLACEMENT_ROOM),sp
 592
 593         /* save registers in execution state */
 594         mov     %rax,(RAX*8+offes_intregs)(sp)
 595         mov     %rbx,(RBX*8+offes_intregs)(sp)
 596         mov     %rcx,(RCX*8+offes_intregs)(sp)
 597         mov     %rdx,(RDX*8+offes_intregs)(sp)
 598         mov     %rsi,(RSI*8+offes_intregs)(sp)
 599         mov     %rdi,(RDI*8+offes_intregs)(sp)
 600         mov     %rbp,(RBP*8+offes_intregs)(sp)
 601         movq    $0  ,(RSP*8+offes_intregs)(sp) /* not used */
 602         mov     %r8 ,(R8 *8+offes_intregs)(sp)
 603         mov     %r9 ,(R9 *8+offes_intregs)(sp)
 604         mov     %r10,(R10*8+offes_intregs)(sp)
 605         mov     %r11,(R11*8+offes_intregs)(sp)
 606         mov     %r12,(R12*8+offes_intregs)(sp)
 607         mov     %r13,(R13*8+offes_intregs)(sp)
 608         mov     %r14,(R14*8+offes_intregs)(sp)
 609         mov     %r15,(R15*8+offes_intregs)(sp)
 610
 611         movq    %xmm0 ,(XMM0 *8+offes_fltregs)(sp)
 612         movq    %xmm1 ,(XMM1 *8+offes_fltregs)(sp)
 613         movq    %xmm2 ,(XMM2 *8+offes_fltregs)(sp)
 614         movq    %xmm3 ,(XMM3 *8+offes_fltregs)(sp)
 615         movq    %xmm4 ,(XMM4 *8+offes_fltregs)(sp)
 616         movq    %xmm5 ,(XMM5 *8+offes_fltregs)(sp)
 617         movq    %xmm6 ,(XMM6 *8+offes_fltregs)(sp)
 618         movq    %xmm7 ,(XMM7 *8+offes_fltregs)(sp)
 619         movq    %xmm8 ,(XMM8 *8+offes_fltregs)(sp)
 620         movq    %xmm9 ,(XMM9 *8+offes_fltregs)(sp)
 621         movq    %xmm10,(XMM10*8+offes_fltregs)(sp)
 622         movq    %xmm11,(XMM11*8+offes_fltregs)(sp)
 623         movq    %xmm12,(XMM12*8+offes_fltregs)(sp)
 624         movq    %xmm13,(XMM13*8+offes_fltregs)(sp)
 625         movq    %xmm14,(XMM14*8+offes_fltregs)(sp)
 626         movq    %xmm15,(XMM15*8+offes_fltregs)(sp)
 627
 628         /* calculate sp of method */
 629         mov     sp,itmp1
 630         add     $(sizeexecutionstate + REPLACEMENT_ROOM + 8),itmp1
 631         mov     itmp1,(offes_sp)(sp)
 632
 633         /* pv must be looked up via AVL tree */
 634         movq    $0,(offes_pv)(sp)
 635
 636         /* call replace_me */
 637         mov     -8(itmp1),a0                /* rplpoint *                         */
 638     mov     sp,a1                       /* arg1: execution state              */
 639     call    replace_me@PLT              /* call C function replace_me         */
 640     call    abort@PLT                   /* NEVER REACHED                      */
 641
 642 /* asm_replacement_in **********************************************************
 643
 644    This code writes the given execution state and jumps to the replacement
 645    code.
 646
 647    This function never returns!
 648
 649    C prototype:
 650       void asm_replacement_in(executionstate *es);
 651
 652 *******************************************************************************/
 653
 654 asm_replacement_in:
 655         mov     a0,%rbp                     /* executionstate *es                 */
 656
 657         /* set new sp */
 658         mov     (offes_sp)(%rbp),%rsp
 659
 660         /* store address of new code */
 661         push    (offes_pc)(%rbp)
 662
 663         /* copy registers from execution state */
 664         movq    (XMM0 *8+offes_fltregs)(%rbp),%xmm0
 665         movq    (XMM1 *8+offes_fltregs)(%rbp),%xmm1
 666         movq    (XMM2 *8+offes_fltregs)(%rbp),%xmm2
 667         movq    (XMM3 *8+offes_fltregs)(%rbp),%xmm3
 668         movq    (XMM4 *8+offes_fltregs)(%rbp),%xmm4
 669         movq    (XMM5 *8+offes_fltregs)(%rbp),%xmm5
 670         movq    (XMM6 *8+offes_fltregs)(%rbp),%xmm6
 671         movq    (XMM7 *8+offes_fltregs)(%rbp),%xmm7
 672         movq    (XMM8 *8+offes_fltregs)(%rbp),%xmm8
 673         movq    (XMM9 *8+offes_fltregs)(%rbp),%xmm9
 674         movq    (XMM10*8+offes_fltregs)(%rbp),%xmm10
 675         movq    (XMM11*8+offes_fltregs)(%rbp),%xmm11
 676         movq    (XMM12*8+offes_fltregs)(%rbp),%xmm12
 677         movq    (XMM13*8+offes_fltregs)(%rbp),%xmm13
 678         movq    (XMM14*8+offes_fltregs)(%rbp),%xmm14
 679         movq    (XMM15*8+offes_fltregs)(%rbp),%xmm15
 680
 681         mov     (RAX*8+offes_intregs)(%rbp),%rax
 682         mov     (RBX*8+offes_intregs)(%rbp),%rbx
 683         mov     (RCX*8+offes_intregs)(%rbp),%rcx
 684         mov     (RDX*8+offes_intregs)(%rbp),%rdx
 685         mov     (RSI*8+offes_intregs)(%rbp),%rsi
 686         mov     (RDI*8+offes_intregs)(%rbp),%rdi
 687         mov     (R8 *8+offes_intregs)(%rbp),%r8
 688         mov     (R9 *8+offes_intregs)(%rbp),%r9
 689         mov     (R10*8+offes_intregs)(%rbp),%r10
 690         mov     (R11*8+offes_intregs)(%rbp),%r11
 691         mov     (R12*8+offes_intregs)(%rbp),%r12
 692         mov     (R13*8+offes_intregs)(%rbp),%r13
 693         mov     (R14*8+offes_intregs)(%rbp),%r14
 694         mov     (R15*8+offes_intregs)(%rbp),%r15
 695
 696         mov     (RBP*8+offes_intregs)(%rbp),%rbp
 697
 698         /* jump to new code */
 699         ret
 700
 701
 702 /* asm_builtin_x2x *************************************************************
 703 *                                                                              *
 704 *   Wrapper functions for float to int corner cases                            *
 705 *                                                                              *
 706 *******************************************************************************/
 707
 708 asm_builtin_f2i:
 709         sub     $(ARG_CNT*8),sp
 710
 711         SAVE_ARGUMENT_REGISTERS(0)
 712
 713         movq    ftmp1,fa0
 714         call    builtin_f2i@PLT
 715
 716         RESTORE_ARGUMENT_REGISTERS(0)
 717
 718         add     $(ARG_CNT*8),sp
 719         ret
 720
 721
 722 asm_builtin_f2l:
 723         sub     $(ARG_CNT*8),sp
 724
 725         SAVE_ARGUMENT_REGISTERS(0)
 726
 727         movq    ftmp1,fa0
 728         call    builtin_f2l@PLT
 729
 730         RESTORE_ARGUMENT_REGISTERS(0)
 731
 732         add     $(ARG_CNT*8),sp
 733         ret
 734
 735
 736 asm_builtin_d2i:
 737         sub     $(ARG_CNT*8),sp
 738
 739         SAVE_ARGUMENT_REGISTERS(0)
 740
 741         movq    ftmp1,fa0
 742         call    builtin_d2i@PLT
 743
 744         RESTORE_ARGUMENT_REGISTERS(0)
 745
 746         add     $(ARG_CNT*8),sp
 747         ret
 748
 749
 750 asm_builtin_d2l:
 751         sub     $(ARG_CNT*8),sp
 752
 753         SAVE_ARGUMENT_REGISTERS(0)
 754
 755         movq    ftmp1,fa0
 756         call    builtin_d2l@PLT
 757
 758         RESTORE_ARGUMENT_REGISTERS(0)
 759
 760         add     $(ARG_CNT*8),sp
 761         ret
 762
 763
 764 asm_getclassvalues_atomic:
 765 _crit_restart:
 766 _crit_begin:
 767         movl    offbaseval(a0),itmp1l
 768         movl    offdiffval(a0),itmp2l
 769         movl    offbaseval(a1),itmp3l
 770 _crit_end:
 771         movl    itmp1l,offcast_super_baseval(a2)
 772         movl    itmp2l,offcast_super_diffval(a2)
 773         movl    itmp3l,offcast_sub_baseval(a2)
 774         ret
 775
 776         .data
 777
 778 asm_criticalsections:
 779 #if defined(ENABLE_THREADS)
 780         .quad   _crit_begin
 781         .quad   _crit_end
 782         .quad   _crit_restart
 783 #endif
 784         .quad 0
 785
 786
 787 /* Disable exec-stacks, required for Gentoo ***********************************/
 788
 789 #if defined(__GCC__) && defined(__ELF__)
 790         .section .note.GNU-stack,"",@progbits
 791 #endif
 792
 793
 794 /*
 795  * These are local overrides for various environment variables in Emacs.
 796  * Please do not remove this and leave it at the end of the file, where
 797  * Emacs will automagically detect them.
 798  * ---------------------------------------------------------------------
 799  * Local variables:
 800  * mode: asm
 801  * indent-tabs-mode: t
 802  * c-basic-offset: 4
 803  * tab-width: 4
 804  * End:
 805  * vim:noexpandtab:sw=4:ts=4:
 806  */