src/vm/jit/m68k/asmpart.S

   1 /* src/vm/jit/m68k/asmpart.S - Java-C interface functions for m68k
   2
   3    Copyright (C) 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25 */
  26
  27
  28 #include "config.h"
  29
  30 #include "md-abi.h"
  31
  32 #include "vm/jit/methodheader.h"
  33
  34
  35 .text
  36
  37 .globl asm_vm_call_method
  38 .globl asm_vm_call_method_int
  39 .globl asm_vm_call_method_long
  40 .globl asm_vm_call_method_float
  41 .globl asm_vm_call_method_double
  42 .globl asm_vm_call_method_end
  43 .globl asm_vm_call_method_exception_handler
  44
  45 .globl asm_abstractmethoderror
  46
  47 .globl asm_handle_exception
  48 .globl asm_handle_nat_exception
  49
  50 /*
  51  *      This functions implement the C prototyped funtion
  52  *      java_objectheader *asm_vm_call_method(methodinfo *m, s4 vmargscount,vm_arg *vmargs);
  53  *      the _int, _long, _float, _double are used for different return types
  54  *
  55  *      The function may still be uncompiled, so the jit compiler gets invoked.
  56  *
  57  *
  58  */
  59
  60         /* this is the method header see src/vm/jit/methodheader.h */
  61
  62         .align  4
  63
  64         .long   0                           /* line number table start            */
  65         .long   0                           /* line number table size             */
  66         .long   0                           /* fltsave                            */
  67         .long   0                           /* intsave                            */
  68         .long   0                           /* isleaf                             */
  69         .long   0                           /* frame size                         */
  70         .long   0                           /* codeinfo pointer                   */
  71
  72
  73 /*
  74         This method gets called with 3 arguments:
  75         1st arg: addres of method to call (fake invokevirtual here)
  76         2nd arg: uint64_t array of argument registers followed by stack
  77         3rd arg: number of 8 byte stack slots to be copied.
  78
  79         coldifire does not use any argument registers, so just the stack has to be copied
  80 */
  81 asm_vm_call_method:
  82 asm_vm_call_method_int:
  83 asm_vm_call_method_long:
  84 asm_vm_call_method_float:
  85 asm_vm_call_method_double:
  86
  87 #if defined(ENABLE_SOFTFLOAT)
  88         addal   #(-12*4),%sp                                            /* create stackframe to save registers, and 1 slot for method invocation */
  89         moveml  %d2/%d3/%d4/%d5/%d6/%d7/%a2/%a3/%a4/%a5/%fp,%sp@        /* save registers */
  90
  91         /* fetch arguments from vmargs data structure */
  92         movel   %sp@(12*4+1*4),%a3                              /* method */
  93         movel   %sp@(12*4+2*4),%a2                              /* arg array */
  94         movel   %sp@(12*4+3*4),%d2                              /* arg count */
  95
  96         movel   %a3, %sp@(12*4)                                 /* copy method address to stackslot */
  97         leal    %sp@(12*4), %a3                                 /* and store that address in %a3 */
  98 #else
  99         addal #(-12*4-6*8), %sp
 100         moveml  %d2/%d3/%d4/%d5/%d6/%d7/%a2/%a3/%a4/%a5/%fp,%sp@        /* save registers */
 101         fmovemd %fp2/%fp3/%fp4/%fp5/%fp6/%fp7,%sp@(11*4)                        /* save registers */
 102
 103         /* fetch arguments from vmargs data structure */
 104         movel   %sp@(12*4+6*8+1*4),%a3                          /* method */
 105         movel   %sp@(12*4+6*8+2*4),%a2                          /* arg array */
 106         movel   %sp@(12*4+6*8+3*4),%d2                          /* arg count */
 107
 108         movel   %a3, %sp@(12*4+6*8)                                     /* copy method address to stackslot */
 109         leal    %sp@(12*4+6*8), %a3                                     /* and store that address in %a3 */
 110 #endif
 111
 112         moveal  %sp, %a5                                        /* memorize stack */
 113
 114         tstl    %d2                                                     /* do we have arguments ? */
 115         beq     L_asm_vm_call_method_copy_done
 116         movel   %d2, %d3                                                /* create stackframe */
 117         asll    #3,  %d3                                                /* number args * 8 */
 118         subal   %d3, %sp
 119         moveal  %sp, %a4                                                /* %a4 is temp stack pointer */
 120
 121 L_asm_vm_call_method_copy_loop:
 122         movel   %a2@(0), %d3
 123         movel   %d3, %a4@(0)                                    /* copy 4 bytes */
 124         movel   %a2@(4), %d3
 125         movel   %d3, %a4@(4)                                    /* a whole stack slot has been copied */
 126
 127         addal   #8, %a2
 128         addal   #8, %a4
 129         addl    #-1, %d2
 130         tstl    %d2                                                             /* do we have more arguments ? */
 131         beq     L_asm_vm_call_method_copy_done
 132         br      L_asm_vm_call_method_copy_loop
 133
 134
 135 L_asm_vm_call_method_copy_done:
 136         /* now we fake method invocation as it would happen from invokevirtual */
 137         /* this is needed as we patch the caller site, so we need a writeable slot */
 138         /* %a3 points to the address containing the method, %a3 == REG_METHODPTR */
 139
 140         moveal  %a3@(0), %a4
 141         jsr     %a4@
 142
 143 L_asm_vm_call_method_return:
 144         movel   %a5, %sp                                                /* pop arguments off stack */
 145
 146 #if defined(ENABLE_SOFTFLOAT)
 147         moveml  %sp@, %d2/%d3/%d4/%d5/%d6/%d7/%a2/%a3/%a4/%a5/%fp       /* restore registers */
 148         addal   #(12*4),%sp                                             /* restore stack */
 149 #else
 150         fmovemd %sp@(12*4), %fp2/%fp3/%fp4/%fp5/%fp6/%fp7                       /* restore registers */
 151         moveml  %sp@, %d2/%d3/%d4/%d5/%d6/%d7/%a2/%a3/%a4/%a5/%fp       /* restore registers */
 152         addal   #(12*4+6*8),%sp                                         /* restore stack */
 153 #endif
 154         moveal  %d0, %a0                                                /* XXX return value in %a0, too, gcc sometimes expects addresses in %a0, wired */
 155 asm_vm_call_method_end:                                         /* symbol needed to insert method into avl tree */
 156         rts                                                                             /* return to c code */
 157
 158 /* asm_vm_call_method_exception_handler ********************************************************************
 159  *
 160  * calls void *builtin_throw_exception(java_objectheader *xptr) when no other handler is appropiate
 161  * this functions gets called indirectly from asm_handle_exception, which back then moved xptr to %a2
 162  * clear software design is in the eye of the beholder.
 163  ************************************************************************************************************/
 164 asm_vm_call_method_exception_handler:
 165         movel   %a2, %sp@-                      /* push xptr argument */
 166         jsr     builtin_throw_exception
 167         lea     %sp@(4), %sp                    /* pop arg off stack */
 168         jmp     L_asm_vm_call_method_return
 169
 170
 171 asm_abstractmethoderror:
 172
 173 /* asm_handle_exception ********************************************************
 174 *                                                                              *
 175 *   This function handles an exception. It does not use the usual calling      *
 176 *   conventions. The exception pointer is passed in REG_ATMP1 and the          *
 177 *   pc from the exception raising position is passed in REG_ATMP2. It searches *
 178 *   the local exception table for a handler. If no one is found, it unwinds    *
 179 *   stacks and continues searching the callers.                                *
 180 *                                                                              *
 181 *   void asm_handle_exception (void);
 182 *   exception object pointer...%a2   exception raising address...%a3           *
 183 *                                                                              *
 184 *******************************************************************************/
 185 asm_handle_nat_exception:
 186         lea     %sp@(4), %sp
 187 asm_handle_exception:
 188 L_asm_handle_exception_stack_loop:
 189         /* save temporary registers */
 190         movel   %d0, %sp@-
 191         movel   %d1, %sp@-
 192         movel   %a0, %sp@-
 193         movel   %a1, %sp@-
 194 #if !defined(ENABLE_SOFTFLOAT)
 195         addal   #-8*2, %sp
 196         fmovemd %fp0, %sp@(0)
 197         fmovemd %fp1, %sp@(8)
 198 #endif
 199
 200         /* we need the dseg, figure it out */
 201         movel   %a3, %sp@-                              /* push ra argument */
 202         jsr     md_codegen_get_pv_from_pc       /* pv in %d0 now */
 203         movel   %d0, %d2                                /* move to safe register */
 204         lea     %sp@(4), %sp                            /* pop args off stack */
 205
 206         /* now call the following c function */
 207         /* u1 *exceptions_handle_exception(java_objectheader *xptr, u1 *xpc, u1 *pv, u1 *sp) */
 208 #if !defined(ENABLE_SOFTFLOAT)
 209         pea             %sp@(4*4 + 8*2)
 210 #else
 211         pea             %sp@(4*4)
 212 #endif
 213         movel   %d2,%sp@-
 214         movel   %a3,%sp@-
 215         movel   %a2,%sp@-
 216         jsr     exceptions_handle_exception             /* %d0 is address of handler or 0 when not catched */
 217         lea     %sp@(4*4), %sp                          /* pop args off stack */
 218         tstl    %d0
 219         beq     L_asm_handle_exception_not_catched
 220
 221         /* %d0 contains address of exception handler */
 222         moveal  %d0, %a3
 223
 224         /* restore temporary registers */
 225         moveal  %sp@+, %a1
 226         moveal  %sp@+, %a0
 227         movel   %sp@+, %d1
 228         movel   %sp@+, %d0
 229 #if !defined(ENABLE_SOFTFLOAT)
 230         fmovemd %fp0, %sp@(0)
 231         fmovemd %fp1, %sp@(8)
 232         addal   #8*2, %sp
 233 #endif
 234
 235         jmp     %a3@
 236
 237 L_asm_handle_exception_not_catched:
 238         /* we did not find an exception handler in this stackframe */
 239         /* remove this frame and search in the one above */
 240         /* %a2 containts exception object ptr, %d2 the actual pv */
 241
 242         /* remove temporary registers stored */
 243 #if !defined(ENABLE_SOFTFLOAT)
 244         addal   #4*4 + 8*2, %sp
 245 #else
 246         addal   #4*4, %sp
 247 #endif
 248
 249         moveal  %d2, %a3
 250         movel   %a3@(FrameSize), %d2
 251
 252         moveal  %sp, %a0
 253         addal   %d2, %a0        /* %a0 now points to top of stackframe, where saved regs are */
 254
 255         /* the saved registers have to be restored */
 256         /* XXX ugly hack: intsave and adrsave share one field */
 257         movel   %a3@(IntSave), %d0
 258         andil   #0x0000ffff, %d0        /* this is IntSave */
 259         cmpb    #0,%d0
 260         beq     L_asm_handle_ex_int_done
 261         movel   -(%a0), %d7
 262
 263         cmpb    #1,%d0
 264         beq     L_asm_handle_ex_int_done
 265         movel   -(%a0), %d6
 266
 267         cmpb    #2,%d0
 268         beq     L_asm_handle_ex_int_done
 269         movel   -(%a0), %d5
 270
 271 L_asm_handle_ex_int_done:
 272
 273         movel   %a3@(IntSave), %d0
 274         andil   #0xffff0000, %d0        /* this is AdrSave */
 275         lsrl    #8, %d0
 276         lsrl    #8, %d0
 277
 278 #if 0
 279         cmpb    #0, %d0
 280         beq     L_asm_handle_ex_adr_done
 281         moveal  -(%a0), %a5
 282 #else
 283         cmpb    #0, %d0
 284         beq     L_asm_handle_ex_adr_done
 285         moveal  -(%a0), %fp
 286
 287         cmpb    #1,%d0
 288         beq     L_asm_handle_ex_adr_done
 289         moveal  -(%a0), %a5
 290 #endif
 291
 292 L_asm_handle_ex_adr_done:
 293
 294 #if !defined(ENABLE_SOFTFLOAT)
 295         movel   %a3@(FltSave), %d0
 296         cmpb    #0,%d0
 297         beq     L_asm_handle_ex_flt_done
 298         fmovemd %a0@(-8), %fp7
 299
 300         cmpb    #1,%d0
 301         beq     L_asm_handle_ex_flt_done
 302         fdmoved %a0@(-16), %fp6
 303
 304         cmpb    #2,%d0
 305         beq     L_asm_handle_ex_flt_done
 306         fdmoved %a0@(-24), %fp5
 307
 308 L_asm_handle_ex_flt_done:
 309 #else
 310         /* nothing to do */
 311 #endif
 312         addal   %d2, %sp                /* remove old stackframe */
 313         moveal  %sp@+, %a3              /* make return address, new exception rasing address */
 314         subal   #2, %a3                 /* it was a jsr %aX, which is 4 bytes long */
 315         jmp     L_asm_handle_exception_stack_loop
 316
 317
 318 illegal
 319 .long 0x23234242
 320
 321
 322 /*
 323  * These are local overrides for various environment variables in Emacs.
 324  * Please do not remove this and leave it at the end of the file, where
 325  * Emacs will automagically detect them.
 326  * ---------------------------------------------------------------------
 327  * Local variables:
 328  * mode: c
 329  * indent-tabs-mode: t
 330  * c-basic-offset: 4
 331  * tab-width: 4
 332  * End:
 333  * vim:noexpandtab:sw=4:ts=4:
 334  */