src/vm/jit/mips/asmpart.S

   1 /* src/vm/jit/mips/asmpart.S - Java-C interface functions for MIPS
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28
  29    Changes: Christian Thalinger
  30                         Edwin Steiner
  31
  32    $Id: asmpart.S 4654 2006-03-19 19:46:11Z edwin $
  33
  34 */
  35
  36
  37 #include "config.h"
  38
  39 #include "vm/jit/mips/md-abi.h"
  40 #include "vm/jit/mips/md-asm.h"
  41 #include "vm/jit/mips/offsets.h"
  42
  43 #include "vm/jit/abi.h"
  44 #include "vm/jit/methodheader.h"
  45
  46
  47         .text
  48         .set    noat
  49
  50
  51 /* export functions ***********************************************************/
  52
  53         .globl asm_vm_call_method
  54         .globl asm_vm_call_method_int
  55         .globl asm_vm_call_method_long
  56         .globl asm_vm_call_method_float
  57         .globl asm_vm_call_method_double
  58
  59         .globl asm_call_jit_compiler
  60         .globl asm_handle_exception
  61         .globl asm_handle_nat_exception
  62
  63         .globl asm_wrapper_patcher
  64
  65         .globl asm_replacement_out
  66         .globl asm_replacement_in
  67
  68         .globl asm_perform_threadswitch
  69         .globl asm_initialize_thread_stack
  70         .globl asm_switchstackandcall
  71         .globl asm_getclassvalues_atomic
  72         .globl asm_criticalsections
  73
  74         .globl compare_and_swap
  75
  76
  77 /********************* function asm_calljavafunction ***************************
  78 *                                                                              *
  79 *   This function calls a Java-method (which possibly needs compilation)       *
  80 *   with up to 4 address parameters.                                           *
  81 *                                                                              *
  82 *   This functions calls the JIT-compiler which eventually translates the      *
  83 *   method into machine code.                                                  *
  84 *                                                                              *
  85 *   A possibly throwed exception will be returned to the caller as function    *
  86 *   return value, so the java method cannot return a fucntion value (this      *
  87 *   function usually calls 'main' and '<clinit>' which do not return a         *
  88 *   function value).                                                           *
  89 *                                                                              *
  90 *   C-prototype:                                                               *
  91 *    javaobject_header *asm_calljavafunction (methodinfo *m,                   *
  92 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  93 *                                                                              *
  94 *******************************************************************************/
  95
  96         .ent    asm_vm_call_method
  97
  98         .align  3
  99
 100         .dword  0                           /* catch type all                     */
 101         .dword  calljava_xhandler2          /* handler pc                         */
 102         .dword  calljava_xhandler2          /* end pc                             */
 103         .dword  asm_vm_call_method          /* start pc                           */
 104         .word   1                           /* extable size                       */
 105         .word   0                           /* 4-byte ALIGNMENT PADDING           */
 106         .dword  0                           /* line number table start            */
 107         .dword  0                           /* line number table size             */
 108         .word   0                           /* 4-byte ALIGNMENT PADDING           */
 109         .word   0                           /* fltsave                            */
 110         .word   0                           /* intsave                            */
 111         .word   0                           /* isleaf                             */
 112         .word   0                           /* IsSync                             */
 113         .word   0                           /* frame size                         */
 114         .dword  0                           /* method pointer (pointer to name)   */
 115
 116 asm_vm_call_method:
 117 asm_vm_call_method_int:
 118 asm_vm_call_method_long:
 119 asm_vm_call_method_float:
 120 asm_vm_call_method_double:
 121         .set    noreorder                 /* XXX we need to recompute pv          */
 122
 123         aaddiu  sp,sp,-12*8               /* allocate stack space (only 11 needed)*/
 124         ast     ra,0(sp)                  /* save return address                  */
 125
 126         bal     L_asm_vm_call_method_compute_pv
 127         ast     pv,1*8(sp)                /* procedure vector                     */
 128 L_asm_vm_call_method_compute_pv:
 129         aaddiu  pv,ra,-4*4
 130         ast     s7,3*8(sp)
 131
 132         sdc1    fss0,5*8(sp)              /* save non JavaABI saved flt registers */
 133         sdc1    fss1,6*8(sp)
 134         sdc1    fss2,7*8(sp)
 135         sdc1    fss3,8*8(sp)
 136         sdc1    fss4,9*8(sp)
 137         sdc1    fss5,10*8(sp)
 138
 139         ast     a0,4*8(sp)                /* save method pointer for compiler     */
 140
 141         move    t0,a2
 142         move    s7,a1
 143         blez    s7,calljava_argsloaded
 144         nop
 145
 146         ald     a0,offvmargdata(t0)
 147         ldc1    fa0,offvmargdata(t0)
 148         daddi   s7,s7,-1
 149         blez    s7,calljava_argsloaded
 150         nop
 151
 152         ald     a1,offvmargdata+sizevmarg*1(t0)
 153         ldc1    fa1,offvmargdata+sizevmarg*1(t0)
 154         daddi   s7,s7,-1
 155         blez    s7,calljava_argsloaded
 156         nop
 157
 158         ald     a2,offvmargdata+sizevmarg*2(t0)
 159         ldc1    fa2,offvmargdata+sizevmarg*2(t0)
 160         daddi   s7,s7,-1
 161         blez    s7,calljava_argsloaded
 162         nop
 163
 164         ald     a3,offvmargdata+sizevmarg*3(t0)
 165         ldc1    fa3,offvmargdata+sizevmarg*3(t0)
 166         daddi   s7,s7,-1
 167         blez    s7,calljava_argsloaded
 168         nop
 169
 170         ald     a4,offvmargdata+sizevmarg*4(t0)
 171         ldc1    fa4,offvmargdata+sizevmarg*4(t0)
 172         daddi   s7,s7,-1
 173         blez    s7,calljava_argsloaded
 174         nop
 175
 176         ald     a5,offvmargdata+sizevmarg*5(t0)
 177         ldc1    fa5,offvmargdata+sizevmarg*5(t0)
 178         daddi   s7,s7,-1
 179         blez    s7,calljava_argsloaded
 180         nop
 181
 182         ald     a6,offvmargdata+sizevmarg*6(t0)
 183         ldc1    fa6,offvmargdata+sizevmarg*6(t0)
 184         daddi   s7,s7,-1
 185         blez    s7,calljava_argsloaded
 186         nop
 187
 188         ald     a7,offvmargdata+sizevmarg*7(t0)
 189         ldc1    fa7,offvmargdata+sizevmarg*7(t0)
 190         daddi   s7,s7,-1
 191
 192 calljava_argsloaded:
 193         move    t8,sp                      /* save stack pointer                  */
 194         blez    s7,calljava_nocopy
 195         nop
 196         subu    t1,zero,s7
 197         sll     t2,t1,3
 198         aaddu   sp,sp,t2
 199         aaddu   t2,t2,t8
 200
 201 calljava_copyloop:
 202     ald     t3,offvmargdata+sizevmarg*8(t0)
 203         ast     t3,0(t2)
 204         ala     t1,1(t1)
 205         ala     t0,sizevmarg(t0)
 206         ala     t2,8(t2)
 207         bnez    t1,calljava_copyloop
 208         nop
 209
 210 calljava_nocopy:
 211         ald     itmp1,4*8(t8)             /* pass method pointer via itmp1        */
 212
 213         ala     mptr,asm_call_jit_compiler/* fake virtual function call (2 instr) */
 214         ast     mptr,2*8(t8)              /* store function address               */
 215         ala     mptr,1*8(t8)              /* set method pointer                   */
 216
 217         ald     pv,1*8(mptr)              /* method call as in Java               */
 218         jalr    pv                        /* call JIT compiler                    */
 219         nop
 220 L_asm_vm_call_method_recompute_pv:
 221 /*      aaddiu  pv,ra,(asm_vm_call_method - L_asm_vm_call_method_recompute_pv)*/
 222         aaddiu  pv,ra,-76*4               /* recompute procedure vector           */
 223
 224         .set    reorder                   /* XXX we need to recompute pv          */
 225
 226 calljava_return2:
 227         ald     ra,0(sp)                  /* restore return address               */
 228         ald     pv,8(sp)                  /* restore procedure vector             */
 229         ald     s7,3*8(sp)
 230
 231         ldc1    fss0,5*8(sp)              /* restore non JavaABI saved flt regs   */
 232         ldc1    fss1,6*8(sp)
 233         ldc1    fss2,7*8(sp)
 234         ldc1    fss3,8*8(sp)
 235         ldc1    fss4,9*8(sp)
 236         ldc1    fss5,10*8(sp)
 237
 238         aaddiu  sp,sp,12*8                /* free stack space                     */
 239         j       ra                        /* return                               */
 240
 241 calljava_xhandler2:
 242         asll    s7,s7,3
 243         aaddu   sp,s7,sp
 244         move    a0,itmp1
 245         jal     builtin_throw_exception
 246         b       calljava_return2
 247
 248         .end    asm_vm_call_method
 249
 250
 251 /****************** function asm_call_jit_compiler *****************************
 252 *                                                                              *
 253 *   invokes the compiler for untranslated JavaVM methods.                      *
 254 *                                                                              *
 255 *   Register REG_ITEMP1 contains a pointer to the method info structure        *
 256 *   (prepared by createcompilerstub). Using the return address in R31 and the  *
 257 *   offset in the LDA instruction or using the value in methodptr R25 the      *
 258 *   patching address for storing the method address can be computed:           *
 259 *                                                                              *
 260 *   method address was either loaded using                                     *
 261 *   M_ALD (REG_PV, REG_PV, a)        ; invokestatic/special    ($28)           *
 262 *   M_JSR (REG_RA, REG_PV);                                                    *
 263 *   M_NOP                                                                      *
 264 *   M_LDA (REG_PV, REG_RA, val)                                                *
 265 *   or                                                                         *
 266 *   M_ALD (REG_PV, REG_METHODPTR, m) ; invokevirtual/interface ($25)           *
 267 *   M_JSR (REG_RA, REG_PV);                                                    *
 268 *   M_NOP                                                                      *
 269 *   in the static case the method pointer can be computed using the            *
 270 *   return address and the lda function following the jmp instruction          *
 271 *                                                                              *
 272 *******************************************************************************/
 273
 274
 275         .ent    asm_call_jit_compiler
 276
 277 asm_call_jit_compiler:
 278         aaddiu  sp,sp,-(20*8+sizestackframeinfo) /* allocate stack space          */
 279
 280         SAVE_ARGUMENT_REGISTERS(0)
 281
 282         ast     mptr,16*8(sp)         /* save method pointer                      */
 283         ast     ra,17*8(sp)           /* save return address                      */
 284         ast     itmp1,18*8(sp)        /* save methodinfo pointer                  */
 285
 286         aaddiu  a0,sp,20*8            /* create stackframe info                   */
 287         move    a1,zero               /* we don't have pv handy                   */
 288         aaddiu  a2,sp,(20*8+sizestackframeinfo) /* pass java sp                   */
 289         ald     a3,17*8(sp)           /* pass java ra                             */
 290         move    a4,a3                 /* xpc is equal to ra                       */
 291         jal     stacktrace_create_extern_stackframeinfo
 292
 293         ald     a0,18*8(sp)           /* pass methodinfo pointer                  */
 294         jal     jit_compile           /* jit compiler                             */
 295         ast     v0,18*8(sp)           /* save return value                        */
 296
 297         aaddiu  a0,sp,20*8            /* remove stackframe info                   */
 298         jal     stacktrace_remove_stackframeinfo
 299
 300         ald     a0,17*8(sp)           /* pass return address                      */
 301         aaddiu  a1,sp,20*8            /* pass stackframeinfo (for PV)             */
 302         ald     a2,16*8(sp)           /* pass method pointer                      */
 303         jal     md_assembler_get_patch_address /* get address of patch position   */
 304         move    t0,v0                 /* move offset to t0 for later use          */
 305
 306         RESTORE_ARGUMENT_REGISTERS(0)
 307
 308         ald     ra,17*8(sp)           /* restore return address                   */
 309         ald     v0,18*8(sp)           /* restore return value                     */
 310         aaddiu  sp,sp,20*8+sizestackframeinfo /* deallocate stack area            */
 311
 312         beqz    v0,L_asm_call_jit_compiler_exception
 313
 314         ast     v0,0(t0)              /* store new method address                 */
 315         move    pv,v0                 /* move method address into pv              */
 316         jr      pv                    /* and call method. The method returns      */
 317                                       /* directly to the caller (ra).             */
 318
 319 L_asm_call_jit_compiler_exception:
 320 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 321         aaddiu  sp,sp,-2*8
 322         ast     ra,0*8(sp)
 323         jal     builtin_asm_get_exceptionptrptr
 324         ald     ra,0*8(sp)
 325         aaddiu  sp,sp,2*8
 326 #else
 327         la      v0,_exceptionptr
 328 #endif
 329         ald     xptr,0(v0)            /* get the exception pointer                */
 330         ast     zero,0(v0)            /* clear the exception pointer              */
 331
 332         aaddiu  xpc,ra,-4             /* faulting address is return adress - 4    */
 333         b       asm_handle_nat_exception
 334
 335         .end    asm_call_jit_compiler
 336
 337
 338 /* asm_handle_exception ********************************************************
 339
 340    This function handles an exception. It does not use the usual calling
 341    conventions. The exception pointer is passed in REG_ITMP1 and the
 342    pc from the exception raising position is passed in REG_ITMP2. It searches
 343    the local exception table for a handler. If no one is found, it unwinds
 344    stacks and continues searching the callers.
 345
 346 *******************************************************************************/
 347
 348         .ent    asm_handle_nat_exception
 349
 350 asm_handle_nat_exception:
 351 L_asm_handle_exception_stack_loop:
 352         aaddiu  sp,sp,-6*8                  /* allocate stack                     */
 353         ast     xptr,0*8(sp)                /* save exception pointer             */
 354         ast     xpc,1*8(sp)                 /* save exception pc                  */
 355         ast     ra,3*8(sp)                  /* save return address                */
 356         ast     zero,4*8(sp)                /* save maybe-leaf flag (cleared)     */
 357
 358         move    a0,ra                       /* pass return address                */
 359         jal     md_codegen_findmethod       /* get PV from RA                     */
 360         ast     v0,2*8(sp)                  /* save data segment pointer          */
 361
 362         ald     a0,0*8(sp)                  /* pass exception pointer             */
 363         ald     a1,1*8(sp)                  /* pass exception pc                  */
 364         move    a2,v0                       /* pass data segment pointer          */
 365         aaddiu  a3,sp,6*8                   /* pass Java stack pointer            */
 366
 367         b       L_asm_handle_exception_continue
 368
 369         .aent    asm_handle_exception
 370
 371 asm_handle_exception:
 372         aaddiu  sp,sp,-(ARG_CNT+TMP_CNT)*8  /* create maybe-leaf stackframe       */
 373
 374         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 375         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 376
 377         aaddiu  sp,sp,-6*8                  /* allocate stack                     */
 378         ast     xptr,0*8(sp)                /* save exception pointer             */
 379         ast     xpc,1*8(sp)                 /* save exception pc                  */
 380         ast     pv,2*8(sp)                  /* save data segment pointer          */
 381         ast     ra,3*8(sp)                  /* save return address                */
 382         addu    t0,zero,1                   /* set maybe-leaf flag                */
 383         ast     t0,4*8(sp)                  /* save maybe-leaf flag               */
 384
 385         move    a0,xptr                     /* pass exception pointer             */
 386         move    a1,xpc                      /* pass exception pc                  */
 387         move    a2,pv                       /* pass data segment pointer          */
 388         aaddiu  a3,sp,(ARG_CNT+TMP_CNT+6)*8 /* pass Java stack pointer            */
 389
 390 L_asm_handle_exception_continue:
 391         jal     exceptions_handle_exception
 392
 393         beqz    v0,L_asm_handle_exception_not_catched
 394
 395         move    xpc,v0                      /* move handlerpc into xpc            */
 396         ald     xptr,0*8(sp)                /* restore exception pointer          */
 397         ald     pv,2*8(sp)                  /* restore data segment pointer       */
 398         ald     ra,3*8(sp)                  /* restore return address             */
 399         ald     t0,4*8(sp)                  /* get maybe-leaf flag                */
 400         aaddiu  sp,sp,6*8                   /* free stackframe                    */
 401
 402         beqz    t0,L_asm_handle_exception_no_leaf
 403
 404         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 405         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 406
 407         aaddiu  sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 408
 409 L_asm_handle_exception_no_leaf:
 410         jr      xpc                         /* jump to the handler                */
 411
 412 L_asm_handle_exception_not_catched:
 413         ald     xptr,0*8(sp)                /* restore exception pointer          */
 414         ald     pv,2*8(sp)                  /* restore data segment pointer       */
 415         ald     ra,3*8(sp)                  /* restore return address             */
 416         ald     t0,4*8(sp)                  /* get maybe-leaf flag                */
 417         aaddiu  sp,sp,6*8                   /* free stackframe                    */
 418
 419         beqz    t0,L_asm_handle_exception_no_leaf_stack
 420
 421         aaddiu  sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 422         move    t0,zero                     /* clear the maybe-leaf flag          */
 423
 424 L_asm_handle_exception_no_leaf_stack:
 425         lw      t1,FrameSize(pv)            /* get frame size                     */
 426         aaddu   t1,sp,t1                    /* pointer to save area               */
 427
 428         lw      t2,IsLeaf(pv)               /* is leaf procedure                  */
 429         bnez    t2,L_asm_handle_exception_no_ra_restore
 430
 431         ald     ra,-1*8(t1)                 /* restore ra                         */
 432         aaddiu  t1,t1,-8                    /* t1--                               */
 433
 434 L_asm_handle_exception_no_ra_restore:
 435         move    xpc,ra                      /* the new xpc is ra                  */
 436         lw      t2,IntSave(pv)              /* t1 = saved int register count      */
 437         ala     t3,ex_int2                  /* t3 = current pc                    */
 438         sll     t2,t2,2                     /* t2 = register count * 4            */
 439         asubu   t3,t3,t2                    /* t3 = IntSave - 4 * register count  */
 440         jr      t3                          /* jump to save position              */
 441
 442         ald     s0,-8*8(t1)
 443         ald     s1,-7*8(t1)
 444         ald     s2,-6*8(t1)
 445         ald     s3,-5*8(t1)
 446         ald     s4,-4*8(t1)
 447         ald     s5,-3*8(t1)
 448         ald     s6,-2*8(t1)
 449         ald     s7,-1*8(t1)
 450 ex_int2:
 451         sll     t2,t2,1               /* t2 = register count * 4 * 2              */
 452         asubu   t1,t1,t2              /* t1 = t0 - 8 * register count             */
 453
 454         lw      t2,FltSave(pv)        /* t2 = saved flt register count            */
 455         ala     t3,ex_flt2            /* t3 = current pc                          */
 456         sll     t2,t2,2               /* t2 = register count * 4                  */
 457         asubu   t3,t3,t2              /* t3 = ex_int_sav - 4 * register count     */
 458         jr      t3                          /* jump to save position              */
 459
 460         ldc1    fs0,-4*8(t1)
 461         ldc1    fs1,-3*8(t1)
 462         ldc1    fs2,-2*8(t1)
 463         ldc1    fs3,-1*8(t1)
 464
 465 ex_flt2:
 466         lw      t1,FrameSize(pv)            /* get frame size                     */
 467         aaddu   sp,sp,t1                    /* unwind stack                       */
 468         b       L_asm_handle_exception_stack_loop
 469
 470         .end    asm_handle_nat_exception
 471
 472
 473 /* asm_wrapper_patcher *********************************************************
 474
 475    XXX
 476
 477    Stack layout:
 478      40   return address into JIT code (patch position)
 479      32   pointer to virtual java_objectheader
 480      24   machine code (which is patched back later)
 481      16   unresolved class/method/field reference
 482       8   data segment displacement from load instructions
 483       0   patcher function pointer to call
 484
 485 *******************************************************************************/
 486
 487     .ent    asm_wrapper_patcher
 488
 489 asm_wrapper_patcher:
 490         aaddiu  sp,sp,-((2+16+22+4)*8+sizestackframeinfo) /* create stack frame   */
 491
 492         SAVE_RETURN_REGISTERS(0)      /* save 1 int/1 float return registers      */
 493         SAVE_ARGUMENT_REGISTERS(2)    /* save 8 int/8 float argument registers    */
 494         SAVE_TEMPORARY_REGISTERS(18)  /* save 5 int/16 float temporary registers  */
 495
 496         ast     itmp1,(2+16+22+0)*8(sp) /* save itmp1                             */
 497         ast     itmp2,(2+16+22+1)*8(sp) /* save itmp2                             */
 498         ast     ra,(2+16+22+2)*8(sp)  /* save method return address (for leafs)   */
 499         ast     pv,(2+16+22+3)*8(sp)  /* save pv of calling java function         */
 500
 501         aaddiu  a0,sp,(2+16+22+4)*8   /* create stackframe info                   */
 502         move    a1,pv                 /* pass java pv                             */
 503         aaddiu  a2,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* pass java sp        */
 504         move    a3,ra                 /* this is correct for leafs                */
 505         ald     a4,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* pass xpc           */
 506         jal     stacktrace_create_extern_stackframeinfo
 507
 508         aaddiu  a0,sp,((0+2+16+22+4)*8+sizestackframeinfo) /* pass sp             */
 509         ald     itmp3,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* get function    */
 510         ald     itmp1,(2+16+22+3)*8(sp) /* save pv to the position of fp          */
 511         ast     itmp1,((0+2+16+22+4)*8+sizestackframeinfo)(sp)
 512         jalr    itmp3
 513         ast     v0,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* save return value  */
 514
 515         aaddiu  a0,sp,(2+16+22+4)*8   /* remove stackframe info                   */
 516         jal     stacktrace_remove_stackframeinfo
 517
 518         RESTORE_RETURN_REGISTERS(0)   /* restore 1 int/1 float return registers   */
 519         RESTORE_ARGUMENT_REGISTERS(2) /* restore 8 int/8 float argument registers */
 520         RESTORE_TEMPORARY_REGISTERS(18) /* restore 5 int/16 float temporary reg.  */
 521
 522         ald     itmp1,(2+16+22+0)*8(sp) /* restore itmp1                          */
 523         ald     itmp2,(2+16+22+1)*8(sp) /* restore itmp2                          */
 524         ald     ra,(2+16+22+2)*8(sp)  /* restore method return address (for leafs)*/
 525         ald     pv,(2+16+22+3)*8(sp)  /* restore pv of calling java function      */
 526
 527         ald     itmp3,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* get return value*/
 528         beqz    itmp3,L_asm_wrapper_patcher_exception
 529
 530         ald     itmp3,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* get RA to JIT   */
 531         aaddiu  sp,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* remove stack frame  */
 532
 533         jr      itmp3                 /* jump to new patched code                 */
 534
 535 L_asm_wrapper_patcher_exception:
 536         ald     xpc,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* RA to JIT is xpc  */
 537         aaddiu  sp,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* remove stack frame  */
 538
 539 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 540         daddiu  sp,sp,-4*8
 541         sd      xpc,0*8(sp)
 542         sd      ra,1*8(sp)
 543         sd      pv,2*8(sp)
 544         jal     builtin_asm_get_exceptionptrptr
 545         ld      xpc,0*8(sp)
 546         ld      ra,1*8(sp)
 547         ld      pv,2*8(sp)
 548         daddiu  sp,sp,4*8
 549 #else
 550         la      v0,_exceptionptr
 551 #endif
 552         ld      xptr,0(v0)            /* get the exception pointer                */
 553         sd      zero,0(v0)            /* clear the exception pointer              */
 554         b       asm_handle_exception
 555
 556         .end    asm_wrapper_patcher
 557
 558
 559 /* asm_replacement_out *********************************************************
 560
 561    This code is jumped to from the replacement-out stubs that are executed
 562    when a thread reaches an activated replacement point.
 563
 564    The purpose of asm_replacement_out is to read out the parts of the
 565    execution state that cannot be accessed from C code, store this state,
 566    and then call the C function replace_me.
 567
 568    Stack layout:
 569      16                 start of stack inside method to replace
 570       0   rplpoint *    info on the replacement point that was reached
 571
 572    NOTE: itmp3 has been clobbered by the replacement-out stub!
 573
 574 *******************************************************************************/
 575
 576 /* some room to accomodate changes of the stack frame size during replacement */
 577         /* XXX we should find a cleaner solution here */
 578 #define REPLACEMENT_ROOM  512
 579
 580 #define REPLACEMENT_STACK_OFFSET ((sizeexecutionstate + REPLACEMENT_ROOM + 0xf) & ~0xf)
 581
 582         .ent asm_replacement_out
 583
 584 asm_replacement_out:
 585     /* create stack frame */
 586         daddiu  sp,sp,-REPLACEMENT_STACK_OFFSET
 587
 588         /* save registers in execution state */
 589         sd      $0 ,( 0*8+offes_intregs)(sp)
 590         sd      $1 ,( 1*8+offes_intregs)(sp)
 591         sd      $2 ,( 2*8+offes_intregs)(sp)
 592         sd      $3 ,( 3*8+offes_intregs)(sp)
 593         sd      $4 ,( 4*8+offes_intregs)(sp)
 594         sd      $5 ,( 5*8+offes_intregs)(sp)
 595         sd      $6 ,( 6*8+offes_intregs)(sp)
 596         sd      $7 ,( 7*8+offes_intregs)(sp)
 597         sd      $8 ,( 8*8+offes_intregs)(sp)
 598         sd      $9 ,( 9*8+offes_intregs)(sp)
 599         sd      $10,(10*8+offes_intregs)(sp)
 600         sd      $11,(11*8+offes_intregs)(sp)
 601         sd      $12,(12*8+offes_intregs)(sp)
 602         sd      $13,(13*8+offes_intregs)(sp)
 603         sd      $14,(14*8+offes_intregs)(sp)
 604         sd      $15,(15*8+offes_intregs)(sp)
 605         sd      $16,(16*8+offes_intregs)(sp)
 606         sd      $17,(17*8+offes_intregs)(sp)
 607         sd      $18,(18*8+offes_intregs)(sp)
 608         sd      $19,(19*8+offes_intregs)(sp)
 609         sd      $20,(20*8+offes_intregs)(sp)
 610         sd      $21,(21*8+offes_intregs)(sp)
 611         sd      $22,(22*8+offes_intregs)(sp)
 612         sd      $23,(23*8+offes_intregs)(sp)
 613         sd      $24,(24*8+offes_intregs)(sp)
 614         sd      $25,(25*8+offes_intregs)(sp)
 615         sd      $26,(26*8+offes_intregs)(sp)
 616         sd      $27,(27*8+offes_intregs)(sp)
 617         sd      $28,(28*8+offes_intregs)(sp)
 618         sd      $29,(29*8+offes_intregs)(sp)
 619         sd      $30,(30*8+offes_intregs)(sp)
 620         sd      $31,(31*8+offes_intregs)(sp)
 621
 622         sdc1    $f0 ,( 0*8+offes_fltregs)(sp)
 623         sdc1    $f1 ,( 1*8+offes_fltregs)(sp)
 624         sdc1    $f2 ,( 2*8+offes_fltregs)(sp)
 625         sdc1    $f3 ,( 3*8+offes_fltregs)(sp)
 626         sdc1    $f4 ,( 4*8+offes_fltregs)(sp)
 627         sdc1    $f5 ,( 5*8+offes_fltregs)(sp)
 628         sdc1    $f6 ,( 6*8+offes_fltregs)(sp)
 629         sdc1    $f7 ,( 7*8+offes_fltregs)(sp)
 630         sdc1    $f8 ,( 8*8+offes_fltregs)(sp)
 631         sdc1    $f9 ,( 9*8+offes_fltregs)(sp)
 632         sdc1    $f10,(10*8+offes_fltregs)(sp)
 633         sdc1    $f11,(11*8+offes_fltregs)(sp)
 634         sdc1    $f12,(12*8+offes_fltregs)(sp)
 635         sdc1    $f13,(13*8+offes_fltregs)(sp)
 636         sdc1    $f14,(14*8+offes_fltregs)(sp)
 637         sdc1    $f15,(15*8+offes_fltregs)(sp)
 638         sdc1    $f16,(16*8+offes_fltregs)(sp)
 639         sdc1    $f17,(17*8+offes_fltregs)(sp)
 640         sdc1    $f18,(18*8+offes_fltregs)(sp)
 641         sdc1    $f19,(19*8+offes_fltregs)(sp)
 642         sdc1    $f20,(20*8+offes_fltregs)(sp)
 643         sdc1    $f21,(21*8+offes_fltregs)(sp)
 644         sdc1    $f22,(22*8+offes_fltregs)(sp)
 645         sdc1    $f23,(23*8+offes_fltregs)(sp)
 646         sdc1    $f24,(24*8+offes_fltregs)(sp)
 647         sdc1    $f25,(25*8+offes_fltregs)(sp)
 648         sdc1    $f26,(26*8+offes_fltregs)(sp)
 649         sdc1    $f27,(27*8+offes_fltregs)(sp)
 650         sdc1    $f28,(28*8+offes_fltregs)(sp)
 651         sdc1    $f29,(29*8+offes_fltregs)(sp)
 652         sdc1    $f30,(30*8+offes_fltregs)(sp)
 653         sdc1    $f31,(31*8+offes_fltregs)(sp)
 654
 655         /* calculate sp of method */
 656         daddiu  itmp1,sp,(REPLACEMENT_STACK_OFFSET + 2*8)
 657         sd      itmp1,(offes_sp)(sp)
 658
 659         /* store pv */
 660         sd      pv,(offes_pv)(sp)
 661
 662         /* call replace_me */
 663         ld      a0,-(2*8)(itmp1)            /* arg0: rplpoint *                   */
 664     move    a1,sp                       /* arg1: execution state              */
 665     jal     replace_me                  /* call C function replace_me         */
 666         jal     abort                       /* NEVER REACHED                      */
 667
 668         .end asm_replacement_out
 669
 670 /* asm_replacement_in **********************************************************
 671
 672    This code writes the given execution state and jumps to the replacement
 673    code.
 674
 675    This function never returns!
 676
 677    NOTE: itmp3 is not restored!
 678
 679    C prototype:
 680       void asm_replacement_in(executionstate *es);
 681
 682 *******************************************************************************/
 683
 684         .ent asm_replacement_in
 685
 686 asm_replacement_in:
 687         /* a0 == executionstate *es */
 688
 689         /* set new sp and pv */
 690         ld      sp,(offes_sp)(a0)
 691         ld      pv,(offes_pv)(a0)
 692
 693         /* copy registers from execution state */
 694         /* $0 is zero                     */
 695         ld      $1 ,( 1*8+offes_intregs)(a0)
 696         ld      $2 ,( 2*8+offes_intregs)(a0)
 697         ld      $3 ,( 2*8+offes_intregs)(a0)
 698         /* a0 is loaded below             */
 699         ld      $5 ,( 5*8+offes_intregs)(a0)
 700         ld      $6 ,( 6*8+offes_intregs)(a0)
 701         ld      $7 ,( 7*8+offes_intregs)(a0)
 702         ld      $8 ,( 8*8+offes_intregs)(a0)
 703         ld      $9 ,( 9*8+offes_intregs)(a0)
 704         ld      $10,(10*8+offes_intregs)(a0)
 705         ld      $11,(11*8+offes_intregs)(a0)
 706         ld      $12,(12*8+offes_intregs)(a0)
 707         ld      $13,(13*8+offes_intregs)(a0)
 708         ld      $14,(14*8+offes_intregs)(a0)
 709         ld      $15,(15*8+offes_intregs)(a0)
 710         ld      $16,(16*8+offes_intregs)(a0)
 711         ld      $17,(17*8+offes_intregs)(a0)
 712         ld      $18,(18*8+offes_intregs)(a0)
 713         ld      $19,(19*8+offes_intregs)(a0)
 714         ld      $20,(20*8+offes_intregs)(a0)
 715         ld      $21,(21*8+offes_intregs)(a0)
 716         ld      $22,(22*8+offes_intregs)(a0)
 717         ld      $23,(23*8+offes_intregs)(a0)
 718         ld      $24,(24*8+offes_intregs)(a0)
 719         ld      $25,(25*8+offes_intregs)(a0)
 720         ld      $26,(26*8+offes_intregs)(a0)
 721         ld      $27,(27*8+offes_intregs)(a0)
 722         ld      $28,(28*8+offes_intregs)(a0)
 723         /* $29 is sp                      */
 724         /* $30 is pv                      */
 725         ld      $31,(31*8+offes_intregs)(a0)
 726
 727         ldc1    $f0 ,( 0*8+offes_fltregs)(a0)
 728         ldc1    $f1 ,( 1*8+offes_fltregs)(a0)
 729         ldc1    $f2 ,( 2*8+offes_fltregs)(a0)
 730         ldc1    $f3 ,( 3*8+offes_fltregs)(a0)
 731         ldc1    $f4 ,( 4*8+offes_fltregs)(a0)
 732         ldc1    $f5 ,( 5*8+offes_fltregs)(a0)
 733         ldc1    $f6 ,( 6*8+offes_fltregs)(a0)
 734         ldc1    $f7 ,( 7*8+offes_fltregs)(a0)
 735         ldc1    $f8 ,( 8*8+offes_fltregs)(a0)
 736         ldc1    $f9 ,( 9*8+offes_fltregs)(a0)
 737         ldc1    $f10,(10*8+offes_fltregs)(a0)
 738         ldc1    $f11,(11*8+offes_fltregs)(a0)
 739         ldc1    $f12,(12*8+offes_fltregs)(a0)
 740         ldc1    $f13,(13*8+offes_fltregs)(a0)
 741         ldc1    $f14,(14*8+offes_fltregs)(a0)
 742         ldc1    $f15,(15*8+offes_fltregs)(a0)
 743         ldc1    $f16,(16*8+offes_fltregs)(a0)
 744         ldc1    $f17,(17*8+offes_fltregs)(a0)
 745         ldc1    $f18,(18*8+offes_fltregs)(a0)
 746         ldc1    $f19,(19*8+offes_fltregs)(a0)
 747         ldc1    $f20,(20*8+offes_fltregs)(a0)
 748         ldc1    $f21,(21*8+offes_fltregs)(a0)
 749         ldc1    $f22,(22*8+offes_fltregs)(a0)
 750         ldc1    $f23,(23*8+offes_fltregs)(a0)
 751         ldc1    $f24,(24*8+offes_fltregs)(a0)
 752         ldc1    $f25,(25*8+offes_fltregs)(a0)
 753         ldc1    $f26,(26*8+offes_fltregs)(a0)
 754         ldc1    $f27,(27*8+offes_fltregs)(a0)
 755         ldc1    $f28,(28*8+offes_fltregs)(a0)
 756         ldc1    $f29,(29*8+offes_fltregs)(a0)
 757         ldc1    $f30,(30*8+offes_fltregs)(a0)
 758         ldc1    $f31,(31*8+offes_fltregs)(a0)
 759
 760         /* load new pc */
 761
 762         ld      itmp3,offes_pc(a0)
 763
 764         /* load a0 */
 765
 766         ld      a0,(4*8+offes_intregs)(a0)
 767
 768         /* jump to new code */
 769
 770         jr      itmp3
 771
 772         .end asm_replacement_in
 773
 774 /******************* function asm_initialize_thread_stack **********************
 775 *                                                                              *
 776 *   u1* asm_initialize_thread_stack (void *func, u1 *stack);                   *
 777 *                                                                              *
 778 *   initialize a thread stack                                                  *
 779 *                                                                              *
 780 *******************************************************************************/
 781
 782         .ent    asm_initialize_thread_stack
 783
 784 asm_initialize_thread_stack:
 785         aaddiu  a1,a1,-14*8     /* allocate save area                             */
 786         sd      zero, 0*8(a1)   /* s0 initalize thread area                       */
 787         sd      zero, 1*8(a1)   /* s1                                             */
 788         sd      zero, 2*8(a1)   /* s2                                             */
 789         sd      zero, 3*8(a1)   /* s3                                             */
 790         sd      zero, 4*8(a1)   /* s4                                             */
 791         sd      zero, 5*8(a1)   /* s5                                             */
 792         sd      zero, 6*8(a1)   /* s6                                             */
 793         sd      zero, 7*8(a1)   /* s7                                             */
 794         sd      zero, 8*8(a1)   /* s8                                             */
 795         sd      zero, 9*8(a1)   /* fs0                                            */
 796         sd      zero,10*8(a1)   /* fs1                                            */
 797         sd      zero,11*8(a1)   /* fs2                                            */
 798         sd      zero,12*8(a1)   /* fs3                                            */
 799         sd      a0, 13*8(a1)
 800         move    v0,a1
 801         j       ra              /* return                                         */
 802
 803         .end    asm_initialize_thread_stack
 804
 805
 806 /******************* function asm_perform_threadswitch *************************
 807 *                                                                              *
 808 *   void asm_perform_threadswitch (u1 **from, u1 **to, u1 **stackTop);         *
 809 *                                                                              *
 810 *   performs a threadswitch                                                    *
 811 *                                                                              *
 812 *******************************************************************************/
 813
 814         .ent    asm_perform_threadswitch
 815
 816 asm_perform_threadswitch:
 817         aaddiu  sp,sp,-14*8     /* allocate new stack                             */
 818         sd      s0,  0*8(sp)    /* save saved registers of old thread             */
 819         sd      s1,  1*8(sp)
 820         sd      s2,  2*8(sp)
 821         sd      s3,  3*8(sp)
 822         sd      s4,  4*8(sp)
 823         sd      s5,  5*8(sp)
 824         sd      s6,  6*8(sp)
 825         sd      s7,  7*8(sp)
 826         sd      s8,  8*8(sp)
 827         sdc1    fs0, 9*8(sp)
 828         sdc1    fs1,10*8(sp)
 829         sdc1    fs2,11*8(sp)
 830         sdc1    fs3,12*8(sp)
 831         sd      ra, 13*8(sp)
 832         ast     sp,0(a0)        /* save old stack pointer                         */
 833         ast     sp,0(a2)        /* stackTop = old stack pointer                   */
 834         ald     sp,0(a1)        /* load new stack pointer                         */
 835         ld      s0,  0*8(sp)    /* load saved registers of new thread             */
 836         ld      s1,  1*8(sp)
 837         ld      s2,  2*8(sp)
 838         ld      s3,  3*8(sp)
 839         ld      s4,  4*8(sp)
 840         ld      s5,  5*8(sp)
 841         ld      s6,  6*8(sp)
 842         ld      s7,  7*8(sp)
 843         ld      s8,  8*8(sp)
 844         ldc1    fs0, 9*8(sp)
 845         ldc1    fs1,10*8(sp)
 846         ldc1    fs2,11*8(sp)
 847         ldc1    fs3,12*8(sp)
 848         ld      ra, 13*8(sp)
 849         aaddiu  sp,sp,14*8      /* deallocate new stack                           */
 850         move    itmp3, ra
 851         j       ra              /* return                                         */
 852
 853         .end    asm_perform_threadswitch
 854
 855
 856 /********************* function asm_switchstackandcall *************************
 857 *                                                                              *
 858 *  void asm_switchstackandcall (void *stack, void *func, void **stacktopsave); *
 859 *                                                                              *
 860 *   Switches to a new stack, calls a function and switches back.               *
 861 *       a0      new stack pointer                                              *
 862 *       a1      function pointer                                               *
 863 *               a2              pointer to variable where stack top should be stored           *
 864 *                                                                              *
 865 *******************************************************************************/
 866
 867         .ent    asm_switchstackandcall
 868
 869 asm_switchstackandcall:
 870         aaddiu  a0,a0,-16       /* allocate new stack                             */
 871         sd      ra,0(a0)        /* save return address on new stack               */
 872         sd      sp,8(a0)        /* save old stack pointer on new stack            */
 873         sd      sp,0(a2)        /* save old stack pointer to variable             */
 874         move    sp,a0           /* switch to new stack                            */
 875
 876         move    itmp3,a1
 877         move    a0,a3
 878         jalr    itmp3           /* and call function                              */
 879
 880         ld      ra,0(sp)        /* load return address                            */
 881         ld      sp,8(sp)        /* switch to old stack                            */
 882
 883         j       ra              /* return                                         */
 884
 885         .end    asm_switchstackandcall
 886
 887
 888         .ent    asm_getclassvalues_atomic
 889
 890 asm_getclassvalues_atomic:
 891 _crit_restart:
 892 _crit_begin:
 893         lw      t0,offbaseval(a0)
 894         lw      t1,offdiffval(a0)
 895         lw      t2,offbaseval(a1)
 896 _crit_end:
 897         sw      t0,offcast_super_baseval(a2)
 898         sw      t1,offcast_super_diffval(a2)
 899         sw      t2,offcast_sub_baseval(a2)
 900         j       ra
 901
 902         .end    asm_getclassvalues_atomic
 903
 904     .data
 905
 906 asm_criticalsections:
 907 #if defined(USE_THREADS) && defined(NATIVE_THREADS)
 908     .dword  _crit_begin
 909     .dword  _crit_end
 910     .dword  _crit_restart
 911 #endif
 912     .dword  0
 913
 914
 915         .text
 916
 917         .ent    compare_and_swap
 918
 919 compare_and_swap:
 920 1:
 921         all     v0,0(a0)
 922         bne     v0,a1,2f
 923         move    t0,a2
 924         asc     t0,0(a0)
 925         beqz    t0,1b
 926 2:
 927         sync
 928         j       ra
 929
 930         .end    compare_and_swap
 931
 932
 933 /* Disable exec-stacks, required for Gentoo ***********************************/
 934
 935 #if defined(__GCC__) && defined(__ELF__)
 936         .section .note.GNU-stack,"",@progbits
 937 #endif
 938
 939
 940 /*
 941  * These are local overrides for various environment variables in Emacs.
 942  * Please do not remove this and leave it at the end of the file, where
 943  * Emacs will automagically detect them.
 944  * ---------------------------------------------------------------------
 945  * Local variables:
 946  * mode: asm
 947  * indent-tabs-mode: t
 948  * c-basic-offset: 4
 949  * tab-width: 4
 950  * End:
 951  * vim:noexpandtab:sw=4:ts=4:
 952  */