configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4 dnl C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5 dnl E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6 dnl J. Wenninger, Institut f. Computersprachen - TU Wien
   7 dnl
   8 dnl This file is part of CACAO.
   9 dnl
  10 dnl This program is free software; you can redistribute it and/or
  11 dnl modify it under the terms of the GNU General Public License as
  12 dnl published by the Free Software Foundation; either version 2, or (at
  13 dnl your option) any later version.
  14 dnl
  15 dnl This program is distributed in the hope that it will be useful, but
  16 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 dnl General Public License for more details.
  19 dnl
  20 dnl You should have received a copy of the GNU General Public License
  21 dnl along with this program; if not, write to the Free Software
  22 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23 dnl 02110-1301, USA.
  24 dnl
  25 dnl $Id: configure.ac 8041 2007-06-07 16:21:11Z twisti $
  26
  27 dnl Process this file with autoconf to produce a configure script.
  28
  29
  30 AC_INIT(cacao, 0.98+svn, cacao@cacaojvm.org)
  31 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  32 AC_CANONICAL_HOST
  33 AC_PREREQ(2.59)
  34 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2])
  35 AM_MAINTAINER_MODE
  36
  37 AM_CONFIG_HEADER([config.h])
  38
  39 AC_PREFIX_DEFAULT(/usr/local/cacao)
  40
  41
  42 dnl set optimization and debugging for all architectures and systems
  43 if test x"$CFLAGS" = "x"; then
  44     OPT_CFLAGS="-O0 -g3"
  45 else
  46     OPT_CFLAGS=$CFLAGS
  47 fi
  48
  49 dnl system type
  50 case "$host_cpu" in
  51 alpha | alphaev56 | alphapca56 )
  52     ARCH_DIR="alpha"
  53     ARCH_CFLAGS="-mieee -D__ALPHA__"
  54     ;;
  55
  56 arm | armv4 | armv4tl | armv5b | armv5l )
  57     ARCH_DIR="arm"
  58     ARCH_CFLAGS="-D__ARM__"
  59     ;;
  60
  61 hppa2.0 )
  62     ARCH_DIR="parisc"
  63     ARCH_CFLAGS="-D__PARISC__"
  64     ;;
  65
  66 i386 | i486 | i586 | i686 )
  67     ARCH_DIR="i386"
  68     ARCH_CFLAGS="-D__I386__"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     ;;
  75
  76 mips | mipsel )
  77     ARCH_DIR="mips"
  78     ARCH_CFLAGS="-D__MIPS__"
  79     ;;
  80
  81 powerpc )
  82     ARCH_DIR="powerpc"
  83     ARCH_CFLAGS="-D__POWERPC__"
  84     ;;
  85
  86 powerpc64 )
  87     ARCH_DIR="powerpc64"
  88     ARCH_CFLAGS="-D__POWERPC64__"
  89     ;;
  90
  91 s390 )
  92     ARCH_DIR="s390"
  93     ARCH_CFLAGS="-D__S390__"
  94     ;;
  95
  96 sparc | sparc64 )
  97     ARCH_DIR="sparc64"
  98     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
  99     ;;
 100
 101 x86_64 )
 102     ARCH_DIR="x86_64"
 103     ARCH_CFLAGS="-D__X86_64__"
 104     ;;
 105
 106 xdspcore )
 107     ARCH_DIR="xdspcore"
 108     ENABLE_STATICVM="yes"
 109     ARCH_CFLAGS="-D__XDSPCORE__"
 110     USE_SCHEDULER="1"
 111     ;;
 112
 113 * )
 114     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 115     ;;
 116 esac
 117
 118 dnl host type
 119 case "$host_os" in
 120 *cygwin* )
 121     OS_DIR="cygwin"
 122     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 123     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 124     ;;
 125
 126 *darwin* )
 127     OS_DIR="darwin"
 128     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 129     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 130     ;;
 131
 132 *freebsd* )
 133     OS_DIR="freebsd"
 134     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 135     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 136     ;;
 137
 138 *irix* )
 139     OS_DIR="irix"
 140     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 141     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 142     ;;
 143
 144 *kfreebsd*-gnu)
 145     OS_DIR="freebsd"
 146     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 147     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 148     ;;
 149
 150 dnl must be before *linux*
 151 *uclinux | *elf )
 152     OS_DIR="uclinux"
 153     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 154     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     ;;
 156
 157 *linux* | *Linux* )
 158     OS_DIR="linux"
 159     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 160     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 161     ;;
 162
 163 *netbsd* )
 164     OS_DIR="netbsd"
 165     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 166     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 167     ;;
 168
 169 *solaris* )
 170     OS_DIR="solaris"
 171         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 172         dnl therefore we add them here
 173     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 174     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 175     ;;
 176
 177 * )
 178     ;;
 179 esac
 180
 181
 182 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 183 dnl we set it properly at the end of this file
 184 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 185
 186 dnl set interpreter flags
 187 AC_SUBST(INTRP_CFLAGS)
 188
 189 dnl define some stuff required for --fullversion
 190 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 191 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 192 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS", [CFLAGS used])
 193
 194
 195 dnl define and substitute some architecture specific variables
 196 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 197 AC_SUBST(ARCH_DIR)
 198 AC_SUBST(OS_DIR)
 199 AC_SUBST(USE_SCHEDULER)
 200
 201
 202 dnl Checks for programs.
 203 AC_PROG_CC
 204 AM_PROG_AS
 205 AC_PROG_LD
 206 AC_PROG_LD_GNU
 207 AC_PROG_RANLIB
 208 AC_PROG_LN_S
 209 AC_PROG_MAKE_SET
 210 AM_PROG_MKDIR_P
 211
 212 dnl Checks for header files.
 213 AC_HEADER_DIRENT
 214 AC_HEADER_STDC
 215
 216 dnl keep them alpha-sorted!
 217 AC_CHECK_HEADERS([fcntl.h])
 218 AC_CHECK_HEADERS([stdlib.h])
 219 AC_CHECK_HEADERS([string.h])
 220 AC_CHECK_HEADERS([time.h])
 221 AC_CHECK_HEADERS([unistd.h])
 222 AC_CHECK_HEADERS([sys/ioctl.h])
 223 AC_CHECK_HEADERS([sys/mman.h])
 224 AC_CHECK_HEADERS([sys/resource.h])
 225 AC_CHECK_HEADERS([sys/select.h])
 226 AC_CHECK_HEADERS([sys/stat.h])
 227 AC_CHECK_HEADERS([sys/time.h])
 228 AC_CHECK_HEADERS([sys/types.h])
 229
 230 dnl this is for fdlibm
 231 AC_CHECK_HEADERS([stdint.h])
 232 AC_CHECK_HEADERS([inttypes.h])
 233 AC_CHECK_HEADERS([sys/config.h])
 234 AC_CHECK_HEADERS([sys/types.h])
 235 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 236 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 237 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 238 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 239
 240 dnl Checks for typedefs, structures, and compiler characteristics.
 241 AC_C_CONST
 242 AC_C_INLINE
 243 AC_C_ATTRIBUTE
 244 AC_TYPE_OFF_T
 245 AC_TYPE_SIZE_T
 246 AC_HEADER_TIME
 247 AC_STRUCT_TM
 248
 249 dnl Checks for library functions.
 250 AC_PROG_GCC_TRADITIONAL
 251 AC_TYPE_SIGNAL
 252 AC_FUNC_MEMCMP
 253 AC_FUNC_MMAP
 254
 255 dnl keep them alpha-sorted!
 256 AC_CHECK_FUNCS([calloc])
 257 AC_CHECK_FUNCS([confstr])
 258 AC_CHECK_FUNCS([getpagesize])
 259 AC_CHECK_FUNCS([free])
 260 AC_CHECK_FUNCS([fstat])
 261 AC_CHECK_FUNCS([getcwd])
 262 AC_CHECK_FUNCS([gettimeofday])
 263 AC_CHECK_FUNCS([getrusage])
 264 AC_CHECK_FUNCS([ioctl])
 265 AC_CHECK_FUNCS([isnan])
 266 AC_CHECK_FUNCS([localtime])
 267 AC_CHECK_FUNCS([localtime_r])
 268 AC_CHECK_FUNCS([mmap])
 269 AC_CHECK_FUNCS([mprotect])
 270 AC_CHECK_FUNCS([scandir])
 271 AC_CHECK_FUNCS([select])
 272 AC_CHECK_FUNCS([strdup])
 273 AC_CHECK_FUNCS([strstr])
 274 AC_CHECK_FUNCS([time])
 275
 276
 277 dnl Checks for libraries.
 278
 279 dnl Checking sizeof void *
 280 AC_CHECK_SIZEOF(void *)
 281 AC_C_BIGENDIAN
 282
 283
 284 dnl define install prefix
 285 if test "x$prefix" = "xNONE"; then
 286     CACAO_PREFIX=$ac_default_prefix
 287 else
 288     CACAO_PREFIX=$prefix
 289 fi
 290 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 291 AC_SUBST(CACAO_PREFIX)
 292
 293 dnl define libdir prefix
 294 if test "x$libdir" = "xNONE"; then
 295     CACAO_LIBDIR=$ac_default_libdir
 296 else
 297     CACAO_LIBDIR=$libdir
 298 fi
 299 dnl expand CACAO_LIBDIR to something that is usable in C code
 300 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 301 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 302 AC_SUBST(CACAO_LIBDIR)
 303
 304
 305 dnl Features
 306
 307 AC_CHECK_ENABLE_JAVA
 308 AC_CHECK_ENABLE_JIT
 309
 310 dnl with-options
 311 AC_CHECK_WITH_CACAOH
 312
 313 dnl check for stuff that should be done in software
 314 AC_CHECK_SOFTFLOAT
 315 AC_CHECK_SOFT_FLOAT_CMP
 316 AC_CHECK_SOFT_DOUBLE_CMP
 317
 318
 319 dnl check for interpreter
 320 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 321
 322 AC_MSG_CHECKING(whether interpreter should be compiled)
 323 if test x"$enable_intrp" = "xyes"; then
 324     AC_MSG_RESULT(yes)
 325     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 326     AM_CONDITIONAL([ENABLE_INTRP], [true])
 327     ENABLE_INTRP=yes
 328
 329     AC_ASM_SKIP16
 330
 331     dnl check for libffi
 332     AC_ARG_WITH([ffi],
 333                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 334                 [WITH_FFI=yes
 335                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 336                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 337                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 338                 [WITH_FFI=no])
 339
 340     dnl check for libffcall
 341     AC_ARG_WITH([ffcall],
 342                 [AS_HELP_STRING(--with-ffcall,use libffcall to call native functions)],
 343                 [WITH_FFCALL=yes
 344                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 345                  AC_CHECK_LIB(avcall, __builtin_avcall,, [AC_MSG_ERROR(cannot find libavcall (from libffcall))])
 346                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 347                 [WITH_FFCALL=no])
 348
 349     dnl check for libffi or libffcall
 350     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 351         AC_ERROR(Enable only libffi or libffcall.)
 352     fi
 353     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 354         AC_ERROR(Enable one of libffi or libffcall.)
 355     fi
 356
 357 else
 358     AC_MSG_RESULT(no)
 359     AM_CONDITIONAL([ENABLE_INTRP], [false])
 360     ENABLE_INTRP="no"
 361 fi
 362
 363 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 364     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 365 fi
 366
 367
 368 dnl check for garbage collector usage
 369 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--enable-gc,enable garbage collector support (none,boehm,cacao) [[default=boehm]])])
 370 AC_MSG_CHECKING(whether GC should be enabled)
 371 enable_gc=${enable_gc:-boehm}
 372 case "$enable_gc" in
 373 no | none)
 374     AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 375     ENABLE_GC=none
 376     AC_MSG_RESULT(no)
 377     ;;
 378
 379 boehm)
 380     AC_DEFINE([ENABLE_GC_BOEHM], 1, [enable conservative boehm-gc])
 381     ENABLE_GC=boehm
 382     AC_MSG_RESULT(yes, boehm-gc)
 383     ;;
 384
 385 cacao)
 386     AC_DEFINE([ENABLE_GC_CACAO], 1, [enable exact cacao-gc])
 387     ENABLE_GC=cacao
 388     AC_MSG_RESULT(yes, cacao-gc)
 389     ;;
 390
 391 *)
 392     AC_MSG_ERROR($enable_gc is an unknown garbage collector package)
 393     ;;
 394 esac
 395 AM_CONDITIONAL([DISABLE_GC], test x"${ENABLE_GC}" = "xnone")
 396 AM_CONDITIONAL([ENABLE_GC_BOEHM], test x"${ENABLE_GC}" = "xboehm")
 397 AM_CONDITIONAL([ENABLE_GC_CACAO], test x"${ENABLE_GC}" = "xcacao")
 398
 399
 400
 401 dnl check for dump memory usage
 402 AC_MSG_CHECKING(whether dump memory should be disabled)
 403 AC_ARG_ENABLE([dump],
 404               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 405               [case "${enableval}" in
 406                    no)
 407                        DISABLE_DUMP=yes
 408                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 409                        ;;
 410                    *) DISABLE_DUMP=no;;
 411                esac],
 412                [DISABLE_DUMP=no])
 413 AC_MSG_RESULT(${DISABLE_DUMP})
 414
 415
 416 dnl check for debug
 417 AC_MSG_CHECKING(whether debug code generation should be enabled)
 418 AC_ARG_ENABLE([debug],
 419               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 420               [case "${enableval}" in
 421                    no) NDEBUG=yes
 422                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 423                        ;;
 424                    *) NDEBUG=no;;
 425                esac],
 426               [NDEBUG=no])
 427
 428 if test x"${NDEBUG}" = "xno"; then
 429     AC_MSG_RESULT(yes)
 430 else
 431     AC_MSG_RESULT(no)
 432 fi
 433 AM_CONDITIONAL([NDEBUG], test x"${NDEBUG}" = "xyes")
 434
 435
 436 dnl check for memcheck support
 437 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 438 AC_ARG_ENABLE([memcheck],
 439               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 440               [case "${enableval}" in
 441                    yes) ENABLE_MEMCHECK=yes;;
 442                    *) ENABLE_MEMCHECK=no;;
 443                esac],
 444               [ENABLE_MEMCHECK=no])
 445 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 446 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 447
 448 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 449     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 450 fi
 451
 452
 453 dnl check for vmlog support
 454 AC_MSG_CHECKING(whether vmlog tracing should be enabled)
 455 AC_ARG_ENABLE([vmlog],
 456               [AS_HELP_STRING(--enable-vmlog,enable vmlog tracing [[default=no]])],
 457               [case "${enableval}" in
 458                    yes) ENABLE_VMLOG=yes;;
 459                    *) ENABLE_VMLOG=no;;
 460                esac],
 461               [ENABLE_VMLOG=no])
 462 AC_MSG_RESULT(${ENABLE_VMLOG})
 463 AM_CONDITIONAL([ENABLE_VMLOG], test x"${ENABLE_VMLOG}" = "xyes")
 464
 465 if test x"${ENABLE_VMLOG}" = "xyes"; then
 466     AC_DEFINE([ENABLE_VMLOG], 1, [enable vmlog tracing code])
 467 fi
 468
 469
 470 dnl check for disassembler support
 471 AC_MSG_CHECKING(whether disassembler should be enabled)
 472 AC_ARG_ENABLE([disassembler],
 473               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 474               [case "${enableval}" in
 475                    yes) ENABLE_DISASSEMBLER=yes;;
 476                    *) ENABLE_DISASSEMBLER=no;;
 477                esac],
 478               [ENABLE_DISASSEMBLER=no])
 479 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 480 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 481
 482 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 483     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 484
 485     dnl check for binutils headers and libraries on some architectures for the
 486     dnl disassembler
 487     case "${ARCH_DIR}" in
 488         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 489             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 490             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 491             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 492             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 493
 494             case "${OS_DIR}" in
 495                 cygwin | darwin | netbsd | solaris)
 496                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 497                      ;;
 498             esac
 499
 500             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 501             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 502             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 503             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 504             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 505             ;;
 506         * )
 507             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 508             ;;
 509     esac
 510 else
 511     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 512 fi
 513
 514
 515 dnl check for statistics
 516 AC_MSG_CHECKING(whether statistics generation should be enabled)
 517 AC_ARG_ENABLE([statistics],
 518               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 519               [case "${enableval}" in
 520                    yes) ENABLE_STATISTICS=yes;;
 521                    *) ENABLE_STATISTICS=no;;
 522                esac],
 523               [ENABLE_STATISTICS=no])
 524 AC_MSG_RESULT(${ENABLE_STATISTICS})
 525 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 526
 527 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 528     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 529 fi
 530
 531
 532 dnl check for verifier
 533 AC_MSG_CHECKING(whether classfile verification should be enabled)
 534 AC_ARG_ENABLE([verifier],
 535               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=yes]])],
 536               [case "${enableval}" in
 537                    no) ENABLE_VERIFIER=no;;
 538                    *) ENABLE_VERIFIER=yes;;
 539                esac],
 540               [ENABLE_VERIFIER=yes])
 541 AC_MSG_RESULT(${ENABLE_VERIFIER})
 542 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 543
 544 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 545     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 546 fi
 547
 548
 549 dnl check for compiler timing
 550 AC_MSG_CHECKING(whether real-time timing should be enabled)
 551 AC_ARG_ENABLE([rt-timing],
 552               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 553               [case "${enableval}" in
 554                    yes) ENABLE_RT_TIMING=yes;;
 555                    *) ENABLE_RT_TIMING=no;;
 556                esac],
 557               [ENABLE_RT_TIMING=no])
 558 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 559 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 560
 561 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 562     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 563 fi
 564
 565
 566 dnl check for cycle count statistics
 567 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 568 AC_ARG_ENABLE([cycles-stats],
 569               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 570               [case "${enableval}" in
 571                    yes) ENABLE_CYCLES_STATS=yes;;
 572                    *) ENABLE_CYCLES_STATS=no;;
 573                esac],
 574               [ENABLE_CYCLES_STATS=no])
 575 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 576 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 577
 578 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 579     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 580 fi
 581
 582
 583 dnl check for JVMTI
 584 AC_MSG_CHECKING(whether to compile JVMTI support)
 585 AC_ARG_ENABLE([jvmti],
 586               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 587               [case "${enableval}" in
 588                    yes) ENABLE_JVMTI=yes;;
 589                    *) ENABLE_JVMTI=no;;
 590                esac],
 591               [ENABLE_JVMTI=no])
 592 AC_MSG_RESULT(${ENABLE_JVMTI})
 593 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 594
 595 if test x"${ENABLE_JVMTI}" = "xyes"; then
 596     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 597 fi
 598
 599
 600 AC_CHECK_ENABLE_THREADS
 601
 602
 603 dnl check if if-conversion should be supported
 604 AC_MSG_CHECKING(whether if-conversion should be supported)
 605 AC_ARG_ENABLE([ifconv],
 606               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=yes]])],
 607               [case "${enableval}" in
 608                    no) ENABLE_IFCONV=no;;
 609                    *) ENABLE_IFCONV=yes;;
 610                esac],
 611               [ENABLE_IFCONV=yes])
 612 AC_MSG_RESULT(${ENABLE_IFCONV})
 613 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 614
 615 if test x"${ENABLE_IFCONV}" = "xyes"; then
 616     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 617 fi
 618
 619
 620 dnl check for inlining
 621 AC_MSG_CHECKING(whether method inlining should be supported)
 622 AC_ARG_ENABLE([inlining],
 623               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 624               [case "${enableval}" in
 625                    yes) ENABLE_INLINING=yes;;
 626                    *) ENABLE_INLINING=no;;
 627                esac],
 628               [ENABLE_INLINING=no])
 629 AC_MSG_RESULT(${ENABLE_INLINING})
 630 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 631
 632 if test x"${ENABLE_INLINING}" = "xyes"; then
 633     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 634 fi
 635
 636
 637 dnl check for inlining debug options
 638 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 639 AC_ARG_ENABLE([inlining-debug],
 640               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 641               [case "${enableval}" in
 642                    yes) ENABLE_INLINING_DEBUG=yes;;
 643                    *) ENABLE_INLINING_DEBUG=no;;
 644                esac],
 645               [ENABLE_INLINING_DEBUG=no])
 646 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 647 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 648
 649 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 650     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 651 fi
 652
 653
 654 dnl check for replacement
 655 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 656 AC_ARG_ENABLE([replacement],
 657               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 658               [case "${enableval}" in
 659                    yes) ENABLE_REPLACEMENT=yes;;
 660                    *) ENABLE_REPLACEMENT=no;;
 661                esac],
 662               [ENABLE_REPLACEMENT=no])
 663 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 664 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 665
 666 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 667     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 668 fi
 669
 670
 671 dnl check for loop optimization
 672 AC_MSG_CHECKING(whether loop optimization should be supported)
 673 AC_ARG_ENABLE([loop],
 674               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 675               [case "${enableval}" in
 676                    yes) ENABLE_LOOP=yes;;
 677                    *) ENABLE_LOOP=no;;
 678                esac],
 679               [ENABLE_LOOP=no])
 680 AC_MSG_RESULT(${ENABLE_LOOP})
 681 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 682
 683 if test x"${ENABLE_LOOP}" = "xyes"; then
 684     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 685 fi
 686
 687
 688 dnl check if linear scan register allocator(lsra) with SSA should be used
 689 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 690 AC_ARG_ENABLE([ssa],
 691               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=no]])],
 692               [case "${enableval}" in
 693                    no) ENABLE_SSA=no;;
 694                    *) ENABLE_SSA=yes;;
 695                esac],
 696               [ENABLE_SSA=no])
 697 AC_MSG_RESULT(${ENABLE_SSA})
 698 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 699
 700 if test x"${ENABLE_SSA}" = "xyes"; then
 701     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 702     ENABLE_LSRA="no"
 703 fi
 704
 705
 706 dnl check if linear scan register allocator(lsra) should be used
 707 AC_MSG_CHECKING(whether lsra should be supported)
 708 AC_ARG_ENABLE([lsra],
 709               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 710               [case "${enableval}" in
 711                    yes) ENABLE_LSRA=yes;;
 712                    *) ENABLE_LSRA=no;;
 713                esac],
 714               [ENABLE_LSRA=no])
 715
 716 if test x"${ENABLE_LSRA}" = "xyes"; then
 717     if test x"${ENABLE_SSA}" = "xyes"; then
 718         ENABLE_LSRA="no"
 719     fi
 720 fi
 721 AC_MSG_RESULT(${ENABLE_LSRA})
 722 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 723
 724 if test x"${ENABLE_LSRA}" = "xyes"; then
 725     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 726 fi
 727
 728
 729 dnl check if profiling should be supported
 730 AC_MSG_CHECKING(whether profiling should be supported)
 731 AC_ARG_ENABLE([profiling],
 732               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 733               [case "${enableval}" in
 734                    yes) ENABLE_PROFILING=yes;;
 735                    *) ENABLE_PROFILING=no;;
 736                esac],
 737               [ENABLE_PROFILING=no])
 738 AC_MSG_RESULT(${ENABLE_PROFILING})
 739 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 740
 741 if test x"${ENABLE_PROFILING}" = "xyes"; then
 742     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 743 fi
 744
 745
 746 dnl check for instruction scheduler
 747 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 748
 749 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 750 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 751         case "${ARCH_DIR}" in
 752                 xdspcore )
 753                         ;;
 754                 * )
 755                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 756                         ;;
 757         esac
 758
 759         AC_MSG_RESULT(yes)
 760         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 761         AM_CONDITIONAL([USE_SCHEDULER], [true])
 762 else
 763         AC_MSG_RESULT(no)
 764         AM_CONDITIONAL([USE_SCHEDULER], [false])
 765 fi
 766
 767
 768 dnl check if zlib should be used
 769 AC_MSG_CHECKING(whether ZIP/JAR archives should be supported)
 770 AC_ARG_ENABLE([zlib],
 771               [AS_HELP_STRING(--disable-zlib,disable ZIP/JAR archive support (needs zlib) [[default=yes]])],
 772               [case "${enableval}" in
 773                   no) ENABLE_ZLIB=no;;
 774                   *) ENABLE_ZLIB=yes;;
 775                esac],
 776               [ENABLE_ZLIB=yes])
 777 AC_MSG_RESULT(${ENABLE_ZLIB})
 778
 779 if test x"${ENABLE_ZLIB}" = "xyes"; then
 780     AC_CHECK_HEADERS([zconf.h],, [AC_MSG_ERROR(cannot find zconf.h)])
 781     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 782     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 783     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 784 fi
 785 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 786
 787
 788 dnl check for stuff to be built
 789 AC_CHECK_ENABLE_JNI
 790
 791
 792 dnl check if a libjvm.so should be built
 793 AC_MSG_CHECKING(whether to build a libjvm.so)
 794 AC_ARG_ENABLE([libjvm],
 795               [AS_HELP_STRING(--disable-libjvm,build a libjvm.so [[default=yes]])],
 796               [case "${enableval}" in
 797                   no) ENABLE_LIBJVM=no;;
 798                   *) ENABLE_LIBJVM=yes;;
 799                esac],
 800               [ENABLE_LIBJVM=yes])
 801 AC_MSG_RESULT(${ENABLE_LIBJVM})
 802 AM_CONDITIONAL([ENABLE_LIBJVM], test x"${ENABLE_LIBJVM}" = "xyes")
 803 AC_SUBST(ENABLE_LIBJVM)
 804
 805 if test x"${ENABLE_LIBJVM}" = "xyes"; then
 806     AC_DEFINE([ENABLE_LIBJVM], 1, [enable libjvm.so])
 807
 808     dnl set AC_ENABLE_SHARED and AC_DISABLE_STATIC properly
 809     enable_shared=yes
 810     enable_static=no
 811 else
 812     enable_shared=no
 813     enable_static=yes
 814 fi
 815
 816 dnl libtool stuff
 817 AC_LIBTOOL_DLOPEN
 818 AC_PROG_LIBTOOL
 819
 820
 821 dnl check if CACAO should be linked statically
 822 AC_MSG_CHECKING(whether to link CACAO statically)
 823 AC_ARG_ENABLE([staticvm],
 824               [AS_HELP_STRING(--enable-staticvm,link CACAO statically [[default=no]])],
 825               [case "${enableval}" in
 826                   yes) ENABLE_STATICVM=yes
 827                        AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 828                        ;;
 829                   *) ENABLE_STATICVM=no;;
 830                esac],
 831               [ENABLE_STATICVM=no])
 832 AC_MSG_RESULT(${ENABLE_STATICVM})
 833 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 834 AC_SUBST(ENABLE_STATICVM)
 835
 836
 837 dnl where is CACAO's vm.zip
 838 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 839 AC_ARG_WITH([vm-zip],
 840             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 841             [CACAO_VM_ZIP=${withval}],
 842             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 843 AC_MSG_RESULT(${CACAO_VM_ZIP})
 844 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 845 AC_SUBST(CACAO_VM_ZIP)
 846
 847
 848 AC_CHECK_WITH_CLASSPATH
 849 AC_CHECK_WITH_CLASSPATH_PREFIX
 850 AC_CHECK_WITH_CLASSPATH_CLASSES
 851 AC_CHECK_WITH_CLASSPATH_LIBDIR
 852 AC_CHECK_WITH_CLASSPATH_INCLUDEDIR
 853
 854
 855 dnl if we compile for a JRE-style directory layout
 856 AC_MSG_CHECKING(if we compile for a JRE-style directory layout)
 857 AC_ARG_WITH([jre-layout],
 858             [AS_HELP_STRING(--with-jre-layout,compile for JRE-style directory layout [[default=no]])],
 859             [case "${enableval}" in
 860                 yes) WITH_JRE_LAYOUT=yes
 861                      AC_DEFINE([WITH_JRE_LAYOUT], 1, [with JRE layout])
 862                      ;;
 863                 *) WITH_JRE_LAYOUT=no;;
 864              esac],
 865             [WITH_JRE_LAYOUT=no])
 866 AC_MSG_RESULT(${WITH_JRE_LAYOUT})
 867
 868
 869 dnl check if GNU Classpath should be linked statically into CACAO
 870 AC_MSG_CHECKING(whether to link GNU Classpath native libraries statically into CACAO)
 871 AC_ARG_WITH([static-classpath],
 872             [AS_HELP_STRING(--with-static-classpath,link GNU classpath native libraries statically into CACAO [[default=no]])],
 873             [case "${enableval}" in
 874                 yes) WITH_STATIC_CLASSPATH=yes;;
 875                 *) WITH_STATIC_CLASSPATH=no;;
 876              esac],
 877             [WITH_STATIC_CLASSPATH=no])
 878 AC_MSG_RESULT(${WITH_STATIC_CLASSPATH})
 879
 880 if test x"${WITH_STATIC_CLASSPATH}" = "xyes"; then
 881     AC_DEFINE([WITH_STATIC_CLASSPATH], 1, [link GNU classpath native libraries statically into CACAO])
 882
 883     dnl check for some classpath related stuff when we link statically
 884     AM_ICONV_LINK
 885 else
 886     dnl we need this check for --enable-staticvm, otherwise ltdl can't find dlopen
 887     if test x"${ENABLE_STATICVM}" = "xyes"; then
 888         AC_CHECK_LIB(dl, dlopen,, [AC_MSG_ERROR(cannot find libdl)])
 889     fi
 890
 891     AC_CHECK_HEADERS([ltdl.h],, [AC_MSG_ERROR(cannot find ltdl.h)])
 892     AC_CHECK_LIB(ltdl, lt_dlopen,, [AC_MSG_ERROR(cannot find libltdl)])
 893 fi
 894 AM_CONDITIONAL([WITH_STATIC_CLASSPATH], test x"${WITH_STATIC_CLASSPATH}" = "xyes")
 895 AC_SUBST(WITH_STATIC_CLASSPATH)
 896
 897
 898 dnl check for some programs we need
 899 AC_PROG_JAVAC
 900 AC_PROG_JAR
 901
 902 AC_CHECK_HEADERS(
 903         [regex.h],
 904         [
 905                 dnl If debug build and regex.h available, enable debug filter
 906                 if test x"${NDEBUG}" = "xno"; then
 907                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 908                 fi
 909                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 910                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 911         ],
 912         [
 913                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 914         ]
 915 )
 916
 917 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 918 CFLAGS=$OPT_CFLAGS
 919 AM_CFLAGS=$ARCH_CFLAGS
 920 AC_SUBST(AM_CFLAGS)
 921
 922
 923 AC_CONFIG_FILES([Makefile]
 924                 [contrib/Makefile]
 925                 [contrib/setenvinstalled]
 926                 [contrib/setenvsource]
 927                 [contrib/vmlog/Makefile]
 928                 [contrib/vmlog/t/Makefile]
 929                 [doc/Makefile]
 930                 [doc/handbook/Makefile]
 931                 [man/Makefile]
 932                 [src/Makefile]
 933                 [src/cacao/Makefile]
 934                 [src/cacaoh/Makefile]
 935                 [src/fdlibm/Makefile]
 936                 [src/lib/Makefile]
 937                 [src/mm/Makefile]
 938                 [src/mm/cacao-gc/Makefile]
 939                 [src/native/Makefile]
 940                 [src/native/include/Makefile]
 941                 [src/native/jvmti/Makefile]
 942                 [src/native/tools/Makefile]
 943                 [src/native/vm/Makefile]
 944                 [src/native/vm/cldc1.1/Makefile]
 945                 [src/native/vm/gnu/Makefile]
 946                 [src/scripts/Makefile]
 947                 [src/scripts/java]
 948                 [src/threads/Makefile]
 949                 [src/threads/native/Makefile]
 950                 [src/threads/none/Makefile]
 951                 [src/toolbox/Makefile]
 952                 [src/vm/Makefile]
 953                 [src/vm/jit/Makefile]
 954                 [src/vm/jit/allocator/Makefile]
 955                 [src/vm/jit/alpha/Makefile]
 956                 [src/vm/jit/alpha/freebsd/Makefile]
 957                 [src/vm/jit/alpha/linux/Makefile]
 958                 [src/vm/jit/arm/Makefile]
 959                 [src/vm/jit/arm/linux/Makefile]
 960                 [src/vm/jit/i386/Makefile]
 961                 [src/vm/jit/i386/cygwin/Makefile]
 962                 [src/vm/jit/i386/darwin/Makefile]
 963                 [src/vm/jit/i386/freebsd/Makefile]
 964                 [src/vm/jit/i386/linux/Makefile]
 965                 [src/vm/jit/intrp/Makefile]
 966                 [src/vm/jit/inline/Makefile]
 967                 [src/vm/jit/loop/Makefile]
 968                 [src/vm/jit/m68k/Makefile]
 969                 [src/vm/jit/m68k/linux/Makefile]
 970                 [src/vm/jit/mips/Makefile]
 971                 [src/vm/jit/mips/irix/Makefile]
 972                 [src/vm/jit/mips/linux/Makefile]
 973                 [src/vm/jit/mips/uclinux/Makefile]
 974                 [src/vm/jit/optimizing/Makefile]
 975                 [src/vm/jit/parisc/Makefile]
 976                 [src/vm/jit/parisc/linux/Makefile]
 977                 [src/vm/jit/powerpc/Makefile]
 978                 [src/vm/jit/powerpc/darwin/Makefile]
 979                 [src/vm/jit/powerpc/linux/Makefile]
 980                 [src/vm/jit/powerpc/netbsd/Makefile]
 981                 [src/vm/jit/powerpc64/Makefile]
 982                 [src/vm/jit/powerpc64/linux/Makefile]
 983                 [src/vm/jit/s390/Makefile]
 984                 [src/vm/jit/schedule/Makefile]
 985                 [src/vm/jit/sparc64/Makefile]
 986                 [src/vm/jit/sparc64/linux/Makefile]
 987                 [src/vm/jit/sparc64/solaris/Makefile]
 988                 [src/vm/jit/tools/Makefile]
 989                 [src/vm/jit/verify/Makefile]
 990                 [src/vm/jit/x86_64/Makefile]
 991                 [src/vm/jit/x86_64/freebsd/Makefile]
 992                 [src/vm/jit/x86_64/linux/Makefile]
 993                 [src/vmcore/Makefile]
 994                 [tests/Makefile]
 995                 [tests/regression/Makefile]
 996                 [tests/regression/codepatching/Makefile]
 997                 [tests/regression/jasmin/Makefile]
 998                 [tests/regression/native/Makefile]
 999                 [tests/regression/resolving/Makefile]
1000                 [tests/regression/resolving/classes1/Makefile]
1001                 [tests/regression/resolving/classes2/Makefile]
1002                 [tests/regression/resolving/classes3/Makefile]
1003                 )
1004
1005
1006 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
1007 export OPT_CFLAGS
1008 export ARCH_CFLAGS
1009 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
1010
1011
1012 AC_OUTPUT
1013
1014
1015 ## Local variables:
1016 ## mode: m4
1017 ## indent-tabs-mode: t
1018 ## c-basic-offset: 4
1019 ## tab-width: 8
1020 ## compile-command: "automake --add-missing"
1021 ## End: