src/vm/jit/x86_64/asmpart.S

   1 /* src/vm/jit/x86_64/asmpart.S - Java-C interface functions for x86_64
   2
   3    Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25 */
  26
  27
  28 #include "config.h"
  29
  30 #include "vm/jit/x86_64/arch.h"
  31 #include "vm/jit/x86_64/md-abi.h"
  32 #include "vm/jit/x86_64/md-asm.h"
  33
  34 #include "vm/jit/abi-asm.h"
  35 #include "vm/jit/methodheader.h"
  36
  37
  38         .text
  39
  40
  41 /* export functions ***********************************************************/
  42
  43         .globl asm_vm_call_method
  44         .globl asm_vm_call_method_int
  45         .globl asm_vm_call_method_long
  46         .globl asm_vm_call_method_float
  47         .globl asm_vm_call_method_double
  48         .globl asm_vm_call_method_exception_handler
  49         .globl asm_vm_call_method_end
  50
  51         .globl asm_handle_exception
  52         .globl asm_handle_nat_exception
  53
  54         .globl asm_abstractmethoderror
  55
  56         .globl asm_builtin_f2i
  57         .globl asm_builtin_f2l
  58         .globl asm_builtin_d2i
  59         .globl asm_builtin_d2l
  60
  61         .globl asm_compare_and_swap
  62         .globl asm_memory_barrier
  63
  64
  65 /********************* function asm_calljavafunction ***************************
  66 *                                                                              *
  67 *   This function calls a Java-method (which possibly needs compilation)       *
  68 *   with up to 4 address parameters.                                           *
  69 *                                                                              *
  70 *   This functions calls the JIT-compiler which eventually translates the      *
  71 *   method into machine code.                                                  *
  72 *                                                                              *
  73 *   C-prototype:                                                               *
  74 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  75 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  76 *                                                                              *
  77 *******************************************************************************/
  78
  79         .align  8
  80
  81         .quad   0                           /* catch type all                     */
  82         .quad   0                           /* handler pc                         */
  83         .quad   0                           /* end pc                             */
  84         .quad   0                           /* start pc                           */
  85         .long   1                           /* extable size                       */
  86         .long   0                           /* ALIGNMENT PADDING                  */
  87         .quad   0                           /* line number table  start           */
  88         .quad   0                           /* line number table  size            */
  89         .long   0                           /* fltsave                            */
  90         .long   0                           /* intsave                            */
  91         .long   0                           /* isleaf                             */
  92         .long   0                           /* frame size                         */
  93         .quad   0                           /* codeinfo pointer                   */
  94
  95 asm_vm_call_method:
  96 asm_vm_call_method_int:
  97 asm_vm_call_method_long:
  98 asm_vm_call_method_float:
  99 asm_vm_call_method_double:
 100         sub     $(7*8),sp                   /* keep stack 16-byte aligned         */
 101         mov     %rbx,0*8(sp)                /* %rbx is not a callee saved in cacao*/
 102         mov     s0,1*8(sp)
 103         mov     s1,2*8(sp)
 104         mov     s2,3*8(sp)
 105         mov     s3,4*8(sp)
 106         mov     s4,5*8(sp)
 107
 108         mov     a0,6*8(sp)                  /* store method PV                    */
 109
 110         mov     sp,s0                       /* save stack pointer                 */
 111
 112         mov     a1,t0                       /* address of data structure          */
 113         mov     a2,itmp1                    /* number of stack arguments          */
 114
 115         mov     0*8(t0),a0
 116         mov     1*8(t0),a1
 117         mov     2*8(t0),a2
 118         mov     3*8(t0),a3
 119         mov     4*8(t0),a4
 120         mov     5*8(t0),a5
 121
 122         movq    6*8(t0),fa0
 123         movq    7*8(t0),fa1
 124         movq    8*8(t0),fa2
 125         movq    9*8(t0),fa3
 126         movq    10*8(t0),fa4
 127         movq    11*8(t0),fa5
 128         movq    12*8(t0),fa6
 129         movq    13*8(t0),fa7
 130
 131         cmp     $0,itmp1l
 132         je      L_asm_vm_call_method_stack_copy_done
 133
 134         mov     itmp1,itmp2
 135         add     $1,itmp2                    /* keep stack 16-byte aligned         */
 136         and     $0xfffffffffffffffe,itmp2
 137         shl     $3,itmp2                    /* calculate stack size               */
 138         sub     itmp2,sp                    /* create stack frame                 */
 139         mov     sp,itmp2                    /* temporary stack pointer            */
 140
 141 L_asm_vm_call_method_stack_copy_loop:
 142         mov     14*8(t0),itmp3              /* load argument                      */
 143         mov     itmp3,0(itmp2)              /* store argument on stack            */
 144
 145         sub     $1,itmp1l                   /* subtract 1 argument                */
 146         add     $8,t0                       /* set address of next argument       */
 147         add     $8,itmp2                    /* increase SP                        */
 148
 149         cmp     $0,itmp1l
 150         jg      L_asm_vm_call_method_stack_copy_loop
 151
 152 L_asm_vm_call_method_stack_copy_done:
 153         lea     (6*8-256)(s0),mptr          /* We subtract 256 to force the next  */
 154                                             /* move instruction to have a 32-bit  */
 155                                             /* offset.                            */
 156
 157         mov     (0*8+256)(mptr),itmp3       /* load PV                            */
 158         call    *itmp3
 159
 160         mov     s0,sp                       /* restore SP                         */
 161
 162 L_asm_vm_call_method_return:
 163         mov     0*8(sp),%rbx                /* restore callee saved registers     */
 164         mov     1*8(sp),s0
 165         mov     2*8(sp),s1
 166         mov     3*8(sp),s2
 167         mov     4*8(sp),s3
 168         mov     5*8(sp),s4
 169         add     $(7*8),sp                   /* free stack space                   */
 170         ret
 171
 172 asm_vm_call_method_exception_handler:
 173         mov     xptr,a0                     /* pass exception pointer             */
 174         call    builtin_throw_exception@PLT
 175         jmp     L_asm_vm_call_method_return
 176
 177 asm_vm_call_method_end:
 178         nop
 179
 180
 181 /* asm_handle_exception ********************************************************
 182 *                                                                              *
 183 *   This function handles an exception. It does not use the usual calling      *
 184 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 185 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 186 *   the local exception table for a handler. If no one is found, it unwinds    *
 187 *   stacks and continues searching the callers.                                *
 188 *                                                                              *
 189 *******************************************************************************/
 190
 191 asm_handle_nat_exception:
 192         add     $8,sp                       /* clear return address of native stub*/
 193
 194 asm_handle_exception:
 195 L_asm_handle_exception:                 /* required for PIC code              */
 196         sub     $((ARG_CNT+TMP_CNT)*8),sp   /* create maybe-leaf stackframe       */
 197
 198         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 199         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 200
 201         mov     $((ARG_CNT+TMP_CNT)*8),a3   /* prepare a3 for handle_exception    */
 202         mov     $1,t0                       /* set maybe-leaf flag                */
 203
 204 L_asm_handle_exception_stack_loop:
 205         sub     $(6*8),sp
 206         mov     xptr,0*8(sp)                /* save exception pointer             */
 207         mov     xpc,1*8(sp)                 /* save exception pc                  */
 208         add     sp,a3                       /* calculate Java sp into a3...       */
 209         add     $(6*8),a3
 210         mov     a3,3*8(sp)                  /* ...and save it                     */
 211         mov     t0,4*8(sp)                  /* save maybe-leaf flag               */
 212
 213         mov     xpc,a0                      /* exception pc                       */
 214         call    codegen_get_pv_from_pc@PLT
 215         mov     v0,2*8(sp)                  /* save data segment pointer          */
 216
 217         mov     0*8(sp),a0                  /* pass exception pointer             */
 218         mov     1*8(sp),a1                  /* pass exception pc                  */
 219         mov     v0,a2                       /* pass data segment pointer          */
 220         mov     3*8(sp),a3                  /* pass Java stack pointer            */
 221         call    exceptions_handle_exception@PLT
 222
 223         test    v0,v0
 224         jz      L_asm_handle_exception_not_catched
 225
 226         mov     v0,xpc                      /* move handlerpc into xpc            */
 227         mov     0*8(sp),xptr                /* restore exception pointer          */
 228         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 229         add     $(6*8),sp                   /* free stack frame                   */
 230
 231         test    t0,t0                       /* test for maybe-leaf flag           */
 232         jz      L_asm_handle_exception_no_leaf
 233
 234         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 235         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 236
 237         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 238
 239 L_asm_handle_exception_no_leaf:
 240         jmp     *xpc                        /* jump to the handler                */
 241
 242 L_asm_handle_exception_not_catched:
 243         mov     0*8(sp),xptr                /* restore exception pointer          */
 244         mov     2*8(sp),itmp3               /* restore data segment pointer       */
 245         mov     4*8(sp),t0                  /* get maybe-leaf flag                */
 246         add     $(6*8),sp
 247
 248         test    t0,t0
 249         jz      L_asm_handle_exception_no_leaf_stack
 250
 251         add     $((ARG_CNT+TMP_CNT)*8),sp   /* remove maybe-leaf stackframe       */
 252         xor     t0,t0                       /* clear the isleaf flags             */
 253
 254 L_asm_handle_exception_no_leaf_stack:
 255         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 256         add     sp,itmp2                    /* pointer to save area               */
 257
 258         mov     IntSave(itmp3),a0l          /* a0l = saved int register count     */
 259         test    a0l,a0l
 260         je      noint
 261
 262         cmp     $1,a0l
 263         je      int1
 264         cmp     $2,a0l
 265         je      int2
 266         cmp     $3,a0l
 267         je      int3
 268         cmp     $4,a0l
 269         je      int4
 270
 271         mov     -5*8(itmp2),s0
 272 int4:
 273         mov     -4*8(itmp2),s1
 274 int3:
 275         mov     -3*8(itmp2),s2
 276 int2:
 277         mov     -2*8(itmp2),s3
 278 int1:
 279         mov     -1*8(itmp2),s4
 280
 281         shl     $3,a0l                      /* multiply by 8 bytes                */
 282         sub     a0,itmp2
 283
 284 noint:
 285 #if 0
 286         mov     FltSave(itmp3),a0l          /* a0l = saved flt register count     */
 287         test    a0l,a0l
 288         je      noflt
 289
 290         cmpl    $1,a0l
 291         je      flt1
 292         cmpl    $2,a0l
 293         je      flt2
 294         cmpl    $3,a0l
 295         je      flt3
 296         cmpl    $4,a0l
 297         je      flt4
 298
 299         movq    -5*8(itmp2),%xmm11
 300 flt4:
 301         movq    -4*8(itmp2),%xmm12
 302 flt3:
 303         movq    -3*8(itmp2),%xmm13
 304 flt2:
 305         movq    -2*8(itmp2),%xmm14
 306 flt1:
 307         movq    -1*8(itmp2),%xmm15
 308
 309 noflt:
 310 #endif
 311         mov     FrameSize(itmp3),itmp2l     /* get frame size                     */
 312         add     itmp2,sp                    /* unwind stack                       */
 313
 314                                             /* exception pointer is still set     */
 315         pop     xpc                         /* the new xpc is return address      */
 316         sub     $3,xpc                      /* subtract 3 bytes for call          */
 317
 318         xor     a3,a3                       /* prepare a3 for handle_exception    */
 319
 320         jmp             L_asm_handle_exception_stack_loop
 321
 322
 323 /* asm_abstractmethoderror *****************************************************
 324
 325    Creates and throws an AbstractMethodError.
 326
 327 *******************************************************************************/
 328
 329 asm_abstractmethoderror:
 330         mov     sp,a0                       /* pass java sp                       */
 331         add     $1*8,a0
 332         mov     0*8(sp),a1                  /* pass exception address             */
 333         sub     $3,a1
 334         call    exceptions_asm_new_abstractmethoderror@PLT
 335                                             /* exception pointer is return value  */
 336         pop     xpc                         /* get exception address              */
 337         sub     $3,xpc                      /* exception address is ra - 3        */
 338         jmp     L_asm_handle_exception
 339
 340
 341 /* asm_builtin_x2x *************************************************************
 342 *                                                                              *
 343 *   Wrapper functions for float to int corner cases                            *
 344 *                                                                              *
 345 *******************************************************************************/
 346
 347 asm_builtin_f2i:
 348         sub     $(ARG_CNT*8),sp
 349
 350         SAVE_ARGUMENT_REGISTERS(0)
 351
 352         movq    ftmp1,fa0
 353         call    builtin_f2i@PLT
 354
 355         RESTORE_ARGUMENT_REGISTERS(0)
 356
 357         add     $(ARG_CNT*8),sp
 358         ret
 359
 360
 361 asm_builtin_f2l:
 362         sub     $(ARG_CNT*8),sp
 363
 364         SAVE_ARGUMENT_REGISTERS(0)
 365
 366         movq    ftmp1,fa0
 367         call    builtin_f2l@PLT
 368
 369         RESTORE_ARGUMENT_REGISTERS(0)
 370
 371         add     $(ARG_CNT*8),sp
 372         ret
 373
 374
 375 asm_builtin_d2i:
 376         sub     $(ARG_CNT*8),sp
 377
 378         SAVE_ARGUMENT_REGISTERS(0)
 379
 380         movq    ftmp1,fa0
 381         call    builtin_d2i@PLT
 382
 383         RESTORE_ARGUMENT_REGISTERS(0)
 384
 385         add     $(ARG_CNT*8),sp
 386         ret
 387
 388
 389 asm_builtin_d2l:
 390         sub     $(ARG_CNT*8),sp
 391
 392         SAVE_ARGUMENT_REGISTERS(0)
 393
 394         movq    ftmp1,fa0
 395         call    builtin_d2l@PLT
 396
 397         RESTORE_ARGUMENT_REGISTERS(0)
 398
 399         add     $(ARG_CNT*8),sp
 400         ret
 401
 402
 403 /* asm_compare_and_swap ********************************************************
 404
 405    Does an atomic compare and swap.  Required for the lock
 406    implementation.
 407
 408 *******************************************************************************/
 409
 410 asm_compare_and_swap:
 411         mov     a1,v0                       /* v0 is %rax                         */
 412         lock cmpxchg a2,(a0)
 413         ret
 414
 415
 416 /* asm_memory_barrier **********************************************************
 417
 418    A memory barrier for the Java Memory Model.
 419
 420 *******************************************************************************/
 421
 422 asm_memory_barrier:
 423         mfence
 424         ret
 425
 426
 427 /* disable exec-stacks ********************************************************/
 428
 429 #if defined(__linux__) && defined(__ELF__)
 430         .section .note.GNU-stack,"",%progbits
 431 #endif
 432
 433
 434 /*
 435  * These are local overrides for various environment variables in Emacs.
 436  * Please do not remove this and leave it at the end of the file, where
 437  * Emacs will automagically detect them.
 438  * ---------------------------------------------------------------------
 439  * Local variables:
 440  * mode: asm
 441  * indent-tabs-mode: t
 442  * c-basic-offset: 4
 443  * tab-width: 4
 444  * End:
 445  * vim:noexpandtab:sw=4:ts=4:
 446  */