configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl set optimization and debugging for all architectures and systems
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-O0 -g"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 dnl system type
  46 case "$host_cpu" in
  47 alpha | alphaev56 | alphapca56 )
  48     ARCH_DIR="alpha"
  49     ARCH_CFLAGS="-mieee -D__ALPHA__"
  50     JAVA_ARCH="alpha"
  51     ;;
  52
  53 arm | armv4 | armv4tl | armv5b | armv5l )
  54     ARCH_DIR="arm"
  55     ARCH_CFLAGS="-D__ARM__"
  56     JAVA_ARCH="arm"
  57     ;;
  58
  59 hppa2.0 )
  60     ARCH_DIR="parisc"
  61     ARCH_CFLAGS="-D__PARISC__"
  62     JAVA_ARCH="hppa"
  63     ;;
  64
  65 i386 | i486 | i586 | i686 )
  66     ARCH_DIR="i386"
  67     ARCH_CFLAGS="-D__I386__"
  68     JAVA_ARCH="i386"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     JAVA_ARCH="m68k"
  75     ;;
  76
  77 mips | mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_CFLAGS="-D__MIPS__"
  80     dnl Is this correct for mipsel?
  81     JAVA_ARCH="mips"
  82     ;;
  83
  84 powerpc )
  85     ARCH_DIR="powerpc"
  86     ARCH_CFLAGS="-D__POWERPC__"
  87     JAVA_ARCH="ppc"
  88     ;;
  89
  90 powerpc64 )
  91     ARCH_DIR="powerpc64"
  92     ARCH_CFLAGS="-D__POWERPC64__"
  93     JAVA_ARCH="ppc64"
  94     ;;
  95
  96 s390 )
  97     ARCH_DIR="s390"
  98     ARCH_CFLAGS="-D__S390__"
  99     JAVA_ARCH="s390"
 100     ;;
 101
 102 sparc | sparc64 )
 103     ARCH_DIR="sparc64"
 104     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 105     dnl Is this correct for 64-bits?
 106     JAVA_ARCH="sparc"
 107     ;;
 108
 109 x86_64 )
 110     ARCH_DIR="x86_64"
 111     ARCH_CFLAGS="-D__X86_64__"
 112     JAVA_ARCH="amd64"
 113     ;;
 114
 115 xdspcore )
 116     ARCH_DIR="xdspcore"
 117     ENABLE_STATICVM="yes"
 118     ARCH_CFLAGS="-D__XDSPCORE__"
 119     USE_SCHEDULER="1"
 120     ;;
 121
 122 * )
 123     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 124     ;;
 125 esac
 126
 127 dnl host type
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 132     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -std=c99 -pedantic -Wall -Wno-long-long"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 138     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -std=c99 -pedantic -Wall -Wno-long-long"
 139     ;;
 140
 141 dnl Must be BEFORE *freebsd*.
 142 *kfreebsd*-gnu)
 143     OS_DIR="freebsd"
 144     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 145     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 146     ;;
 147
 148 *freebsd* )
 149     OS_DIR="freebsd"
 150     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 151     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 152     ;;
 153
 154 *irix* )
 155     OS_DIR="irix"
 156     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 157     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 158     ;;
 159
 160 dnl Must be BEFORE *linux*.
 161 *uclinux | *elf )
 162     OS_DIR="uclinux"
 163     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 165     ;;
 166
 167 *linux* | *Linux* )
 168     OS_DIR="linux"
 169     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 171     ;;
 172
 173 *netbsd* )
 174     OS_DIR="netbsd"
 175     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 177     ;;
 178
 179 *solaris* )
 180     OS_DIR="solaris"
 181     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 182     dnl not set when cpp is called with -std=c99, therefore we add them
 183     dnl here.
 184     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 185     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -std=c99 -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 186     ;;
 187
 188 * )
 189     ;;
 190 esac
 191
 192
 193 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 194 dnl we set it properly at the end of this file
 195 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 196
 197 dnl set interpreter flags
 198 AC_SUBST(INTRP_CFLAGS)
 199
 200 dnl define and substitute some architecture specific variables
 201 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 202 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 203 AC_SUBST(ARCH_DIR)
 204 AC_SUBST(JAVA_ARCH)
 205 AC_SUBST(OS_DIR)
 206 AC_SUBST(USE_SCHEDULER)
 207
 208
 209 dnl Checks for programs.
 210 AC_PROG_CC
 211 AM_PROG_AS
 212 AC_PROG_LD
 213 AC_PROG_LD_GNU
 214 AC_PROG_LN_S
 215 AC_PROG_MAKE_SET
 216 AM_PROG_MKDIR_P
 217
 218 dnl Checks for header files.
 219 AC_HEADER_DIRENT
 220 AC_HEADER_STDC
 221
 222 dnl Crucial header files.
 223 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 224 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 225
 226 dnl keep them alpha-sorted!
 227 AC_CHECK_HEADERS([assert.h])
 228 AC_CHECK_HEADERS([errno.h])
 229 AC_CHECK_HEADERS([fcntl.h])
 230 AC_CHECK_HEADERS([libgen.h])
 231 AC_CHECK_HEADERS([netdb.h])
 232 AC_CHECK_HEADERS([stdint.h])
 233 AC_CHECK_HEADERS([stdio.h])
 234 AC_CHECK_HEADERS([stdlib.h])
 235 AC_CHECK_HEADERS([string.h])
 236 AC_CHECK_HEADERS([time.h])
 237 AC_CHECK_HEADERS([ucontext.h])
 238 AC_CHECK_HEADERS([unistd.h])
 239 AC_CHECK_HEADERS([sys/ioctl.h])
 240 AC_CHECK_HEADERS([sys/mman.h])
 241 AC_CHECK_HEADERS([sys/resource.h])
 242 AC_CHECK_HEADERS([sys/select.h])
 243 AC_CHECK_HEADERS([sys/socket.h])
 244 AC_CHECK_HEADERS([sys/stat.h])
 245 AC_CHECK_HEADERS([sys/time.h])
 246 AC_CHECK_HEADERS([sys/types.h])
 247
 248 dnl Checks for typedefs, structures, and compiler characteristics.
 249 AC_C_CONST
 250 AC_C_INLINE
 251 AC_C_ATTRIBUTE
 252 AC_TYPE_OFF_T
 253 AC_TYPE_SIZE_T
 254 AC_HEADER_TIME
 255 AC_STRUCT_TM
 256
 257 dnl Checks for libraries (NOTE: Should be done before function checks,
 258 dnl as some functions may be in libraries we check for).
 259
 260 dnl Checks for library functions.
 261 AC_PROG_GCC_TRADITIONAL
 262 AC_TYPE_SIGNAL
 263 AC_FUNC_MEMCMP
 264 AC_FUNC_MMAP
 265
 266 dnl keep them alpha-sorted!
 267 AC_CHECK_FUNCS([abort])
 268 AC_CHECK_FUNCS([accept])
 269 AC_CHECK_FUNCS([access])
 270 AC_CHECK_FUNCS([atoi])
 271 AC_CHECK_FUNCS([atol])
 272 AC_CHECK_FUNCS([calloc])
 273 AC_CHECK_FUNCS([close])
 274 AC_CHECK_FUNCS([confstr])
 275 AC_CHECK_FUNCS([connect])
 276 AC_CHECK_FUNCS([dirname])
 277 AC_CHECK_FUNCS([fclose])
 278 AC_CHECK_FUNCS([fflush])
 279 AC_CHECK_FUNCS([fopen])
 280 AC_CHECK_FUNCS([fprintf])
 281 AC_CHECK_FUNCS([fread])
 282 AC_CHECK_FUNCS([free])
 283 AC_CHECK_FUNCS([fstat])
 284 AC_CHECK_FUNCS([fsync])
 285 AC_CHECK_FUNCS([ftruncate])
 286 AC_CHECK_FUNCS([getcwd])
 287 AC_CHECK_FUNCS([gethostbyname])
 288 AC_CHECK_FUNCS([gethostname])
 289 AC_CHECK_FUNCS([getpagesize])
 290 AC_CHECK_FUNCS([getrusage])
 291 AC_CHECK_FUNCS([getsockname])
 292 AC_CHECK_FUNCS([getsockopt])
 293 AC_CHECK_FUNCS([gettimeofday])
 294 AC_CHECK_FUNCS([htons])
 295 AC_CHECK_FUNCS([ioctl])
 296 AC_CHECK_FUNCS([isnan])
 297 AC_CHECK_FUNCS([listen])
 298 AC_CHECK_FUNCS([localtime])
 299 AC_CHECK_FUNCS([localtime_r])
 300 AC_CHECK_FUNCS([lseek])
 301 AC_CHECK_FUNCS([malloc])
 302 AC_CHECK_FUNCS([memcpy])
 303 AC_CHECK_FUNCS([memset])
 304 AC_CHECK_FUNCS([mmap])
 305 AC_CHECK_FUNCS([mprotect])
 306 AC_CHECK_FUNCS([open])
 307 AC_CHECK_FUNCS([read])
 308 AC_CHECK_FUNCS([readlink])
 309 AC_CHECK_FUNCS([realloc])
 310 AC_CHECK_FUNCS([recv])
 311 AC_CHECK_FUNCS([scandir])
 312 AC_CHECK_FUNCS([select])
 313 AC_CHECK_FUNCS([send])
 314 AC_CHECK_FUNCS([setsockopt])
 315 AC_CHECK_FUNCS([shutdown])
 316 AC_CHECK_FUNCS([socket])
 317 AC_CHECK_FUNCS([stat])
 318 AC_CHECK_FUNCS([strcat])
 319 AC_CHECK_FUNCS([strchr])
 320 AC_CHECK_FUNCS([strcpy])
 321 AC_CHECK_FUNCS([strdup])
 322 AC_CHECK_FUNCS([strerror])
 323 AC_CHECK_FUNCS([strlen])
 324 AC_CHECK_FUNCS([strncmp])
 325 AC_CHECK_FUNCS([strstr])
 326 AC_CHECK_FUNCS([time])
 327 AC_CHECK_FUNCS([write])
 328
 329
 330 dnl Checks for libraries.
 331
 332 dnl Checking sizeof void *
 333 AC_CHECK_SIZEOF(void *)
 334 AC_C_BIGENDIAN
 335
 336
 337 dnl define install prefix
 338 if test "x$prefix" = "xNONE"; then
 339     CACAO_PREFIX=$ac_default_prefix
 340 else
 341     CACAO_PREFIX=$prefix
 342 fi
 343 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 344 AC_SUBST(CACAO_PREFIX)
 345
 346 dnl define libdir prefix
 347 if test "x$libdir" = "xNONE"; then
 348     CACAO_LIBDIR=$ac_default_libdir
 349 else
 350     CACAO_LIBDIR=$libdir
 351 fi
 352 dnl expand CACAO_LIBDIR to something that is usable in C code
 353 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 354 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 355 AC_SUBST(CACAO_LIBDIR)
 356
 357
 358 AC_CHECK_ENABLE_DL
 359 AC_CHECK_ENABLE_JAVA
 360
 361 AC_CHECK_ENABLE_JIT
 362 AC_CHECK_ENABLE_INTRP
 363
 364 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 365     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 366 fi
 367
 368 AC_CHECK_SOFTFLOAT
 369 AC_CHECK_SOFT_FLOAT_CMP
 370 AC_CHECK_SOFT_DOUBLE_CMP
 371
 372 AC_CHECK_ENABLE_GC
 373 AC_CHECK_ENABLE_DEBUG
 374 AC_CHECK_ENABLE_DUMP
 375 AC_CHECK_ENABLE_MEMCHECK
 376 AC_CHECK_ENABLE_HANDLES
 377 AC_CHECK_ENABLE_VMLOG
 378 AC_CHECK_ENABLE_DISASSEMBLER
 379 AC_CHECK_ENABLE_STATISTICS
 380 AC_CHECK_ENABLE_VERIFIER
 381
 382 dnl check for compiler timing
 383 AC_MSG_CHECKING(whether real-time timing should be enabled)
 384 AC_ARG_ENABLE([rt-timing],
 385               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 386               [case "${enableval}" in
 387                    yes) ENABLE_RT_TIMING=yes;;
 388                    *) ENABLE_RT_TIMING=no;;
 389                esac],
 390               [ENABLE_RT_TIMING=no])
 391 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 392 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 393
 394 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 395     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 396 fi
 397
 398
 399 dnl check for cycle count statistics
 400 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 401 AC_ARG_ENABLE([cycles-stats],
 402               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 403               [case "${enableval}" in
 404                    yes) ENABLE_CYCLES_STATS=yes;;
 405                    *) ENABLE_CYCLES_STATS=no;;
 406                esac],
 407               [ENABLE_CYCLES_STATS=no])
 408 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 409 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 410
 411 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 412     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 413 fi
 414
 415 AC_CHECK_ENABLE_JVMTI
 416 AC_CHECK_ENABLE_THREADS
 417
 418
 419 dnl check if if-conversion should be supported
 420 AC_MSG_CHECKING(whether if-conversion should be supported)
 421 AC_ARG_ENABLE([ifconv],
 422               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=enabled]])],
 423               [case "${enableval}" in
 424                    no) ENABLE_IFCONV=no;;
 425                    *) ENABLE_IFCONV=yes;;
 426                esac],
 427               [ENABLE_IFCONV=yes])
 428 AC_MSG_RESULT(${ENABLE_IFCONV})
 429 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 430
 431 if test x"${ENABLE_IFCONV}" = "xyes"; then
 432     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 433 fi
 434
 435 AC_CHECK_ENABLE_INLINING
 436 AC_CHECK_ENABLE_INLINING_DEBUG
 437 AC_CHECK_ENABLE_REPLACEMENT
 438
 439 dnl check for loop optimization
 440 AC_MSG_CHECKING(whether loop optimization should be supported)
 441 AC_ARG_ENABLE([loop],
 442               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 443               [case "${enableval}" in
 444                    yes) ENABLE_LOOP=yes;;
 445                    *) ENABLE_LOOP=no;;
 446                esac],
 447               [ENABLE_LOOP=no])
 448 AC_MSG_RESULT(${ENABLE_LOOP})
 449 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 450
 451 if test x"${ENABLE_LOOP}" = "xyes"; then
 452     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 453 fi
 454
 455
 456 dnl check if linear scan register allocator(lsra) with SSA should be used
 457 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 458 AC_ARG_ENABLE([ssa],
 459               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 460               [case "${enableval}" in
 461                    no) ENABLE_SSA=no;;
 462                    *) ENABLE_SSA=yes;;
 463                esac],
 464               [ENABLE_SSA=no])
 465 AC_MSG_RESULT(${ENABLE_SSA})
 466 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 467 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 468 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 469
 470 if test x"${ENABLE_SSA}" = "xyes"; then
 471     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 472     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 473     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 474     ENABLE_LSRA="no"
 475 fi
 476
 477
 478 dnl check if linear scan register allocator(lsra) should be used
 479 AC_MSG_CHECKING(whether lsra should be supported)
 480 AC_ARG_ENABLE([lsra],
 481               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 482               [case "${enableval}" in
 483                    yes) ENABLE_LSRA=yes;;
 484                    *) ENABLE_LSRA=no;;
 485                esac],
 486               [ENABLE_LSRA=no])
 487
 488 if test x"${ENABLE_LSRA}" = "xyes"; then
 489     if test x"${ENABLE_SSA}" = "xyes"; then
 490         ENABLE_LSRA="no"
 491     fi
 492 fi
 493 AC_MSG_RESULT(${ENABLE_LSRA})
 494 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 495
 496 if test x"${ENABLE_LSRA}" = "xyes"; then
 497     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 498 fi
 499
 500 dnl check if profiling should be supported
 501 AC_MSG_CHECKING(whether profiling should be supported)
 502 AC_ARG_ENABLE([profiling],
 503               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 504               [case "${enableval}" in
 505                    yes) ENABLE_PROFILING=yes;;
 506                    *) ENABLE_PROFILING=no;;
 507                esac],
 508               [ENABLE_PROFILING=no])
 509 AC_MSG_RESULT(${ENABLE_PROFILING})
 510 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 511
 512 if test x"${ENABLE_PROFILING}" = "xyes"; then
 513     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 514 fi
 515
 516
 517 dnl check for instruction scheduler
 518 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 519
 520 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 521 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 522         case "${ARCH_DIR}" in
 523                 xdspcore )
 524                         ;;
 525                 * )
 526                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 527                         ;;
 528         esac
 529
 530         AC_MSG_RESULT(yes)
 531         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 532         AM_CONDITIONAL([USE_SCHEDULER], [true])
 533 else
 534         AC_MSG_RESULT(no)
 535         AM_CONDITIONAL([USE_SCHEDULER], [false])
 536 fi
 537
 538
 539 AC_CHECK_ENABLE_ZLIB
 540
 541 dnl check for stuff to be built
 542 AC_CHECK_ENABLE_JNI
 543 AC_CHECK_ENABLE_LIBJVM
 544
 545 dnl ATTENTION: These check must be after setting
 546 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 547 dnl because libtool uses them to build the correct libraries.
 548 AC_LIBTOOL_DLOPEN
 549 AC_PROG_LIBTOOL
 550
 551 AC_CHECK_ENABLE_STATICVM
 552 AC_CHECK_ENABLE_ANNOTATIONS
 553 AC_CHECK_ENABLE_ASSERTION
 554
 555
 556 dnl where is CACAO's vm.zip
 557 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 558 AC_ARG_WITH([vm-zip],
 559             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 560             [CACAO_VM_ZIP=${withval}],
 561             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 562 AC_MSG_RESULT(${CACAO_VM_ZIP})
 563 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 564 AC_SUBST(CACAO_VM_ZIP)
 565
 566
 567 AC_CHECK_WITH_CACAOH
 568 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 569
 570 dnl Now we check for jre-layout so we can skip some checks that are
 571 dnl not required.
 572 AC_CHECK_ENABLE_JRE_LAYOUT
 573
 574 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 575 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 576
 577 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 578    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 579 fi
 580
 581 dnl The check for jni_md.h must be before jni.h.
 582 AC_CHECK_WITH_JNI_MD_H
 583 AC_CHECK_WITH_JNI_H
 584
 585 dnl HPI is only required for OpenJDK
 586 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 587     openjdk)
 588         AC_CHECK_WITH_HPI_MD_H
 589         AC_CHECK_WITH_HPI_H
 590         ;;
 591     *)
 592         ;;
 593 esac
 594
 595 dnl check for some programs we need
 596
 597 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 598     cldc1.1 | gnuclasspath)
 599         AC_PROG_JAVAC
 600         AC_PROG_JAR
 601         ;;
 602     openjdk)
 603         ;;
 604     *)
 605         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 606         ;;
 607 esac
 608
 609 AC_CHECK_WITH_JASMIN_JAR
 610 AC_CHECK_WITH_JUNIT_JAR
 611
 612 AC_CHECK_HEADERS(
 613         [regex.h],
 614         [
 615                 dnl If debug build and regex.h available, enable debug filter
 616                 if test x"${NDEBUG}" = "xno"; then
 617                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 618                 fi
 619                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 620                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 621         ],
 622         [
 623                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 624         ]
 625 )
 626
 627 dnl python
 628
 629 AZ_PYTHON_DEFAULT
 630 AZ_PYTHON_ENABLE
 631 AZ_PYTHON_WITH
 632 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 633 AZ_PYTHON_CSPEC
 634 AZ_PYTHON_LSPEC
 635
 636
 637 dnl define some stuff required for --fullversion
 638 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 639 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 640 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CPPFLAGS", [CFLAGS used])
 641
 642
 643 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 644 CFLAGS="$OPT_CFLAGS"
 645 AM_CFLAGS=$ARCH_CFLAGS
 646 AM_CPPFLAGS="$CPPFLAGS"
 647 AC_SUBST(AM_CFLAGS)
 648 AC_SUBST(AM_CPPFLAGS)
 649
 650
 651 AC_CONFIG_FILES([Makefile]
 652                 [contrib/Makefile]
 653                 [contrib/setenvinstalled]
 654                 [contrib/setenvsource]
 655                 [contrib/vmlog/Makefile]
 656                 [contrib/vmlog/t/Makefile]
 657                 [doc/Makefile]
 658                 [doc/doxygen/Makefile]
 659                 [doc/handbook/Makefile]
 660                 [man/Makefile]
 661                 [src/Makefile]
 662                 [src/cacao/Makefile]
 663                 [src/cacaoh/Makefile]
 664                 [src/classes/Makefile]
 665                 [src/fdlibm/Makefile]
 666                 [src/mm/Makefile]
 667                 [src/mm/cacao-gc/Makefile]
 668                 [src/native/Makefile]
 669                 [src/native/include/Makefile]
 670                 [src/native/jvmti/Makefile]
 671                 [src/native/vm/Makefile]
 672                 [src/native/vm/cldc1.1/Makefile]
 673                 [src/native/vm/gnuclasspath/Makefile]
 674                 [src/native/vm/openjdk/Makefile]
 675                 [src/scripts/Makefile]
 676                 [src/scripts/java]
 677                 [src/threads/Makefile]
 678                 [src/threads/none/Makefile]
 679                 [src/threads/posix/Makefile]
 680                 [src/toolbox/Makefile]
 681                 [src/vm/Makefile]
 682                 [src/vm/jit/Makefile]
 683                 [src/vm/jit/allocator/Makefile]
 684                 [src/vm/jit/alpha/Makefile]
 685                 [src/vm/jit/alpha/freebsd/Makefile]
 686                 [src/vm/jit/alpha/linux/Makefile]
 687                 [src/vm/jit/arm/Makefile]
 688                 [src/vm/jit/arm/linux/Makefile]
 689                 [src/vm/jit/i386/Makefile]
 690                 [src/vm/jit/i386/cygwin/Makefile]
 691                 [src/vm/jit/i386/darwin/Makefile]
 692                 [src/vm/jit/i386/freebsd/Makefile]
 693                 [src/vm/jit/i386/linux/Makefile]
 694                 [src/vm/jit/intrp/Makefile]
 695                 [src/vm/jit/inline/Makefile]
 696                 [src/vm/jit/ir/Makefile]
 697                 [src/vm/jit/loop/Makefile]
 698                 [src/vm/jit/m68k/Makefile]
 699                 [src/vm/jit/m68k/linux/Makefile]
 700                 [src/vm/jit/mips/Makefile]
 701                 [src/vm/jit/mips/irix/Makefile]
 702                 [src/vm/jit/mips/linux/Makefile]
 703                 [src/vm/jit/mips/uclinux/Makefile]
 704                 [src/vm/jit/optimizing/Makefile]
 705                 [src/vm/jit/parisc/Makefile]
 706                 [src/vm/jit/parisc/linux/Makefile]
 707                 [src/vm/jit/powerpc/Makefile]
 708                 [src/vm/jit/powerpc/darwin/Makefile]
 709                 [src/vm/jit/powerpc/linux/Makefile]
 710                 [src/vm/jit/powerpc/netbsd/Makefile]
 711                 [src/vm/jit/powerpc64/Makefile]
 712                 [src/vm/jit/powerpc64/linux/Makefile]
 713                 [src/vm/jit/s390/Makefile]
 714                 [src/vm/jit/schedule/Makefile]
 715                 [src/vm/jit/sparc64/Makefile]
 716                 [src/vm/jit/sparc64/linux/Makefile]
 717                 [src/vm/jit/sparc64/solaris/Makefile]
 718                 [src/vm/jit/verify/Makefile]
 719                 [src/vm/jit/x86_64/Makefile]
 720                 [src/vm/jit/x86_64/freebsd/Makefile]
 721                 [src/vm/jit/x86_64/linux/Makefile]
 722                 [src/vmcore/Makefile]
 723                 [tests/Makefile]
 724                 [tests/regression/Makefile]
 725                 [tests/regression/assertion/Makefile]
 726                 [tests/regression/base/Makefile]
 727                 [tests/regression/bugzilla/Makefile]
 728                 [tests/regression/jasmin/Makefile]
 729                 [tests/regression/native/Makefile]
 730                 [tests/regression/resolving/Makefile]
 731                 [tests/regression/resolving/classes1/Makefile]
 732                 [tests/regression/resolving/classes2/Makefile]
 733                 [tests/regression/resolving/classes3/Makefile]
 734 )
 735
 736
 737 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
 738 export OPT_CFLAGS
 739 export ARCH_CFLAGS
 740 dnl We only build the shared library objects but we use it as
 741 dnl noinst_LTLIBRARIES
 742 ac_configure_args="$ac_configure_args --disable-static"
 743 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 744
 745
 746 AC_OUTPUT
 747
 748
 749 ## Local variables:
 750 ## mode: m4
 751 ## indent-tabs-mode: t
 752 ## c-basic-offset: 4
 753 ## tab-width: 8
 754 ## compile-command: "automake --add-missing"
 755 ## End: