configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl Set optimization and debugging for all architectures and systems.
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-g -O0"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 if test x"$CXXFLAGS" = "x"; then
  46     OPT_CXXFLAGS="-g -O0"
  47 else
  48     OPT_CXXFLAGS=$CXXFLAGS
  49 fi
  50
  51 dnl system type
  52 case "$host_cpu" in
  53 alpha | alphaev56 | alphapca56 )
  54     ARCH_DIR="alpha"
  55     ARCH_FLAGS="-mieee -D__ALPHA__"
  56     JAVA_ARCH="alpha"
  57     ;;
  58
  59 arm | armv4 | armv4tl | armv5b | armv5l | armv5tel | armv5tejl )
  60     ARCH_DIR="arm"
  61     ARCH_FLAGS="-D__ARM__"
  62     JAVA_ARCH="arm"
  63     ;;
  64
  65 hppa2.0 )
  66     ARCH_DIR="parisc"
  67     ARCH_FLAGS="-D__PARISC__"
  68     JAVA_ARCH="hppa"
  69     ;;
  70
  71 i386 | i486 | i586 | i686 )
  72     ARCH_DIR="i386"
  73     ARCH_FLAGS="-m32 -D__I386__"
  74     JAVA_ARCH="i386"
  75     ;;
  76
  77 m68k )
  78     ARCH_DIR="m68k"
  79     ARCH_FLAGS="-D__M68K__"
  80     JAVA_ARCH="m68k"
  81     ;;
  82
  83 mips | mipsel )
  84     ARCH_DIR="mips"
  85     ARCH_FLAGS="-D__MIPS__"
  86     dnl Is this correct for mipsel?
  87     JAVA_ARCH="mips"
  88     ;;
  89
  90 powerpc )
  91     ARCH_DIR="powerpc"
  92     ARCH_FLAGS="-m32 -D__POWERPC__"
  93     JAVA_ARCH="ppc"
  94     ;;
  95
  96 powerpc64 )
  97     ARCH_DIR="powerpc64"
  98     ARCH_FLAGS="-m64 -D__POWERPC64__"
  99     JAVA_ARCH="ppc64"
 100     ;;
 101
 102 s390 )
 103     ARCH_DIR="s390"
 104     ARCH_FLAGS="-D__S390__"
 105     JAVA_ARCH="s390"
 106     ;;
 107
 108 sparc | sparc64 )
 109     ARCH_DIR="sparc64"
 110     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 111     dnl Is this correct for 64-bits?
 112     JAVA_ARCH="sparc"
 113     ;;
 114
 115 x86_64 )
 116     ARCH_DIR="x86_64"
 117     ARCH_FLAGS="-m64 -D__X86_64__"
 118     JAVA_ARCH="amd64"
 119     ;;
 120
 121 xdspcore )
 122     ARCH_DIR="xdspcore"
 123     ENABLE_STATICVM="yes"
 124     ARCH_FLAGS="-D__XDSPCORE__"
 125     USE_SCHEDULER="1"
 126     ;;
 127
 128 * )
 129     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 130     ;;
 131 esac
 132
 133 dnl host type
 134 case "$host_os" in
 135 *cygwin* )
 136     OS_DIR="cygwin"
 137     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 138     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 139     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 140     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 141     ;;
 142
 143 *darwin* )
 144     OS_DIR="darwin"
 145     OS_FLAGS="-D__DARWIN__"
 146     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 147     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 148     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 149     ;;
 150
 151 dnl Must be BEFORE *freebsd*.
 152 *kfreebsd*-gnu)
 153     OS_DIR="freebsd"
 154     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 156     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 157     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 *freebsd* )
 161     OS_DIR="freebsd"
 162     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 163     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 164     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 165     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 166     ;;
 167
 168 *irix* )
 169     OS_DIR="irix"
 170     OS_FLAGS="-D__IRIX__"
 171     CC_FLAGS=""
 172     CXX_FLAGS=""
 173     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 174     ;;
 175
 176 dnl Must be BEFORE *linux*.
 177 *uclinux | *elf )
 178     OS_DIR="uclinux"
 179     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 180     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 181     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 182     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 183     ;;
 184
 185 *linux* | *Linux* )
 186     OS_DIR="linux"
 187     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 188     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 189     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 190     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 191     ;;
 192
 193 *netbsd* )
 194     OS_DIR="netbsd"
 195     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 196     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long"
 197     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 198     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 199     ;;
 200
 201 *solaris* )
 202     OS_DIR="solaris"
 203     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 204     dnl not set when cpp is called with -std=c99, therefore we add them
 205     dnl here.
 206     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 207     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE=600"
 208     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long"
 209     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 210     ;;
 211
 212 * )
 213     ;;
 214 esac
 215
 216
 217 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 218 dnl we set it properly at the end of this file
 219 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 220 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 221
 222 dnl set interpreter flags
 223 AC_SUBST(INTRP_CFLAGS)
 224
 225 dnl define and substitute some architecture specific variables
 226 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 227 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 228 AC_SUBST(ARCH_DIR)
 229 AC_SUBST(JAVA_ARCH)
 230 AC_SUBST(OS_DIR)
 231 AC_SUBST(USE_SCHEDULER)
 232
 233
 234 dnl Checks for programs.
 235 AC_PROG_CC
 236 AC_PROG_CXX
 237 AM_PROG_AS
 238 AC_PROG_LD
 239 AC_PROG_LD_GNU
 240 AC_PROG_LN_S
 241 AC_PROG_MAKE_SET
 242 AM_PROG_MKDIR_P
 243
 244 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 245
 246 dnl Checks for header files.
 247 AC_HEADER_DIRENT
 248 AC_HEADER_STDC
 249
 250 dnl Crucial header files.
 251 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 252 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 253
 254 dnl keep them alpha-sorted!
 255 AC_CHECK_HEADERS([assert.h])
 256 AC_CHECK_HEADERS([errno.h])
 257 AC_CHECK_HEADERS([execinfo.h])
 258 AC_CHECK_HEADERS([fcntl.h])
 259 AC_CHECK_HEADERS([libgen.h])
 260 AC_CHECK_HEADERS([netdb.h])
 261 AC_CHECK_HEADERS([signal.h])
 262 AC_CHECK_HEADERS([stdarg.h])
 263 AC_CHECK_HEADERS([stdint.h])
 264 AC_CHECK_HEADERS([stdio.h])
 265 AC_CHECK_HEADERS([stdlib.h])
 266 AC_CHECK_HEADERS([string.h])
 267 AC_CHECK_HEADERS([time.h])
 268 AC_CHECK_HEADERS([ucontext.h])
 269 AC_CHECK_HEADERS([unistd.h])
 270 AC_CHECK_HEADERS([sys/ioctl.h])
 271 AC_CHECK_HEADERS([sys/mman.h])
 272 AC_CHECK_HEADERS([sys/resource.h])
 273 AC_CHECK_HEADERS([sys/select.h])
 274 AC_CHECK_HEADERS([sys/socket.h])
 275 AC_CHECK_HEADERS([sys/stat.h])
 276 AC_CHECK_HEADERS([sys/time.h])
 277 AC_CHECK_HEADERS([sys/types.h])
 278
 279 dnl Checks for typedefs, structures, and compiler characteristics.
 280 AC_C_CONST
 281 AC_C_INLINE
 282 AC_C_ATTRIBUTE
 283 AC_TYPE_OFF_T
 284 AC_TYPE_SIZE_T
 285 AC_HEADER_TIME
 286 AC_STRUCT_TM
 287
 288 dnl Checks for libraries (NOTE: Should be done before function checks,
 289 dnl as some functions may be in libraries we check for).
 290
 291 case "${OS_DIR}" in
 292     solaris )
 293          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 294          ;;
 295 esac
 296
 297 dnl Checks for library functions.
 298 AC_PROG_GCC_TRADITIONAL
 299 AC_TYPE_SIGNAL
 300 AC_FUNC_MEMCMP
 301 AC_FUNC_MMAP
 302
 303 dnl keep them alpha-sorted!
 304 AC_CHECK_FUNCS([abort])
 305 AC_CHECK_FUNCS([accept])
 306 AC_CHECK_FUNCS([access])
 307 AC_CHECK_FUNCS([atoi])
 308 AC_CHECK_FUNCS([atol])
 309 AC_CHECK_FUNCS([backtrace])
 310 AC_CHECK_FUNCS([backtrace_symbols])
 311 AC_CHECK_FUNCS([calloc])
 312 AC_CHECK_FUNCS([close])
 313 AC_CHECK_FUNCS([confstr])
 314 AC_CHECK_FUNCS([connect])
 315 AC_CHECK_FUNCS([dirname])
 316 AC_CHECK_FUNCS([fclose])
 317 AC_CHECK_FUNCS([fflush])
 318 AC_CHECK_FUNCS([fopen])
 319 AC_CHECK_FUNCS([fprintf])
 320 AC_CHECK_FUNCS([fread])
 321 AC_CHECK_FUNCS([free])
 322 AC_CHECK_FUNCS([fstat])
 323 AC_CHECK_FUNCS([fsync])
 324 AC_CHECK_FUNCS([ftruncate])
 325 AC_CHECK_FUNCS([getcwd])
 326 AC_CHECK_FUNCS([getenv])
 327 AC_CHECK_FUNCS([gethostbyname])
 328 AC_CHECK_FUNCS([gethostname])
 329 AC_CHECK_FUNCS([getpagesize])
 330 AC_CHECK_FUNCS([getrusage])
 331 AC_CHECK_FUNCS([getsockname])
 332 AC_CHECK_FUNCS([getsockopt])
 333 AC_CHECK_FUNCS([gettimeofday])
 334 AC_CHECK_FUNCS([htons])
 335 AC_CHECK_FUNCS([ioctl])
 336 AC_CHECK_FUNCS([isnan])
 337 AC_CHECK_FUNCS([listen])
 338 AC_CHECK_FUNCS([localtime])
 339 AC_CHECK_FUNCS([localtime_r])
 340 AC_CHECK_FUNCS([lseek])
 341 AC_CHECK_FUNCS([malloc])
 342 AC_CHECK_FUNCS([memcpy])
 343 AC_CHECK_FUNCS([memset])
 344 AC_CHECK_FUNCS([mmap])
 345 AC_CHECK_FUNCS([mprotect])
 346 AC_CHECK_FUNCS([open])
 347 AC_CHECK_FUNCS([printf])
 348 AC_CHECK_FUNCS([read])
 349 AC_CHECK_FUNCS([readlink])
 350 AC_CHECK_FUNCS([realloc])
 351 AC_CHECK_FUNCS([recv])
 352 AC_CHECK_FUNCS([scandir])
 353 AC_CHECK_FUNCS([select])
 354 AC_CHECK_FUNCS([send])
 355 AC_CHECK_FUNCS([setsockopt])
 356 AC_CHECK_FUNCS([shutdown])
 357 AC_CHECK_FUNCS([socket])
 358 AC_CHECK_FUNCS([stat])
 359 AC_CHECK_FUNCS([str2sig])
 360 AC_CHECK_FUNCS([strcat])
 361 AC_CHECK_FUNCS([strchr])
 362 AC_CHECK_FUNCS([strcpy])
 363 AC_CHECK_FUNCS([strcmp])
 364 AC_CHECK_FUNCS([strdup])
 365 AC_CHECK_FUNCS([strerror])
 366 AC_CHECK_FUNCS([strlen])
 367 AC_CHECK_FUNCS([strncmp])
 368 AC_CHECK_FUNCS([strstr])
 369 AC_CHECK_FUNCS([time])
 370 AC_CHECK_FUNCS([va_end])
 371 AC_CHECK_FUNCS([va_start])
 372 AC_CHECK_FUNCS([write])
 373
 374
 375 dnl Checks for libraries.
 376
 377 dnl Checking sizeof void *
 378 AC_CHECK_SIZEOF(void *)
 379 AC_C_BIGENDIAN
 380
 381
 382 dnl define install prefix
 383 if test "x$prefix" = "xNONE"; then
 384     CACAO_PREFIX=$ac_default_prefix
 385 else
 386     CACAO_PREFIX=$prefix
 387 fi
 388 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 389 AC_SUBST(CACAO_PREFIX)
 390
 391 dnl define libdir prefix
 392 if test "x$libdir" = "xNONE"; then
 393     CACAO_LIBDIR=$ac_default_libdir
 394 else
 395     CACAO_LIBDIR=$libdir
 396 fi
 397 dnl expand CACAO_LIBDIR to something that is usable in C code
 398 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 399 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 400 AC_SUBST(CACAO_LIBDIR)
 401
 402
 403 AC_CHECK_ENABLE_DL
 404 AC_CHECK_ENABLE_JAVA
 405
 406 AC_CHECK_ENABLE_JIT
 407 AC_CHECK_ENABLE_INTRP
 408
 409 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 410     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 411 fi
 412
 413 AC_CHECK_SOFTFLOAT
 414 AC_CHECK_SOFT_FLOAT_CMP
 415 AC_CHECK_SOFT_DOUBLE_CMP
 416
 417 AC_CHECK_ENABLE_GC
 418 AC_CHECK_ENABLE_DEBUG
 419 AC_CHECK_ENABLE_DUMP
 420 AC_CHECK_ENABLE_MEMCHECK
 421 AC_CHECK_ENABLE_HANDLES
 422 AC_CHECK_ENABLE_VMLOG
 423 AC_CHECK_ENABLE_DISASSEMBLER
 424 AC_CHECK_ENABLE_STATISTICS
 425 AC_CHECK_ENABLE_VERIFIER
 426 AC_CHECK_ENABLE_RT_TIMING
 427 AC_CHECK_ENABLE_CYCLE_STATS
 428 AC_CHECK_ENABLE_JVMTI
 429 AC_CHECK_ENABLE_THREADS
 430 AC_CHECK_ENABLE_IFCONV
 431 AC_CHECK_ENABLE_INLINING
 432 AC_CHECK_ENABLE_INLINING_DEBUG
 433 AC_CHECK_ENABLE_REPLACEMENT
 434
 435 dnl check for loop optimization
 436 AC_MSG_CHECKING(whether loop optimization should be supported)
 437 AC_ARG_ENABLE([loop],
 438               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 439               [case "${enableval}" in
 440                    yes) ENABLE_LOOP=yes;;
 441                    *) ENABLE_LOOP=no;;
 442                esac],
 443               [ENABLE_LOOP=no])
 444 AC_MSG_RESULT(${ENABLE_LOOP})
 445 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 446
 447 if test x"${ENABLE_LOOP}" = "xyes"; then
 448     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 449 fi
 450
 451
 452 dnl check if linear scan register allocator(lsra) with SSA should be used
 453 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 454 AC_ARG_ENABLE([ssa],
 455               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 456               [case "${enableval}" in
 457                    no) ENABLE_SSA=no;;
 458                    *) ENABLE_SSA=yes;;
 459                esac],
 460               [ENABLE_SSA=no])
 461 AC_MSG_RESULT(${ENABLE_SSA})
 462 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 463 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 464 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 465 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 466
 467 if test x"${ENABLE_SSA}" = "xyes"; then
 468     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 469     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 470     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 471     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 472     ENABLE_LSRA="no"
 473 fi
 474
 475
 476 dnl check if linear scan register allocator(lsra) should be used
 477 AC_MSG_CHECKING(whether lsra should be supported)
 478 AC_ARG_ENABLE([lsra],
 479               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 480               [case "${enableval}" in
 481                    yes) ENABLE_LSRA=yes;;
 482                    *) ENABLE_LSRA=no;;
 483                esac],
 484               [ENABLE_LSRA=no])
 485
 486 if test x"${ENABLE_LSRA}" = "xyes"; then
 487     if test x"${ENABLE_SSA}" = "xyes"; then
 488         ENABLE_LSRA="no"
 489     fi
 490 fi
 491 AC_MSG_RESULT(${ENABLE_LSRA})
 492 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 493
 494 if test x"${ENABLE_LSRA}" = "xyes"; then
 495     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 496 fi
 497
 498 dnl check if profiling should be supported
 499 AC_MSG_CHECKING(whether profiling should be supported)
 500 AC_ARG_ENABLE([profiling],
 501               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 502               [case "${enableval}" in
 503                    yes) ENABLE_PROFILING=yes;;
 504                    *) ENABLE_PROFILING=no;;
 505                esac],
 506               [ENABLE_PROFILING=no])
 507 AC_MSG_RESULT(${ENABLE_PROFILING})
 508 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 509
 510 if test x"${ENABLE_PROFILING}" = "xyes"; then
 511     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 512 fi
 513
 514
 515 dnl check for instruction scheduler
 516 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 517
 518 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 519 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 520         case "${ARCH_DIR}" in
 521                 xdspcore )
 522                         ;;
 523                 * )
 524                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 525                         ;;
 526         esac
 527
 528         AC_MSG_RESULT(yes)
 529         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 530         AM_CONDITIONAL([USE_SCHEDULER], [true])
 531 else
 532         AC_MSG_RESULT(no)
 533         AM_CONDITIONAL([USE_SCHEDULER], [false])
 534 fi
 535
 536 AC_CHECK_ENABLE_OPAGENT
 537
 538 AC_CHECK_ENABLE_ZLIB
 539
 540 dnl check for stuff to be built
 541 AC_CHECK_ENABLE_JNI
 542 AC_CHECK_ENABLE_LIBJVM
 543
 544 dnl ATTENTION: These check must be after setting
 545 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 546 dnl because libtool uses them to build the correct libraries.
 547 AC_LIBTOOL_DLOPEN
 548 AC_PROG_LIBTOOL
 549
 550 AC_CHECK_ENABLE_STATICVM
 551 AC_CHECK_ENABLE_ANNOTATIONS
 552 AC_CHECK_ENABLE_ASSERTION
 553
 554 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 555 AC_CHECK_WITH_VM_ZIP
 556
 557 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 558
 559 dnl Now we check for jre-layout so we can skip some checks that are
 560 dnl not required.
 561 AC_CHECK_ENABLE_JRE_LAYOUT
 562
 563 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 564 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 565 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 566
 567 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 568    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 569 fi
 570
 571 dnl The check for jni_md.h must be before jni.h.
 572 AC_CHECK_WITH_JNI_MD_H
 573 AC_CHECK_WITH_JNI_H
 574
 575 dnl HPI is only required for OpenJDK
 576 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 577     openjdk)
 578         AC_CHECK_WITH_HPI_MD_H
 579         AC_CHECK_WITH_HPI_H
 580         ;;
 581     *)
 582         ;;
 583 esac
 584
 585 dnl check for some programs we need
 586
 587 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 588     cldc1.1 | gnuclasspath)
 589         AC_PROG_JAVAC
 590         AC_PROG_JAR
 591         ;;
 592     openjdk)
 593         ;;
 594     *)
 595         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 596         ;;
 597 esac
 598
 599 AC_CHECK_WITH_JASMIN_JAR
 600 AC_CHECK_WITH_JUNIT_JAR
 601
 602 AC_CHECK_HEADERS(
 603         [regex.h],
 604         [
 605                 dnl If debug build and regex.h available, enable debug filter
 606                 if test x"${NDEBUG}" = "xno"; then
 607                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 608                 fi
 609                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 610                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 611         ],
 612         [
 613                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 614         ]
 615 )
 616
 617 dnl python
 618
 619 AZ_PYTHON_DEFAULT
 620 AZ_PYTHON_ENABLE
 621 AZ_PYTHON_WITH
 622 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 623 AZ_PYTHON_CSPEC
 624 AZ_PYTHON_LSPEC
 625
 626
 627 dnl define some stuff required for --fullversion
 628 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 629 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 630 AC_DEFINE_UNQUOTED(VERSION_CXX, "$CXX", [CXX used])
 631 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CC_FLAGS $CPPFLAGS", [CFLAGS used])
 632 AC_DEFINE_UNQUOTED(VERSION_CXXFLAGS, "$OPT_CXXFLAGS $ARCH_CXXFLAGS $CXX_FLAGS $CPPFLAGS", [CXXFLAGS used])
 633
 634
 635 dnl Finally pass flags to Makefiles.
 636 CFLAGS="$OPT_CFLAGS"
 637 CXXFLAGS="$OPT_CXXFLAGS"
 638
 639 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 640 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 641 AM_CPPFLAGS="$CPPFLAGS"
 642
 643 AC_SUBST(AM_CFLAGS)
 644 AC_SUBST(AM_CXXFLAGS)
 645 AC_SUBST(AM_CPPFLAGS)
 646
 647
 648 AC_CONFIG_FILES([Makefile]
 649                 [contrib/Makefile]
 650                 [contrib/setenvinstalled]
 651                 [contrib/setenvsource]
 652                 [contrib/vmlog/Makefile]
 653                 [contrib/vmlog/t/Makefile]
 654                 [doc/Makefile]
 655                 [doc/doxygen/Makefile]
 656                 [doc/handbook/Makefile]
 657                 [man/Makefile]
 658                 [src/Makefile]
 659                 [src/cacao/Makefile]
 660                 [src/classes/Makefile]
 661                 [src/fdlibm/Makefile]
 662                 [src/mm/Makefile]
 663                 [src/mm/cacao-gc/Makefile]
 664                 [src/native/Makefile]
 665                 [src/native/include/Makefile]
 666                 [src/native/jvmti/Makefile]
 667                 [src/native/vm/Makefile]
 668                 [src/native/vm/cldc1.1/Makefile]
 669                 [src/native/vm/gnuclasspath/Makefile]
 670                 [src/native/vm/openjdk/Makefile]
 671                 [src/scripts/Makefile]
 672                 [src/scripts/java]
 673                 [src/threads/Makefile]
 674                 [src/threads/none/Makefile]
 675                 [src/threads/posix/Makefile]
 676                 [src/toolbox/Makefile]
 677                 [src/vm/Makefile]
 678                 [src/vm/jit/Makefile]
 679                 [src/vm/jit/allocator/Makefile]
 680                 [src/vm/jit/alpha/Makefile]
 681                 [src/vm/jit/alpha/freebsd/Makefile]
 682                 [src/vm/jit/alpha/linux/Makefile]
 683                 [src/vm/jit/arm/Makefile]
 684                 [src/vm/jit/arm/linux/Makefile]
 685                 [src/vm/jit/i386/Makefile]
 686                 [src/vm/jit/i386/cygwin/Makefile]
 687                 [src/vm/jit/i386/darwin/Makefile]
 688                 [src/vm/jit/i386/freebsd/Makefile]
 689                 [src/vm/jit/i386/linux/Makefile]
 690                 [src/vm/jit/i386/solaris/Makefile]
 691                 [src/vm/jit/intrp/Makefile]
 692                 [src/vm/jit/inline/Makefile]
 693                 [src/vm/jit/ir/Makefile]
 694                 [src/vm/jit/loop/Makefile]
 695                 [src/vm/jit/m68k/Makefile]
 696                 [src/vm/jit/m68k/linux/Makefile]
 697                 [src/vm/jit/mips/Makefile]
 698                 [src/vm/jit/mips/irix/Makefile]
 699                 [src/vm/jit/mips/linux/Makefile]
 700                 [src/vm/jit/mips/uclinux/Makefile]
 701                 [src/vm/jit/optimizing/Makefile]
 702                 [src/vm/jit/parisc/Makefile]
 703                 [src/vm/jit/parisc/linux/Makefile]
 704                 [src/vm/jit/powerpc/Makefile]
 705                 [src/vm/jit/powerpc/darwin/Makefile]
 706                 [src/vm/jit/powerpc/linux/Makefile]
 707                 [src/vm/jit/powerpc/netbsd/Makefile]
 708                 [src/vm/jit/powerpc64/Makefile]
 709                 [src/vm/jit/powerpc64/linux/Makefile]
 710                 [src/vm/jit/s390/Makefile]
 711                 [src/vm/jit/schedule/Makefile]
 712                 [src/vm/jit/sparc64/Makefile]
 713                 [src/vm/jit/sparc64/linux/Makefile]
 714                 [src/vm/jit/sparc64/solaris/Makefile]
 715                 [src/vm/jit/verify/Makefile]
 716                 [src/vm/jit/x86_64/Makefile]
 717                 [src/vm/jit/x86_64/freebsd/Makefile]
 718                 [src/vm/jit/x86_64/linux/Makefile]
 719                 [src/vm/jit/x86_64/solaris/Makefile]
 720                 [tests/Makefile]
 721                 [tests/regression/Makefile]
 722                 [tests/regression/assertion/Makefile]
 723                 [tests/regression/base/Makefile]
 724                 [tests/regression/bugzilla/Makefile]
 725                 [tests/regression/jasmin/Makefile]
 726                 [tests/regression/native/Makefile]
 727                 [tests/regression/resolving/Makefile]
 728                 [tests/regression/resolving/classes1/Makefile]
 729                 [tests/regression/resolving/classes2/Makefile]
 730                 [tests/regression/resolving/classes3/Makefile]
 731 )
 732
 733
 734 dnl We only build the shared library objects but we use it as
 735 dnl noinst_LTLIBRARIES.
 736 ac_configure_args="$ac_configure_args --disable-static"
 737 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 738
 739
 740 AC_OUTPUT
 741
 742
 743 ## Local variables:
 744 ## mode: m4
 745 ## indent-tabs-mode: t
 746 ## c-basic-offset: 4
 747 ## tab-width: 8
 748 ## compile-command: "automake --add-missing"
 749 ## End: