configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 0.99rc5, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl set optimization and debugging for all architectures and systems
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-O0 -g3"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 dnl system type
  46 case "$host_cpu" in
  47 alpha | alphaev56 | alphapca56 )
  48     ARCH_DIR="alpha"
  49     ARCH_CFLAGS="-mieee -D__ALPHA__"
  50     JAVA_ARCH="alpha"
  51     ;;
  52
  53 arm | armv4 | armv4tl | armv5b | armv5l )
  54     ARCH_DIR="arm"
  55     ARCH_CFLAGS="-D__ARM__"
  56     JAVA_ARCH="arm"
  57     ;;
  58
  59 hppa2.0 )
  60     ARCH_DIR="parisc"
  61     ARCH_CFLAGS="-D__PARISC__"
  62     JAVA_ARCH="hppa"
  63     ;;
  64
  65 i386 | i486 | i586 | i686 )
  66     ARCH_DIR="i386"
  67     ARCH_CFLAGS="-D__I386__"
  68     JAVA_ARCH="i386"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     JAVA_ARCH="m68k"
  75     ;;
  76
  77 mips | mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_CFLAGS="-D__MIPS__"
  80     dnl Is this correct for mipsel?
  81     JAVA_ARCH="mips"
  82     ;;
  83
  84 powerpc )
  85     ARCH_DIR="powerpc"
  86     ARCH_CFLAGS="-D__POWERPC__"
  87     JAVA_ARCH="ppc"
  88     ;;
  89
  90 powerpc64 )
  91     ARCH_DIR="powerpc64"
  92     ARCH_CFLAGS="-D__POWERPC64__"
  93     JAVA_ARCH="ppc64"
  94     ;;
  95
  96 s390 )
  97     ARCH_DIR="s390"
  98     ARCH_CFLAGS="-D__S390__"
  99     JAVA_ARCH="s390"
 100     ;;
 101
 102 sparc | sparc64 )
 103     ARCH_DIR="sparc64"
 104     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 105     dnl Is this correct for 64-bits?
 106     JAVA_ARCH="sparc"
 107     ;;
 108
 109 x86_64 )
 110     ARCH_DIR="x86_64"
 111     ARCH_CFLAGS="-D__X86_64__"
 112     JAVA_ARCH="amd64"
 113     ;;
 114
 115 xdspcore )
 116     ARCH_DIR="xdspcore"
 117     ENABLE_STATICVM="yes"
 118     ARCH_CFLAGS="-D__XDSPCORE__"
 119     USE_SCHEDULER="1"
 120     ;;
 121
 122 * )
 123     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 124     ;;
 125 esac
 126
 127 dnl host type
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 132     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 138     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 139     ;;
 140
 141 *freebsd* )
 142     OS_DIR="freebsd"
 143     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 144     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 145     ;;
 146
 147 *irix* )
 148     OS_DIR="irix"
 149     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 150     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 151     ;;
 152
 153 *kfreebsd*-gnu)
 154     OS_DIR="freebsd"
 155     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 156     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 157     ;;
 158
 159 dnl must be before *linux*
 160 *uclinux | *elf )
 161     OS_DIR="uclinux"
 162     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 163     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     ;;
 165
 166 *linux* | *Linux* )
 167     OS_DIR="linux"
 168     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 169     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     ;;
 171
 172 *netbsd* )
 173     OS_DIR="netbsd"
 174     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 175     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     ;;
 177
 178 *solaris* )
 179     OS_DIR="solaris"
 180         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 181         dnl therefore we add them here
 182     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 183     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 184     ;;
 185
 186 * )
 187     ;;
 188 esac
 189
 190
 191 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 192 dnl we set it properly at the end of this file
 193 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 194
 195 dnl set interpreter flags
 196 AC_SUBST(INTRP_CFLAGS)
 197
 198 dnl define and substitute some architecture specific variables
 199 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 200 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 201 AC_SUBST(ARCH_DIR)
 202 AC_SUBST(OS_DIR)
 203 AC_SUBST(USE_SCHEDULER)
 204
 205
 206 dnl Checks for programs.
 207 AC_PROG_CC
 208 AM_PROG_AS
 209 AC_PROG_LD
 210 AC_PROG_LD_GNU
 211 AC_PROG_RANLIB
 212 AC_PROG_LN_S
 213 AC_PROG_MAKE_SET
 214 AM_PROG_MKDIR_P
 215
 216 dnl Checks for header files.
 217 AC_HEADER_DIRENT
 218 AC_HEADER_STDC
 219
 220 dnl keep them alpha-sorted!
 221 AC_CHECK_HEADERS([assert.h])
 222 AC_CHECK_HEADERS([errno.h])
 223 AC_CHECK_HEADERS([fcntl.h])
 224 AC_CHECK_HEADERS([libgen.h])
 225 AC_CHECK_HEADERS([netdb.h])
 226 AC_CHECK_HEADERS([stdint.h])
 227 AC_CHECK_HEADERS([stdio.h])
 228 AC_CHECK_HEADERS([stdlib.h])
 229 AC_CHECK_HEADERS([string.h])
 230 AC_CHECK_HEADERS([time.h])
 231 AC_CHECK_HEADERS([ucontext.h])
 232 AC_CHECK_HEADERS([unistd.h])
 233 AC_CHECK_HEADERS([sys/ioctl.h])
 234 AC_CHECK_HEADERS([sys/mman.h])
 235 AC_CHECK_HEADERS([sys/resource.h])
 236 AC_CHECK_HEADERS([sys/select.h])
 237 AC_CHECK_HEADERS([sys/socket.h])
 238 AC_CHECK_HEADERS([sys/stat.h])
 239 AC_CHECK_HEADERS([sys/time.h])
 240 AC_CHECK_HEADERS([sys/types.h])
 241
 242 dnl this is for fdlibm
 243 AC_CHECK_HEADERS([inttypes.h])
 244 AC_CHECK_HEADERS([sys/config.h])
 245 AC_CHECK_HEADERS([sys/types.h])
 246 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 247 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 248 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 249 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 250
 251 dnl Checks for typedefs, structures, and compiler characteristics.
 252 AC_C_CONST
 253 AC_C_INLINE
 254 AC_C_ATTRIBUTE
 255 AC_TYPE_OFF_T
 256 AC_TYPE_SIZE_T
 257 AC_HEADER_TIME
 258 AC_STRUCT_TM
 259
 260 dnl Checks for libraries (NOTE: Should be done before function checks,
 261 dnl as some functions may be in libraries we check for).
 262 AC_CHECK_LIB(dl, dlopen,,)
 263
 264 dnl Checks for library functions.
 265 AC_PROG_GCC_TRADITIONAL
 266 AC_TYPE_SIGNAL
 267 AC_FUNC_MEMCMP
 268 AC_FUNC_MMAP
 269
 270 dnl keep them alpha-sorted!
 271 AC_CHECK_FUNCS([abort])
 272 AC_CHECK_FUNCS([accept])
 273 AC_CHECK_FUNCS([access])
 274 AC_CHECK_FUNCS([atoi])
 275 AC_CHECK_FUNCS([atol])
 276 AC_CHECK_FUNCS([calloc])
 277 AC_CHECK_FUNCS([close])
 278 AC_CHECK_FUNCS([confstr])
 279 AC_CHECK_FUNCS([connect])
 280 AC_CHECK_FUNCS([dirname])
 281 AC_CHECK_FUNCS([fclose])
 282 AC_CHECK_FUNCS([fflush])
 283 AC_CHECK_FUNCS([fopen])
 284 AC_CHECK_FUNCS([fprintf])
 285 AC_CHECK_FUNCS([fread])
 286 AC_CHECK_FUNCS([free])
 287 AC_CHECK_FUNCS([fstat])
 288 AC_CHECK_FUNCS([fsync])
 289 AC_CHECK_FUNCS([ftruncate])
 290 AC_CHECK_FUNCS([getcwd])
 291 AC_CHECK_FUNCS([gethostbyname])
 292 AC_CHECK_FUNCS([gethostname])
 293 AC_CHECK_FUNCS([getpagesize])
 294 AC_CHECK_FUNCS([getrusage])
 295 AC_CHECK_FUNCS([getsockname])
 296 AC_CHECK_FUNCS([getsockopt])
 297 AC_CHECK_FUNCS([gettimeofday])
 298 AC_CHECK_FUNCS([htons])
 299 AC_CHECK_FUNCS([ioctl])
 300 AC_CHECK_FUNCS([isnan])
 301 AC_CHECK_FUNCS([listen])
 302 AC_CHECK_FUNCS([localtime])
 303 AC_CHECK_FUNCS([localtime_r])
 304 AC_CHECK_FUNCS([lseek])
 305 AC_CHECK_FUNCS([malloc])
 306 AC_CHECK_FUNCS([memcpy])
 307 AC_CHECK_FUNCS([memset])
 308 AC_CHECK_FUNCS([mmap])
 309 AC_CHECK_FUNCS([mprotect])
 310 AC_CHECK_FUNCS([open])
 311 AC_CHECK_FUNCS([read])
 312 AC_CHECK_FUNCS([readlink])
 313 AC_CHECK_FUNCS([realloc])
 314 AC_CHECK_FUNCS([recv])
 315 AC_CHECK_FUNCS([scandir])
 316 AC_CHECK_FUNCS([select])
 317 AC_CHECK_FUNCS([send])
 318 AC_CHECK_FUNCS([setsockopt])
 319 AC_CHECK_FUNCS([shutdown])
 320 AC_CHECK_FUNCS([socket])
 321 AC_CHECK_FUNCS([stat])
 322 AC_CHECK_FUNCS([strcat])
 323 AC_CHECK_FUNCS([strchr])
 324 AC_CHECK_FUNCS([strcpy])
 325 AC_CHECK_FUNCS([strdup])
 326 AC_CHECK_FUNCS([strerror])
 327 AC_CHECK_FUNCS([strlen])
 328 AC_CHECK_FUNCS([strncmp])
 329 AC_CHECK_FUNCS([strstr])
 330 AC_CHECK_FUNCS([time])
 331 AC_CHECK_FUNCS([write])
 332
 333
 334 dnl Checks for libraries.
 335
 336 dnl Checking sizeof void *
 337 AC_CHECK_SIZEOF(void *)
 338 AC_C_BIGENDIAN
 339
 340
 341 dnl define install prefix
 342 if test "x$prefix" = "xNONE"; then
 343     CACAO_PREFIX=$ac_default_prefix
 344 else
 345     CACAO_PREFIX=$prefix
 346 fi
 347 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 348 AC_SUBST(CACAO_PREFIX)
 349
 350 dnl define libdir prefix
 351 if test "x$libdir" = "xNONE"; then
 352     CACAO_LIBDIR=$ac_default_libdir
 353 else
 354     CACAO_LIBDIR=$libdir
 355 fi
 356 dnl expand CACAO_LIBDIR to something that is usable in C code
 357 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 358 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 359 AC_SUBST(CACAO_LIBDIR)
 360
 361
 362 AC_CHECK_ENABLE_LTDL
 363
 364 AC_CHECK_ENABLE_JAVA
 365
 366 AC_CHECK_ENABLE_JIT
 367 AC_CHECK_ENABLE_INTRP
 368
 369 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 370     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 371 fi
 372
 373 AC_CHECK_SOFTFLOAT
 374 AC_CHECK_SOFT_FLOAT_CMP
 375 AC_CHECK_SOFT_DOUBLE_CMP
 376
 377 AC_CHECK_ENABLE_GC
 378 AC_CHECK_ENABLE_DEBUG
 379 AC_CHECK_ENABLE_DUMP
 380
 381
 382 dnl check for memcheck support
 383 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 384 AC_ARG_ENABLE([memcheck],
 385               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 386               [case "${enableval}" in
 387                    yes) ENABLE_MEMCHECK=yes;;
 388                    *) ENABLE_MEMCHECK=no;;
 389                esac],
 390               [ENABLE_MEMCHECK=no])
 391 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 392 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 393
 394 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 395     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 396 fi
 397
 398
 399 dnl check for handles (indirection cells) support
 400 AC_MSG_CHECKING(whether handles (indirection cells) should be enabled)
 401 AC_ARG_ENABLE([handles],
 402               [AS_HELP_STRING(--enable-handles,enable handles (indirection cells) [[default=no]])],
 403               [case "${enableval}" in
 404                    yes) ENABLE_HANDLES=yes;;
 405                    *) ENABLE_HANDLES=no;;
 406                esac],
 407               [ENABLE_HANDLES=no])
 408 AC_MSG_RESULT(${ENABLE_HANDLES})
 409 AM_CONDITIONAL([ENABLE_HANDLES], test x"${ENABLE_HANDLES}" = "xyes")
 410
 411 if test x"${ENABLE_HANDLES}" = "xyes"; then
 412     AC_DEFINE([ENABLE_HANDLES], 1, [enable handles (indirection cells)])
 413 fi
 414
 415
 416 dnl check for vmlog support
 417 AC_MSG_CHECKING(whether vmlog tracing should be enabled)
 418 AC_ARG_ENABLE([vmlog],
 419               [AS_HELP_STRING(--enable-vmlog,enable vmlog tracing [[default=no]])],
 420               [case "${enableval}" in
 421                    yes) ENABLE_VMLOG=yes;;
 422                    *) ENABLE_VMLOG=no;;
 423                esac],
 424               [ENABLE_VMLOG=no])
 425 AC_MSG_RESULT(${ENABLE_VMLOG})
 426 AM_CONDITIONAL([ENABLE_VMLOG], test x"${ENABLE_VMLOG}" = "xyes")
 427
 428 if test x"${ENABLE_VMLOG}" = "xyes"; then
 429     AC_DEFINE([ENABLE_VMLOG], 1, [enable vmlog tracing code])
 430 fi
 431
 432
 433 dnl check for disassembler support
 434 AC_MSG_CHECKING(whether disassembler should be enabled)
 435 AC_ARG_ENABLE([disassembler],
 436               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 437               [case "${enableval}" in
 438                    yes) ENABLE_DISASSEMBLER=yes;;
 439                    *) ENABLE_DISASSEMBLER=no;;
 440                esac],
 441               [ENABLE_DISASSEMBLER=no])
 442 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 443 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 444
 445 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 446     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 447
 448     dnl check for binutils headers and libraries on some architectures for the
 449     dnl disassembler
 450     case "${ARCH_DIR}" in
 451         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 452             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 453             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 454             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 455             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 456
 457             case "${OS_DIR}" in
 458                 cygwin | darwin | netbsd | solaris)
 459                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 460                      ;;
 461             esac
 462
 463             case "${OS_DIR}" in
 464                 solaris)
 465                                          AC_CHECK_LIB(rt, sem_init,, [AC_MSG_ERROR(cannot find librt)])
 466                      ;;
 467             esac
 468
 469
 470             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 471             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 472             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 473             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 474             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 475             ;;
 476         * )
 477             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 478             ;;
 479     esac
 480 else
 481     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 482 fi
 483
 484
 485 dnl check for statistics
 486 AC_MSG_CHECKING(whether statistics generation should be enabled)
 487 AC_ARG_ENABLE([statistics],
 488               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 489               [case "${enableval}" in
 490                    yes) ENABLE_STATISTICS=yes;;
 491                    *) ENABLE_STATISTICS=no;;
 492                esac],
 493               [ENABLE_STATISTICS=no])
 494 AC_MSG_RESULT(${ENABLE_STATISTICS})
 495 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 496
 497 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 498     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 499 fi
 500
 501
 502 dnl check for verifier
 503 AC_MSG_CHECKING(whether classfile verification should be enabled)
 504 AC_ARG_ENABLE([verifier],
 505               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=enabled]])],
 506               [case "${enableval}" in
 507                    no) ENABLE_VERIFIER=no;;
 508                    *) ENABLE_VERIFIER=yes;;
 509                esac],
 510               [ENABLE_VERIFIER=yes])
 511 AC_MSG_RESULT(${ENABLE_VERIFIER})
 512 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 513
 514 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 515     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 516 fi
 517
 518
 519 dnl check for compiler timing
 520 AC_MSG_CHECKING(whether real-time timing should be enabled)
 521 AC_ARG_ENABLE([rt-timing],
 522               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 523               [case "${enableval}" in
 524                    yes) ENABLE_RT_TIMING=yes;;
 525                    *) ENABLE_RT_TIMING=no;;
 526                esac],
 527               [ENABLE_RT_TIMING=no])
 528 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 529 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 530
 531 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 532     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 533 fi
 534
 535
 536 dnl check for cycle count statistics
 537 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 538 AC_ARG_ENABLE([cycles-stats],
 539               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 540               [case "${enableval}" in
 541                    yes) ENABLE_CYCLES_STATS=yes;;
 542                    *) ENABLE_CYCLES_STATS=no;;
 543                esac],
 544               [ENABLE_CYCLES_STATS=no])
 545 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 546 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 547
 548 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 549     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 550 fi
 551
 552
 553 dnl check for JVMTI
 554 AC_MSG_CHECKING(whether to compile JVMTI support)
 555 AC_ARG_ENABLE([jvmti],
 556               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 557               [case "${enableval}" in
 558                    yes) ENABLE_JVMTI=yes;;
 559                    *) ENABLE_JVMTI=no;;
 560                esac],
 561               [ENABLE_JVMTI=no])
 562 AC_MSG_RESULT(${ENABLE_JVMTI})
 563 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 564
 565 if test x"${ENABLE_JVMTI}" = "xyes"; then
 566     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 567 fi
 568
 569
 570 AC_CHECK_ENABLE_THREADS
 571
 572
 573 dnl check if if-conversion should be supported
 574 AC_MSG_CHECKING(whether if-conversion should be supported)
 575 AC_ARG_ENABLE([ifconv],
 576               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=enabled]])],
 577               [case "${enableval}" in
 578                    no) ENABLE_IFCONV=no;;
 579                    *) ENABLE_IFCONV=yes;;
 580                esac],
 581               [ENABLE_IFCONV=yes])
 582 AC_MSG_RESULT(${ENABLE_IFCONV})
 583 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 584
 585 if test x"${ENABLE_IFCONV}" = "xyes"; then
 586     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 587 fi
 588
 589
 590 dnl check for inlining
 591 AC_MSG_CHECKING(whether method inlining should be supported)
 592 AC_ARG_ENABLE([inlining],
 593               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 594               [case "${enableval}" in
 595                    yes) ENABLE_INLINING=yes;;
 596                    *) ENABLE_INLINING=no;;
 597                esac],
 598               [ENABLE_INLINING=no])
 599 AC_MSG_RESULT(${ENABLE_INLINING})
 600 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 601
 602 if test x"${ENABLE_INLINING}" = "xyes"; then
 603     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 604 fi
 605
 606
 607 dnl check for inlining debug options
 608 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 609 AC_ARG_ENABLE([inlining-debug],
 610               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 611               [case "${enableval}" in
 612                    yes) ENABLE_INLINING_DEBUG=yes;;
 613                    *) ENABLE_INLINING_DEBUG=no;;
 614                esac],
 615               [ENABLE_INLINING_DEBUG=no])
 616 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 617 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 618
 619 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 620     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 621 fi
 622
 623
 624 dnl check for replacement
 625 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 626 AC_ARG_ENABLE([replacement],
 627               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 628               [case "${enableval}" in
 629                    yes) ENABLE_REPLACEMENT=yes;;
 630                    *) ENABLE_REPLACEMENT=no;;
 631                esac],
 632               [ENABLE_REPLACEMENT=no])
 633 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 634 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 635
 636 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 637     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 638 fi
 639
 640
 641 dnl check for loop optimization
 642 AC_MSG_CHECKING(whether loop optimization should be supported)
 643 AC_ARG_ENABLE([loop],
 644               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 645               [case "${enableval}" in
 646                    yes) ENABLE_LOOP=yes;;
 647                    *) ENABLE_LOOP=no;;
 648                esac],
 649               [ENABLE_LOOP=no])
 650 AC_MSG_RESULT(${ENABLE_LOOP})
 651 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 652
 653 if test x"${ENABLE_LOOP}" = "xyes"; then
 654     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 655 fi
 656
 657
 658 dnl check if linear scan register allocator(lsra) with SSA should be used
 659 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 660 AC_ARG_ENABLE([ssa],
 661               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 662               [case "${enableval}" in
 663                    no) ENABLE_SSA=no;;
 664                    *) ENABLE_SSA=yes;;
 665                esac],
 666               [ENABLE_SSA=no])
 667 AC_MSG_RESULT(${ENABLE_SSA})
 668 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 669 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 670 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 671 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 672
 673 if test x"${ENABLE_SSA}" = "xyes"; then
 674     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 675     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 676     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 677     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 678     ENABLE_LSRA="no"
 679 fi
 680
 681
 682 dnl check if linear scan register allocator(lsra) should be used
 683 AC_MSG_CHECKING(whether lsra should be supported)
 684 AC_ARG_ENABLE([lsra],
 685               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 686               [case "${enableval}" in
 687                    yes) ENABLE_LSRA=yes;;
 688                    *) ENABLE_LSRA=no;;
 689                esac],
 690               [ENABLE_LSRA=no])
 691
 692 if test x"${ENABLE_LSRA}" = "xyes"; then
 693     if test x"${ENABLE_SSA}" = "xyes"; then
 694         ENABLE_LSRA="no"
 695     fi
 696 fi
 697 AC_MSG_RESULT(${ENABLE_LSRA})
 698 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 699
 700 if test x"${ENABLE_LSRA}" = "xyes"; then
 701     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 702 fi
 703
 704 dnl check if profiling should be supported
 705 AC_MSG_CHECKING(whether profiling should be supported)
 706 AC_ARG_ENABLE([profiling],
 707               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 708               [case "${enableval}" in
 709                    yes) ENABLE_PROFILING=yes;;
 710                    *) ENABLE_PROFILING=no;;
 711                esac],
 712               [ENABLE_PROFILING=no])
 713 AC_MSG_RESULT(${ENABLE_PROFILING})
 714 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 715
 716 if test x"${ENABLE_PROFILING}" = "xyes"; then
 717     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 718 fi
 719
 720
 721 dnl check for instruction scheduler
 722 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 723
 724 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 725 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 726         case "${ARCH_DIR}" in
 727                 xdspcore )
 728                         ;;
 729                 * )
 730                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 731                         ;;
 732         esac
 733
 734         AC_MSG_RESULT(yes)
 735         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 736         AM_CONDITIONAL([USE_SCHEDULER], [true])
 737 else
 738         AC_MSG_RESULT(no)
 739         AM_CONDITIONAL([USE_SCHEDULER], [false])
 740 fi
 741
 742
 743 AC_CHECK_ENABLE_ZLIB
 744
 745 dnl check for stuff to be built
 746 AC_CHECK_ENABLE_JNI
 747 AC_CHECK_ENABLE_LIBJVM
 748
 749 dnl ATTENTION: These check must be after setting
 750 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 751 dnl because libtool uses them to build the correct libraries.
 752 AC_LIBTOOL_DLOPEN
 753 AC_PROG_LIBTOOL
 754
 755 AC_CHECK_ENABLE_STATICVM
 756 AC_CHECK_ENABLE_ANNOTATIONS
 757 AC_CHECK_ENABLE_ASSERTION
 758
 759
 760 dnl where is CACAO's vm.zip
 761 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 762 AC_ARG_WITH([vm-zip],
 763             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 764             [CACAO_VM_ZIP=${withval}],
 765             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 766 AC_MSG_RESULT(${CACAO_VM_ZIP})
 767 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 768 AC_SUBST(CACAO_VM_ZIP)
 769
 770
 771 AC_CHECK_WITH_CACAOH
 772 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 773
 774 dnl Now we check for jre-layout so we can skip some checks that are
 775 dnl not required.
 776 AC_CHECK_ENABLE_JRE_LAYOUT
 777
 778 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 779 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 780
 781 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 782    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 783 fi
 784
 785 dnl The check for jni_md.h must be before jni.h.
 786 AC_CHECK_WITH_JNI_MD_H
 787 AC_CHECK_WITH_JNI_H
 788
 789 dnl HPI is only required for OpenJDK
 790 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 791     openjdk)
 792         AC_CHECK_WITH_HPI_MD_H
 793         AC_CHECK_WITH_HPI_H
 794         ;;
 795     *)
 796         ;;
 797 esac
 798
 799 dnl check for some programs we need
 800
 801 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 802     cldc1.1 | gnuclasspath)
 803         AC_PROG_JAVAC
 804         AC_PROG_JAR
 805         ;;
 806     openjdk)
 807         ;;
 808     *)
 809         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 810         ;;
 811 esac
 812
 813
 814 AC_CHECK_HEADERS(
 815         [regex.h],
 816         [
 817                 dnl If debug build and regex.h available, enable debug filter
 818                 if test x"${NDEBUG}" = "xno"; then
 819                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 820                 fi
 821                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 822                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 823         ],
 824         [
 825                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 826         ]
 827 )
 828
 829 dnl python
 830
 831 AZ_PYTHON_DEFAULT
 832 AZ_PYTHON_ENABLE
 833 AZ_PYTHON_WITH
 834 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 835 AZ_PYTHON_CSPEC
 836 AZ_PYTHON_LSPEC
 837
 838
 839 dnl define some stuff required for --fullversion
 840 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 841 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 842 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CPPFLAGS", [CFLAGS used])
 843
 844
 845 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 846 CFLAGS="$OPT_CFLAGS"
 847 AM_CFLAGS=$ARCH_CFLAGS
 848 AM_CPPFLAGS="$CPPFLAGS"
 849 AC_SUBST(AM_CFLAGS)
 850 AC_SUBST(AM_CPPFLAGS)
 851
 852
 853 AC_CONFIG_FILES([Makefile]
 854                 [contrib/Makefile]
 855                 [contrib/setenvinstalled]
 856                 [contrib/setenvsource]
 857                 [contrib/vmlog/Makefile]
 858                 [contrib/vmlog/t/Makefile]
 859                 [doc/Makefile]
 860                 [doc/doxygen/Makefile]
 861                 [doc/handbook/Makefile]
 862                 [man/Makefile]
 863                 [src/Makefile]
 864                 [src/cacao/Makefile]
 865                 [src/cacaoh/Makefile]
 866                 [src/classes/Makefile]
 867                 [src/fdlibm/Makefile]
 868                 [src/mm/Makefile]
 869                 [src/mm/cacao-gc/Makefile]
 870                 [src/native/Makefile]
 871                 [src/native/include/Makefile]
 872                 [src/native/jvmti/Makefile]
 873                 [src/native/vm/Makefile]
 874                 [src/native/vm/cldc1.1/Makefile]
 875                 [src/native/vm/gnuclasspath/Makefile]
 876                 [src/native/vm/openjdk/Makefile]
 877                 [src/scripts/Makefile]
 878                 [src/scripts/java]
 879                 [src/threads/Makefile]
 880                 [src/threads/none/Makefile]
 881                 [src/threads/posix/Makefile]
 882                 [src/toolbox/Makefile]
 883                 [src/vm/Makefile]
 884                 [src/vm/jit/Makefile]
 885                 [src/vm/jit/allocator/Makefile]
 886                 [src/vm/jit/alpha/Makefile]
 887                 [src/vm/jit/alpha/freebsd/Makefile]
 888                 [src/vm/jit/alpha/linux/Makefile]
 889                 [src/vm/jit/arm/Makefile]
 890                 [src/vm/jit/arm/linux/Makefile]
 891                 [src/vm/jit/i386/Makefile]
 892                 [src/vm/jit/i386/cygwin/Makefile]
 893                 [src/vm/jit/i386/darwin/Makefile]
 894                 [src/vm/jit/i386/freebsd/Makefile]
 895                 [src/vm/jit/i386/linux/Makefile]
 896                 [src/vm/jit/intrp/Makefile]
 897                 [src/vm/jit/inline/Makefile]
 898                 [src/vm/jit/ir/Makefile]
 899                 [src/vm/jit/loop/Makefile]
 900                 [src/vm/jit/m68k/Makefile]
 901                 [src/vm/jit/m68k/linux/Makefile]
 902                 [src/vm/jit/mips/Makefile]
 903                 [src/vm/jit/mips/irix/Makefile]
 904                 [src/vm/jit/mips/linux/Makefile]
 905                 [src/vm/jit/mips/uclinux/Makefile]
 906                 [src/vm/jit/optimizing/Makefile]
 907                 [src/vm/jit/parisc/Makefile]
 908                 [src/vm/jit/parisc/linux/Makefile]
 909                 [src/vm/jit/powerpc/Makefile]
 910                 [src/vm/jit/powerpc/darwin/Makefile]
 911                 [src/vm/jit/powerpc/linux/Makefile]
 912                 [src/vm/jit/powerpc/netbsd/Makefile]
 913                 [src/vm/jit/powerpc64/Makefile]
 914                 [src/vm/jit/powerpc64/linux/Makefile]
 915                 [src/vm/jit/s390/Makefile]
 916                 [src/vm/jit/schedule/Makefile]
 917                 [src/vm/jit/sparc64/Makefile]
 918                 [src/vm/jit/sparc64/linux/Makefile]
 919                 [src/vm/jit/sparc64/solaris/Makefile]
 920                 [src/vm/jit/verify/Makefile]
 921                 [src/vm/jit/x86_64/Makefile]
 922                 [src/vm/jit/x86_64/freebsd/Makefile]
 923                 [src/vm/jit/x86_64/linux/Makefile]
 924                 [src/vmcore/Makefile]
 925                 [tests/Makefile]
 926                 [tests/regression/Makefile]
 927                 [tests/regression/bugzilla/Makefile]
 928                 [tests/regression/assertion/Makefile]
 929                 [tests/regression/jasmin/Makefile]
 930                 [tests/regression/junit/Makefile]
 931                 [tests/regression/native/Makefile]
 932                 [tests/regression/resolving/Makefile]
 933                 [tests/regression/resolving/classes1/Makefile]
 934                 [tests/regression/resolving/classes2/Makefile]
 935                 [tests/regression/resolving/classes3/Makefile]
 936 )
 937
 938
 939 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
 940 export OPT_CFLAGS
 941 export ARCH_CFLAGS
 942 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 943
 944
 945 AC_OUTPUT
 946
 947
 948 ## Local variables:
 949 ## mode: m4
 950 ## indent-tabs-mode: t
 951 ## c-basic-offset: 4
 952 ## tab-width: 8
 953 ## compile-command: "automake --add-missing"
 954 ## End: