configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl system type
  16 case "$host_cpu" in
  17 alpha | alphaev56 | alphapca56 )
  18         ARCH_DIR="alpha"
  19         CFLAGS="-mieee -D__ALPHA__"
  20         ;;
  21
  22 arm )
  23         ARCH_DIR="arm"
  24         ENABLE_STATICVM="1"
  25         CFLAGS="-D__ARM__"
  26         ;;
  27
  28 i386 | i486 | i586 | i686 )
  29         ARCH_DIR="i386"
  30         CFLAGS="-D__I386__ $CFLAGS"
  31         ;;
  32
  33 mips )
  34         ARCH_DIR="mips"
  35
  36 dnl for MIPSPro Compiler
  37 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  38         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  39 dnl     CFLAGS="-D__MIPS__ -D__MIPSEB__"
  40
  41 dnl for GCC
  42 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  43 dnl     LDFLAGS="-mabi=64"
  44         ;;
  45
  46 powerpc )
  47         ARCH_DIR="powerpc"
  48         CFLAGS="-D__POWERPC__"
  49         ;;
  50
  51 x86_64 )
  52         ARCH_DIR="x86_64"
  53         CFLAGS="-D__X86_64__"
  54         ;;
  55
  56 xdspcore )
  57         ARCH_DIR="xdspcore"
  58         ENABLE_STATICVM="1"
  59         CFLAGS="-D__XDSPCORE__"
  60         USE_SCHEDULER="1"
  61         ;;
  62 * )
  63         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  64         ;;
  65 esac
  66
  67
  68 dnl set optimization and debugging for all architectures and systems
  69 CFLAGS="-O0 -g3 $CFLAGS"
  70
  71
  72 case "$host_os" in
  73 *linux* | *Linux* )
  74         OS_DIR="linux"
  75         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  76         ;;
  77 *darwin* )
  78         OS_DIR="darwin"
  79         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  80         ;;
  81 *freebsd* )
  82         OS_DIR="freebsd"
  83         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
  84         ;;
  85 *irix* )
  86         OS_DIR="irix"
  87         CFLAGS="$CFLAGS -D__IRIX__"
  88         ;;
  89 * )
  90         ;;
  91 esac
  92
  93
  94 dnl define and substitute some architecture specific variables
  95 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [Architecture directory])
  96 AC_SUBST(ARCH_DIR)
  97 AC_SUBST(OS_DIR)
  98 AC_SUBST(USE_SCHEDULER)
  99
 100
 101 dnl Checks for programs.
 102 AC_PROG_CC
 103 AM_PROG_AS
 104 AC_PROG_LD
 105 AC_PROG_LD_GNU
 106 AC_PROG_RANLIB
 107 AC_DISABLE_SHARED
 108 AC_PROG_LN_S
 109 AC_PROG_MAKE_SET
 110
 111 dnl libtool stuff
 112 AC_LIBTOOL_DLOPEN
 113 AC_LIBLTDL_CONVENIENCE
 114 AC_PROG_LIBTOOL
 115 AC_SUBST(LIBLTDL)
 116
 117 dnl Checks for header files.
 118 AC_HEADER_DIRENT
 119 AC_HEADER_STDC
 120 AC_CHECK_HEADERS([fcntl.h])
 121 AC_CHECK_HEADERS([sys/time.h])
 122 AC_CHECK_HEADERS([unistd.h])
 123 AC_CHECK_HEADERS([sys/ioctl.h])
 124
 125 dnl Checks for typedefs, structures, and compiler characteristics.
 126 AC_C_CONST
 127 AC_C_INLINE
 128 AC_C_ATTRIBUTE
 129 AC_TYPE_OFF_T
 130 AC_TYPE_SIZE_T
 131 AC_HEADER_TIME
 132 AC_STRUCT_TM
 133
 134 dnl Checks for library functions.
 135 AC_PROG_GCC_TRADITIONAL
 136 AC_FUNC_MEMCMP
 137 AC_FUNC_MMAP
 138 AC_TYPE_SIGNAL
 139 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 140
 141 dnl Checks for libraries.
 142
 143 dnl Checking sizeof void *
 144 AC_COMPILE_CHECK_SIZEOF(void *)
 145 AC_C_BIGENDIAN
 146
 147 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 148 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 149         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 150                        ac_cv_map_failed,
 151                        AC_EGREP_CPP(yes,
 152                                     [#include <sys/mman.h>
 153                                      #ifdef MAP_FAILED
 154                                         yes
 155                                      #endif],
 156                                     ac_cv_map_failed=yes,
 157                                     ac_cv_map_failed=no))
 158
 159         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 160                        ac_cv_map_anonymous,
 161                        AC_EGREP_CPP(yes,
 162                                     [#include <sys/mman.h>
 163                                      #ifdef MAP_ANONYMOUS
 164                                         yes
 165                                      #endif],
 166                                     ac_cv_map_anonymous=yes,
 167                                     ac_cv_map_anonymous=no))
 168
 169         AC_CACHE_CHECK(whether MAP_ANON is defined,
 170                        ac_cv_map_anon,
 171                        AC_EGREP_CPP(yes,
 172                                     [#include <sys/mman.h>
 173                                      #ifdef MAP_ANON
 174                                         yes
 175                                      #endif],
 176                                     ac_cv_map_anon=yes,
 177                                     ac_cv_map_anon=no))
 178
 179         if test $ac_cv_map_failed = yes; then
 180                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 181         fi
 182
 183         if test $ac_cv_map_anonymous = yes; then
 184                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 185         fi
 186
 187         if test $ac_cv_map_anon = yes; then
 188                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 189         fi
 190 fi
 191
 192
 193 dnl check which ld flags are required to export symbols
 194 if test x"$with_gnu_ld" = "xyes"; then
 195         EXPORT_SYMBOLS_FLAGS="-Wl,--export-dynamic"
 196 else
 197         EXPORT_SYMBOLS_FLAGS=""
 198 fi
 199 AC_SUBST(EXPORT_SYMBOLS_FLAGS)
 200
 201
 202 dnl define install prefix
 203 if test "x$prefix" = "xNONE"; then
 204         CACAO_INSTALL_PREFIX=$ac_default_prefix
 205 else
 206         CACAO_INSTALL_PREFIX=$prefix
 207 fi
 208 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [Installation prefix])
 209 AC_SUBST(CACAO_INSTALL_PREFIX)
 210
 211
 212 dnl Features
 213
 214 dnl check arguments
 215
 216 dnl check for garbage collector usage
 217 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-gc,disable garbage collector (for debugging only!) [[default=yes]])])
 218
 219 AC_MSG_CHECKING(whether GC should be used)
 220 if test x"$enable_gc" = "xno"; then
 221         AC_MSG_RESULT(no)
 222         AM_CONDITIONAL([DISABLE_GC], [true])
 223 else
 224         AC_MSG_RESULT(yes)
 225         AM_CONDITIONAL([DISABLE_GC], [false])
 226 fi
 227
 228 dnl check for dump memory usage
 229 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])])
 230
 231 AC_MSG_CHECKING(whether dump memory should be used)
 232 if test x"$enable_dump" = "xno"; then
 233         AC_MSG_RESULT(no)
 234         AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 235 else
 236         AC_MSG_RESULT(yes)
 237 fi
 238
 239 dnl check for statistics
 240 AC_ARG_ENABLE([statistics], [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])])
 241
 242 AC_MSG_CHECKING(whether statistics generation should be enabled)
 243 if test x"$enable_statistics" = "xno"; then
 244         AC_MSG_RESULT(no)
 245         AM_CONDITIONAL([STATISTICS], [false])
 246 else
 247         AC_MSG_RESULT(yes)
 248         AC_DEFINE([STATISTICS], 1, [use statistics])
 249         AM_CONDITIONAL([STATISTICS], [true])
 250 fi
 251
 252
 253 dnl threads
 254 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 255 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 256
 257 AC_MSG_CHECKING(whether to include threads support)
 258 enable_threads=${enable_threads:-native}
 259 case "$enable_threads" in
 260 no | none | single)
 261         AC_MSG_RESULT(no)
 262         dnl no threads for boehm
 263         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 264         AM_CONDITIONAL([USE_THREADS], [false])
 265         AM_CONDITIONAL([NATIVE_THREADS], [false])
 266         ;;
 267
 268 green | native | posix | pthreads)
 269         AC_DEFINE([USE_THREADS], 1, [use threads])
 270         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 271         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 272
 273         AM_CONDITIONAL([USE_THREADS], [true])
 274
 275         if test x"$enable_threads" != "xgreen"; then
 276                 AC_MSG_RESULT(yes, native)
 277                 AC_CHECK_LIB(pthread, main)
 278                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 279
 280                 CFLAGS="$CFLAGS -D_REENTRANT"
 281
 282                 dnl tell boehm to support threads as well
 283                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-boehm-threads=posix"
 284                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 285
 286         else
 287                 AC_MSG_RESULT(yes, green)
 288
 289                 dnl no threads for boehm
 290                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-boehm-threads"
 291                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 292         fi
 293     ;;
 294 *)
 295     AC_MSG_ERROR($enable_threads is an unknown thread package)
 296     ;;
 297 esac
 298
 299
 300 dnl Check whether the compiler supports the __thread keyword.
 301 if test "x$use__thread" != xno; then
 302   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 303   [cat > conftest.c <<\EOF
 304 __thread int a = 42;
 305 EOF
 306   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 307     ac_cv_gcc___thread=yes
 308   else
 309     ac_cv_gcc___thread=no
 310   fi
 311   rm -f conftest*])
 312   if test "$ac_cv_gcc___thread" = yes; then
 313     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 314   fi
 315 else
 316   ac_cv_gcc___thread=no
 317 fi
 318
 319
 320 dnl check if linear scan register allocator(lsra) should be used
 321 AC_ARG_ENABLE([lsra], [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])])
 322
 323 AC_MSG_CHECKING(whether lsra should be supported)
 324 if test x"$enable_lsra" = "xno"; then
 325         AC_MSG_RESULT(no)
 326 else
 327         AC_MSG_RESULT(yes)
 328         AC_DEFINE([LSRA], 1, [use lsra])
 329 fi
 330
 331
 332 dnl check for inlining
 333 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 334
 335 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 336 dnl if test x"$enable_inlining" = "xno"; then
 337 dnl     AC_MSG_RESULT(yes)
 338 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 339 dnl else
 340 dnl     AC_MSG_RESULT(no)
 341         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 342         AM_CONDITIONAL([USE_INLINING], [true])
 343 dnl fi
 344
 345
 346 dnl check for instruction scheduler
 347 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 348
 349 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 350 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 351         case "${ARCH_DIR}" in
 352                 xdspcore )
 353                         ;;
 354                 * )
 355                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 356                         ;;
 357         esac
 358
 359         AC_MSG_RESULT(yes)
 360         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 361         AM_CONDITIONAL([USE_SCHEDULER], [true])
 362 else
 363         AC_MSG_RESULT(no)
 364         AM_CONDITIONAL([USE_SCHEDULER], [false])
 365 fi
 366
 367
 368 dnl check if zlib should be used
 369 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 370
 371 AC_MSG_CHECKING(whether zip archives should be supported)
 372 if test x"$enable_zlib" = "xno"; then
 373         AC_MSG_RESULT(no)
 374         AM_CONDITIONAL([USE_ZLIB], [false])
 375 else
 376         AC_MSG_RESULT(yes)
 377         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 378         AC_CHECK_HEADERS([zlib.h])
 379         AC_CHECK_LIB(z, main)
 380         AM_CONDITIONAL([USE_ZLIB], [true])
 381 fi
 382
 383
 384 dnl check if CACAO should be linked statically
 385 AC_ARG_ENABLE([staticvm], [AS_HELP_STRING(--enable-staticvm, link GNU classpath's native libraries statically into CACAO [[default=no]])])
 386
 387 AC_MSG_CHECKING(whether to link GNU classpath statically into CACAO)
 388 if test x"$enable_staticvm" = "xyes"; then
 389         ENABLE_STATICVM="1"
 390 fi
 391
 392 if test x"${ENABLE_STATICVM}" = "x1"; then
 393         AC_MSG_RESULT(yes)
 394         AM_CONDITIONAL([ENABLE_STATICVM], [true])
 395 else
 396         AC_MSG_RESULT(no)
 397         AM_CONDITIONAL([ENABLE_STATICVM], [false])
 398 fi
 399 AC_SUBST(ENABLE_STATICVM)
 400
 401
 402 dnl check if we build gtk peers
 403 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--disable-gtk-peer,compile GTK native peers [[default=yes]])])
 404
 405 AC_MSG_CHECKING(whether to compile GTK awt peers)
 406 if test x"$enable_gtk_peer" = "xno"; then
 407         AC_MSG_RESULT(no)
 408         AM_CONDITIONAL([USE_GTK_PEER], [false])
 409         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-gtk-peer"
 410         USE_GTK_PEER=no
 411 else
 412         AC_MSG_RESULT(yes)
 413         AC_DEFINE([USE_GTK], 1, [use gtk])
 414         AM_CONDITIONAL([USE_GTK_PEER], [true])
 415         USE_GTK_PEER=yes
 416 fi
 417 AC_SUBST(USE_GTK_PEER)
 418
 419
 420 dnl pass configure options to classpath
 421 if test x"${ENABLE_STATICVM}" = "x1"; then
 422         AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 423         AM_CONDITIONAL([ENABLE_STATICVM], [true])
 424         CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-static --disable-shared"
 425
 426         dnl check for some classpath related stuff when we link statically
 427         AM_ICONV_LINK
 428
 429         dnl taken from GNU classpath configure.ac
 430         if test x"${USE_GTK_PEER}" = "xyes"; then
 431                 AC_ERROR(XXX this is not supported yet)
 432                 AC_PATH_XTRA
 433                 if test "$no_x" = yes; then
 434                         AC_MSG_ERROR([GTK+ peers requested but no X library available])
 435                 fi
 436                 dnl We explicitly want the XTest Extension for Robot support.
 437                 AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
 438                              [AC_MSG_ERROR([libXtst NOT found, required for GdkRobot])],
 439                              [${X_LIBS}])
 440                 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4 gthread-2.0 >= 2.2 libart-2.0 gdk-pixbuf-2.0)
 441                 AC_SUBST(GTK_CFLAGS)
 442                 AC_SUBST(GTK_LIBS)
 443
 444                 AC_SUBST(CAIRO_LIBS)
 445                 AC_SUBST(CAIRO_CFLAGS)
 446                 PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 447                 AC_SUBST(PANGOFT2_LIBS)
 448                 AC_SUBST(PANGOFT2_CFLAGS)
 449         fi
 450 else
 451         AM_CONDITIONAL([ENABLE_STATICVM], [false])
 452         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-static --enable-shared"
 453 fi
 454
 455
 456 dnl should we use an external classpath installation
 457 AC_ARG_WITH([external-classpath], [AS_HELP_STRING(--with-external-classpath=<dir>,installation directory of external GNU classpath [[default=no]])])
 458
 459 AC_MSG_CHECKING(whether to use an external GNU classpath)
 460 if test x"$with_external_classpath" != "x"; then
 461         if test x"$with_external_classpath" = "xyes"; then
 462                 AC_MSG_ERROR(please specify the installation prefix)
 463         fi
 464         AC_MSG_RESULT($with_external_classpath)
 465         AC_DEFINE([WITH_EXTERNAL_CLASSPATH], 1, [external classpath])
 466         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [true])
 467         EXTERNAL_CLASSPATH_PREFIX="$with_external_classpath"
 468         AC_DEFINE_UNQUOTED([EXTERNAL_CLASSPATH_PREFIX], "${EXTERNAL_CLASSPATH_PREFIX}", [external classpath directory])
 469         AC_SUBST(EXTERNAL_CLASSPATH_PREFIX)
 470 else
 471         AC_MSG_RESULT(no)
 472         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [false])
 473 fi
 474
 475
 476 dnl set some essential classpath options, even if their classpath default is
 477 dnl suitable for us
 478 ac_configure_args="$ac_configure_args --libdir=${CACAO_INSTALL_PREFIX}/jre/lib/${ARCH_DIR} --enable-jni --disable-cni --disable-regen-headers ${CONFIGURE_ARGS}"
 479
 480
 481 dnl now configure boehm gc and gnu classpath
 482 dnl the export is not my favorite (is there another way?)
 483 export CFLAGS
 484 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath src/libltdl)
 485
 486
 487 AC_CONFIG_FILES([Makefile]
 488                 [contrib/Makefile]
 489                 [doc/Makefile]
 490                 [doc/handbook/Makefile]
 491                 [man/Makefile]
 492                 [src/Makefile]
 493                 [src/cacao/Makefile]
 494                 [src/cacaoh/Makefile]
 495                 [src/lib/Makefile]
 496                 [src/mm/Makefile]
 497                 [src/native/Makefile]
 498                 [src/native/include/Makefile]
 499                 [src/native/tools/Makefile]
 500                 [src/native/vm/Makefile]
 501                 [src/scripts/Makefile]
 502                 [src/scripts/cacao]
 503                 [src/scripts/java]
 504                 [src/scripts/javac]
 505                 [src/scripts/kjc]
 506                 [src/scripts/rmiregistry]
 507                 [src/threads/Makefile]
 508                 [src/threads/green/Makefile]
 509                 [src/threads/native/Makefile]
 510                 [src/toolbox/Makefile]
 511                 [src/vm/Makefile]
 512                 [src/vm/jit/Makefile]
 513                 [src/vm/jit/alpha/Makefile]
 514                 [src/vm/jit/arm/Makefile]
 515                 [src/vm/jit/i386/Makefile]
 516                 [src/vm/jit/i386/linux/Makefile]
 517                 [src/vm/jit/i386/freebsd/Makefile]
 518                 [src/vm/jit/inline/Makefile]
 519                 [src/vm/jit/loop/Makefile]
 520                 [src/vm/jit/mips/Makefile]
 521                 [src/vm/jit/powerpc/Makefile]
 522                 [src/vm/jit/powerpc/darwin/Makefile]
 523                 [src/vm/jit/powerpc/linux/Makefile]
 524                 [src/vm/jit/schedule/Makefile]
 525                 [src/vm/jit/tools/Makefile]
 526                 [src/vm/jit/verify/Makefile]
 527                 [src/vm/jit/x86_64/Makefile]
 528                 [tests/Makefile]
 529                 [tests/codepatching/Makefile]
 530                 [tests/native/Makefile])
 531
 532 AC_OUTPUT
 533
 534
 535 ## Local variables:
 536 ## mode: m4
 537 ## indent-tabs-mode: t
 538 ## c-basic-offset: 4
 539 ## tab-width: 8
 540 ## compile-command: "automake --add-missing"
 541 ## End: