configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 1.1.0pre, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.cpp)
  28 AC_CONFIG_AUX_DIR([.])
  29 AC_CANONICAL_HOST
  30 AC_PREREQ(2.59)
  31 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2 tar-ustar])
  32 AM_MAINTAINER_MODE
  33
  34 AM_CONFIG_HEADER([config.h])
  35
  36 AC_PREFIX_DEFAULT(/usr/local/cacao)
  37
  38
  39 dnl Host CPU type.
  40 case "$host_cpu" in
  41 alpha | alphaev56 | alphapca56 )
  42     ARCH_DIR="alpha"
  43     ARCH_FLAGS="-mieee -D__ALPHA__"
  44     JAVA_ARCH="alpha"
  45     ;;
  46
  47 arm | armv4* | armv5* | armv6* )
  48     ARCH_DIR="arm"
  49     ARCH_FLAGS="-D__ARM__"
  50     JAVA_ARCH="arm"
  51     ;;
  52
  53 hppa2.0 )
  54     ARCH_DIR="parisc"
  55     ARCH_FLAGS="-D__PARISC__"
  56     JAVA_ARCH="hppa"
  57     ;;
  58
  59 i386 | i486 | i586 | i686 )
  60     ARCH_DIR="i386"
  61     ARCH_FLAGS="-m32 -D__I386__"
  62     JAVA_ARCH="i386"
  63     ;;
  64
  65 m68k )
  66     ARCH_DIR="m68k"
  67     ARCH_FLAGS="-D__M68K__"
  68     JAVA_ARCH="m68k"
  69     ;;
  70
  71 mips )
  72     ARCH_DIR="mips"
  73     ARCH_FLAGS="-D__MIPS__"
  74     JAVA_ARCH="mips"
  75     ;;
  76
  77 mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_FLAGS="-D__MIPS__"
  80     JAVA_ARCH="mipsel"
  81     ;;
  82
  83 powerpc )
  84     ARCH_DIR="powerpc"
  85     ARCH_FLAGS="-m32 -D__POWERPC__"
  86     JAVA_ARCH="ppc"
  87     ;;
  88
  89 powerpc64 )
  90     ARCH_DIR="powerpc64"
  91     ARCH_FLAGS="-m64 -D__POWERPC64__"
  92     JAVA_ARCH="ppc64"
  93     ;;
  94
  95 s390 )
  96     ARCH_DIR="s390"
  97     ARCH_FLAGS="-D__S390__"
  98     JAVA_ARCH="s390"
  99     ;;
 100
 101 sparc | sparc64 )
 102     ARCH_DIR="sparc64"
 103     ARCH_FLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 104     dnl Is this correct for 64-bits?
 105     JAVA_ARCH="sparc"
 106     ;;
 107
 108 x86_64 )
 109     ARCH_DIR="x86_64"
 110     ARCH_FLAGS="-m64 -D__X86_64__"
 111     JAVA_ARCH="amd64"
 112     ;;
 113
 114 xdspcore )
 115     ARCH_DIR="xdspcore"
 116     ENABLE_STATICVM="yes"
 117     ARCH_FLAGS="-D__XDSPCORE__"
 118     USE_SCHEDULER="1"
 119     ;;
 120
 121 * )
 122     AC_MSG_ERROR([$host_cpu systems are currently not supported.])
 123     ;;
 124 esac
 125
 126
 127 dnl Host operating system type.
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     OS_FLAGS="-D__WINDOWS__ -D__CYGWIN__"
 132     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     OS_FLAGS="-D__DARWIN__"
 138     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 139     ;;
 140
 141 dnl Must be BEFORE *freebsd*.
 142 *kfreebsd*-gnu)
 143     OS_DIR="freebsd"
 144     OS_FLAGS="-D__FREEBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 145     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 146     ;;
 147
 148 *freebsd* )
 149     OS_DIR="freebsd"
 150     OS_FLAGS="-D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
 151     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 152     ;;
 153
 154 *irix* )
 155     OS_DIR="irix"
 156     OS_FLAGS="-D__IRIX__"
 157     INTRP_CFLAGS="$ARCH_FLAGS $OS_FLAGS"
 158     ;;
 159
 160 dnl Must be BEFORE *linux*.
 161 *uclinux | *elf )
 162     OS_DIR="uclinux"
 163     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 165     ;;
 166
 167 *linux* | *Linux* )
 168     OS_DIR="linux"
 169     OS_FLAGS="-D__LINUX__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 171     ;;
 172
 173 *netbsd* )
 174     OS_DIR="netbsd"
 175     OS_FLAGS="-D__NETBSD__ -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 177     ;;
 178
 179 *solaris* )
 180     OS_DIR="solaris"
 181     dnl On solaris the architecture defines 'sparc', 'sun', 'unix' are
 182     dnl not set when cpp is called with -std=c99, therefore we add them
 183     dnl here.
 184     OS_FLAGS="-D__SOLARIS__ -D_POSIX_C_SOURCE=200112L -D__EXTENSIONS__ -D_BSD_SOURCE"
 185     CC_FLAGS="-D_XOPEN_SOURCE=600"
 186     CXX_FLAGS="-D_XOPEN_SOURCE=500"
 187     INTRP_CFLAGS="-Wall -Wno-long-long $ARCH_FLAGS $OS_FLAGS"
 188     ;;
 189
 190 * )
 191     AC_MSG_ERROR([$host_os operating systems are currently not supported.])
 192     ;;
 193 esac
 194
 195
 196 dnl Set optimization and debugging for all architectures and systems.
 197 dnl NOTE: Setting the CFLAGS/CXXFLAGS only works before calling AC_PROG_CC/AC_PROG_CXX.
 198 if test x"$CFLAGS" = "x"; then
 199     OPT_CFLAGS="-g -O0"
 200 else
 201     OPT_CFLAGS=$CFLAGS
 202 fi
 203
 204 if test x"$CXXFLAGS" = "x"; then
 205     OPT_CXXFLAGS="-g -O0"
 206 else
 207     OPT_CXXFLAGS=$CXXFLAGS
 208 fi
 209
 210 dnl Check for compiler.
 211 AC_PROG_CC
 212 AC_PROG_CXX
 213
 214 dnl Check compiler vendor.
 215 AX_COMPILER_VENDOR
 216
 217 dnl Set compiler flags depending on the compiler vendor.
 218 case "$ax_cv_c_compiler_vendor" in
 219 gnu )
 220     CC_FLAGS="-std=c99 -pedantic -Wall -Wno-long-long $CC_FLAGS"
 221     CXX_FLAGS="-std=c++98 -pedantic -Wall -Wno-long-long $CXX_FLAGS"
 222     ;;
 223
 224 sgi )
 225     CC_FLAGS="-c99 $CC_FLAGS"
 226     CXX_FLAGS="$CXX_FLAGS"
 227     ;;
 228
 229 sun )
 230     CC_FLAGS="-xc99 $CC_FLAGS"
 231     CXX_FLAGS="$CXX_FLAGS"
 232     ;;
 233
 234 * )
 235     AC_MSG_ERROR([$ax_cv_c_compiler_vendor compilers are currently not supported.])
 236     ;;
 237 esac
 238
 239 dnl Temporary set the CFLAGS for configure tests (e.g. inline keyword)
 240 dnl we set it properly at the end of this file.
 241 CFLAGS="$OPT_CFLAGS $ARCH_FLAGS $OS_FLAGS $CC_FLAGS"
 242 CXXFLAGS="$OPT_CXXFLAGS $ARCH_FLAGS $OS_FLAGS $CXX_FLAGS"
 243
 244 dnl set interpreter flags
 245 AC_SUBST(INTRP_CFLAGS)
 246
 247 dnl define and substitute some architecture specific variables
 248 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 249 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 250 AC_SUBST(ARCH_DIR)
 251 AC_SUBST(JAVA_ARCH)
 252 AC_SUBST(OS_DIR)
 253 AC_SUBST(USE_SCHEDULER)
 254
 255 dnl Checks for programs.
 256 AM_PROG_AS
 257 AC_PROG_LD
 258 AC_PROG_LD_GNU
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AM_PROG_MKDIR_P
 262
 263 AM_CONDITIONAL([WITH_GNU_LD], [test x"$with_gnu_ld" = "xyes"])
 264
 265 dnl Checks for header files.
 266 AC_HEADER_DIRENT
 267 AC_HEADER_STDC
 268
 269 dnl Crucial header files.
 270 AC_CHECK_HEADERS([stdbool.h],, [AC_MSG_ERROR(cannot find stdbool.h)])
 271 AC_CHECK_HEADERS([stdint.h],, [AC_MSG_ERROR(cannot find stdint.h)])
 272
 273 dnl keep them alpha-sorted!
 274 AC_CHECK_HEADERS([assert.h])
 275 AC_CHECK_HEADERS([errno.h])
 276 AC_CHECK_HEADERS([execinfo.h])
 277 AC_CHECK_HEADERS([fcntl.h])
 278 AC_CHECK_HEADERS([libgen.h])
 279 AC_CHECK_HEADERS([netdb.h])
 280 AC_CHECK_HEADERS([signal.h])
 281 AC_CHECK_HEADERS([stdarg.h])
 282 AC_CHECK_HEADERS([stdint.h])
 283 AC_CHECK_HEADERS([stdio.h])
 284 AC_CHECK_HEADERS([stdlib.h])
 285 AC_CHECK_HEADERS([string.h])
 286 AC_CHECK_HEADERS([time.h])
 287 AC_CHECK_HEADERS([ucontext.h])
 288 AC_CHECK_HEADERS([unistd.h])
 289 AC_CHECK_HEADERS([mach/mach.h])
 290 AC_CHECK_HEADERS([sys/ioctl.h])
 291 AC_CHECK_HEADERS([sys/loadavg.h])
 292 AC_CHECK_HEADERS([sys/mman.h])
 293 AC_CHECK_HEADERS([sys/resource.h])
 294 AC_CHECK_HEADERS([sys/select.h])
 295 AC_CHECK_HEADERS([sys/socket.h])
 296 AC_CHECK_HEADERS([sys/stat.h])
 297 AC_CHECK_HEADERS([sys/time.h])
 298 AC_CHECK_HEADERS([sys/types.h])
 299 AC_CHECK_HEADERS([sys/utsname.h])
 300
 301 dnl Checks for typedefs, structures, and compiler characteristics.
 302 AC_C_CONST
 303 AC_C_INLINE
 304 AC_C_ATTRIBUTE
 305 AC_TYPE_OFF_T
 306 AC_TYPE_SIZE_T
 307 AC_HEADER_TIME
 308 AC_STRUCT_TM
 309
 310 dnl Checks for libraries (NOTE: Should be done before function checks,
 311 dnl as some functions may be in libraries we check for).
 312 case "${OS_DIR}" in
 313     solaris )
 314          AC_CHECK_LIB([socket], [gethostname],, [AC_MSG_ERROR(cannot find libsocket)])
 315          ;;
 316 esac
 317
 318 dnl Checks for library functions.
 319 AC_PROG_GCC_TRADITIONAL
 320 AC_TYPE_SIGNAL
 321 AC_FUNC_MEMCMP
 322 AC_FUNC_MMAP
 323
 324 dnl keep them alpha-sorted!
 325 AC_CHECK_FUNCS([abort])
 326 AC_CHECK_FUNCS([accept])
 327 AC_CHECK_FUNCS([access])
 328 AC_CHECK_FUNCS([atoi])
 329 AC_CHECK_FUNCS([atol])
 330 AC_CHECK_FUNCS([backtrace])
 331 AC_CHECK_FUNCS([backtrace_symbols])
 332 AC_CHECK_FUNCS([calloc])
 333 AC_CHECK_FUNCS([close])
 334 AC_CHECK_FUNCS([confstr])
 335 AC_CHECK_FUNCS([connect])
 336 AC_CHECK_FUNCS([dirname])
 337 AC_CHECK_FUNCS([fclose])
 338 AC_CHECK_FUNCS([fflush])
 339 AC_CHECK_FUNCS([fopen])
 340 AC_CHECK_FUNCS([fprintf])
 341 AC_CHECK_FUNCS([fread])
 342 AC_CHECK_FUNCS([free])
 343 AC_CHECK_FUNCS([fstat])
 344 AC_CHECK_FUNCS([fsync])
 345 AC_CHECK_FUNCS([ftruncate])
 346 AC_CHECK_FUNCS([getcwd])
 347 AC_CHECK_FUNCS([getenv])
 348 AC_CHECK_FUNCS([gethostbyname])
 349 AC_CHECK_FUNCS([gethostname])
 350 AC_CHECK_FUNCS([getloadavg])
 351 AC_CHECK_FUNCS([getpagesize])
 352 AC_CHECK_FUNCS([getpid])
 353 AC_CHECK_FUNCS([getrusage])
 354 AC_CHECK_FUNCS([getsockname])
 355 AC_CHECK_FUNCS([getsockopt])
 356 AC_CHECK_FUNCS([gettimeofday])
 357 AC_CHECK_FUNCS([htons])
 358 AC_CHECK_FUNCS([ioctl])
 359 AC_CHECK_FUNCS([isnan])
 360 AC_CHECK_FUNCS([listen])
 361 AC_CHECK_FUNCS([localtime])
 362 AC_CHECK_FUNCS([localtime_r])
 363 AC_CHECK_FUNCS([lseek])
 364 AC_CHECK_FUNCS([malloc])
 365 AC_CHECK_FUNCS([memcpy])
 366 AC_CHECK_FUNCS([memset])
 367 AC_CHECK_FUNCS([mmap])
 368 AC_CHECK_FUNCS([mprotect])
 369 AC_CHECK_FUNCS([open])
 370 AC_CHECK_FUNCS([printf])
 371 AC_CHECK_FUNCS([read])
 372 AC_CHECK_FUNCS([readlink])
 373 AC_CHECK_FUNCS([realloc])
 374 AC_CHECK_FUNCS([recv])
 375 AC_CHECK_FUNCS([scandir])
 376 AC_CHECK_FUNCS([select])
 377 AC_CHECK_FUNCS([send])
 378 AC_CHECK_FUNCS([setsockopt])
 379 AC_CHECK_FUNCS([shutdown])
 380 AC_CHECK_FUNCS([socket])
 381 AC_CHECK_FUNCS([stat])
 382 AC_CHECK_FUNCS([str2sig])
 383 AC_CHECK_FUNCS([strcat])
 384 AC_CHECK_FUNCS([strchr])
 385 AC_CHECK_FUNCS([strcpy])
 386 AC_CHECK_FUNCS([strcmp])
 387 AC_CHECK_FUNCS([strdup])
 388 AC_CHECK_FUNCS([strerror])
 389 AC_CHECK_FUNCS([strlen])
 390 AC_CHECK_FUNCS([strncmp])
 391 AC_CHECK_FUNCS([strstr])
 392 AC_CHECK_FUNCS([time])
 393 AC_CHECK_FUNCS([write])
 394
 395
 396 dnl Checks for libraries.
 397
 398 dnl Checking sizeof void *
 399 AC_CHECK_SIZEOF(void *)
 400 AC_C_BIGENDIAN
 401
 402
 403 dnl define install prefix
 404 if test "x$prefix" = "xNONE"; then
 405     CACAO_PREFIX=$ac_default_prefix
 406 else
 407     CACAO_PREFIX=$prefix
 408 fi
 409 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 410 AC_SUBST(CACAO_PREFIX)
 411
 412 dnl define libdir prefix
 413 if test "x$libdir" = "xNONE"; then
 414     CACAO_LIBDIR=$ac_default_libdir
 415 else
 416     CACAO_LIBDIR=$libdir
 417 fi
 418 dnl expand CACAO_LIBDIR to something that is usable in C code
 419 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 420 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 421 AC_SUBST(CACAO_LIBDIR)
 422
 423
 424 AC_CHECK_ENABLE_DL
 425 AC_CHECK_ENABLE_JAVA
 426
 427 AC_CHECK_ENABLE_JIT
 428 AC_CHECK_ENABLE_INTRP
 429
 430 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 431     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 432 fi
 433
 434 AC_CHECK_SOFTFLOAT
 435 AC_CHECK_SOFT_FLOAT_CMP
 436 AC_CHECK_SOFT_DOUBLE_CMP
 437
 438 AC_CHECK_ENABLE_GC
 439 AC_CHECK_ENABLE_DEBUG
 440 AC_CHECK_ENABLE_DUMP
 441 AC_CHECK_ENABLE_MEMCHECK
 442 AC_CHECK_ENABLE_HANDLES
 443 AC_CHECK_ENABLE_VMLOG
 444 AC_CHECK_ENABLE_DISASSEMBLER
 445 AC_CHECK_ENABLE_STATISTICS
 446 AC_CHECK_ENABLE_VERIFIER
 447 AC_CHECK_ENABLE_RT_TIMING
 448 AC_CHECK_ENABLE_CYCLE_STATS
 449 AC_CHECK_ENABLE_JVMTI
 450 AC_CHECK_ENABLE_THREADS
 451 if test x"${ENABLE_THREADS}" != "xno"; then
 452     AC_CHECK_USE___THREAD
 453 fi
 454 AC_CHECK_ENABLE_IFCONV
 455 AC_CHECK_ENABLE_INLINING
 456 AC_CHECK_ENABLE_INLINING_DEBUG
 457 AC_CHECK_ENABLE_REPLACEMENT
 458
 459 dnl check for loop optimization
 460 AC_MSG_CHECKING(whether loop optimization should be supported)
 461 AC_ARG_ENABLE([loop],
 462               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 463               [case "${enableval}" in
 464                    yes) ENABLE_LOOP=yes;;
 465                    *) ENABLE_LOOP=no;;
 466                esac],
 467               [ENABLE_LOOP=no])
 468 AC_MSG_RESULT(${ENABLE_LOOP})
 469 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 470
 471 if test x"${ENABLE_LOOP}" = "xyes"; then
 472     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 473 fi
 474
 475
 476 dnl check if linear scan register allocator(lsra) with SSA should be used
 477 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 478 AC_ARG_ENABLE([ssa],
 479               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 480               [case "${enableval}" in
 481                    no) ENABLE_SSA=no;;
 482                    *) ENABLE_SSA=yes;;
 483                esac],
 484               [ENABLE_SSA=no])
 485 AC_MSG_RESULT(${ENABLE_SSA})
 486 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 487 AM_CONDITIONAL([ENABLE_ESCAPE], test x"${ENABLE_SSA}" = "xyes")
 488 AM_CONDITIONAL([ENABLE_ESCAPE_CHECK], test x"${ENABLE_SSA}" = "xyes")
 489 AM_CONDITIONAL([ENABLE_TLH], test x"${ENABLE_SSA}" = "xyes")
 490
 491 if test x"${ENABLE_SSA}" = "xyes"; then
 492     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 493     AC_DEFINE([ENABLE_ESCAPE], 1, [enable escape analysis with ssa])
 494     AC_DEFINE([ENABLE_ESCAPE_CHECK], 1, [enable generating code to validate escape analysis results])
 495     AC_DEFINE([ENABLE_TLH], 1, [enable thread local heap])
 496     ENABLE_LSRA="no"
 497 fi
 498
 499
 500 dnl check if linear scan register allocator(lsra) should be used
 501 AC_MSG_CHECKING(whether lsra should be supported)
 502 AC_ARG_ENABLE([lsra],
 503               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 504               [case "${enableval}" in
 505                    yes) ENABLE_LSRA=yes;;
 506                    *) ENABLE_LSRA=no;;
 507                esac],
 508               [ENABLE_LSRA=no])
 509
 510 if test x"${ENABLE_LSRA}" = "xyes"; then
 511     if test x"${ENABLE_SSA}" = "xyes"; then
 512         ENABLE_LSRA="no"
 513     fi
 514 fi
 515 AC_MSG_RESULT(${ENABLE_LSRA})
 516 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 517
 518 if test x"${ENABLE_LSRA}" = "xyes"; then
 519     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 520 fi
 521
 522 dnl check if profiling should be supported
 523 AC_MSG_CHECKING(whether profiling should be supported)
 524 AC_ARG_ENABLE([profiling],
 525               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 526               [case "${enableval}" in
 527                    yes) ENABLE_PROFILING=yes;;
 528                    *) ENABLE_PROFILING=no;;
 529                esac],
 530               [ENABLE_PROFILING=no])
 531 AC_MSG_RESULT(${ENABLE_PROFILING})
 532 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 533
 534 if test x"${ENABLE_PROFILING}" = "xyes"; then
 535     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 536 fi
 537
 538
 539 dnl check for instruction scheduler
 540 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 541
 542 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 543 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 544         case "${ARCH_DIR}" in
 545                 xdspcore )
 546                         ;;
 547                 * )
 548                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 549                         ;;
 550         esac
 551
 552         AC_MSG_RESULT(yes)
 553         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 554         AM_CONDITIONAL([USE_SCHEDULER], [true])
 555 else
 556         AC_MSG_RESULT(no)
 557         AM_CONDITIONAL([USE_SCHEDULER], [false])
 558 fi
 559
 560 AC_CHECK_ENABLE_OPAGENT
 561
 562 AC_CHECK_ENABLE_ZLIB
 563
 564 dnl check for stuff to be built
 565 AC_CHECK_ENABLE_JNI
 566 AC_CHECK_ENABLE_LIBJVM
 567
 568 dnl ATTENTION: These check must be after setting
 569 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 570 dnl because libtool uses them to build the correct libraries.
 571 AC_LIBTOOL_DLOPEN
 572 AC_PROG_LIBTOOL
 573
 574 AC_CHECK_ENABLE_STATICVM
 575 AC_CHECK_ENABLE_ANNOTATIONS
 576 AC_CHECK_ENABLE_ASSERTION
 577
 578 dnl This one depends on AC_CHECK_ENABLE_ZLIB.
 579 AC_CHECK_WITH_VM_ZIP
 580
 581 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY
 582
 583 dnl Now we check for jre-layout so we can skip some checks that are
 584 dnl not required.
 585 AC_CHECK_ENABLE_JRE_LAYOUT
 586
 587 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_PREFIX
 588 AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_CLASSES
 589 AC_CHECK_WITH_BUILD_JAVA_RUNTIME_LIBRARY_CLASSES
 590
 591 if test x"${ENABLE_JRE_LAYOUT}" = "xno"; then
 592    AC_CHECK_WITH_JAVA_RUNTIME_LIBRARY_LIBDIR
 593 fi
 594
 595 dnl The check for jni_md.h must be before jni.h.
 596 AC_CHECK_WITH_JNI_MD_H
 597 AC_CHECK_WITH_JNI_H
 598
 599 dnl The jvmti.h header is only required if JVMTI is enabled.
 600 if test x"${ENABLE_JVMTI}" = "xyes"; then
 601     AC_CHECK_WITH_JVMTI_H
 602 fi
 603
 604 dnl JVM, HPI, and JMM is only required for OpenJDK.
 605 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 606     openjdk)
 607         AC_CHECK_WITH_JVM_MD_H
 608         AC_CHECK_WITH_JVM_H
 609         AC_CHECK_WITH_HPI_MD_H
 610         AC_CHECK_WITH_HPI_H
 611         AC_CHECK_WITH_JMM_H
 612         ;;
 613     *)
 614         ;;
 615 esac
 616
 617 dnl check for some programs we need
 618
 619 case "${WITH_JAVA_RUNTIME_LIBRARY}" in
 620     cldc1.1 | gnuclasspath)
 621         AC_PROG_JAVAC
 622         AC_PROG_JAR
 623         ;;
 624     openjdk)
 625         ;;
 626     *)
 627         AC_MSG_ERROR(unknown classpath configuration ${WITH_JAVA_RUNTIME_LIBRARY})
 628         ;;
 629 esac
 630
 631 AC_CHECK_WITH_JASMIN_JAR
 632 AC_CHECK_WITH_JUNIT_JAR
 633
 634 AC_CHECK_HEADERS(
 635         [regex.h],
 636         [
 637                 dnl If debug build and regex.h available, enable debug filter
 638                 if test x"${NDEBUG}" = "xno"; then
 639                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 640                 fi
 641                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 642                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 643         ],
 644         [
 645                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 646         ]
 647 )
 648
 649 dnl python
 650
 651 AZ_PYTHON_DEFAULT
 652 AZ_PYTHON_ENABLE
 653 AZ_PYTHON_WITH
 654 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 655 AZ_PYTHON_CSPEC
 656 AZ_PYTHON_LSPEC
 657
 658 dnl Define version numbers.
 659 AC_VERSION_DETAIL
 660 AC_VERSION_CONFIG
 661
 662 dnl Finally pass flags to Makefiles.
 663 CFLAGS="$OPT_CFLAGS"
 664 CXXFLAGS="$OPT_CXXFLAGS"
 665
 666 AM_CFLAGS="$CC_FLAGS $ARCH_FLAGS $OS_FLAGS"
 667 AM_CXXFLAGS="$CXX_FLAGS $ARCH_FLAGS $OS_FLAGS"
 668 AM_CPPFLAGS="$CPPFLAGS"
 669
 670 AC_SUBST(AM_CFLAGS)
 671 AC_SUBST(AM_CXXFLAGS)
 672 AC_SUBST(AM_CPPFLAGS)
 673
 674
 675 AC_CONFIG_FILES([Makefile]
 676                 [contrib/Makefile]
 677                 [contrib/setenvinstalled]
 678                 [contrib/setenvsource]
 679                 [contrib/vmlog/Makefile]
 680                 [contrib/vmlog/t/Makefile]
 681                 [doc/Makefile]
 682                 [doc/doxygen/Makefile]
 683                 [doc/handbook/Makefile]
 684                 [man/Makefile]
 685                 [src/Makefile]
 686                 [src/cacao/Makefile]
 687                 [src/classes/Makefile]
 688                 [src/fdlibm/Makefile]
 689                 [src/mm/Makefile]
 690                 [src/mm/cacao-gc/Makefile]
 691                 [src/native/Makefile]
 692                 [src/native/jvmti/Makefile]
 693                 [src/native/vm/Makefile]
 694                 [src/native/vm/cldc1.1/Makefile]
 695                 [src/native/vm/gnuclasspath/Makefile]
 696                 [src/native/vm/openjdk/Makefile]
 697                 [src/scripts/Makefile]
 698                 [src/scripts/java]
 699                 [src/threads/Makefile]
 700                 [src/threads/none/Makefile]
 701                 [src/threads/posix/Makefile]
 702                 [src/toolbox/Makefile]
 703                 [src/vm/Makefile]
 704                 [src/vm/jit/Makefile]
 705                 [src/vm/jit/allocator/Makefile]
 706                 [src/vm/jit/alpha/Makefile]
 707                 [src/vm/jit/alpha/freebsd/Makefile]
 708                 [src/vm/jit/alpha/linux/Makefile]
 709                 [src/vm/jit/arm/Makefile]
 710                 [src/vm/jit/arm/linux/Makefile]
 711                 [src/vm/jit/i386/Makefile]
 712                 [src/vm/jit/i386/cygwin/Makefile]
 713                 [src/vm/jit/i386/darwin/Makefile]
 714                 [src/vm/jit/i386/freebsd/Makefile]
 715                 [src/vm/jit/i386/linux/Makefile]
 716                 [src/vm/jit/i386/solaris/Makefile]
 717                 [src/vm/jit/intrp/Makefile]
 718                 [src/vm/jit/inline/Makefile]
 719                 [src/vm/jit/ir/Makefile]
 720                 [src/vm/jit/loop/Makefile]
 721                 [src/vm/jit/m68k/Makefile]
 722                 [src/vm/jit/m68k/linux/Makefile]
 723                 [src/vm/jit/mips/Makefile]
 724                 [src/vm/jit/mips/irix/Makefile]
 725                 [src/vm/jit/mips/linux/Makefile]
 726                 [src/vm/jit/mips/uclinux/Makefile]
 727                 [src/vm/jit/optimizing/Makefile]
 728                 [src/vm/jit/parisc/Makefile]
 729                 [src/vm/jit/parisc/linux/Makefile]
 730                 [src/vm/jit/powerpc/Makefile]
 731                 [src/vm/jit/powerpc/darwin/Makefile]
 732                 [src/vm/jit/powerpc/linux/Makefile]
 733                 [src/vm/jit/powerpc/netbsd/Makefile]
 734                 [src/vm/jit/powerpc64/Makefile]
 735                 [src/vm/jit/powerpc64/linux/Makefile]
 736                 [src/vm/jit/s390/Makefile]
 737                 [src/vm/jit/schedule/Makefile]
 738                 [src/vm/jit/sparc64/Makefile]
 739                 [src/vm/jit/sparc64/linux/Makefile]
 740                 [src/vm/jit/sparc64/solaris/Makefile]
 741                 [src/vm/jit/verify/Makefile]
 742                 [src/vm/jit/x86_64/Makefile]
 743                 [src/vm/jit/x86_64/freebsd/Makefile]
 744                 [src/vm/jit/x86_64/linux/Makefile]
 745                 [src/vm/jit/x86_64/solaris/Makefile]
 746                 [tests/Makefile]
 747                 [tests/regression/Makefile]
 748                 [tests/regression/assertion/Makefile]
 749                 [tests/regression/base/Makefile]
 750                 [tests/regression/bugzilla/Makefile]
 751                 [tests/regression/jasmin/Makefile]
 752                 [tests/regression/native/Makefile]
 753                 [tests/regression/resolving/Makefile]
 754                 [tests/regression/resolving/classes1/Makefile]
 755                 [tests/regression/resolving/classes2/Makefile]
 756                 [tests/regression/resolving/classes3/Makefile]
 757 )
 758
 759
 760 dnl We only build the shared library objects but we use it as
 761 dnl noinst_LTLIBRARIES.
 762 ac_configure_args="$ac_configure_args --disable-static"
 763 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 764
 765
 766 AC_OUTPUT
 767
 768
 769 ## Local variables:
 770 ## mode: m4
 771 ## indent-tabs-mode: t
 772 ## c-basic-offset: 4
 773 ## tab-width: 8
 774 ## compile-command: "automake --add-missing"
 775 ## End: