configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl Set optimization and debugging for all architectures and systems.
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-g -O0"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 if test x"$CXXFLAGS" = "x"; then
  46     OPT_CXXFLAGS="-g -O0"
  47 else
  48     OPT_CXXFLAGS=$CXXFLAGS
  49 fi
  50
  51 dnl system type
  52 case "$host_cpu" in
  53 alpha | alphaev56 | alphapca56 )
  54     ARCH_DIR="alpha"
  55     ARCH_FLAGS="-mieee -D__ALPHA__"
  56     JAVA_ARCH="alpha"
  57     ;;
  58
  59 arm | armv4 | armv4tl | armv5b | armv5l | armv5tel | armv5tejl )
  60     ARCH_DIR="arm"
  61     ARCH_FLAGS="-D__ARM__"
  62     JAVA_ARCH="arm"
  63     ;;
  64
  65 hppa2.0 )
  66     ARCH_DIR="parisc"
  67     ARCH_FLAGS="-D__PARISC__"
  68     JAVA_ARCH="hppa"
  69     ;;
  70
  71 i386 | i486 | i586 | i686 )
  72     ARCH_DIR="i386"
  73     ARCH_FLAGS="-m32 -D__I386__"
  74     JAVA_ARCH="i386"
  75     ;;
  76
  77 m68k )
  78     ARCH_DIR="m68k"
  79     ARCH_FLAGS="-D__M68K__"
  80     JAVA_ARCH="m68k"
  81     ;;
  82
  83 mips | mipsel )
  84     ARCH_DIR="mips"
  85     ARCH_FLAGS="-D__MIPS__"
  86     dnl Is this correct for mipsel?
  87     JAVA_ARCH="mips"
  88     ;;
  89
  90 powerpc )
  91     ARCH_DIR="powerpc"
  92     ARCH_FLAGS="-m32 -D__POWERPC__"
  93     JAVA_ARCH="ppc"
  94     ;;
  95
  96 powerpc64 )
  97     ARCH_DIR="powerpc64"
  98     ARCH_FLAGS="-m64 -D__POWERPC64__"
  99     JAVA_ARCH="ppc64"
 100     ;;
 101
 102 s390 )
 103     ARCH_DIR="s390"
 104     ARCH_FLAGS="-D__S390__"
 105     JAVA_ARCH="s390"
 106     ;;
 107
 108 sparc | sparc64 )
 109     ARCH_DIR="sparc64"
 110     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 111     dnl Is this correct for 64-bits?
 112     JAVA_ARCH="sparc"
 113     ;;
 114
 115 x86_64 )
 116     ARCH_DIR="x86_64"
 117     ARCH_FLAGS="-m64 -D__X86_64__"
 118     JAVA_ARCH="amd64"
 119     ;;
 120
 121 xdspcore )
 122     ARCH_DIR="xdspcore"
 123     ENABLE_STATICVM="yes"
 124     ARCH_FLAGS="-D__XDSPCORE__"
 125     USE_SCHEDULER="1"
 126     ;;
 127
 128 * )
 129     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 130     ;;
 131 esac
 132
 133 dnl host type
 134 case "$host_os" in
 135 *cygwin* )
 136     OS_DIR="cygwin"
 137     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 138     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 139     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 140     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 141     ;;
 142
 143 *darwin* )
 144     OS_DIR="darwin"
 145     OS_FLAGS="-D__DARWIN__"
 146     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 147     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 148     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 149     ;;
 150
 151 dnl Must be BEFORE *freebsd*.
 152 *kfreebsd*-gnu)
 153     OS_DIR="freebsd"
 154     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 156     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 157     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 *freebsd* )
 161     OS_DIR="freebsd"
 162     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 163     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 164     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 165     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 166     ;;
 167
 168 *irix* )
 169     OS_DIR="irix"
 170     OS_FLAGS="-D__IRIX__"
 171     CC_FLAGS=""
 172     CXX_FLAGS=""
 173     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 174     ;;
 175
 176 dnl Must be BEFORE *linux*.
 177 *uclinux | *elf )
 178     OS_DIR="uclinux"
 179     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 180     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 181     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 182     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 183     ;;
 184
 185 *linux* | *Linux* )
 186     OS_DIR="linux"
 187     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 188     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 189     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 190     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 191     ;;
 192
 193 *netbsd* )
 194     OS_DIR="netbsd"
 195     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 196     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 197     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 198     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 199     ;;
 200
 201 *solaris* )
 202     OS_DIR="solaris"
 203     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 204     dnl not set when cpp is called with -std=c99, therefore we add them
 205     dnl here.
 206     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 207     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE=600"
 208     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 209     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 210     ;;
 211
 212 * )
 213     ;;
 214 esac
 215
 216
 217 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 218 dnl we set it properly at the end of this file
 219 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 220 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 221
 222 dnl set interpreter flags
 223 AC_SUBST(INTRP_CFLAGS)
 224
 225 dnl define and substitute some architecture specific variables
 226 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 227 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 228 AC_SUBST(ARCH_DIR)
 229 AC_SUBST(JAVA_ARCH)
 230 AC_SUBST(OS_DIR)
 231 AC_SUBST(USE_SCHEDULER)
 232
 233
 234 dnl Checks for programs.
 235 AC_PROG_CC
 236 AC_PROG_CXX
 237 AM_PROG_AS
 238 AC_PROG_LD
 239 AC_PROG_LD_GNU
 240 AC_PROG_LN_S
 241 AC_PROG_MAKE_SET
 242 AM_PROG_MKDIR_P
 243
 244 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 245
 246 dnl Checks for header files.
 247 AC_HEADER_DIRENT
 248 AC_HEADER_STDC
 249
 250 dnl Crucial header files.
 251 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 252 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 253
 254 dnl keep them alpha-sorted!
 255 AC_CHECK_HEADERS([assert.h])
 256 AC_CHECK_HEADERS([errno.h])
 257 AC_CHECK_HEADERS([execinfo.h])
 258 AC_CHECK_HEADERS([fcntl.h])
 259 AC_CHECK_HEADERS([libgen.h])
 260 AC_CHECK_HEADERS([netdb.h])
 261 AC_CHECK_HEADERS([signal.h])
 262 AC_CHECK_HEADERS([stdint.h])
 263 AC_CHECK_HEADERS([stdio.h])
 264 AC_CHECK_HEADERS([stdlib.h])
 265 AC_CHECK_HEADERS([string.h])
 266 AC_CHECK_HEADERS([time.h])
 267 AC_CHECK_HEADERS([ucontext.h])
 268 AC_CHECK_HEADERS([unistd.h])
 269 AC_CHECK_HEADERS([sys/ioctl.h])
 270 AC_CHECK_HEADERS([sys/mman.h])
 271 AC_CHECK_HEADERS([sys/resource.h])
 272 AC_CHECK_HEADERS([sys/select.h])
 273 AC_CHECK_HEADERS([sys/socket.h])
 274 AC_CHECK_HEADERS([sys/stat.h])
 275 AC_CHECK_HEADERS([sys/time.h])
 276 AC_CHECK_HEADERS([sys/types.h])
 277
 278 dnl Checks for typedefs, structures, and compiler characteristics.
 279 AC_C_CONST
 280 AC_C_INLINE
 281 AC_C_ATTRIBUTE
 282 AC_TYPE_OFF_T
 283 AC_TYPE_SIZE_T
 284 AC_HEADER_TIME
 285 AC_STRUCT_TM
 286
 287 dnl Checks for libraries (NOTE: Should be done before function checks,
 288 dnl as some functions may be in libraries we check for).
 289
 290 case "${OS_DIR}" in
 291     solaris )
 292          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 293          ;;
 294 esac
 295
 296 dnl Checks for library functions.
 297 AC_PROG_GCC_TRADITIONAL
 298 AC_TYPE_SIGNAL
 299 AC_FUNC_MEMCMP
 300 AC_FUNC_MMAP
 301
 302 dnl keep them alpha-sorted!
 303 AC_CHECK_FUNCS([abort])
 304 AC_CHECK_FUNCS([accept])
 305 AC_CHECK_FUNCS([access])
 306 AC_CHECK_FUNCS([atoi])
 307 AC_CHECK_FUNCS([atol])
 308 AC_CHECK_FUNCS([backtrace])
 309 AC_CHECK_FUNCS([backtrace_symbols])
 310 AC_CHECK_FUNCS([calloc])
 311 AC_CHECK_FUNCS([close])
 312 AC_CHECK_FUNCS([confstr])
 313 AC_CHECK_FUNCS([connect])
 314 AC_CHECK_FUNCS([dirname])
 315 AC_CHECK_FUNCS([fclose])
 316 AC_CHECK_FUNCS([fflush])
 317 AC_CHECK_FUNCS([fopen])
 318 AC_CHECK_FUNCS([fprintf])
 319 AC_CHECK_FUNCS([fread])
 320 AC_CHECK_FUNCS([free])
 321 AC_CHECK_FUNCS([fstat])
 322 AC_CHECK_FUNCS([fsync])
 323 AC_CHECK_FUNCS([ftruncate])
 324 AC_CHECK_FUNCS([getcwd])
 325 AC_CHECK_FUNCS([getenv])
 326 AC_CHECK_FUNCS([gethostbyname])
 327 AC_CHECK_FUNCS([gethostname])
 328 AC_CHECK_FUNCS([getpagesize])
 329 AC_CHECK_FUNCS([getrusage])
 330 AC_CHECK_FUNCS([getsockname])
 331 AC_CHECK_FUNCS([getsockopt])
 332 AC_CHECK_FUNCS([gettimeofday])
 333 AC_CHECK_FUNCS([htons])
 334 AC_CHECK_FUNCS([ioctl])
 335 AC_CHECK_FUNCS([isnan])
 336 AC_CHECK_FUNCS([listen])
 337 AC_CHECK_FUNCS([localtime])
 338 AC_CHECK_FUNCS([localtime_r])
 339 AC_CHECK_FUNCS([lseek])
 340 AC_CHECK_FUNCS([malloc])
 341 AC_CHECK_FUNCS([memcpy])
 342 AC_CHECK_FUNCS([memset])
 343 AC_CHECK_FUNCS([mmap])
 344 AC_CHECK_FUNCS([mprotect])
 345 AC_CHECK_FUNCS([open])
 346 AC_CHECK_FUNCS([read])
 347 AC_CHECK_FUNCS([readlink])
 348 AC_CHECK_FUNCS([realloc])
 349 AC_CHECK_FUNCS([recv])
 350 AC_CHECK_FUNCS([scandir])
 351 AC_CHECK_FUNCS([select])
 352 AC_CHECK_FUNCS([send])
 353 AC_CHECK_FUNCS([setsockopt])
 354 AC_CHECK_FUNCS([shutdown])
 355 AC_CHECK_FUNCS([socket])
 356 AC_CHECK_FUNCS([stat])
 357 AC_CHECK_FUNCS([str2sig])
 358 AC_CHECK_FUNCS([strcat])
 359 AC_CHECK_FUNCS([strchr])
 360 AC_CHECK_FUNCS([strcpy])
 361 AC_CHECK_FUNCS([strcmp])
 362 AC_CHECK_FUNCS([strdup])
 363 AC_CHECK_FUNCS([strerror])
 364 AC_CHECK_FUNCS([strlen])
 365 AC_CHECK_FUNCS([strncmp])
 366 AC_CHECK_FUNCS([strstr])
 367 AC_CHECK_FUNCS([time])
 368 AC_CHECK_FUNCS([write])
 369
 370
 371 dnl Checks for libraries.
 372
 373 dnl Checking sizeof void *
 374 AC_CHECK_SIZEOF(void *)
 375 AC_C_BIGENDIAN
 376
 377
 378 dnl define install prefix
 379 if test "x$prefix" = "xNONE"; then
 380     CACAO_PREFIX=$ac_default_prefix
 381 else
 382     CACAO_PREFIX=$prefix
 383 fi
 384 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 385 AC_SUBST(CACAO_PREFIX)
 386
 387 dnl define libdir prefix
 388 if test "x$libdir" = "xNONE"; then
 389     CACAO_LIBDIR=$ac_default_libdir
 390 else
 391     CACAO_LIBDIR=$libdir
 392 fi
 393 dnl expand CACAO_LIBDIR to something that is usable in C code
 394 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 395 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 396 AC_SUBST(CACAO_LIBDIR)
 397
 398
 399 AC_CHECK_ENABLE_DL
 400 AC_CHECK_ENABLE_JAVA
 401
 402 AC_CHECK_ENABLE_JIT
 403 AC_CHECK_ENABLE_INTRP
 404
 405 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 406     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 407 fi
 408
 409 AC_CHECK_SOFTFLOAT
 410 AC_CHECK_SOFT_FLOAT_CMP
 411 AC_CHECK_SOFT_DOUBLE_CMP
 412
 413 AC_CHECK_ENABLE_GC
 414 AC_CHECK_ENABLE_DEBUG
 415 AC_CHECK_ENABLE_DUMP
 416 AC_CHECK_ENABLE_MEMCHECK
 417 AC_CHECK_ENABLE_HANDLES
 418 AC_CHECK_ENABLE_VMLOG
 419 AC_CHECK_ENABLE_DISASSEMBLER
 420 AC_CHECK_ENABLE_STATISTICS
 421 AC_CHECK_ENABLE_VERIFIER
 422 AC_CHECK_ENABLE_RT_TIMING
 423 AC_CHECK_ENABLE_CYCLE_STATS
 424 AC_CHECK_ENABLE_JVMTI
 425 AC_CHECK_ENABLE_THREADS
 426 AC_CHECK_ENABLE_IFCONV
 427 AC_CHECK_ENABLE_INLINING
 428 AC_CHECK_ENABLE_INLINING_DEBUG
 429 AC_CHECK_ENABLE_REPLACEMENT
 430
 431 dnl check for loop optimization
 432 AC_MSG_CHECKING(whether loop optimization should be supported)
 433 AC_ARG_ENABLE([loop],
 434               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 435               [case "${enableval}" in
 436                    yes) ENABLE_LOOP=yes;;
 437                    *) ENABLE_LOOP=no;;
 438                esac],
 439               [ENABLE_LOOP=no])
 440 AC_MSG_RESULT(${ENABLE_LOOP})
 441 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 442
 443 if test x"${ENABLE_LOOP}" = "xyes"; then
 444     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 445 fi
 446
 447
 448 dnl check if linear scan register allocator(lsra) with SSA should be used
 449 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 450 AC_ARG_ENABLE([ssa],
 451               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 452               [case "${enableval}" in
 453                    no) ENABLE_SSA=no;;
 454                    *) ENABLE_SSA=yes;;
 455                esac],
 456               [ENABLE_SSA=no])
 457 AC_MSG_RESULT(${ENABLE_SSA})
 458 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 459 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 460 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 461 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 462
 463 if test x"${ENABLE_SSA}" = "xyes"; then
 464     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 465     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 466     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 467     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 468     ENABLE_LSRA="no"
 469 fi
 470
 471
 472 dnl check if linear scan register allocator(lsra) should be used
 473 AC_MSG_CHECKING(whether lsra should be supported)
 474 AC_ARG_ENABLE([lsra],
 475               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 476               [case "${enableval}" in
 477                    yes) ENABLE_LSRA=yes;;
 478                    *) ENABLE_LSRA=no;;
 479                esac],
 480               [ENABLE_LSRA=no])
 481
 482 if test x"${ENABLE_LSRA}" = "xyes"; then
 483     if test x"${ENABLE_SSA}" = "xyes"; then
 484         ENABLE_LSRA="no"
 485     fi
 486 fi
 487 AC_MSG_RESULT(${ENABLE_LSRA})
 488 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 489
 490 if test x"${ENABLE_LSRA}" = "xyes"; then
 491     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 492 fi
 493
 494 dnl check if profiling should be supported
 495 AC_MSG_CHECKING(whether profiling should be supported)
 496 AC_ARG_ENABLE([profiling],
 497               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 498               [case "${enableval}" in
 499                    yes) ENABLE_PROFILING=yes;;
 500                    *) ENABLE_PROFILING=no;;
 501                esac],
 502               [ENABLE_PROFILING=no])
 503 AC_MSG_RESULT(${ENABLE_PROFILING})
 504 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 505
 506 if test x"${ENABLE_PROFILING}" = "xyes"; then
 507     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 508 fi
 509
 510
 511 dnl check for instruction scheduler
 512 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 513
 514 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 515 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 516         case "${ARCH_DIR}" in
 517                 xdspcore )
 518                         ;;
 519                 * )
 520                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 521                         ;;
 522         esac
 523
 524         AC_MSG_RESULT(yes)
 525         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 526         AM_CONDITIONAL([USE_SCHEDULER], [true])
 527 else
 528         AC_MSG_RESULT(no)
 529         AM_CONDITIONAL([USE_SCHEDULER], [false])
 530 fi
 531
 532 AC_CHECK_ENABLE_OPAGENT
 533
 534 AC_CHECK_ENABLE_ZLIB
 535
 536 dnl check for stuff to be built
 537 AC_CHECK_ENABLE_JNI
 538 AC_CHECK_ENABLE_LIBJVM
 539
 540 dnl ATTENTION: These check must be after setting
 541 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 542 dnl because libtool uses them to build the correct libraries.
 543 AC_LIBTOOL_DLOPEN
 544 AC_PROG_LIBTOOL
 545
 546 AC_CHECK_ENABLE_STATICVM
 547 AC_CHECK_ENABLE_ANNOTATIONS
 548 AC_CHECK_ENABLE_ASSERTION
 549
 550 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 551 AC_CHECK_WITH_VM_ZIP
 552
 553 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 554
 555 dnl Now we check for jre-layout so we can skip some checks that are
 556 dnl not required.
 557 AC_CHECK_ENABLE_JRE_LAYOUT
 558
 559 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 560 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 561 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 562
 563 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 564    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 565 fi
 566
 567 dnl The check for jni_md.h must be before jni.h.
 568 AC_CHECK_WITH_JNI_MD_H
 569 AC_CHECK_WITH_JNI_H
 570
 571 dnl HPI is only required for OpenJDK
 572 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 573     openjdk)
 574         AC_CHECK_WITH_HPI_MD_H
 575         AC_CHECK_WITH_HPI_H
 576         ;;
 577     *)
 578         ;;
 579 esac
 580
 581 dnl check for some programs we need
 582
 583 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 584     cldc1.1 | gnuclasspath)
 585         AC_PROG_JAVAC
 586         AC_PROG_JAR
 587         ;;
 588     openjdk)
 589         ;;
 590     *)
 591         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 592         ;;
 593 esac
 594
 595 AC_CHECK_WITH_JASMIN_JAR
 596 AC_CHECK_WITH_JUNIT_JAR
 597
 598 AC_CHECK_HEADERS(
 599         [regex.h],
 600         [
 601                 dnl If debug build and regex.h available, enable debug filter
 602                 if test x"${NDEBUG}" = "xno"; then
 603                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 604                 fi
 605                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 606                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 607         ],
 608         [
 609                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 610         ]
 611 )
 612
 613 dnl python
 614
 615 AZ_PYTHON_DEFAULT
 616 AZ_PYTHON_ENABLE
 617 AZ_PYTHON_WITH
 618 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 619 AZ_PYTHON_CSPEC
 620 AZ_PYTHON_LSPEC
 621
 622
 623 dnl define some stuff required for --fullversion
 624 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 625 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 626 AC_DEFINE_UNQUOTED(VERSION_CXX, "$CXX", [CXX used])
 627 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CC_FLAGS $CPPFLAGS", [CFLAGS used])
 628 AC_DEFINE_UNQUOTED(VERSION_CXXFLAGS, "$OPT_CXXFLAGS $ARCH_CXXFLAGS $CXX_FLAGS $CPPFLAGS", [CXXFLAGS used])
 629
 630
 631 dnl Finally pass flags to Makefiles.
 632 CFLAGS="$OPT_CFLAGS"
 633 CXXFLAGS="$OPT_CXXFLAGS"
 634
 635 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 636 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 637 AM_CPPFLAGS="$CPPFLAGS"
 638
 639 AC_SUBST(AM_CFLAGS)
 640 AC_SUBST(AM_CXXFLAGS)
 641 AC_SUBST(AM_CPPFLAGS)
 642
 643
 644 AC_CONFIG_FILES([Makefile]
 645                 [contrib/Makefile]
 646                 [contrib/setenvinstalled]
 647                 [contrib/setenvsource]
 648                 [contrib/vmlog/Makefile]
 649                 [contrib/vmlog/t/Makefile]
 650                 [doc/Makefile]
 651                 [doc/doxygen/Makefile]
 652                 [doc/handbook/Makefile]
 653                 [man/Makefile]
 654                 [src/Makefile]
 655                 [src/cacao/Makefile]
 656                 [src/classes/Makefile]
 657                 [src/fdlibm/Makefile]
 658                 [src/mm/Makefile]
 659                 [src/mm/cacao-gc/Makefile]
 660                 [src/native/Makefile]
 661                 [src/native/include/Makefile]
 662                 [src/native/jvmti/Makefile]
 663                 [src/native/vm/Makefile]
 664                 [src/native/vm/cldc1.1/Makefile]
 665                 [src/native/vm/gnuclasspath/Makefile]
 666                 [src/native/vm/openjdk/Makefile]
 667                 [src/scripts/Makefile]
 668                 [src/scripts/java]
 669                 [src/threads/Makefile]
 670                 [src/threads/none/Makefile]
 671                 [src/threads/posix/Makefile]
 672                 [src/toolbox/Makefile]
 673                 [src/vm/Makefile]
 674                 [src/vm/jit/Makefile]
 675                 [src/vm/jit/allocator/Makefile]
 676                 [src/vm/jit/alpha/Makefile]
 677                 [src/vm/jit/alpha/freebsd/Makefile]
 678                 [src/vm/jit/alpha/linux/Makefile]
 679                 [src/vm/jit/arm/Makefile]
 680                 [src/vm/jit/arm/linux/Makefile]
 681                 [src/vm/jit/i386/Makefile]
 682                 [src/vm/jit/i386/cygwin/Makefile]
 683                 [src/vm/jit/i386/darwin/Makefile]
 684                 [src/vm/jit/i386/freebsd/Makefile]
 685                 [src/vm/jit/i386/linux/Makefile]
 686                 [src/vm/jit/i386/solaris/Makefile]
 687                 [src/vm/jit/intrp/Makefile]
 688                 [src/vm/jit/inline/Makefile]
 689                 [src/vm/jit/ir/Makefile]
 690                 [src/vm/jit/loop/Makefile]
 691                 [src/vm/jit/m68k/Makefile]
 692                 [src/vm/jit/m68k/linux/Makefile]
 693                 [src/vm/jit/mips/Makefile]
 694                 [src/vm/jit/mips/irix/Makefile]
 695                 [src/vm/jit/mips/linux/Makefile]
 696                 [src/vm/jit/mips/uclinux/Makefile]
 697                 [src/vm/jit/optimizing/Makefile]
 698                 [src/vm/jit/parisc/Makefile]
 699                 [src/vm/jit/parisc/linux/Makefile]
 700                 [src/vm/jit/powerpc/Makefile]
 701                 [src/vm/jit/powerpc/darwin/Makefile]
 702                 [src/vm/jit/powerpc/linux/Makefile]
 703                 [src/vm/jit/powerpc/netbsd/Makefile]
 704                 [src/vm/jit/powerpc64/Makefile]
 705                 [src/vm/jit/powerpc64/linux/Makefile]
 706                 [src/vm/jit/s390/Makefile]
 707                 [src/vm/jit/schedule/Makefile]
 708                 [src/vm/jit/sparc64/Makefile]
 709                 [src/vm/jit/sparc64/linux/Makefile]
 710                 [src/vm/jit/sparc64/solaris/Makefile]
 711                 [src/vm/jit/verify/Makefile]
 712                 [src/vm/jit/x86_64/Makefile]
 713                 [src/vm/jit/x86_64/freebsd/Makefile]
 714                 [src/vm/jit/x86_64/linux/Makefile]
 715                 [src/vm/jit/x86_64/solaris/Makefile]
 716                 [tests/Makefile]
 717                 [tests/regression/Makefile]
 718                 [tests/regression/assertion/Makefile]
 719                 [tests/regression/base/Makefile]
 720                 [tests/regression/bugzilla/Makefile]
 721                 [tests/regression/jasmin/Makefile]
 722                 [tests/regression/native/Makefile]
 723                 [tests/regression/resolving/Makefile]
 724                 [tests/regression/resolving/classes1/Makefile]
 725                 [tests/regression/resolving/classes2/Makefile]
 726                 [tests/regression/resolving/classes3/Makefile]
 727 )
 728
 729
 730 dnl We only build the shared library objects but we use it as
 731 dnl noinst_LTLIBRARIES.
 732 ac_configure_args="$ac_configure_args --disable-static"
 733 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 734
 735
 736 AC_OUTPUT
 737
 738
 739 ## Local variables:
 740 ## mode: m4
 741 ## indent-tabs-mode: t
 742 ## c-basic-offset: 4
 743 ## tab-width: 8
 744 ## compile-command: "automake --add-missing"
 745 ## End: