configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl set optimization and debugging for all architectures and systems
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-O0 -g"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 dnl system type
  46 case "$host_cpu" in
  47 alpha | alphaev56 | alphapca56 )
  48     ARCH_DIR="alpha"
  49     ARCH_CFLAGS="-mieee -D__ALPHA__"
  50     JAVA_ARCH="alpha"
  51     ;;
  52
  53 arm | armv4 | armv4tl | armv5b | armv5l )
  54     ARCH_DIR="arm"
  55     ARCH_CFLAGS="-D__ARM__"
  56     JAVA_ARCH="arm"
  57     ;;
  58
  59 hppa2.0 )
  60     ARCH_DIR="parisc"
  61     ARCH_CFLAGS="-D__PARISC__"
  62     JAVA_ARCH="hppa"
  63     ;;
  64
  65 i386 | i486 | i586 | i686 )
  66     ARCH_DIR="i386"
  67     ARCH_CFLAGS="-D__I386__"
  68     JAVA_ARCH="i386"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     JAVA_ARCH="m68k"
  75     ;;
  76
  77 mips | mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_CFLAGS="-D__MIPS__"
  80     dnl Is this correct for mipsel?
  81     JAVA_ARCH="mips"
  82     ;;
  83
  84 powerpc )
  85     ARCH_DIR="powerpc"
  86     ARCH_CFLAGS="-D__POWERPC__"
  87     JAVA_ARCH="ppc"
  88     ;;
  89
  90 powerpc64 )
  91     ARCH_DIR="powerpc64"
  92     ARCH_CFLAGS="-D__POWERPC64__"
  93     JAVA_ARCH="ppc64"
  94     ;;
  95
  96 s390 )
  97     ARCH_DIR="s390"
  98     ARCH_CFLAGS="-D__S390__"
  99     JAVA_ARCH="s390"
 100     ;;
 101
 102 sparc | sparc64 )
 103     ARCH_DIR="sparc64"
 104     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 105     dnl Is this correct for 64-bits?
 106     JAVA_ARCH="sparc"
 107     ;;
 108
 109 x86_64 )
 110     ARCH_DIR="x86_64"
 111     ARCH_CFLAGS="-D__X86_64__"
 112     JAVA_ARCH="amd64"
 113     ;;
 114
 115 xdspcore )
 116     ARCH_DIR="xdspcore"
 117     ENABLE_STATICVM="yes"
 118     ARCH_CFLAGS="-D__XDSPCORE__"
 119     USE_SCHEDULER="1"
 120     ;;
 121
 122 * )
 123     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 124     ;;
 125 esac
 126
 127 dnl host type
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 132     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -std=c99 -pedantic -Wall -Wno-long-long"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 138     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -std=c99 -pedantic -Wall -Wno-long-long"
 139     ;;
 140
 141 dnl Must be BEFORE *freebsd*.
 142 *kfreebsd*-gnu)
 143     OS_DIR="freebsd"
 144     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 145     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 146     ;;
 147
 148 *freebsd* )
 149     OS_DIR="freebsd"
 150     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 151     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 152     ;;
 153
 154 *irix* )
 155     OS_DIR="irix"
 156     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 157     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 158     ;;
 159
 160 dnl Must be BEFORE *linux*.
 161 *uclinux | *elf )
 162     OS_DIR="uclinux"
 163     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 165     ;;
 166
 167 *linux* | *Linux* )
 168     OS_DIR="linux"
 169     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 171     ;;
 172
 173 *netbsd* )
 174     OS_DIR="netbsd"
 175     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 177     ;;
 178
 179 *solaris* )
 180     OS_DIR="solaris"
 181     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 182     dnl not set when cpp is called with -std=c99, therefore we add them
 183     dnl here.
 184     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 185     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 186     ;;
 187
 188 * )
 189     ;;
 190 esac
 191
 192
 193 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 194 dnl we set it properly at the end of this file
 195 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 196
 197 dnl set interpreter flags
 198 AC_SUBST(INTRP_CFLAGS)
 199
 200 dnl define and substitute some architecture specific variables
 201 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 202 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 203 AC_SUBST(ARCH_DIR)
 204 AC_SUBST(JAVA_ARCH)
 205 AC_SUBST(OS_DIR)
 206 AC_SUBST(USE_SCHEDULER)
 207
 208
 209 dnl Checks for programs.
 210 AC_PROG_CC
 211 AM_PROG_AS
 212 AC_PROG_LD
 213 AC_PROG_LD_GNU
 214 AC_PROG_LN_S
 215 AC_PROG_MAKE_SET
 216 AM_PROG_MKDIR_P
 217
 218 dnl Checks for header files.
 219 AC_HEADER_DIRENT
 220 AC_HEADER_STDC
 221
 222 dnl Crucial header files.
 223 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 224 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 225
 226 dnl keep them alpha-sorted!
 227 AC_CHECK_HEADERS([assert.h])
 228 AC_CHECK_HEADERS([errno.h])
 229 AC_CHECK_HEADERS([fcntl.h])
 230 AC_CHECK_HEADERS([libgen.h])
 231 AC_CHECK_HEADERS([netdb.h])
 232 AC_CHECK_HEADERS([stdint.h])
 233 AC_CHECK_HEADERS([stdio.h])
 234 AC_CHECK_HEADERS([stdlib.h])
 235 AC_CHECK_HEADERS([string.h])
 236 AC_CHECK_HEADERS([time.h])
 237 AC_CHECK_HEADERS([ucontext.h])
 238 AC_CHECK_HEADERS([unistd.h])
 239 AC_CHECK_HEADERS([sys/ioctl.h])
 240 AC_CHECK_HEADERS([sys/mman.h])
 241 AC_CHECK_HEADERS([sys/resource.h])
 242 AC_CHECK_HEADERS([sys/select.h])
 243 AC_CHECK_HEADERS([sys/socket.h])
 244 AC_CHECK_HEADERS([sys/stat.h])
 245 AC_CHECK_HEADERS([sys/time.h])
 246 AC_CHECK_HEADERS([sys/types.h])
 247
 248 dnl Checks for typedefs, structures, and compiler characteristics.
 249 AC_C_CONST
 250 AC_C_INLINE
 251 AC_C_ATTRIBUTE
 252 AC_TYPE_OFF_T
 253 AC_TYPE_SIZE_T
 254 AC_HEADER_TIME
 255 AC_STRUCT_TM
 256
 257 dnl Checks for libraries (NOTE: Should be done before function checks,
 258 dnl as some functions may be in libraries we check for).
 259
 260 dnl Checks for library functions.
 261 AC_PROG_GCC_TRADITIONAL
 262 AC_TYPE_SIGNAL
 263 AC_FUNC_MEMCMP
 264 AC_FUNC_MMAP
 265
 266 dnl keep them alpha-sorted!
 267 AC_CHECK_FUNCS([abort])
 268 AC_CHECK_FUNCS([accept])
 269 AC_CHECK_FUNCS([access])
 270 AC_CHECK_FUNCS([atoi])
 271 AC_CHECK_FUNCS([atol])
 272 AC_CHECK_FUNCS([calloc])
 273 AC_CHECK_FUNCS([close])
 274 AC_CHECK_FUNCS([confstr])
 275 AC_CHECK_FUNCS([connect])
 276 AC_CHECK_FUNCS([dirname])
 277 AC_CHECK_FUNCS([fclose])
 278 AC_CHECK_FUNCS([fflush])
 279 AC_CHECK_FUNCS([fopen])
 280 AC_CHECK_FUNCS([fprintf])
 281 AC_CHECK_FUNCS([fread])
 282 AC_CHECK_FUNCS([free])
 283 AC_CHECK_FUNCS([fstat])
 284 AC_CHECK_FUNCS([fsync])
 285 AC_CHECK_FUNCS([ftruncate])
 286 AC_CHECK_FUNCS([getcwd])
 287 AC_CHECK_FUNCS([gethostbyname])
 288 AC_CHECK_FUNCS([gethostname])
 289 AC_CHECK_FUNCS([getpagesize])
 290 AC_CHECK_FUNCS([getrusage])
 291 AC_CHECK_FUNCS([getsockname])
 292 AC_CHECK_FUNCS([getsockopt])
 293 AC_CHECK_FUNCS([gettimeofday])
 294 AC_CHECK_FUNCS([htons])
 295 AC_CHECK_FUNCS([ioctl])
 296 AC_CHECK_FUNCS([isnan])
 297 AC_CHECK_FUNCS([listen])
 298 AC_CHECK_FUNCS([localtime])
 299 AC_CHECK_FUNCS([localtime_r])
 300 AC_CHECK_FUNCS([lseek])
 301 AC_CHECK_FUNCS([malloc])
 302 AC_CHECK_FUNCS([memcpy])
 303 AC_CHECK_FUNCS([memset])
 304 AC_CHECK_FUNCS([mmap])
 305 AC_CHECK_FUNCS([mprotect])
 306 AC_CHECK_FUNCS([open])
 307 AC_CHECK_FUNCS([read])
 308 AC_CHECK_FUNCS([readlink])
 309 AC_CHECK_FUNCS([realloc])
 310 AC_CHECK_FUNCS([recv])
 311 AC_CHECK_FUNCS([scandir])
 312 AC_CHECK_FUNCS([select])
 313 AC_CHECK_FUNCS([send])
 314 AC_CHECK_FUNCS([setsockopt])
 315 AC_CHECK_FUNCS([shutdown])
 316 AC_CHECK_FUNCS([socket])
 317 AC_CHECK_FUNCS([stat])
 318 AC_CHECK_FUNCS([strcat])
 319 AC_CHECK_FUNCS([strchr])
 320 AC_CHECK_FUNCS([strcpy])
 321 AC_CHECK_FUNCS([strdup])
 322 AC_CHECK_FUNCS([strerror])
 323 AC_CHECK_FUNCS([strlen])
 324 AC_CHECK_FUNCS([strncmp])
 325 AC_CHECK_FUNCS([strstr])
 326 AC_CHECK_FUNCS([time])
 327 AC_CHECK_FUNCS([write])
 328
 329
 330 dnl Checks for libraries.
 331
 332 dnl Checking sizeof void *
 333 AC_CHECK_SIZEOF(void *)
 334 AC_C_BIGENDIAN
 335
 336
 337 dnl define install prefix
 338 if test "x$prefix" = "xNONE"; then
 339     CACAO_PREFIX=$ac_default_prefix
 340 else
 341     CACAO_PREFIX=$prefix
 342 fi
 343 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 344 AC_SUBST(CACAO_PREFIX)
 345
 346 dnl define libdir prefix
 347 if test "x$libdir" = "xNONE"; then
 348     CACAO_LIBDIR=$ac_default_libdir
 349 else
 350     CACAO_LIBDIR=$libdir
 351 fi
 352 dnl expand CACAO_LIBDIR to something that is usable in C code
 353 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 354 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 355 AC_SUBST(CACAO_LIBDIR)
 356
 357
 358 AC_CHECK_ENABLE_DL
 359 AC_CHECK_ENABLE_JAVA
 360
 361 AC_CHECK_ENABLE_JIT
 362 AC_CHECK_ENABLE_INTRP
 363
 364 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 365     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 366 fi
 367
 368 AC_CHECK_SOFTFLOAT
 369 AC_CHECK_SOFT_FLOAT_CMP
 370 AC_CHECK_SOFT_DOUBLE_CMP
 371
 372 AC_CHECK_ENABLE_GC
 373 AC_CHECK_ENABLE_DEBUG
 374 AC_CHECK_ENABLE_DUMP
 375 AC_CHECK_ENABLE_MEMCHECK
 376 AC_CHECK_ENABLE_HANDLES
 377 AC_CHECK_ENABLE_VMLOG
 378 AC_CHECK_ENABLE_DISASSEMBLER
 379 AC_CHECK_ENABLE_STATISTICS
 380 AC_CHECK_ENABLE_VERIFIER
 381
 382 dnl check for compiler timing
 383 AC_MSG_CHECKING(whether real-time timing should be enabled)
 384 AC_ARG_ENABLE([rt-timing],
 385               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 386               [case "${enableval}" in
 387                    yes) ENABLE_RT_TIMING=yes;;
 388                    *) ENABLE_RT_TIMING=no;;
 389                esac],
 390               [ENABLE_RT_TIMING=no])
 391 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 392 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 393
 394 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 395     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 396 fi
 397
 398
 399 dnl check for cycle count statistics
 400 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 401 AC_ARG_ENABLE([cycles-stats],
 402               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 403               [case "${enableval}" in
 404                    yes) ENABLE_CYCLES_STATS=yes;;
 405                    *) ENABLE_CYCLES_STATS=no;;
 406                esac],
 407               [ENABLE_CYCLES_STATS=no])
 408 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 409 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 410
 411 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 412     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 413 fi
 414
 415
 416 dnl check for JVMTI
 417 AC_MSG_CHECKING(whether to compile JVMTI support)
 418 AC_ARG_ENABLE([jvmti],
 419               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 420               [case "${enableval}" in
 421                    yes) ENABLE_JVMTI=yes;;
 422                    *) ENABLE_JVMTI=no;;
 423                esac],
 424               [ENABLE_JVMTI=no])
 425 AC_MSG_RESULT(${ENABLE_JVMTI})
 426 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 427
 428 if test x"${ENABLE_JVMTI}" = "xyes"; then
 429     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 430 fi
 431
 432
 433 AC_CHECK_ENABLE_THREADS
 434
 435
 436 dnl check if if-conversion should be supported
 437 AC_MSG_CHECKING(whether if-conversion should be supported)
 438 AC_ARG_ENABLE([ifconv],
 439               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=enabled]])],
 440               [case "${enableval}" in
 441                    no) ENABLE_IFCONV=no;;
 442                    *) ENABLE_IFCONV=yes;;
 443                esac],
 444               [ENABLE_IFCONV=yes])
 445 AC_MSG_RESULT(${ENABLE_IFCONV})
 446 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 447
 448 if test x"${ENABLE_IFCONV}" = "xyes"; then
 449     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 450 fi
 451
 452
 453 dnl check for inlining
 454 AC_MSG_CHECKING(whether method inlining should be supported)
 455 AC_ARG_ENABLE([inlining],
 456               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 457               [case "${enableval}" in
 458                    yes) ENABLE_INLINING=yes;;
 459                    *) ENABLE_INLINING=no;;
 460                esac],
 461               [ENABLE_INLINING=no])
 462 AC_MSG_RESULT(${ENABLE_INLINING})
 463 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 464
 465 if test x"${ENABLE_INLINING}" = "xyes"; then
 466     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 467 fi
 468
 469
 470 dnl check for inlining debug options
 471 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 472 AC_ARG_ENABLE([inlining-debug],
 473               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 474               [case "${enableval}" in
 475                    yes) ENABLE_INLINING_DEBUG=yes;;
 476                    *) ENABLE_INLINING_DEBUG=no;;
 477                esac],
 478               [ENABLE_INLINING_DEBUG=no])
 479 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 480 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 481
 482 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 483     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 484 fi
 485
 486
 487 dnl check for replacement
 488 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 489 AC_ARG_ENABLE([replacement],
 490               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 491               [case "${enableval}" in
 492                    yes) ENABLE_REPLACEMENT=yes;;
 493                    *) ENABLE_REPLACEMENT=no;;
 494                esac],
 495               [ENABLE_REPLACEMENT=no])
 496 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 497 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 498
 499 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 500     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 501 fi
 502
 503
 504 dnl check for loop optimization
 505 AC_MSG_CHECKING(whether loop optimization should be supported)
 506 AC_ARG_ENABLE([loop],
 507               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 508               [case "${enableval}" in
 509                    yes) ENABLE_LOOP=yes;;
 510                    *) ENABLE_LOOP=no;;
 511                esac],
 512               [ENABLE_LOOP=no])
 513 AC_MSG_RESULT(${ENABLE_LOOP})
 514 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 515
 516 if test x"${ENABLE_LOOP}" = "xyes"; then
 517     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 518 fi
 519
 520
 521 dnl check if linear scan register allocator(lsra) with SSA should be used
 522 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 523 AC_ARG_ENABLE([ssa],
 524               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 525               [case "${enableval}" in
 526                    no) ENABLE_SSA=no;;
 527                    *) ENABLE_SSA=yes;;
 528                esac],
 529               [ENABLE_SSA=no])
 530 AC_MSG_RESULT(${ENABLE_SSA})
 531 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 532 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 533 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 534
 535 if test x"${ENABLE_SSA}" = "xyes"; then
 536     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 537     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 538     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 539     ENABLE_LSRA="no"
 540 fi
 541
 542
 543 dnl check if linear scan register allocator(lsra) should be used
 544 AC_MSG_CHECKING(whether lsra should be supported)
 545 AC_ARG_ENABLE([lsra],
 546               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 547               [case "${enableval}" in
 548                    yes) ENABLE_LSRA=yes;;
 549                    *) ENABLE_LSRA=no;;
 550                esac],
 551               [ENABLE_LSRA=no])
 552
 553 if test x"${ENABLE_LSRA}" = "xyes"; then
 554     if test x"${ENABLE_SSA}" = "xyes"; then
 555         ENABLE_LSRA="no"
 556     fi
 557 fi
 558 AC_MSG_RESULT(${ENABLE_LSRA})
 559 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 560
 561 if test x"${ENABLE_LSRA}" = "xyes"; then
 562     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 563 fi
 564
 565 dnl check if profiling should be supported
 566 AC_MSG_CHECKING(whether profiling should be supported)
 567 AC_ARG_ENABLE([profiling],
 568               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 569               [case "${enableval}" in
 570                    yes) ENABLE_PROFILING=yes;;
 571                    *) ENABLE_PROFILING=no;;
 572                esac],
 573               [ENABLE_PROFILING=no])
 574 AC_MSG_RESULT(${ENABLE_PROFILING})
 575 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 576
 577 if test x"${ENABLE_PROFILING}" = "xyes"; then
 578     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 579 fi
 580
 581
 582 dnl check for instruction scheduler
 583 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 584
 585 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 586 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 587         case "${ARCH_DIR}" in
 588                 xdspcore )
 589                         ;;
 590                 * )
 591                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 592                         ;;
 593         esac
 594
 595         AC_MSG_RESULT(yes)
 596         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 597         AM_CONDITIONAL([USE_SCHEDULER], [true])
 598 else
 599         AC_MSG_RESULT(no)
 600         AM_CONDITIONAL([USE_SCHEDULER], [false])
 601 fi
 602
 603
 604 AC_CHECK_ENABLE_ZLIB
 605
 606 dnl check for stuff to be built
 607 AC_CHECK_ENABLE_JNI
 608 AC_CHECK_ENABLE_LIBJVM
 609
 610 dnl ATTENTION: These check must be after setting
 611 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 612 dnl because libtool uses them to build the correct libraries.
 613 AC_LIBTOOL_DLOPEN
 614 AC_PROG_LIBTOOL
 615
 616 AC_CHECK_ENABLE_STATICVM
 617 AC_CHECK_ENABLE_ANNOTATIONS
 618 AC_CHECK_ENABLE_ASSERTION
 619
 620
 621 dnl where is CACAO's vm.zip
 622 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 623 AC_ARG_WITH([vm-zip],
 624             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 625             [CACAO_VM_ZIP=${withval}],
 626             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 627 AC_MSG_RESULT(${CACAO_VM_ZIP})
 628 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 629 AC_SUBST(CACAO_VM_ZIP)
 630
 631
 632 AC_CHECK_WITH_CACAOH
 633 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 634
 635 dnl Now we check for jre-layout so we can skip some checks that are
 636 dnl not required.
 637 AC_CHECK_ENABLE_JRE_LAYOUT
 638
 639 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 640 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 641
 642 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 643    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 644 fi
 645
 646 dnl The check for jni_md.h must be before jni.h.
 647 AC_CHECK_WITH_JNI_MD_H
 648 AC_CHECK_WITH_JNI_H
 649
 650 dnl HPI is only required for OpenJDK
 651 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 652     openjdk)
 653         AC_CHECK_WITH_HPI_MD_H
 654         AC_CHECK_WITH_HPI_H
 655         ;;
 656     *)
 657         ;;
 658 esac
 659
 660 dnl check for some programs we need
 661
 662 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 663     cldc1.1 | gnuclasspath)
 664         AC_PROG_JAVAC
 665         AC_PROG_JAR
 666         ;;
 667     openjdk)
 668         ;;
 669     *)
 670         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 671         ;;
 672 esac
 673
 674 AC_CHECK_WITH_JASMIN_JAR
 675 AC_CHECK_WITH_JUNIT_JAR
 676
 677 AC_CHECK_HEADERS(
 678         [regex.h],
 679         [
 680                 dnl If debug build and regex.h available, enable debug filter
 681                 if test x"${NDEBUG}" = "xno"; then
 682                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 683                 fi
 684                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 685                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 686         ],
 687         [
 688                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 689         ]
 690 )
 691
 692 dnl python
 693
 694 AZ_PYTHON_DEFAULT
 695 AZ_PYTHON_ENABLE
 696 AZ_PYTHON_WITH
 697 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 698 AZ_PYTHON_CSPEC
 699 AZ_PYTHON_LSPEC
 700
 701
 702 dnl define some stuff required for --fullversion
 703 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 704 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 705 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CPPFLAGS", [CFLAGS used])
 706
 707
 708 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 709 CFLAGS="$OPT_CFLAGS"
 710 AM_CFLAGS=$ARCH_CFLAGS
 711 AM_CPPFLAGS="$CPPFLAGS"
 712 AC_SUBST(AM_CFLAGS)
 713 AC_SUBST(AM_CPPFLAGS)
 714
 715
 716 AC_CONFIG_FILES([Makefile]
 717                 [contrib/Makefile]
 718                 [contrib/setenvinstalled]
 719                 [contrib/setenvsource]
 720                 [contrib/vmlog/Makefile]
 721                 [contrib/vmlog/t/Makefile]
 722                 [doc/Makefile]
 723                 [doc/doxygen/Makefile]
 724                 [doc/handbook/Makefile]
 725                 [man/Makefile]
 726                 [src/Makefile]
 727                 [src/cacao/Makefile]
 728                 [src/cacaoh/Makefile]
 729                 [src/classes/Makefile]
 730                 [src/fdlibm/Makefile]
 731                 [src/mm/Makefile]
 732                 [src/mm/cacao-gc/Makefile]
 733                 [src/native/Makefile]
 734                 [src/native/include/Makefile]
 735                 [src/native/jvmti/Makefile]
 736                 [src/native/vm/Makefile]
 737                 [src/native/vm/cldc1.1/Makefile]
 738                 [src/native/vm/gnuclasspath/Makefile]
 739                 [src/native/vm/openjdk/Makefile]
 740                 [src/scripts/Makefile]
 741                 [src/scripts/java]
 742                 [src/threads/Makefile]
 743                 [src/threads/none/Makefile]
 744                 [src/threads/posix/Makefile]
 745                 [src/toolbox/Makefile]
 746                 [src/vm/Makefile]
 747                 [src/vm/jit/Makefile]
 748                 [src/vm/jit/allocator/Makefile]
 749                 [src/vm/jit/alpha/Makefile]
 750                 [src/vm/jit/alpha/freebsd/Makefile]
 751                 [src/vm/jit/alpha/linux/Makefile]
 752                 [src/vm/jit/arm/Makefile]
 753                 [src/vm/jit/arm/linux/Makefile]
 754                 [src/vm/jit/i386/Makefile]
 755                 [src/vm/jit/i386/cygwin/Makefile]
 756                 [src/vm/jit/i386/darwin/Makefile]
 757                 [src/vm/jit/i386/freebsd/Makefile]
 758                 [src/vm/jit/i386/linux/Makefile]
 759                 [src/vm/jit/intrp/Makefile]
 760                 [src/vm/jit/inline/Makefile]
 761                 [src/vm/jit/ir/Makefile]
 762                 [src/vm/jit/loop/Makefile]
 763                 [src/vm/jit/m68k/Makefile]
 764                 [src/vm/jit/m68k/linux/Makefile]
 765                 [src/vm/jit/mips/Makefile]
 766                 [src/vm/jit/mips/irix/Makefile]
 767                 [src/vm/jit/mips/linux/Makefile]
 768                 [src/vm/jit/mips/uclinux/Makefile]
 769                 [src/vm/jit/optimizing/Makefile]
 770                 [src/vm/jit/parisc/Makefile]
 771                 [src/vm/jit/parisc/linux/Makefile]
 772                 [src/vm/jit/powerpc/Makefile]
 773                 [src/vm/jit/powerpc/darwin/Makefile]
 774                 [src/vm/jit/powerpc/linux/Makefile]
 775                 [src/vm/jit/powerpc/netbsd/Makefile]
 776                 [src/vm/jit/powerpc64/Makefile]
 777                 [src/vm/jit/powerpc64/linux/Makefile]
 778                 [src/vm/jit/s390/Makefile]
 779                 [src/vm/jit/schedule/Makefile]
 780                 [src/vm/jit/sparc64/Makefile]
 781                 [src/vm/jit/sparc64/linux/Makefile]
 782                 [src/vm/jit/sparc64/solaris/Makefile]
 783                 [src/vm/jit/verify/Makefile]
 784                 [src/vm/jit/x86_64/Makefile]
 785                 [src/vm/jit/x86_64/freebsd/Makefile]
 786                 [src/vm/jit/x86_64/linux/Makefile]
 787                 [src/vmcore/Makefile]
 788                 [tests/Makefile]
 789                 [tests/regression/Makefile]
 790                 [tests/regression/assertion/Makefile]
 791                 [tests/regression/base/Makefile]
 792                 [tests/regression/bugzilla/Makefile]
 793                 [tests/regression/jasmin/Makefile]
 794                 [tests/regression/native/Makefile]
 795                 [tests/regression/resolving/Makefile]
 796                 [tests/regression/resolving/classes1/Makefile]
 797                 [tests/regression/resolving/classes2/Makefile]
 798                 [tests/regression/resolving/classes3/Makefile]
 799 )
 800
 801
 802 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
 803 export OPT_CFLAGS
 804 export ARCH_CFLAGS
 805 dnl We only build the shared library objects but we use it as
 806 dnl noinst_LTLIBRARIES
 807 ac_configure_args="$ac_configure_args --disable-static"
 808 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 809
 810
 811 AC_OUTPUT
 812
 813
 814 ## Local variables:
 815 ## mode: m4
 816 ## indent-tabs-mode: t
 817 ## c-basic-offset: 4
 818 ## tab-width: 8
 819 ## compile-command: "automake --add-missing"
 820 ## End: