configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2010
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre2, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CONFIG_AUX_DIR([.])
  29 AC_CANONICAL_HOST
  30 AC_PREREQ(2.59)
  31 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  32 AM_MAINTAINER_MODE
  33
  34 AM_CONFIG_HEADER([config.h])
  35
  36 AC_PREFIX_DEFAULT(/usr/local/cacao)
  37
  38
  39 dnl Host CPU type.
  40 case "$host_cpu" in
  41 alpha | alphaev56 | alphapca56 )
  42     ARCH_DIR="alpha"
  43     ARCH_FLAGS="-mieee -D__ALPHA__"
  44     JAVA_ARCH="alpha"
  45     ;;
  46
  47 arm | armv4* | armv5* | armv6* | armv7* )
  48     ARCH_DIR="arm"
  49     ARCH_FLAGS="-D__ARM__"
  50     JAVA_ARCH="arm"
  51     ;;
  52
  53 hppa2.0 )
  54     ARCH_DIR="parisc"
  55     ARCH_FLAGS="-D__PARISC__"
  56     JAVA_ARCH="hppa"
  57     ;;
  58
  59 i386 | i486 | i586 | i686 )
  60     ARCH_DIR="i386"
  61     ARCH_FLAGS="-m32 -D__I386__"
  62     JAVA_ARCH="i386"
  63     ;;
  64
  65 m68k )
  66     ARCH_DIR="m68k"
  67     ARCH_FLAGS="-D__M68K__"
  68     JAVA_ARCH="m68k"
  69     ;;
  70
  71 mips )
  72     ARCH_DIR="mips"
  73     ARCH_FLAGS="-D__MIPS__"
  74     JAVA_ARCH="mips"
  75     ;;
  76
  77 mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_FLAGS="-D__MIPS__"
  80     JAVA_ARCH="mipsel"
  81     ;;
  82
  83 powerpc )
  84     ARCH_DIR="powerpc"
  85     ARCH_FLAGS="-m32 -D__POWERPC__"
  86     JAVA_ARCH="ppc"
  87     ;;
  88
  89 powerpc64 )
  90     ARCH_DIR="powerpc64"
  91     ARCH_FLAGS="-m64 -D__POWERPC64__"
  92     JAVA_ARCH="ppc64"
  93     ;;
  94
  95 s390 )
  96     ARCH_DIR="s390"
  97     ARCH_FLAGS="-D__S390__"
  98     JAVA_ARCH="s390"
  99     ;;
 100
 101 sparc | sparc64 )
 102     ARCH_DIR="sparc64"
 103     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 104     dnl Is this correct for 64-bits?
 105     JAVA_ARCH="sparc"
 106     ;;
 107
 108 x86_64 )
 109     ARCH_DIR="x86_64"
 110     ARCH_FLAGS="-m64 -D__X86_64__"
 111     JAVA_ARCH="amd64"
 112     ;;
 113
 114 xdspcore )
 115     ARCH_DIR="xdspcore"
 116     ENABLE_STATICVM="yes"
 117     ARCH_FLAGS="-D__XDSPCORE__"
 118     USE_SCHEDULER="1"
 119     ;;
 120
 121 * )
 122     AC_MSG_ERROR([$host_cpu systems are currently not supported.])
 123     ;;
 124 esac
 125
 126
 127 dnl Host operating system type.
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 132     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     OS_FLAGS="-D__DARWIN__ -D_XOPEN_SOURCE=600 -D_DARWIN_C_SOURCE"
 138     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 139     ;;
 140
 141 dnl Must be BEFORE *freebsd*.
 142 *kfreebsd*-gnu)
 143     OS_DIR="freebsd"
 144     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 145     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 146     ;;
 147
 148 *freebsd* )
 149     OS_DIR="freebsd"
 150     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 151     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 152     ;;
 153
 154 *irix* )
 155     OS_DIR="irix"
 156     OS_FLAGS="-D__IRIX__"
 157     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 dnl Must be BEFORE *linux*.
 161 *uclinux | *elf )
 162     OS_DIR="uclinux"
 163     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 165     ;;
 166
 167 *linux* | *Linux* )
 168     OS_DIR="linux"
 169     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 171     ;;
 172
 173 *netbsd* )
 174     OS_DIR="netbsd"
 175     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 177     ;;
 178
 179 *solaris* )
 180     OS_DIR="solaris"
 181     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 182     dnl not set when cpp is called with -std=c99, therefore we add them
 183     dnl here.
 184     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 185     CC_FLAGS="-D_XOPEN_SOURCE=600"
 186     CXX_FLAGS="-D_XOPEN_SOURCE=500"
 187     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 188     ;;
 189
 190 * )
 191     AC_MSG_ERROR([$host_os operating systems are currently not supported.])
 192     ;;
 193 esac
 194
 195
 196 dnl Set optimization and debugging for all architectures and systems.
 197 dnl NOTE: Setting the CFLAGS/CXXFLAGS only works before calling AC_PROG_CC/AC_PROG_CXX.
 198 if test x"$CFLAGS" = "x"; then
 199     OPT_CFLAGS="-g -O2"
 200 else
 201     OPT_CFLAGS=$CFLAGS
 202 fi
 203 OPT_CFLAGS="$OPT_CFLAGS -fno-strict-aliasing"
 204
 205 if test x"$CXXFLAGS" = "x"; then
 206     OPT_CXXFLAGS="-g -O2"
 207 else
 208     OPT_CXXFLAGS=$CXXFLAGS
 209 fi
 210 OPT_CXXFLAGS="$OPT_CXXFLAGS -fno-strict-aliasing"
 211
 212 dnl Check for compiler.
 213 AC_PROG_CC
 214 AC_PROG_CXX
 215
 216 dnl Check compiler vendor.
 217 AX_COMPILER_VENDOR
 218
 219 dnl Set compiler flags depending on the compiler vendor.
 220 case "$ax_cv_c_compiler_vendor" in
 221 gnu )
 222     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long $CC_FLAGS"
 223     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long $CXX_FLAGS"
 224     ;;
 225
 226 sgi )
 227     CC_FLAGS="-c99 $CC_FLAGS"
 228     CXX_FLAGS="$CXX_FLAGS"
 229     ;;
 230
 231 sun )
 232     CC_FLAGS="-xc99 $CC_FLAGS"
 233     CXX_FLAGS="$CXX_FLAGS"
 234     ;;
 235
 236 * )
 237     AC_MSG_ERROR([$ax_cv_c_compiler_vendor compilers are currently not supported.])
 238     ;;
 239 esac
 240
 241 dnl Temporary set the CFLAGS for configure tests (e.g. inline keyword)
 242 dnl we set it properly at the end of this file.
 243 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 244 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 245
 246 dnl set interpreter flags
 247 AC_SUBST(INTRP_CFLAGS)
 248
 249 dnl define and substitute some architecture specific variables
 250 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 251 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 252 AC_SUBST(ARCH_DIR)
 253 AC_SUBST(JAVA_ARCH)
 254 AC_SUBST(OS_DIR)
 255 AC_SUBST(USE_SCHEDULER)
 256
 257 dnl Checks for programs.
 258 AM_PROG_AS
 259 AC_PROG_LD
 260 AC_PROG_LD_GNU
 261 AC_PROG_LN_S
 262 AC_PROG_MAKE_SET
 263 AM_PROG_MKDIR_P
 264
 265 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 266
 267 dnl Checks for header files.
 268 AC_HEADER_DIRENT
 269 AC_HEADER_STDC
 270
 271 dnl Crucial header files.
 272 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 273 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 274
 275 dnl keep them alpha-sorted!
 276 AC_CHECK_HEADERS([assert.h])
 277 AC_CHECK_HEADERS([errno.h])
 278 AC_CHECK_HEADERS([execinfo.h])
 279 AC_CHECK_HEADERS([fcntl.h])
 280 AC_CHECK_HEADERS([libgen.h])
 281 AC_CHECK_HEADERS([locale.h])
 282 AC_CHECK_HEADERS([netdb.h])
 283 AC_CHECK_HEADERS([signal.h])
 284 AC_CHECK_HEADERS([stdarg.h])
 285 AC_CHECK_HEADERS([stdint.h])
 286 AC_CHECK_HEADERS([stdio.h])
 287 AC_CHECK_HEADERS([stdlib.h])
 288 AC_CHECK_HEADERS([string.h])
 289 AC_CHECK_HEADERS([time.h])
 290 AC_CHECK_HEADERS([ucontext.h])
 291 AC_CHECK_HEADERS([unistd.h])
 292 AC_CHECK_HEADERS([mach/mach.h])
 293 AC_CHECK_HEADERS([sys/ioctl.h])
 294 AC_CHECK_HEADERS([sys/loadavg.h])
 295 AC_CHECK_HEADERS([sys/mman.h])
 296 AC_CHECK_HEADERS([sys/resource.h])
 297 AC_CHECK_HEADERS([sys/select.h])
 298 AC_CHECK_HEADERS([sys/socket.h])
 299 AC_CHECK_HEADERS([sys/stat.h])
 300 AC_CHECK_HEADERS([sys/time.h])
 301 AC_CHECK_HEADERS([sys/types.h])
 302 AC_CHECK_HEADERS([sys/utsname.h])
 303
 304 dnl Checks for typedefs, structures, and compiler characteristics.
 305 AC_C_CONST
 306 AC_C_INLINE
 307 AC_C_ATTRIBUTE
 308 AC_TYPE_OFF_T
 309 AC_TYPE_SIZE_T
 310 AC_HEADER_TIME
 311 AC_STRUCT_TM
 312
 313 dnl Checks for libraries (NOTE: Should be done before function checks,
 314 dnl as some functions may be in libraries we check for).
 315 case "${OS_DIR}" in
 316     solaris )
 317          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 318          ;;
 319 esac
 320
 321 dnl Checks for library functions.
 322 AC_PROG_GCC_TRADITIONAL
 323 AC_TYPE_SIGNAL
 324 AC_FUNC_MEMCMP
 325 AC_FUNC_MMAP
 326
 327 dnl keep them alpha-sorted!
 328 AC_CHECK_FUNCS([abort])
 329 AC_CHECK_FUNCS([accept])
 330 AC_CHECK_FUNCS([access])
 331 AC_CHECK_FUNCS([atoi])
 332 AC_CHECK_FUNCS([atol])
 333 AC_CHECK_FUNCS([backtrace])
 334 AC_CHECK_FUNCS([backtrace_symbols])
 335 AC_CHECK_FUNCS([calloc])
 336 AC_CHECK_FUNCS([close])
 337 AC_CHECK_FUNCS([confstr])
 338 AC_CHECK_FUNCS([connect])
 339 AC_CHECK_FUNCS([dirname])
 340 AC_CHECK_FUNCS([fclose])
 341 AC_CHECK_FUNCS([fflush])
 342 AC_CHECK_FUNCS([fopen])
 343 AC_CHECK_FUNCS([fprintf])
 344 AC_CHECK_FUNCS([fread])
 345 AC_CHECK_FUNCS([free])
 346 AC_CHECK_FUNCS([fstat])
 347 AC_CHECK_FUNCS([fsync])
 348 AC_CHECK_FUNCS([ftruncate])
 349 AC_CHECK_FUNCS([getcwd])
 350 AC_CHECK_FUNCS([getenv])
 351 AC_CHECK_FUNCS([gethostbyname])
 352 AC_CHECK_FUNCS([gethostname])
 353 AC_CHECK_FUNCS([getloadavg])
 354 AC_CHECK_FUNCS([getpagesize])
 355 AC_CHECK_FUNCS([getpid])
 356 AC_CHECK_FUNCS([getrusage])
 357 AC_CHECK_FUNCS([getsockname])
 358 AC_CHECK_FUNCS([getsockopt])
 359 AC_CHECK_FUNCS([gettimeofday])
 360 AC_CHECK_FUNCS([htons])
 361 AC_CHECK_FUNCS([ioctl])
 362 AC_CHECK_FUNCS([isnan])
 363 AC_CHECK_FUNCS([listen])
 364 AC_CHECK_FUNCS([localtime])
 365 AC_CHECK_FUNCS([localtime_r])
 366 AC_CHECK_FUNCS([lseek])
 367 AC_CHECK_FUNCS([malloc])
 368 AC_CHECK_FUNCS([memcpy])
 369 AC_CHECK_FUNCS([memset])
 370 AC_CHECK_FUNCS([mmap])
 371 AC_CHECK_FUNCS([mprotect])
 372 AC_CHECK_FUNCS([open])
 373 AC_CHECK_FUNCS([printf])
 374 AC_CHECK_FUNCS([read])
 375 AC_CHECK_FUNCS([readlink])
 376 AC_CHECK_FUNCS([realloc])
 377 AC_CHECK_FUNCS([recv])
 378 AC_CHECK_FUNCS([scandir])
 379 AC_CHECK_FUNCS([select])
 380 AC_CHECK_FUNCS([send])
 381 AC_CHECK_FUNCS([setlocale])
 382 AC_CHECK_FUNCS([setsockopt])
 383 AC_CHECK_FUNCS([shutdown])
 384 AC_CHECK_FUNCS([socket])
 385 AC_CHECK_FUNCS([stat])
 386 AC_CHECK_FUNCS([str2sig])
 387 AC_CHECK_FUNCS([strcat])
 388 AC_CHECK_FUNCS([strchr])
 389 AC_CHECK_FUNCS([strcpy])
 390 AC_CHECK_FUNCS([strcmp])
 391 AC_CHECK_FUNCS([strdup])
 392 AC_CHECK_FUNCS([strerror])
 393 AC_CHECK_FUNCS([strlen])
 394 AC_CHECK_FUNCS([strncmp])
 395 AC_CHECK_FUNCS([strstr])
 396 AC_CHECK_FUNCS([time])
 397 AC_CHECK_FUNCS([write])
 398
 399 AM_LC_MESSAGES
 400
 401 dnl Checks for libraries.
 402
 403 dnl Checking sizeof void *
 404 AC_CHECK_SIZEOF(void *)
 405 AC_C_BIGENDIAN
 406
 407
 408 dnl define install prefix
 409 if test "x$prefix" = "xNONE"; then
 410     CACAO_PREFIX=$ac_default_prefix
 411 else
 412     CACAO_PREFIX=$prefix
 413 fi
 414 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 415 AC_SUBST(CACAO_PREFIX)
 416
 417 dnl define libdir prefix
 418 if test "x$libdir" = "xNONE"; then
 419     CACAO_LIBDIR=$ac_default_libdir
 420 else
 421     CACAO_LIBDIR=$libdir
 422 fi
 423 dnl expand CACAO_LIBDIR to something that is usable in C code
 424 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 425 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 426 AC_SUBST(CACAO_LIBDIR)
 427
 428
 429 AC_CHECK_ENABLE_DL
 430 AC_CHECK_ENABLE_JAVA
 431
 432 AC_CHECK_ENABLE_JIT
 433 AC_CHECK_ENABLE_INTRP
 434
 435 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 436     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 437 fi
 438
 439 AC_CHECK_SOFTFLOAT
 440 AC_CHECK_SOFT_FLOAT_CMP
 441 AC_CHECK_SOFT_DOUBLE_CMP
 442
 443 AC_CHECK_ENABLE_GC
 444 AC_CHECK_ENABLE_DEBUG
 445 AC_CHECK_ENABLE_DUMP
 446 AC_CHECK_ENABLE_MEMCHECK
 447 AC_CHECK_ENABLE_HANDLES
 448 AC_CHECK_ENABLE_VMLOG
 449 AC_CHECK_ENABLE_DISASSEMBLER
 450 AC_CHECK_ENABLE_STATISTICS
 451 AC_CHECK_ENABLE_VERIFIER
 452 AC_CHECK_ENABLE_RT_TIMING
 453 AC_CHECK_ENABLE_CYCLE_STATS
 454 AC_CHECK_ENABLE_JVMTI
 455 AC_CHECK_ENABLE_THREADS
 456 if test x"${ENABLE_THREADS}" != "xno"; then
 457     AC_CHECK_USE___THREAD
 458 fi
 459 AC_CHECK_ENABLE_IFCONV
 460 AC_CHECK_ENABLE_INLINING
 461 AC_CHECK_ENABLE_INLINING_DEBUG
 462 AC_CHECK_ENABLE_REPLACEMENT
 463
 464 dnl check for loop optimization
 465 AC_MSG_CHECKING(whether loop optimization should be supported)
 466 AC_ARG_ENABLE([loop],
 467               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 468               [case "${enableval}" in
 469                    yes) ENABLE_LOOP=yes;;
 470                    *) ENABLE_LOOP=no;;
 471                esac],
 472               [ENABLE_LOOP=no])
 473 AC_MSG_RESULT(${ENABLE_LOOP})
 474 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 475
 476 if test x"${ENABLE_LOOP}" = "xyes"; then
 477     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 478 fi
 479
 480
 481 dnl check if linear scan register allocator(lsra) with SSA should be used
 482 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 483 AC_ARG_ENABLE([ssa],
 484               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 485               [case "${enableval}" in
 486                    no) ENABLE_SSA=no;;
 487                    *) ENABLE_SSA=yes;;
 488                esac],
 489               [ENABLE_SSA=no])
 490 AC_MSG_RESULT(${ENABLE_SSA})
 491 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 492 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 493 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 494 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 495
 496 if test x"${ENABLE_SSA}" = "xyes"; then
 497     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 498     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 499     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 500     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 501     ENABLE_LSRA="no"
 502 fi
 503
 504
 505 dnl check if linear scan register allocator(lsra) should be used
 506 AC_MSG_CHECKING(whether lsra should be supported)
 507 AC_ARG_ENABLE([lsra],
 508               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 509               [case "${enableval}" in
 510                    yes) ENABLE_LSRA=yes;;
 511                    *) ENABLE_LSRA=no;;
 512                esac],
 513               [ENABLE_LSRA=no])
 514
 515 if test x"${ENABLE_LSRA}" = "xyes"; then
 516     if test x"${ENABLE_SSA}" = "xyes"; then
 517         ENABLE_LSRA="no"
 518     fi
 519 fi
 520 AC_MSG_RESULT(${ENABLE_LSRA})
 521 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 522
 523 if test x"${ENABLE_LSRA}" = "xyes"; then
 524     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 525 fi
 526
 527 dnl check if profiling should be supported
 528 AC_MSG_CHECKING(whether profiling should be supported)
 529 AC_ARG_ENABLE([profiling],
 530               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 531               [case "${enableval}" in
 532                    yes) ENABLE_PROFILING=yes;;
 533                    *) ENABLE_PROFILING=no;;
 534                esac],
 535               [ENABLE_PROFILING=no])
 536 AC_MSG_RESULT(${ENABLE_PROFILING})
 537 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 538
 539 if test x"${ENABLE_PROFILING}" = "xyes"; then
 540     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 541 fi
 542
 543
 544 dnl check for instruction scheduler
 545 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 546
 547 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 548 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 549         case "${ARCH_DIR}" in
 550                 xdspcore )
 551                         ;;
 552                 * )
 553                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 554                         ;;
 555         esac
 556
 557         AC_MSG_RESULT(yes)
 558         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 559         AM_CONDITIONAL([USE_SCHEDULER], [true])
 560 else
 561         AC_MSG_RESULT(no)
 562         AM_CONDITIONAL([USE_SCHEDULER], [false])
 563 fi
 564
 565 AC_CHECK_ENABLE_OPAGENT
 566
 567 AC_CHECK_ENABLE_ZLIB
 568
 569 dnl check for stuff to be built
 570 AC_CHECK_ENABLE_JNI
 571 AC_CHECK_ENABLE_LIBJVM
 572
 573 dnl ATTENTION: These check must be after setting
 574 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 575 dnl because libtool uses them to build the correct libraries.
 576 AC_LIBTOOL_DLOPEN
 577 AC_PROG_LIBTOOL
 578
 579 AC_CHECK_ENABLE_STATICVM
 580 AC_CHECK_ENABLE_ANNOTATIONS
 581 AC_CHECK_ENABLE_ASSERTION
 582
 583 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 584 AC_CHECK_WITH_VM_ZIP
 585 AC_CHECK_WITH_HGREV
 586
 587 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 588
 589 dnl Now we check for jre-layout so we can skip some checks that are
 590 dnl not required.
 591 AC_CHECK_ENABLE_JRE_LAYOUT
 592
 593 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 594 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 595 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 596
 597 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 598    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 599 fi
 600
 601 dnl The check for jni_md.h must be before jni.h.
 602 AC_CHECK_WITH_JNI_MD_H
 603 AC_CHECK_WITH_JNI_H
 604
 605 dnl The jvmti.h header is only required if JVMTI is enabled.
 606 if test x"${ENABLE_JVMTI}" = "xyes"; then
 607     AC_CHECK_WITH_JVMTI_H
 608 fi
 609
 610 dnl JVM, HPI, and JMM is only required for OpenJDK.
 611 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 612     openjdk)
 613         AC_CHECK_WITH_JVM_MD_H
 614         AC_CHECK_WITH_JVM_H
 615         AC_CHECK_WITH_HPI_MD_H
 616         AC_CHECK_WITH_HPI_H
 617         AC_CHECK_WITH_JMM_H
 618         ;;
 619     *)
 620         ;;
 621 esac
 622
 623 dnl check for some programs we need
 624
 625 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 626     cldc1.1 | gnuclasspath)
 627         AC_PROG_JAVAC
 628         AC_PROG_JAR
 629         ;;
 630     openjdk)
 631         ;;
 632     *)
 633         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 634         ;;
 635 esac
 636
 637 AC_CHECK_WITH_JASMIN_JAR
 638 AC_CHECK_WITH_JUNIT_JAR
 639
 640 AC_CHECK_HEADERS(
 641         [regex.h],
 642         [
 643                 dnl If debug build and regex.h available, enable debug filter
 644                 if test x"${NDEBUG}" = "xno"; then
 645                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 646                 fi
 647                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 648                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 649         ],
 650         [
 651                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 652         ]
 653 )
 654
 655 dnl python
 656
 657 AZ_PYTHON_DEFAULT
 658 AZ_PYTHON_ENABLE
 659 AZ_PYTHON_WITH
 660 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 661 AZ_PYTHON_CSPEC
 662 AZ_PYTHON_LSPEC
 663
 664 AC_CHECK_ENABLE_GCC_PR40134
 665
 666 AC_CHECK_ENABLE_PIC_ASM
 667
 668 dnl Define version numbers.
 669 AC_VERSION_DETAIL
 670 AC_VERSION_CONFIG
 671
 672 dnl Finally pass flags to Makefiles.
 673 CFLAGS="$OPT_CFLAGS"
 674 CXXFLAGS="$OPT_CXXFLAGS"
 675
 676 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 677 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 678 AM_CPPFLAGS="$CPPFLAGS"
 679
 680 AC_SUBST(AM_CFLAGS)
 681 AC_SUBST(AM_CXXFLAGS)
 682 AC_SUBST(AM_CPPFLAGS)
 683
 684
 685 AC_CONFIG_FILES([Makefile]
 686                 [contrib/Makefile]
 687                 [contrib/setenvinstalled]
 688                 [contrib/setenvsource]
 689                 [contrib/vmlog/Makefile]
 690                 [contrib/vmlog/t/Makefile]
 691                 [doc/Makefile]
 692                 [doc/doxygen/Makefile]
 693                 [doc/handbook/Makefile]
 694                 [man/Makefile]
 695                 [src/Makefile]
 696                 [src/cacao/Makefile]
 697                 [src/classes/Makefile]
 698                 [src/fdlibm/Makefile]
 699                 [src/mm/Makefile]
 700                 [src/mm/cacao-gc/Makefile]
 701                 [src/native/Makefile]
 702                 [src/native/jvmti/Makefile]
 703                 [src/native/vm/Makefile]
 704                 [src/native/vm/cldc1.1/Makefile]
 705                 [src/native/vm/gnuclasspath/Makefile]
 706                 [src/native/vm/openjdk/Makefile]
 707                 [src/scripts/Makefile]
 708                 [src/scripts/java]
 709                 [src/threads/Makefile]
 710                 [src/threads/none/Makefile]
 711                 [src/threads/posix/Makefile]
 712                 [src/toolbox/Makefile]
 713                 [src/vm/Makefile]
 714                 [src/vm/jit/Makefile]
 715                 [src/vm/jit/allocator/Makefile]
 716                 [src/vm/jit/alpha/Makefile]
 717                 [src/vm/jit/alpha/freebsd/Makefile]
 718                 [src/vm/jit/alpha/linux/Makefile]
 719                 [src/vm/jit/arm/Makefile]
 720                 [src/vm/jit/arm/linux/Makefile]
 721                 [src/vm/jit/i386/Makefile]
 722                 [src/vm/jit/i386/cygwin/Makefile]
 723                 [src/vm/jit/i386/darwin/Makefile]
 724                 [src/vm/jit/i386/freebsd/Makefile]
 725                 [src/vm/jit/i386/linux/Makefile]
 726                 [src/vm/jit/i386/solaris/Makefile]
 727                 [src/vm/jit/intrp/Makefile]
 728                 [src/vm/jit/inline/Makefile]
 729                 [src/vm/jit/ir/Makefile]
 730                 [src/vm/jit/loop/Makefile]
 731                 [src/vm/jit/m68k/Makefile]
 732                 [src/vm/jit/m68k/linux/Makefile]
 733                 [src/vm/jit/mips/Makefile]
 734                 [src/vm/jit/mips/irix/Makefile]
 735                 [src/vm/jit/mips/linux/Makefile]
 736                 [src/vm/jit/mips/uclinux/Makefile]
 737                 [src/vm/jit/optimizing/Makefile]
 738                 [src/vm/jit/parisc/Makefile]
 739                 [src/vm/jit/parisc/linux/Makefile]
 740                 [src/vm/jit/powerpc/Makefile]
 741                 [src/vm/jit/powerpc/darwin/Makefile]
 742                 [src/vm/jit/powerpc/linux/Makefile]
 743                 [src/vm/jit/powerpc/netbsd/Makefile]
 744                 [src/vm/jit/powerpc64/Makefile]
 745                 [src/vm/jit/powerpc64/linux/Makefile]
 746                 [src/vm/jit/s390/Makefile]
 747                 [src/vm/jit/schedule/Makefile]
 748                 [src/vm/jit/sparc64/Makefile]
 749                 [src/vm/jit/sparc64/linux/Makefile]
 750                 [src/vm/jit/sparc64/solaris/Makefile]
 751                 [src/vm/jit/verify/Makefile]
 752                 [src/vm/jit/x86_64/Makefile]
 753                 [src/vm/jit/x86_64/freebsd/Makefile]
 754                 [src/vm/jit/x86_64/linux/Makefile]
 755                 [src/vm/jit/x86_64/solaris/Makefile]
 756                 [tests/Makefile]
 757                 [tests/regression/Makefile]
 758                 [tests/regression/assertion/Makefile]
 759                 [tests/regression/base/Makefile]
 760                 [tests/regression/bugzilla/Makefile]
 761                 [tests/regression/jasmin/Makefile]
 762                 [tests/regression/native/Makefile]
 763                 [tests/regression/resolving/Makefile]
 764                 [tests/regression/resolving/classes1/Makefile]
 765                 [tests/regression/resolving/classes2/Makefile]
 766                 [tests/regression/resolving/classes3/Makefile]
 767 )
 768
 769
 770 dnl We only build the shared library objects but we use it as
 771 dnl noinst_LTLIBRARIES.
 772 ac_configure_args="$ac_configure_args --disable-static"
 773 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 774
 775
 776 AC_OUTPUT
 777
 778
 779 ## Local variables:
 780 ## mode: m4
 781 ## indent-tabs-mode: t
 782 ## c-basic-offset: 4
 783 ## tab-width: 8
 784 ## compile-command: "automake --add-missing"
 785 ## End: