configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl Set optimization and debugging for all architectures and systems.
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-g -O0"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 if test x"$CXXFLAGS" = "x"; then
  46     OPT_CXXFLAGS="-g -O0"
  47 else
  48     OPT_CXXFLAGS=$CXXFLAGS
  49 fi
  50
  51 dnl system type
  52 case "$host_cpu" in
  53 alpha | alphaev56 | alphapca56 )
  54     ARCH_DIR="alpha"
  55     ARCH_FLAGS="-mieee -D__ALPHA__"
  56     JAVA_ARCH="alpha"
  57     ;;
  58
  59 arm | armv4 | armv4tl | armv5b | armv5l | armv5tel | armv5tejl )
  60     ARCH_DIR="arm"
  61     ARCH_FLAGS="-D__ARM__"
  62     JAVA_ARCH="arm"
  63     ;;
  64
  65 hppa2.0 )
  66     ARCH_DIR="parisc"
  67     ARCH_FLAGS="-D__PARISC__"
  68     JAVA_ARCH="hppa"
  69     ;;
  70
  71 i386 | i486 | i586 | i686 )
  72     ARCH_DIR="i386"
  73     ARCH_FLAGS="-m32 -D__I386__"
  74     JAVA_ARCH="i386"
  75     ;;
  76
  77 m68k )
  78     ARCH_DIR="m68k"
  79     ARCH_FLAGS="-D__M68K__"
  80     JAVA_ARCH="m68k"
  81     ;;
  82
  83 mips | mipsel )
  84     ARCH_DIR="mips"
  85     ARCH_FLAGS="-D__MIPS__"
  86     dnl Is this correct for mipsel?
  87     JAVA_ARCH="mips"
  88     ;;
  89
  90 powerpc )
  91     ARCH_DIR="powerpc"
  92     ARCH_FLAGS="-m32 -D__POWERPC__"
  93     JAVA_ARCH="ppc"
  94     ;;
  95
  96 powerpc64 )
  97     ARCH_DIR="powerpc64"
  98     ARCH_FLAGS="-m64 -D__POWERPC64__"
  99     JAVA_ARCH="ppc64"
 100     ;;
 101
 102 s390 )
 103     ARCH_DIR="s390"
 104     ARCH_FLAGS="-D__S390__"
 105     JAVA_ARCH="s390"
 106     ;;
 107
 108 sparc | sparc64 )
 109     ARCH_DIR="sparc64"
 110     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 111     dnl Is this correct for 64-bits?
 112     JAVA_ARCH="sparc"
 113     ;;
 114
 115 x86_64 )
 116     ARCH_DIR="x86_64"
 117     ARCH_FLAGS="-m64 -D__X86_64__"
 118     JAVA_ARCH="amd64"
 119     ;;
 120
 121 xdspcore )
 122     ARCH_DIR="xdspcore"
 123     ENABLE_STATICVM="yes"
 124     ARCH_FLAGS="-D__XDSPCORE__"
 125     USE_SCHEDULER="1"
 126     ;;
 127
 128 * )
 129     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 130     ;;
 131 esac
 132
 133 dnl host type
 134 case "$host_os" in
 135 *cygwin* )
 136     OS_DIR="cygwin"
 137     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 138     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 139     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 140     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 141     ;;
 142
 143 *darwin* )
 144     OS_DIR="darwin"
 145     OS_FLAGS="-D__DARWIN__"
 146     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 147     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 148     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 149     ;;
 150
 151 dnl Must be BEFORE *freebsd*.
 152 *kfreebsd*-gnu)
 153     OS_DIR="freebsd"
 154     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 156     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 157     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 *freebsd* )
 161     OS_DIR="freebsd"
 162     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 163     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 164     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 165     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 166     ;;
 167
 168 *irix* )
 169     OS_DIR="irix"
 170     OS_FLAGS="-D__IRIX__"
 171     CC_FLAGS=""
 172     CXX_FLAGS=""
 173     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 174     ;;
 175
 176 dnl Must be BEFORE *linux*.
 177 *uclinux | *elf )
 178     OS_DIR="uclinux"
 179     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 180     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 181     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 182     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 183     ;;
 184
 185 *linux* | *Linux* )
 186     OS_DIR="linux"
 187     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 188     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 189     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 190     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 191     ;;
 192
 193 *netbsd* )
 194     OS_DIR="netbsd"
 195     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 196     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 197     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 198     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 199     ;;
 200
 201 *solaris* )
 202     OS_DIR="solaris"
 203     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 204     dnl not set when cpp is called with -std=c99, therefore we add them
 205     dnl here.
 206     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 207     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE=600"
 208     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 209     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 210     ;;
 211
 212 * )
 213     ;;
 214 esac
 215
 216
 217 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 218 dnl we set it properly at the end of this file
 219 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 220 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 221
 222 dnl set interpreter flags
 223 AC_SUBST(INTRP_CFLAGS)
 224
 225 dnl define and substitute some architecture specific variables
 226 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 227 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 228 AC_SUBST(ARCH_DIR)
 229 AC_SUBST(JAVA_ARCH)
 230 AC_SUBST(OS_DIR)
 231 AC_SUBST(USE_SCHEDULER)
 232
 233
 234 dnl Checks for programs.
 235 AC_PROG_CC
 236 AC_PROG_CXX
 237 AM_PROG_AS
 238 AC_PROG_LD
 239 AC_PROG_LD_GNU
 240 AC_PROG_LN_S
 241 AC_PROG_MAKE_SET
 242 AM_PROG_MKDIR_P
 243
 244 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 245
 246 dnl Checks for header files.
 247 AC_HEADER_DIRENT
 248 AC_HEADER_STDC
 249
 250 dnl Crucial header files.
 251 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 252 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 253
 254 dnl keep them alpha-sorted!
 255 AC_CHECK_HEADERS([assert.h])
 256 AC_CHECK_HEADERS([errno.h])
 257 AC_CHECK_HEADERS([execinfo.h])
 258 AC_CHECK_HEADERS([fcntl.h])
 259 AC_CHECK_HEADERS([libgen.h])
 260 AC_CHECK_HEADERS([netdb.h])
 261 AC_CHECK_HEADERS([signal.h])
 262 AC_CHECK_HEADERS([stdint.h])
 263 AC_CHECK_HEADERS([stdio.h])
 264 AC_CHECK_HEADERS([stdlib.h])
 265 AC_CHECK_HEADERS([string.h])
 266 AC_CHECK_HEADERS([time.h])
 267 AC_CHECK_HEADERS([ucontext.h])
 268 AC_CHECK_HEADERS([unistd.h])
 269 AC_CHECK_HEADERS([sys/ioctl.h])
 270 AC_CHECK_HEADERS([sys/mman.h])
 271 AC_CHECK_HEADERS([sys/resource.h])
 272 AC_CHECK_HEADERS([sys/select.h])
 273 AC_CHECK_HEADERS([sys/socket.h])
 274 AC_CHECK_HEADERS([sys/stat.h])
 275 AC_CHECK_HEADERS([sys/time.h])
 276 AC_CHECK_HEADERS([sys/types.h])
 277
 278 dnl Checks for typedefs, structures, and compiler characteristics.
 279 AC_C_CONST
 280 AC_C_INLINE
 281 AC_C_ATTRIBUTE
 282 AC_TYPE_OFF_T
 283 AC_TYPE_SIZE_T
 284 AC_HEADER_TIME
 285 AC_STRUCT_TM
 286
 287 dnl Checks for libraries (NOTE: Should be done before function checks,
 288 dnl as some functions may be in libraries we check for).
 289
 290 case "${OS_DIR}" in
 291     solaris )
 292          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 293          ;;
 294 esac
 295
 296 dnl Checks for library functions.
 297 AC_PROG_GCC_TRADITIONAL
 298 AC_TYPE_SIGNAL
 299 AC_FUNC_MEMCMP
 300 AC_FUNC_MMAP
 301
 302 dnl keep them alpha-sorted!
 303 AC_CHECK_FUNCS([abort])
 304 AC_CHECK_FUNCS([accept])
 305 AC_CHECK_FUNCS([access])
 306 AC_CHECK_FUNCS([atoi])
 307 AC_CHECK_FUNCS([atol])
 308 AC_CHECK_FUNCS([backtrace])
 309 AC_CHECK_FUNCS([backtrace_symbols])
 310 AC_CHECK_FUNCS([calloc])
 311 AC_CHECK_FUNCS([close])
 312 AC_CHECK_FUNCS([confstr])
 313 AC_CHECK_FUNCS([connect])
 314 AC_CHECK_FUNCS([dirname])
 315 AC_CHECK_FUNCS([fclose])
 316 AC_CHECK_FUNCS([fflush])
 317 AC_CHECK_FUNCS([fopen])
 318 AC_CHECK_FUNCS([fprintf])
 319 AC_CHECK_FUNCS([fread])
 320 AC_CHECK_FUNCS([free])
 321 AC_CHECK_FUNCS([fstat])
 322 AC_CHECK_FUNCS([fsync])
 323 AC_CHECK_FUNCS([ftruncate])
 324 AC_CHECK_FUNCS([getcwd])
 325 AC_CHECK_FUNCS([gethostbyname])
 326 AC_CHECK_FUNCS([gethostname])
 327 AC_CHECK_FUNCS([getpagesize])
 328 AC_CHECK_FUNCS([getrusage])
 329 AC_CHECK_FUNCS([getsockname])
 330 AC_CHECK_FUNCS([getsockopt])
 331 AC_CHECK_FUNCS([gettimeofday])
 332 AC_CHECK_FUNCS([htons])
 333 AC_CHECK_FUNCS([ioctl])
 334 AC_CHECK_FUNCS([isnan])
 335 AC_CHECK_FUNCS([listen])
 336 AC_CHECK_FUNCS([localtime])
 337 AC_CHECK_FUNCS([localtime_r])
 338 AC_CHECK_FUNCS([lseek])
 339 AC_CHECK_FUNCS([malloc])
 340 AC_CHECK_FUNCS([memcpy])
 341 AC_CHECK_FUNCS([memset])
 342 AC_CHECK_FUNCS([mmap])
 343 AC_CHECK_FUNCS([mprotect])
 344 AC_CHECK_FUNCS([open])
 345 AC_CHECK_FUNCS([read])
 346 AC_CHECK_FUNCS([readlink])
 347 AC_CHECK_FUNCS([realloc])
 348 AC_CHECK_FUNCS([recv])
 349 AC_CHECK_FUNCS([scandir])
 350 AC_CHECK_FUNCS([select])
 351 AC_CHECK_FUNCS([send])
 352 AC_CHECK_FUNCS([setsockopt])
 353 AC_CHECK_FUNCS([shutdown])
 354 AC_CHECK_FUNCS([socket])
 355 AC_CHECK_FUNCS([stat])
 356 AC_CHECK_FUNCS([str2sig])
 357 AC_CHECK_FUNCS([strcat])
 358 AC_CHECK_FUNCS([strchr])
 359 AC_CHECK_FUNCS([strcpy])
 360 AC_CHECK_FUNCS([strdup])
 361 AC_CHECK_FUNCS([strerror])
 362 AC_CHECK_FUNCS([strlen])
 363 AC_CHECK_FUNCS([strncmp])
 364 AC_CHECK_FUNCS([strstr])
 365 AC_CHECK_FUNCS([time])
 366 AC_CHECK_FUNCS([write])
 367
 368
 369 dnl Checks for libraries.
 370
 371 dnl Checking sizeof void *
 372 AC_CHECK_SIZEOF(void *)
 373 AC_C_BIGENDIAN
 374
 375
 376 dnl define install prefix
 377 if test "x$prefix" = "xNONE"; then
 378     CACAO_PREFIX=$ac_default_prefix
 379 else
 380     CACAO_PREFIX=$prefix
 381 fi
 382 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 383 AC_SUBST(CACAO_PREFIX)
 384
 385 dnl define libdir prefix
 386 if test "x$libdir" = "xNONE"; then
 387     CACAO_LIBDIR=$ac_default_libdir
 388 else
 389     CACAO_LIBDIR=$libdir
 390 fi
 391 dnl expand CACAO_LIBDIR to something that is usable in C code
 392 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 393 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 394 AC_SUBST(CACAO_LIBDIR)
 395
 396
 397 AC_CHECK_ENABLE_DL
 398 AC_CHECK_ENABLE_JAVA
 399
 400 AC_CHECK_ENABLE_JIT
 401 AC_CHECK_ENABLE_INTRP
 402
 403 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 404     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 405 fi
 406
 407 AC_CHECK_SOFTFLOAT
 408 AC_CHECK_SOFT_FLOAT_CMP
 409 AC_CHECK_SOFT_DOUBLE_CMP
 410
 411 AC_CHECK_ENABLE_GC
 412 AC_CHECK_ENABLE_DEBUG
 413 AC_CHECK_ENABLE_DUMP
 414 AC_CHECK_ENABLE_MEMCHECK
 415 AC_CHECK_ENABLE_HANDLES
 416 AC_CHECK_ENABLE_VMLOG
 417 AC_CHECK_ENABLE_DISASSEMBLER
 418 AC_CHECK_ENABLE_STATISTICS
 419 AC_CHECK_ENABLE_VERIFIER
 420 AC_CHECK_ENABLE_RT_TIMING
 421 AC_CHECK_ENABLE_CYCLE_STATS
 422 AC_CHECK_ENABLE_JVMTI
 423 AC_CHECK_ENABLE_THREADS
 424 AC_CHECK_ENABLE_IFCONV
 425 AC_CHECK_ENABLE_INLINING
 426 AC_CHECK_ENABLE_INLINING_DEBUG
 427 AC_CHECK_ENABLE_REPLACEMENT
 428
 429 dnl check for loop optimization
 430 AC_MSG_CHECKING(whether loop optimization should be supported)
 431 AC_ARG_ENABLE([loop],
 432               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 433               [case "${enableval}" in
 434                    yes) ENABLE_LOOP=yes;;
 435                    *) ENABLE_LOOP=no;;
 436                esac],
 437               [ENABLE_LOOP=no])
 438 AC_MSG_RESULT(${ENABLE_LOOP})
 439 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 440
 441 if test x"${ENABLE_LOOP}" = "xyes"; then
 442     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 443 fi
 444
 445
 446 dnl check if linear scan register allocator(lsra) with SSA should be used
 447 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 448 AC_ARG_ENABLE([ssa],
 449               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 450               [case "${enableval}" in
 451                    no) ENABLE_SSA=no;;
 452                    *) ENABLE_SSA=yes;;
 453                esac],
 454               [ENABLE_SSA=no])
 455 AC_MSG_RESULT(${ENABLE_SSA})
 456 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 457 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 458 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 459 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 460
 461 if test x"${ENABLE_SSA}" = "xyes"; then
 462     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 463     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 464     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 465     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 466     ENABLE_LSRA="no"
 467 fi
 468
 469
 470 dnl check if linear scan register allocator(lsra) should be used
 471 AC_MSG_CHECKING(whether lsra should be supported)
 472 AC_ARG_ENABLE([lsra],
 473               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 474               [case "${enableval}" in
 475                    yes) ENABLE_LSRA=yes;;
 476                    *) ENABLE_LSRA=no;;
 477                esac],
 478               [ENABLE_LSRA=no])
 479
 480 if test x"${ENABLE_LSRA}" = "xyes"; then
 481     if test x"${ENABLE_SSA}" = "xyes"; then
 482         ENABLE_LSRA="no"
 483     fi
 484 fi
 485 AC_MSG_RESULT(${ENABLE_LSRA})
 486 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 487
 488 if test x"${ENABLE_LSRA}" = "xyes"; then
 489     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 490 fi
 491
 492 dnl check if profiling should be supported
 493 AC_MSG_CHECKING(whether profiling should be supported)
 494 AC_ARG_ENABLE([profiling],
 495               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 496               [case "${enableval}" in
 497                    yes) ENABLE_PROFILING=yes;;
 498                    *) ENABLE_PROFILING=no;;
 499                esac],
 500               [ENABLE_PROFILING=no])
 501 AC_MSG_RESULT(${ENABLE_PROFILING})
 502 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 503
 504 if test x"${ENABLE_PROFILING}" = "xyes"; then
 505     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 506 fi
 507
 508
 509 dnl check for instruction scheduler
 510 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 511
 512 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 513 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 514         case "${ARCH_DIR}" in
 515                 xdspcore )
 516                         ;;
 517                 * )
 518                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 519                         ;;
 520         esac
 521
 522         AC_MSG_RESULT(yes)
 523         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 524         AM_CONDITIONAL([USE_SCHEDULER], [true])
 525 else
 526         AC_MSG_RESULT(no)
 527         AM_CONDITIONAL([USE_SCHEDULER], [false])
 528 fi
 529
 530 AC_CHECK_ENABLE_OPAGENT
 531
 532 AC_CHECK_ENABLE_ZLIB
 533
 534 dnl check for stuff to be built
 535 AC_CHECK_ENABLE_JNI
 536 AC_CHECK_ENABLE_LIBJVM
 537
 538 dnl ATTENTION: These check must be after setting
 539 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 540 dnl because libtool uses them to build the correct libraries.
 541 AC_LIBTOOL_DLOPEN
 542 AC_PROG_LIBTOOL
 543
 544 AC_CHECK_ENABLE_STATICVM
 545 AC_CHECK_ENABLE_ANNOTATIONS
 546 AC_CHECK_ENABLE_ASSERTION
 547
 548 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 549 AC_CHECK_WITH_VM_ZIP
 550
 551 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 552
 553 dnl Now we check for jre-layout so we can skip some checks that are
 554 dnl not required.
 555 AC_CHECK_ENABLE_JRE_LAYOUT
 556
 557 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 558 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 559 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 560
 561 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 562    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 563 fi
 564
 565 dnl The check for jni_md.h must be before jni.h.
 566 AC_CHECK_WITH_JNI_MD_H
 567 AC_CHECK_WITH_JNI_H
 568
 569 dnl HPI is only required for OpenJDK
 570 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 571     openjdk)
 572         AC_CHECK_WITH_HPI_MD_H
 573         AC_CHECK_WITH_HPI_H
 574         ;;
 575     *)
 576         ;;
 577 esac
 578
 579 dnl check for some programs we need
 580
 581 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 582     cldc1.1 | gnuclasspath)
 583         AC_PROG_JAVAC
 584         AC_PROG_JAR
 585         ;;
 586     openjdk)
 587         ;;
 588     *)
 589         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 590         ;;
 591 esac
 592
 593 AC_CHECK_WITH_JASMIN_JAR
 594 AC_CHECK_WITH_JUNIT_JAR
 595
 596 AC_CHECK_HEADERS(
 597         [regex.h],
 598         [
 599                 dnl If debug build and regex.h available, enable debug filter
 600                 if test x"${NDEBUG}" = "xno"; then
 601                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 602                 fi
 603                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 604                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 605         ],
 606         [
 607                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 608         ]
 609 )
 610
 611 dnl python
 612
 613 AZ_PYTHON_DEFAULT
 614 AZ_PYTHON_ENABLE
 615 AZ_PYTHON_WITH
 616 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 617 AZ_PYTHON_CSPEC
 618 AZ_PYTHON_LSPEC
 619
 620
 621 dnl define some stuff required for --fullversion
 622 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 623 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 624 AC_DEFINE_UNQUOTED(VERSION_CXX, "$CXX", [CXX used])
 625 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CC_FLAGS $CPPFLAGS", [CFLAGS used])
 626 AC_DEFINE_UNQUOTED(VERSION_CXXFLAGS, "$OPT_CXXFLAGS $ARCH_CXXFLAGS $CXX_FLAGS $CPPFLAGS", [CXXFLAGS used])
 627
 628
 629 dnl Finally pass flags to Makefiles.
 630 CFLAGS="$OPT_CFLAGS"
 631 CXXFLAGS="$OPT_CXXFLAGS"
 632
 633 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 634 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 635 AM_CPPFLAGS="$CPPFLAGS"
 636
 637 AC_SUBST(AM_CFLAGS)
 638 AC_SUBST(AM_CXXFLAGS)
 639 AC_SUBST(AM_CPPFLAGS)
 640
 641
 642 AC_CONFIG_FILES([Makefile]
 643                 [contrib/Makefile]
 644                 [contrib/setenvinstalled]
 645                 [contrib/setenvsource]
 646                 [contrib/vmlog/Makefile]
 647                 [contrib/vmlog/t/Makefile]
 648                 [doc/Makefile]
 649                 [doc/doxygen/Makefile]
 650                 [doc/handbook/Makefile]
 651                 [man/Makefile]
 652                 [src/Makefile]
 653                 [src/cacao/Makefile]
 654                 [src/classes/Makefile]
 655                 [src/fdlibm/Makefile]
 656                 [src/mm/Makefile]
 657                 [src/mm/cacao-gc/Makefile]
 658                 [src/native/Makefile]
 659                 [src/native/include/Makefile]
 660                 [src/native/jvmti/Makefile]
 661                 [src/native/vm/Makefile]
 662                 [src/native/vm/cldc1.1/Makefile]
 663                 [src/native/vm/gnuclasspath/Makefile]
 664                 [src/native/vm/openjdk/Makefile]
 665                 [src/scripts/Makefile]
 666                 [src/scripts/java]
 667                 [src/threads/Makefile]
 668                 [src/threads/none/Makefile]
 669                 [src/threads/posix/Makefile]
 670                 [src/toolbox/Makefile]
 671                 [src/vm/Makefile]
 672                 [src/vm/jit/Makefile]
 673                 [src/vm/jit/allocator/Makefile]
 674                 [src/vm/jit/alpha/Makefile]
 675                 [src/vm/jit/alpha/freebsd/Makefile]
 676                 [src/vm/jit/alpha/linux/Makefile]
 677                 [src/vm/jit/arm/Makefile]
 678                 [src/vm/jit/arm/linux/Makefile]
 679                 [src/vm/jit/i386/Makefile]
 680                 [src/vm/jit/i386/cygwin/Makefile]
 681                 [src/vm/jit/i386/darwin/Makefile]
 682                 [src/vm/jit/i386/freebsd/Makefile]
 683                 [src/vm/jit/i386/linux/Makefile]
 684                 [src/vm/jit/i386/solaris/Makefile]
 685                 [src/vm/jit/intrp/Makefile]
 686                 [src/vm/jit/inline/Makefile]
 687                 [src/vm/jit/ir/Makefile]
 688                 [src/vm/jit/loop/Makefile]
 689                 [src/vm/jit/m68k/Makefile]
 690                 [src/vm/jit/m68k/linux/Makefile]
 691                 [src/vm/jit/mips/Makefile]
 692                 [src/vm/jit/mips/irix/Makefile]
 693                 [src/vm/jit/mips/linux/Makefile]
 694                 [src/vm/jit/mips/uclinux/Makefile]
 695                 [src/vm/jit/optimizing/Makefile]
 696                 [src/vm/jit/parisc/Makefile]
 697                 [src/vm/jit/parisc/linux/Makefile]
 698                 [src/vm/jit/powerpc/Makefile]
 699                 [src/vm/jit/powerpc/darwin/Makefile]
 700                 [src/vm/jit/powerpc/linux/Makefile]
 701                 [src/vm/jit/powerpc/netbsd/Makefile]
 702                 [src/vm/jit/powerpc64/Makefile]
 703                 [src/vm/jit/powerpc64/linux/Makefile]
 704                 [src/vm/jit/s390/Makefile]
 705                 [src/vm/jit/schedule/Makefile]
 706                 [src/vm/jit/sparc64/Makefile]
 707                 [src/vm/jit/sparc64/linux/Makefile]
 708                 [src/vm/jit/sparc64/solaris/Makefile]
 709                 [src/vm/jit/verify/Makefile]
 710                 [src/vm/jit/x86_64/Makefile]
 711                 [src/vm/jit/x86_64/freebsd/Makefile]
 712                 [src/vm/jit/x86_64/linux/Makefile]
 713                 [src/vm/jit/x86_64/solaris/Makefile]
 714                 [tests/Makefile]
 715                 [tests/regression/Makefile]
 716                 [tests/regression/assertion/Makefile]
 717                 [tests/regression/base/Makefile]
 718                 [tests/regression/bugzilla/Makefile]
 719                 [tests/regression/jasmin/Makefile]
 720                 [tests/regression/native/Makefile]
 721                 [tests/regression/resolving/Makefile]
 722                 [tests/regression/resolving/classes1/Makefile]
 723                 [tests/regression/resolving/classes2/Makefile]
 724                 [tests/regression/resolving/classes3/Makefile]
 725 )
 726
 727
 728 dnl We only build the shared library objects but we use it as
 729 dnl noinst_LTLIBRARIES.
 730 ac_configure_args="$ac_configure_args --disable-static"
 731 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 732
 733
 734 AC_OUTPUT
 735
 736
 737 ## Local variables:
 738 ## mode: m4
 739 ## indent-tabs-mode: t
 740 ## c-basic-offset: 4
 741 ## tab-width: 8
 742 ## compile-command: "automake --add-missing"
 743 ## End: