configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CONFIG_AUX_DIR([.])
  29 AC_CANONICAL_HOST
  30 AC_PREREQ(2.59)
  31 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  32 AM_MAINTAINER_MODE
  33
  34 AM_CONFIG_HEADER([config.h])
  35
  36 AC_PREFIX_DEFAULT(/usr/local/cacao)
  37
  38
  39 dnl Host CPU type.
  40 case "$host_cpu" in
  41 alpha | alphaev56 | alphapca56 )
  42     ARCH_DIR="alpha"
  43     ARCH_FLAGS="-mieee -D__ALPHA__"
  44     JAVA_ARCH="alpha"
  45     ;;
  46
  47 arm | armv4* | armv5* | armv6* )
  48     ARCH_DIR="arm"
  49     ARCH_FLAGS="-D__ARM__"
  50     JAVA_ARCH="arm"
  51     ;;
  52
  53 hppa2.0 )
  54     ARCH_DIR="parisc"
  55     ARCH_FLAGS="-D__PARISC__"
  56     JAVA_ARCH="hppa"
  57     ;;
  58
  59 i386 | i486 | i586 | i686 )
  60     ARCH_DIR="i386"
  61     ARCH_FLAGS="-m32 -D__I386__"
  62     JAVA_ARCH="i386"
  63     ;;
  64
  65 m68k )
  66     ARCH_DIR="m68k"
  67     ARCH_FLAGS="-D__M68K__"
  68     JAVA_ARCH="m68k"
  69     ;;
  70
  71 mips )
  72     ARCH_DIR="mips"
  73     ARCH_FLAGS="-D__MIPS__"
  74     JAVA_ARCH="mips"
  75     ;;
  76
  77 mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_FLAGS="-D__MIPS__"
  80     JAVA_ARCH="mipsel"
  81     ;;
  82
  83 powerpc )
  84     ARCH_DIR="powerpc"
  85     ARCH_FLAGS="-m32 -D__POWERPC__"
  86     JAVA_ARCH="ppc"
  87     ;;
  88
  89 powerpc64 )
  90     ARCH_DIR="powerpc64"
  91     ARCH_FLAGS="-m64 -D__POWERPC64__"
  92     JAVA_ARCH="ppc64"
  93     ;;
  94
  95 s390 )
  96     ARCH_DIR="s390"
  97     ARCH_FLAGS="-D__S390__"
  98     JAVA_ARCH="s390"
  99     ;;
 100
 101 sparc | sparc64 )
 102     ARCH_DIR="sparc64"
 103     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 104     dnl Is this correct for 64-bits?
 105     JAVA_ARCH="sparc"
 106     ;;
 107
 108 x86_64 )
 109     ARCH_DIR="x86_64"
 110     ARCH_FLAGS="-m64 -D__X86_64__"
 111     JAVA_ARCH="amd64"
 112     ;;
 113
 114 xdspcore )
 115     ARCH_DIR="xdspcore"
 116     ENABLE_STATICVM="yes"
 117     ARCH_FLAGS="-D__XDSPCORE__"
 118     USE_SCHEDULER="1"
 119     ;;
 120
 121 * )
 122     AC_MSG_ERROR([$host_cpu systems are currently not supported.])
 123     ;;
 124 esac
 125
 126
 127 dnl Host operating system type.
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 132     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     OS_FLAGS="-D__DARWIN__"
 138     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 139     ;;
 140
 141 dnl Must be BEFORE *freebsd*.
 142 *kfreebsd*-gnu)
 143     OS_DIR="freebsd"
 144     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 145     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 146     ;;
 147
 148 *freebsd* )
 149     OS_DIR="freebsd"
 150     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 151     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 152     ;;
 153
 154 *irix* )
 155     OS_DIR="irix"
 156     OS_FLAGS="-D__IRIX__"
 157     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 dnl Must be BEFORE *linux*.
 161 *uclinux | *elf )
 162     OS_DIR="uclinux"
 163     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 165     ;;
 166
 167 *linux* | *Linux* )
 168     OS_DIR="linux"
 169     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 171     ;;
 172
 173 *netbsd* )
 174     OS_DIR="netbsd"
 175     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 177     ;;
 178
 179 *solaris* )
 180     OS_DIR="solaris"
 181     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 182     dnl not set when cpp is called with -std=c99, therefore we add them
 183     dnl here.
 184     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 185     CC_FLAGS="-D_XOPEN_SOURCE=600"
 186     CXX_FLAGS="-D_XOPEN_SOURCE=500"
 187     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 188     ;;
 189
 190 * )
 191     AC_MSG_ERROR([$host_os operating systems are currently not supported.])
 192     ;;
 193 esac
 194
 195
 196 dnl Set optimization and debugging for all architectures and systems.
 197 dnl NOTE: Setting the CFLAGS/CXXFLAGS only works before calling AC_PROG_CC/AC_PROG_CXX.
 198 if test x"$CFLAGS" = "x"; then
 199     OPT_CFLAGS="-g -O0"
 200 else
 201     OPT_CFLAGS=$CFLAGS
 202 fi
 203
 204 if test x"$CXXFLAGS" = "x"; then
 205     OPT_CXXFLAGS="-g -O0"
 206 else
 207     OPT_CXXFLAGS=$CXXFLAGS
 208 fi
 209
 210 dnl Check for compiler.
 211 AC_PROG_CC
 212 AC_PROG_CXX
 213
 214 dnl Check compiler vendor.
 215 AX_COMPILER_VENDOR
 216
 217 dnl Set compiler flags depending on the compiler vendor.
 218 case "$ax_cv_c_compiler_vendor" in
 219 gnu )
 220     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long $CC_FLAGS"
 221     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long $CXX_FLAGS"
 222     ;;
 223
 224 sgi )
 225     CC_FLAGS="-c99 $CC_FLAGS"
 226     CXX_FLAGS="$CXX_FLAGS"
 227     ;;
 228
 229 sun )
 230     CC_FLAGS="-xc99 $CC_FLAGS"
 231     CXX_FLAGS="$CXX_FLAGS"
 232     ;;
 233
 234 * )
 235     AC_MSG_ERROR([$ax_cv_c_compiler_vendor compilers are currently not supported.])
 236     ;;
 237 esac
 238
 239 dnl Temporary set the CFLAGS for configure tests (e.g. inline keyword)
 240 dnl we set it properly at the end of this file.
 241 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 242 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 243
 244 dnl set interpreter flags
 245 AC_SUBST(INTRP_CFLAGS)
 246
 247 dnl define and substitute some architecture specific variables
 248 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 249 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 250 AC_SUBST(ARCH_DIR)
 251 AC_SUBST(JAVA_ARCH)
 252 AC_SUBST(OS_DIR)
 253 AC_SUBST(USE_SCHEDULER)
 254
 255 dnl Checks for programs.
 256 AM_PROG_AS
 257 AC_PROG_LD
 258 AC_PROG_LD_GNU
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AM_PROG_MKDIR_P
 262
 263 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 264
 265 dnl Checks for header files.
 266 AC_HEADER_DIRENT
 267 AC_HEADER_STDC
 268
 269 dnl Crucial header files.
 270 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 271 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 272
 273 dnl keep them alpha-sorted!
 274 AC_CHECK_HEADERS([assert.h])
 275 AC_CHECK_HEADERS([errno.h])
 276 AC_CHECK_HEADERS([execinfo.h])
 277 AC_CHECK_HEADERS([fcntl.h])
 278 AC_CHECK_HEADERS([libgen.h])
 279 AC_CHECK_HEADERS([netdb.h])
 280 AC_CHECK_HEADERS([signal.h])
 281 AC_CHECK_HEADERS([stdarg.h])
 282 AC_CHECK_HEADERS([stdint.h])
 283 AC_CHECK_HEADERS([stdio.h])
 284 AC_CHECK_HEADERS([stdlib.h])
 285 AC_CHECK_HEADERS([string.h])
 286 AC_CHECK_HEADERS([time.h])
 287 AC_CHECK_HEADERS([ucontext.h])
 288 AC_CHECK_HEADERS([unistd.h])
 289 AC_CHECK_HEADERS([sys/ioctl.h])
 290 AC_CHECK_HEADERS([sys/mman.h])
 291 AC_CHECK_HEADERS([sys/resource.h])
 292 AC_CHECK_HEADERS([sys/select.h])
 293 AC_CHECK_HEADERS([sys/socket.h])
 294 AC_CHECK_HEADERS([sys/stat.h])
 295 AC_CHECK_HEADERS([sys/time.h])
 296 AC_CHECK_HEADERS([sys/types.h])
 297
 298 dnl Checks for typedefs, structures, and compiler characteristics.
 299 AC_C_CONST
 300 AC_C_INLINE
 301 AC_C_ATTRIBUTE
 302 AC_TYPE_OFF_T
 303 AC_TYPE_SIZE_T
 304 AC_HEADER_TIME
 305 AC_STRUCT_TM
 306
 307 dnl Checks for libraries (NOTE: Should be done before function checks,
 308 dnl as some functions may be in libraries we check for).
 309 case "${OS_DIR}" in
 310     solaris )
 311          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 312          ;;
 313 esac
 314
 315 dnl Checks for library functions.
 316 AC_PROG_GCC_TRADITIONAL
 317 AC_TYPE_SIGNAL
 318 AC_FUNC_MEMCMP
 319 AC_FUNC_MMAP
 320
 321 dnl keep them alpha-sorted!
 322 AC_CHECK_FUNCS([abort])
 323 AC_CHECK_FUNCS([accept])
 324 AC_CHECK_FUNCS([access])
 325 AC_CHECK_FUNCS([atoi])
 326 AC_CHECK_FUNCS([atol])
 327 AC_CHECK_FUNCS([backtrace])
 328 AC_CHECK_FUNCS([backtrace_symbols])
 329 AC_CHECK_FUNCS([calloc])
 330 AC_CHECK_FUNCS([close])
 331 AC_CHECK_FUNCS([confstr])
 332 AC_CHECK_FUNCS([connect])
 333 AC_CHECK_FUNCS([dirname])
 334 AC_CHECK_FUNCS([fclose])
 335 AC_CHECK_FUNCS([fflush])
 336 AC_CHECK_FUNCS([fopen])
 337 AC_CHECK_FUNCS([fprintf])
 338 AC_CHECK_FUNCS([fread])
 339 AC_CHECK_FUNCS([free])
 340 AC_CHECK_FUNCS([fstat])
 341 AC_CHECK_FUNCS([fsync])
 342 AC_CHECK_FUNCS([ftruncate])
 343 AC_CHECK_FUNCS([getcwd])
 344 AC_CHECK_FUNCS([getenv])
 345 AC_CHECK_FUNCS([gethostbyname])
 346 AC_CHECK_FUNCS([gethostname])
 347 AC_CHECK_FUNCS([getloadavg])
 348 AC_CHECK_FUNCS([getpagesize])
 349 AC_CHECK_FUNCS([getrusage])
 350 AC_CHECK_FUNCS([getsockname])
 351 AC_CHECK_FUNCS([getsockopt])
 352 AC_CHECK_FUNCS([gettimeofday])
 353 AC_CHECK_FUNCS([htons])
 354 AC_CHECK_FUNCS([ioctl])
 355 AC_CHECK_FUNCS([isnan])
 356 AC_CHECK_FUNCS([listen])
 357 AC_CHECK_FUNCS([localtime])
 358 AC_CHECK_FUNCS([localtime_r])
 359 AC_CHECK_FUNCS([lseek])
 360 AC_CHECK_FUNCS([malloc])
 361 AC_CHECK_FUNCS([memcpy])
 362 AC_CHECK_FUNCS([memset])
 363 AC_CHECK_FUNCS([mmap])
 364 AC_CHECK_FUNCS([mprotect])
 365 AC_CHECK_FUNCS([open])
 366 AC_CHECK_FUNCS([printf])
 367 AC_CHECK_FUNCS([read])
 368 AC_CHECK_FUNCS([readlink])
 369 AC_CHECK_FUNCS([realloc])
 370 AC_CHECK_FUNCS([recv])
 371 AC_CHECK_FUNCS([scandir])
 372 AC_CHECK_FUNCS([select])
 373 AC_CHECK_FUNCS([send])
 374 AC_CHECK_FUNCS([setsockopt])
 375 AC_CHECK_FUNCS([shutdown])
 376 AC_CHECK_FUNCS([socket])
 377 AC_CHECK_FUNCS([stat])
 378 AC_CHECK_FUNCS([str2sig])
 379 AC_CHECK_FUNCS([strcat])
 380 AC_CHECK_FUNCS([strchr])
 381 AC_CHECK_FUNCS([strcpy])
 382 AC_CHECK_FUNCS([strcmp])
 383 AC_CHECK_FUNCS([strdup])
 384 AC_CHECK_FUNCS([strerror])
 385 AC_CHECK_FUNCS([strlen])
 386 AC_CHECK_FUNCS([strncmp])
 387 AC_CHECK_FUNCS([strstr])
 388 AC_CHECK_FUNCS([time])
 389 AC_CHECK_FUNCS([write])
 390
 391
 392 dnl Checks for libraries.
 393
 394 dnl Checking sizeof void *
 395 AC_CHECK_SIZEOF(void *)
 396 AC_C_BIGENDIAN
 397
 398
 399 dnl define install prefix
 400 if test "x$prefix" = "xNONE"; then
 401     CACAO_PREFIX=$ac_default_prefix
 402 else
 403     CACAO_PREFIX=$prefix
 404 fi
 405 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 406 AC_SUBST(CACAO_PREFIX)
 407
 408 dnl define libdir prefix
 409 if test "x$libdir" = "xNONE"; then
 410     CACAO_LIBDIR=$ac_default_libdir
 411 else
 412     CACAO_LIBDIR=$libdir
 413 fi
 414 dnl expand CACAO_LIBDIR to something that is usable in C code
 415 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 416 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 417 AC_SUBST(CACAO_LIBDIR)
 418
 419
 420 AC_CHECK_ENABLE_DL
 421 AC_CHECK_ENABLE_JAVA
 422
 423 AC_CHECK_ENABLE_JIT
 424 AC_CHECK_ENABLE_INTRP
 425
 426 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 427     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 428 fi
 429
 430 AC_CHECK_SOFTFLOAT
 431 AC_CHECK_SOFT_FLOAT_CMP
 432 AC_CHECK_SOFT_DOUBLE_CMP
 433
 434 AC_CHECK_ENABLE_GC
 435 AC_CHECK_ENABLE_DEBUG
 436 AC_CHECK_ENABLE_DUMP
 437 AC_CHECK_ENABLE_MEMCHECK
 438 AC_CHECK_ENABLE_HANDLES
 439 AC_CHECK_ENABLE_VMLOG
 440 AC_CHECK_ENABLE_DISASSEMBLER
 441 AC_CHECK_ENABLE_STATISTICS
 442 AC_CHECK_ENABLE_VERIFIER
 443 AC_CHECK_ENABLE_RT_TIMING
 444 AC_CHECK_ENABLE_CYCLE_STATS
 445 AC_CHECK_ENABLE_JVMTI
 446 AC_CHECK_ENABLE_THREADS
 447 if test x"${ENABLE_THREADS}" != "xno"; then
 448     AC_CHECK_USE___THREAD
 449 fi
 450 AC_CHECK_ENABLE_IFCONV
 451 AC_CHECK_ENABLE_INLINING
 452 AC_CHECK_ENABLE_INLINING_DEBUG
 453 AC_CHECK_ENABLE_REPLACEMENT
 454
 455 dnl check for loop optimization
 456 AC_MSG_CHECKING(whether loop optimization should be supported)
 457 AC_ARG_ENABLE([loop],
 458               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 459               [case "${enableval}" in
 460                    yes) ENABLE_LOOP=yes;;
 461                    *) ENABLE_LOOP=no;;
 462                esac],
 463               [ENABLE_LOOP=no])
 464 AC_MSG_RESULT(${ENABLE_LOOP})
 465 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 466
 467 if test x"${ENABLE_LOOP}" = "xyes"; then
 468     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 469 fi
 470
 471
 472 dnl check if linear scan register allocator(lsra) with SSA should be used
 473 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 474 AC_ARG_ENABLE([ssa],
 475               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 476               [case "${enableval}" in
 477                    no) ENABLE_SSA=no;;
 478                    *) ENABLE_SSA=yes;;
 479                esac],
 480               [ENABLE_SSA=no])
 481 AC_MSG_RESULT(${ENABLE_SSA})
 482 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 483 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 484 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 485 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 486
 487 if test x"${ENABLE_SSA}" = "xyes"; then
 488     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 489     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 490     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 491     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 492     ENABLE_LSRA="no"
 493 fi
 494
 495
 496 dnl check if linear scan register allocator(lsra) should be used
 497 AC_MSG_CHECKING(whether lsra should be supported)
 498 AC_ARG_ENABLE([lsra],
 499               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 500               [case "${enableval}" in
 501                    yes) ENABLE_LSRA=yes;;
 502                    *) ENABLE_LSRA=no;;
 503                esac],
 504               [ENABLE_LSRA=no])
 505
 506 if test x"${ENABLE_LSRA}" = "xyes"; then
 507     if test x"${ENABLE_SSA}" = "xyes"; then
 508         ENABLE_LSRA="no"
 509     fi
 510 fi
 511 AC_MSG_RESULT(${ENABLE_LSRA})
 512 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 513
 514 if test x"${ENABLE_LSRA}" = "xyes"; then
 515     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 516 fi
 517
 518 dnl check if profiling should be supported
 519 AC_MSG_CHECKING(whether profiling should be supported)
 520 AC_ARG_ENABLE([profiling],
 521               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 522               [case "${enableval}" in
 523                    yes) ENABLE_PROFILING=yes;;
 524                    *) ENABLE_PROFILING=no;;
 525                esac],
 526               [ENABLE_PROFILING=no])
 527 AC_MSG_RESULT(${ENABLE_PROFILING})
 528 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 529
 530 if test x"${ENABLE_PROFILING}" = "xyes"; then
 531     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 532 fi
 533
 534
 535 dnl check for instruction scheduler
 536 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 537
 538 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 539 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 540         case "${ARCH_DIR}" in
 541                 xdspcore )
 542                         ;;
 543                 * )
 544                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 545                         ;;
 546         esac
 547
 548         AC_MSG_RESULT(yes)
 549         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 550         AM_CONDITIONAL([USE_SCHEDULER], [true])
 551 else
 552         AC_MSG_RESULT(no)
 553         AM_CONDITIONAL([USE_SCHEDULER], [false])
 554 fi
 555
 556 AC_CHECK_ENABLE_OPAGENT
 557
 558 AC_CHECK_ENABLE_ZLIB
 559
 560 dnl check for stuff to be built
 561 AC_CHECK_ENABLE_JNI
 562 AC_CHECK_ENABLE_LIBJVM
 563
 564 dnl ATTENTION: These check must be after setting
 565 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 566 dnl because libtool uses them to build the correct libraries.
 567 AC_LIBTOOL_DLOPEN
 568 AC_PROG_LIBTOOL
 569
 570 AC_CHECK_ENABLE_STATICVM
 571 AC_CHECK_ENABLE_ANNOTATIONS
 572 AC_CHECK_ENABLE_ASSERTION
 573
 574 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 575 AC_CHECK_WITH_VM_ZIP
 576
 577 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 578
 579 dnl Now we check for jre-layout so we can skip some checks that are
 580 dnl not required.
 581 AC_CHECK_ENABLE_JRE_LAYOUT
 582
 583 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 584 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 585 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 586
 587 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 588    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 589 fi
 590
 591 dnl The check for jni_md.h must be before jni.h.
 592 AC_CHECK_WITH_JNI_MD_H
 593 AC_CHECK_WITH_JNI_H
 594
 595 dnl JVM, HPI, and JMM is only required for OpenJDK.
 596 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 597     openjdk)
 598         AC_CHECK_WITH_JVM_MD_H
 599         AC_CHECK_WITH_JVM_H
 600         AC_CHECK_WITH_HPI_MD_H
 601         AC_CHECK_WITH_HPI_H
 602         AC_CHECK_WITH_JMM_H
 603         ;;
 604     *)
 605         ;;
 606 esac
 607
 608 dnl check for some programs we need
 609
 610 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 611     cldc1.1 | gnuclasspath)
 612         AC_PROG_JAVAC
 613         AC_PROG_JAR
 614         ;;
 615     openjdk)
 616         ;;
 617     *)
 618         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 619         ;;
 620 esac
 621
 622 AC_CHECK_WITH_JASMIN_JAR
 623 AC_CHECK_WITH_JUNIT_JAR
 624
 625 AC_CHECK_HEADERS(
 626         [regex.h],
 627         [
 628                 dnl If debug build and regex.h available, enable debug filter
 629                 if test x"${NDEBUG}" = "xno"; then
 630                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 631                 fi
 632                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 633                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 634         ],
 635         [
 636                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 637         ]
 638 )
 639
 640 dnl python
 641
 642 AZ_PYTHON_DEFAULT
 643 AZ_PYTHON_ENABLE
 644 AZ_PYTHON_WITH
 645 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 646 AZ_PYTHON_CSPEC
 647 AZ_PYTHON_LSPEC
 648
 649
 650 dnl define some stuff required for --fullversion
 651 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 652 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 653 AC_DEFINE_UNQUOTED(VERSION_CXX, "$CXX", [CXX used])
 654 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CC_FLAGS $CPPFLAGS", [CFLAGS used])
 655 AC_DEFINE_UNQUOTED(VERSION_CXXFLAGS, "$OPT_CXXFLAGS $ARCH_CXXFLAGS $CXX_FLAGS $CPPFLAGS", [CXXFLAGS used])
 656
 657
 658 dnl Finally pass flags to Makefiles.
 659 CFLAGS="$OPT_CFLAGS"
 660 CXXFLAGS="$OPT_CXXFLAGS"
 661
 662 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 663 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 664 AM_CPPFLAGS="$CPPFLAGS"
 665
 666 AC_SUBST(AM_CFLAGS)
 667 AC_SUBST(AM_CXXFLAGS)
 668 AC_SUBST(AM_CPPFLAGS)
 669
 670
 671 AC_CONFIG_FILES([Makefile]
 672                 [contrib/Makefile]
 673                 [contrib/setenvinstalled]
 674                 [contrib/setenvsource]
 675                 [contrib/vmlog/Makefile]
 676                 [contrib/vmlog/t/Makefile]
 677                 [doc/Makefile]
 678                 [doc/doxygen/Makefile]
 679                 [doc/handbook/Makefile]
 680                 [man/Makefile]
 681                 [src/Makefile]
 682                 [src/cacao/Makefile]
 683                 [src/classes/Makefile]
 684                 [src/fdlibm/Makefile]
 685                 [src/mm/Makefile]
 686                 [src/mm/cacao-gc/Makefile]
 687                 [src/native/Makefile]
 688                 [src/native/include/Makefile]
 689                 [src/native/jvmti/Makefile]
 690                 [src/native/vm/Makefile]
 691                 [src/native/vm/cldc1.1/Makefile]
 692                 [src/native/vm/gnuclasspath/Makefile]
 693                 [src/native/vm/openjdk/Makefile]
 694                 [src/scripts/Makefile]
 695                 [src/scripts/java]
 696                 [src/threads/Makefile]
 697                 [src/threads/none/Makefile]
 698                 [src/threads/posix/Makefile]
 699                 [src/toolbox/Makefile]
 700                 [src/vm/Makefile]
 701                 [src/vm/jit/Makefile]
 702                 [src/vm/jit/allocator/Makefile]
 703                 [src/vm/jit/alpha/Makefile]
 704                 [src/vm/jit/alpha/freebsd/Makefile]
 705                 [src/vm/jit/alpha/linux/Makefile]
 706                 [src/vm/jit/arm/Makefile]
 707                 [src/vm/jit/arm/linux/Makefile]
 708                 [src/vm/jit/i386/Makefile]
 709                 [src/vm/jit/i386/cygwin/Makefile]
 710                 [src/vm/jit/i386/darwin/Makefile]
 711                 [src/vm/jit/i386/freebsd/Makefile]
 712                 [src/vm/jit/i386/linux/Makefile]
 713                 [src/vm/jit/i386/solaris/Makefile]
 714                 [src/vm/jit/intrp/Makefile]
 715                 [src/vm/jit/inline/Makefile]
 716                 [src/vm/jit/ir/Makefile]
 717                 [src/vm/jit/loop/Makefile]
 718                 [src/vm/jit/m68k/Makefile]
 719                 [src/vm/jit/m68k/linux/Makefile]
 720                 [src/vm/jit/mips/Makefile]
 721                 [src/vm/jit/mips/irix/Makefile]
 722                 [src/vm/jit/mips/linux/Makefile]
 723                 [src/vm/jit/mips/uclinux/Makefile]
 724                 [src/vm/jit/optimizing/Makefile]
 725                 [src/vm/jit/parisc/Makefile]
 726                 [src/vm/jit/parisc/linux/Makefile]
 727                 [src/vm/jit/powerpc/Makefile]
 728                 [src/vm/jit/powerpc/darwin/Makefile]
 729                 [src/vm/jit/powerpc/linux/Makefile]
 730                 [src/vm/jit/powerpc/netbsd/Makefile]
 731                 [src/vm/jit/powerpc64/Makefile]
 732                 [src/vm/jit/powerpc64/linux/Makefile]
 733                 [src/vm/jit/s390/Makefile]
 734                 [src/vm/jit/schedule/Makefile]
 735                 [src/vm/jit/sparc64/Makefile]
 736                 [src/vm/jit/sparc64/linux/Makefile]
 737                 [src/vm/jit/sparc64/solaris/Makefile]
 738                 [src/vm/jit/verify/Makefile]
 739                 [src/vm/jit/x86_64/Makefile]
 740                 [src/vm/jit/x86_64/freebsd/Makefile]
 741                 [src/vm/jit/x86_64/linux/Makefile]
 742                 [src/vm/jit/x86_64/solaris/Makefile]
 743                 [tests/Makefile]
 744                 [tests/regression/Makefile]
 745                 [tests/regression/assertion/Makefile]
 746                 [tests/regression/base/Makefile]
 747                 [tests/regression/bugzilla/Makefile]
 748                 [tests/regression/jasmin/Makefile]
 749                 [tests/regression/native/Makefile]
 750                 [tests/regression/resolving/Makefile]
 751                 [tests/regression/resolving/classes1/Makefile]
 752                 [tests/regression/resolving/classes2/Makefile]
 753                 [tests/regression/resolving/classes3/Makefile]
 754 )
 755
 756
 757 dnl We only build the shared library objects but we use it as
 758 dnl noinst_LTLIBRARIES.
 759 ac_configure_args="$ac_configure_args --disable-static"
 760 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 761
 762
 763 AC_OUTPUT
 764
 765
 766 ## Local variables:
 767 ## mode: m4
 768 ## indent-tabs-mode: t
 769 ## c-basic-offset: 4
 770 ## tab-width: 8
 771 ## compile-command: "automake --add-missing"
 772 ## End: