configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4 dnl C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5 dnl E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6 dnl J. Wenninger, Institut f. Computersprachen - TU Wien
   7 dnl
   8 dnl This file is part of CACAO.
   9 dnl
  10 dnl This program is free software; you can redistribute it and/or
  11 dnl modify it under the terms of the GNU General Public License as
  12 dnl published by the Free Software Foundation; either version 2, or (at
  13 dnl your option) any later version.
  14 dnl
  15 dnl This program is distributed in the hope that it will be useful, but
  16 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 dnl General Public License for more details.
  19 dnl
  20 dnl You should have received a copy of the GNU General Public License
  21 dnl along with this program; if not, write to the Free Software
  22 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23 dnl 02110-1301, USA.
  24 dnl
  25 dnl $Id: configure.ac 7596 2007-03-28 21:05:53Z twisti $
  26
  27 dnl Process this file with autoconf to produce a configure script.
  28
  29
  30 AC_INIT(cacao, 0.97+svn, cacao@cacaojvm.org)
  31 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  32 AC_CANONICAL_HOST
  33 AC_PREREQ(2.59)
  34 AM_INIT_AUTOMAKE([1.9.0])
  35 AM_MAINTAINER_MODE
  36
  37 AM_CONFIG_HEADER([config.h])
  38
  39 AC_PREFIX_DEFAULT(/usr/local/cacao)
  40
  41
  42 dnl set optimization and debugging for all architectures and systems
  43 if test x"$CFLAGS" = "x"; then
  44     OPT_CFLAGS="-O0 -g3"
  45 else
  46     OPT_CFLAGS=$CFLAGS
  47 fi
  48
  49 dnl system type
  50 case "$host_cpu" in
  51 alpha | alphaev56 | alphapca56 )
  52     ARCH_DIR="alpha"
  53     ARCH_CFLAGS="-mieee -D__ALPHA__"
  54     ;;
  55
  56 arm | armv4tl | armv5b | armv5l )
  57     ARCH_DIR="arm"
  58     ARCH_CFLAGS="-D__ARM__"
  59     ;;
  60
  61 hppa2.0 )
  62     ARCH_DIR="parisc"
  63     ARCH_CFLAGS="-D__PARISC__"
  64     ;;
  65
  66 i386 | i486 | i586 | i686 )
  67     ARCH_DIR="i386"
  68     ARCH_CFLAGS="-D__I386__"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     ;;
  75
  76 mips | mipsel )
  77     ARCH_DIR="mips"
  78     ARCH_CFLAGS="-D__MIPS__"
  79     ;;
  80
  81 powerpc )
  82     ARCH_DIR="powerpc"
  83     ARCH_CFLAGS="-D__POWERPC__"
  84     ;;
  85
  86 powerpc64 )
  87     ARCH_DIR="powerpc64"
  88     ARCH_CFLAGS="-D__POWERPC64__"
  89     ;;
  90
  91 sparc | sparc64 )
  92     ARCH_DIR="sparc64"
  93     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
  94     ;;
  95
  96 x86_64 )
  97     ARCH_DIR="x86_64"
  98     ARCH_CFLAGS="-D__X86_64__"
  99     ;;
 100
 101 xdspcore )
 102     ARCH_DIR="xdspcore"
 103     ENABLE_STATICVM="yes"
 104     ARCH_CFLAGS="-D__XDSPCORE__"
 105     USE_SCHEDULER="1"
 106     ;;
 107
 108 s390 )
 109     ARCH_DIR="s390"
 110     ARCH_CFLAGS="-D__S390__"
 111     ;;
 112
 113
 114 * )
 115     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 116     ;;
 117 esac
 118
 119 dnl host type
 120 case "$host_os" in
 121 *cygwin* )
 122     OS_DIR="cygwin"
 123     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 124     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 125     ;;
 126
 127 *darwin* )
 128     OS_DIR="darwin"
 129     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 130     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 131     ;;
 132
 133 *freebsd* )
 134     OS_DIR="freebsd"
 135     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 136     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 137     ;;
 138
 139 *irix* )
 140     OS_DIR="irix"
 141     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 142     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 143     ;;
 144
 145 *kfreebsd*-gnu)
 146     OS_DIR="freebsd"
 147     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 148     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 149     ;;
 150
 151 dnl must be before *linux*
 152 *uclinux | *elf )
 153     OS_DIR="uclinux"
 154     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 156     ;;
 157
 158 *linux* | *Linux* )
 159     OS_DIR="linux"
 160     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 161     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 162     ;;
 163
 164 *netbsd* )
 165     OS_DIR="netbsd"
 166     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 167     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 168     ;;
 169
 170 *solaris* )
 171     OS_DIR="solaris"
 172         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 173         dnl therefore we add them here
 174     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 175     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 176     ;;
 177
 178 * )
 179     ;;
 180 esac
 181
 182
 183 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 184 dnl we set it properly at the end of this file
 185 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 186
 187 dnl set interpreter flags
 188 AC_SUBST(INTRP_CFLAGS)
 189
 190 dnl define some stuff required for --fullversion
 191 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 192 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 193 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS", [CFLAGS used])
 194
 195
 196 dnl define and substitute some architecture specific variables
 197 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 198 AC_SUBST(ARCH_DIR)
 199 AC_SUBST(OS_DIR)
 200 AC_SUBST(USE_SCHEDULER)
 201
 202
 203 dnl Checks for programs.
 204 AC_PROG_CC
 205 AM_PROG_AS
 206 AC_PROG_LD
 207 AC_PROG_LD_GNU
 208 AC_PROG_RANLIB
 209 AC_PROG_LN_S
 210 AC_PROG_MAKE_SET
 211 AM_PROG_MKDIR_P
 212
 213 dnl Checks for header files.
 214 AC_HEADER_DIRENT
 215 AC_HEADER_STDC
 216 AC_CHECK_HEADERS([fcntl.h])
 217 AC_CHECK_HEADERS([sys/time.h])
 218 AC_CHECK_HEADERS([unistd.h])
 219 AC_CHECK_HEADERS([sys/ioctl.h])
 220
 221 dnl this is for fdlibm
 222 AC_CHECK_HEADERS([stdint.h])
 223 AC_CHECK_HEADERS([inttypes.h])
 224 AC_CHECK_HEADERS([sys/config.h])
 225 AC_CHECK_HEADERS([sys/types.h])
 226 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 227 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 228 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 229 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 230
 231 dnl Checks for typedefs, structures, and compiler characteristics.
 232 AC_C_CONST
 233 AC_C_INLINE
 234 AC_C_ATTRIBUTE
 235 AC_TYPE_OFF_T
 236 AC_TYPE_SIZE_T
 237 AC_HEADER_TIME
 238 AC_STRUCT_TM
 239
 240 dnl Checks for library functions.
 241 AC_PROG_GCC_TRADITIONAL
 242 AC_TYPE_SIGNAL
 243 AC_FUNC_MEMCMP
 244 AC_FUNC_MMAP
 245 AC_CHECK_FUNCS([calloc mmap getpagesize free])
 246 AC_CHECK_FUNCS([getcwd gettimeofday])
 247 AC_CHECK_FUNCS([scandir])
 248 AC_CHECK_FUNCS([isnan])
 249
 250 dnl Checks for libraries.
 251
 252 dnl Checking sizeof void *
 253 AC_CHECK_SIZEOF(void *)
 254 AC_C_BIGENDIAN
 255
 256
 257 dnl define install prefix
 258 if test "x$prefix" = "xNONE"; then
 259     CACAO_PREFIX=$ac_default_prefix
 260 else
 261     CACAO_PREFIX=$prefix
 262 fi
 263 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 264 AC_SUBST(CACAO_PREFIX)
 265
 266 dnl define libdir prefix
 267 if test "x$libdir" = "xNONE"; then
 268     CACAO_LIBDIR=$ac_default_libdir
 269 else
 270     CACAO_LIBDIR=$libdir
 271 fi
 272 dnl expand CACAO_LIBDIR to something that is usable in C code
 273 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 274 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 275 AC_SUBST(CACAO_LIBDIR)
 276
 277
 278 dnl Features
 279
 280 AC_CHECK_ENABLE_JAVA
 281 AC_CHECK_ENABLE_JIT
 282
 283 dnl with-options
 284 AC_CHECK_WITH_CACAOH
 285
 286 dnl check for stuff that should be done in software
 287 AC_CHECK_SOFTFLOAT
 288 AC_CHECK_SOFT_FLOAT_CMP
 289 AC_CHECK_SOFT_DOUBLE_CMP
 290
 291
 292 dnl check for interpreter
 293 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 294
 295 AC_MSG_CHECKING(whether interpreter should be compiled)
 296 if test x"$enable_intrp" = "xyes"; then
 297     AC_MSG_RESULT(yes)
 298     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 299     AM_CONDITIONAL([ENABLE_INTRP], [true])
 300     ENABLE_INTRP=yes
 301
 302     AC_ASM_SKIP16
 303
 304     dnl check for libffi
 305     AC_ARG_WITH([ffi],
 306                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 307                 [WITH_FFI=yes
 308                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 309                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 310                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 311                 [WITH_FFI=no])
 312
 313     dnl check for libffcall
 314     AC_ARG_WITH([ffcall],
 315                 [AS_HELP_STRING(--with-ffcall,use libffcall to call native functions)],
 316                 [WITH_FFCALL=yes
 317                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 318                  AC_CHECK_LIB(avcall, __builtin_avcall,, [AC_MSG_ERROR(cannot find libavcall (from libffcall))])
 319                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 320                 [WITH_FFCALL=no])
 321
 322     dnl check for libffi or libffcall
 323     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 324         AC_ERROR(Enable only libffi or libffcall.)
 325     fi
 326     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 327         AC_ERROR(Enable one of libffi or libffcall.)
 328     fi
 329
 330 else
 331     AC_MSG_RESULT(no)
 332     AM_CONDITIONAL([ENABLE_INTRP], [false])
 333     ENABLE_INTRP="no"
 334 fi
 335
 336 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 337     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 338 fi
 339
 340
 341 dnl check for garbage collector usage
 342 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--enable-gc,enable garbage collector support (none,boehm,cacao) [[default=boehm]])])
 343 AC_MSG_CHECKING(whether GC should be enabled)
 344 enable_gc=${enable_gc:-boehm}
 345 case "$enable_gc" in
 346 no | none)
 347     AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 348     ENABLE_GC=none
 349     AC_MSG_RESULT(no)
 350     ;;
 351
 352 boehm)
 353     AC_DEFINE([ENABLE_GC_BOEHM], 1, [enable conservative boehm-gc])
 354     ENABLE_GC=boehm
 355     AC_MSG_RESULT(yes, boehm-gc)
 356     ;;
 357
 358 cacao)
 359     AC_DEFINE([ENABLE_GC_CACAO], 1, [enable exact cacao-gc])
 360     ENABLE_GC=cacao
 361     AC_MSG_RESULT(yes, cacao-gc)
 362     ;;
 363
 364 *)
 365     AC_MSG_ERROR($enable_gc is an unknown garbage collector package)
 366     ;;
 367 esac
 368 AM_CONDITIONAL([DISABLE_GC], test x"${ENABLE_GC}" = "xnone")
 369 AM_CONDITIONAL([ENABLE_GC_BOEHM], test x"${ENABLE_GC}" = "xboehm")
 370 AM_CONDITIONAL([ENABLE_GC_CACAO], test x"${ENABLE_GC}" = "xcacao")
 371
 372
 373
 374 dnl check for dump memory usage
 375 AC_MSG_CHECKING(whether dump memory should be disabled)
 376 AC_ARG_ENABLE([dump],
 377               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 378               [case "${enableval}" in
 379                    no)
 380                        DISABLE_DUMP=yes
 381                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 382                        ;;
 383                    *) DISABLE_DUMP=no;;
 384                esac],
 385                [DISABLE_DUMP=no])
 386 AC_MSG_RESULT(${DISABLE_DUMP})
 387
 388
 389 dnl check for debug
 390 AC_MSG_CHECKING(whether debug code generation should be enabled)
 391 AC_ARG_ENABLE([debug],
 392               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 393               [case "${enableval}" in
 394                    no) NDEBUG=yes
 395                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 396                        ;;
 397                    *) NDEBUG=no;;
 398                esac],
 399               [NDEBUG=no])
 400
 401 if test x"${NDEBUG}" = "xno"; then
 402     AC_MSG_RESULT(yes)
 403 else
 404     AC_MSG_RESULT(no)
 405 fi
 406 AM_CONDITIONAL([NDEBUG], test x"${NDEBUG}" = "xyes")
 407
 408
 409 dnl check for memcheck support
 410 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 411 AC_ARG_ENABLE([memcheck],
 412               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 413               [case "${enableval}" in
 414                    yes) ENABLE_MEMCHECK=yes;;
 415                    *) ENABLE_MEMCHECK=no;;
 416                esac],
 417               [ENABLE_MEMCHECK=no])
 418 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 419 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 420
 421 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 422     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 423 fi
 424
 425
 426 dnl check for disassembler support
 427 AC_MSG_CHECKING(whether disassembler should be enabled)
 428 AC_ARG_ENABLE([disassembler],
 429               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 430               [case "${enableval}" in
 431                    yes) ENABLE_DISASSEMBLER=yes;;
 432                    *) ENABLE_DISASSEMBLER=no;;
 433                esac],
 434               [ENABLE_DISASSEMBLER=no])
 435 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 436 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 437
 438 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 439     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 440
 441     dnl check for binutils headers and libraries on some architectures for the
 442     dnl disassembler
 443     case "${ARCH_DIR}" in
 444         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 445             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 446             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 447             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 448             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 449
 450             case "${OS_DIR}" in
 451                 cygwin | darwin | netbsd | solaris)
 452                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 453                      ;;
 454             esac
 455
 456             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 457             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 458             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 459             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 460             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 461             ;;
 462         * )
 463             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 464             ;;
 465     esac
 466 else
 467     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 468 fi
 469
 470
 471 dnl check for statistics
 472 AC_MSG_CHECKING(whether statistics generation should be enabled)
 473 AC_ARG_ENABLE([statistics],
 474               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 475               [case "${enableval}" in
 476                    yes) ENABLE_STATISTICS=yes;;
 477                    *) ENABLE_STATISTICS=no;;
 478                esac],
 479               [ENABLE_STATISTICS=no])
 480 AC_MSG_RESULT(${ENABLE_STATISTICS})
 481 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 482
 483 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 484     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 485 fi
 486
 487
 488 dnl check for verifier
 489 AC_MSG_CHECKING(whether classfile verification should be enabled)
 490 AC_ARG_ENABLE([verifier],
 491               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=yes]])],
 492               [case "${enableval}" in
 493                    no) ENABLE_VERIFIER=no;;
 494                    *) ENABLE_VERIFIER=yes;;
 495                esac],
 496               [ENABLE_VERIFIER=yes])
 497 AC_MSG_RESULT(${ENABLE_VERIFIER})
 498 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 499
 500 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 501     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 502 fi
 503
 504
 505 dnl check for compiler timing
 506 AC_MSG_CHECKING(whether real-time timing should be enabled)
 507 AC_ARG_ENABLE([rt-timing],
 508               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 509               [case "${enableval}" in
 510                    yes) ENABLE_RT_TIMING=yes;;
 511                    *) ENABLE_RT_TIMING=no;;
 512                esac],
 513               [ENABLE_RT_TIMING=no])
 514 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 515 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 516
 517 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 518     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 519 fi
 520
 521
 522 dnl check for cycle count statistics
 523 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 524 AC_ARG_ENABLE([cycles-stats],
 525               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 526               [case "${enableval}" in
 527                    yes) ENABLE_CYCLES_STATS=yes;;
 528                    *) ENABLE_CYCLES_STATS=no;;
 529                esac],
 530               [ENABLE_CYCLES_STATS=no])
 531 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 532 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 533
 534 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 535     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 536 fi
 537
 538
 539 dnl check for JVMTI
 540 AC_MSG_CHECKING(whether to compile JVMTI support)
 541 AC_ARG_ENABLE([jvmti],
 542               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 543               [case "${enableval}" in
 544                    yes) ENABLE_JVMTI=yes;;
 545                    *) ENABLE_JVMTI=no;;
 546                esac],
 547               [ENABLE_JVMTI=no])
 548 AC_MSG_RESULT(${ENABLE_JVMTI})
 549 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 550
 551 if test x"${ENABLE_JVMTI}" = "xyes"; then
 552     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 553 fi
 554
 555
 556 dnl threads
 557 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,native) [[default=native]])])
 558 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 559
 560 AC_MSG_CHECKING(whether to include threads support)
 561 enable_threads=${enable_threads:-native}
 562 case "$enable_threads" in
 563 no | none | single)
 564     AC_MSG_RESULT(no)
 565     dnl no threads for boehm
 566     ac_configure_args="$ac_configure_args --disable-boehm-threads"
 567     AM_CONDITIONAL([ENABLE_THREADS], [false])
 568     ;;
 569
 570 native | posix | pthreads)
 571     AC_DEFINE([ENABLE_THREADS], 1, [enable threads])
 572
 573     AM_CONDITIONAL([ENABLE_THREADS], [true])
 574
 575     AC_MSG_RESULT(yes, native)
 576     AC_CHECK_LIB(pthread, main)
 577
 578     ARCH_CFLAGS="$ARCH_CFLAGS -D_REENTRANT"
 579
 580     dnl we changed ARCH_CFLAGS, set CFLAGS again
 581     CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 582
 583     dnl tell boehm to support threads as well
 584     ac_configure_args="$ac_configure_args --enable-boehm-threads=posix"
 585     ;;
 586
 587 *)
 588     AC_MSG_ERROR($enable_threads is an unknown thread package)
 589     ;;
 590 esac
 591
 592
 593 dnl Check whether the compiler supports the __thread keyword.
 594 if test "x$use__thread" != xno; then
 595   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 596   [cat > conftest.c <<\EOF
 597 __thread int a = 42;
 598 EOF
 599   if AC_TRY_COMMAND([${CC-cc} $ARCH_CFLAGS $OPT_CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 600     ac_cv_gcc___thread=yes
 601   else
 602     ac_cv_gcc___thread=no
 603   fi
 604   rm -f conftest*])
 605   if test "$ac_cv_gcc___thread" = yes; then
 606     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 607   fi
 608 else
 609   ac_cv_gcc___thread=no
 610 fi
 611
 612
 613 dnl check if if-conversion should be supported
 614 AC_MSG_CHECKING(whether if-conversion should be supported)
 615 AC_ARG_ENABLE([ifconv],
 616               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=yes]])],
 617               [case "${enableval}" in
 618                    no) ENABLE_IFCONV=no;;
 619                    *) ENABLE_IFCONV=yes;;
 620                esac],
 621               [ENABLE_IFCONV=yes])
 622 AC_MSG_RESULT(${ENABLE_IFCONV})
 623 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 624
 625 if test x"${ENABLE_IFCONV}" = "xyes"; then
 626     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 627 fi
 628
 629
 630 dnl check for inlining
 631 AC_MSG_CHECKING(whether method inlining should be supported)
 632 AC_ARG_ENABLE([inlining],
 633               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 634               [case "${enableval}" in
 635                    yes) ENABLE_INLINING=yes;;
 636                    *) ENABLE_INLINING=no;;
 637                esac],
 638               [ENABLE_INLINING=no])
 639 AC_MSG_RESULT(${ENABLE_INLINING})
 640 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 641
 642 if test x"${ENABLE_INLINING}" = "xyes"; then
 643     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 644 fi
 645
 646
 647 dnl check for inlining debug options
 648 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 649 AC_ARG_ENABLE([inlining-debug],
 650               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 651               [case "${enableval}" in
 652                    yes) ENABLE_INLINING_DEBUG=yes;;
 653                    *) ENABLE_INLINING_DEBUG=no;;
 654                esac],
 655               [ENABLE_INLINING_DEBUG=no])
 656 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 657 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 658
 659 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 660     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 661 fi
 662
 663
 664 dnl check for replacement
 665 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 666 AC_ARG_ENABLE([replacement],
 667               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 668               [case "${enableval}" in
 669                    yes) ENABLE_REPLACEMENT=yes;;
 670                    *) ENABLE_REPLACEMENT=no;;
 671                esac],
 672               [ENABLE_REPLACEMENT=no])
 673 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 674 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 675
 676 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 677     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 678 fi
 679
 680
 681 dnl check for loop optimization
 682 AC_MSG_CHECKING(whether loop optimization should be supported)
 683 AC_ARG_ENABLE([loop],
 684               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 685               [case "${enableval}" in
 686                    yes) ENABLE_LOOP=yes;;
 687                    *) ENABLE_LOOP=no;;
 688                esac],
 689               [ENABLE_LOOP=no])
 690 AC_MSG_RESULT(${ENABLE_LOOP})
 691 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 692
 693 if test x"${ENABLE_LOOP}" = "xyes"; then
 694     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 695 fi
 696
 697
 698 dnl check if linear scan register allocator(lsra) with SSA should be used
 699 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 700 AC_ARG_ENABLE([ssa],
 701               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=no]])],
 702               [case "${enableval}" in
 703                    no) ENABLE_SSA=no;;
 704                    *) ENABLE_SSA=yes;;
 705                esac],
 706               [ENABLE_SSA=no])
 707 AC_MSG_RESULT(${ENABLE_SSA})
 708 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 709
 710 if test x"${ENABLE_SSA}" = "xyes"; then
 711     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 712     ENABLE_LSRA="no"
 713 fi
 714
 715
 716 dnl check if linear scan register allocator(lsra) should be used
 717 AC_MSG_CHECKING(whether lsra should be supported)
 718 AC_ARG_ENABLE([lsra],
 719               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 720               [case "${enableval}" in
 721                    yes) ENABLE_LSRA=yes;;
 722                    *) ENABLE_LSRA=no;;
 723                esac],
 724               [ENABLE_LSRA=no])
 725
 726 if test x"${ENABLE_LSRA}" = "xyes"; then
 727     if test x"${ENABLE_SSA}" = "xyes"; then
 728         ENABLE_LSRA="no"
 729     fi
 730 fi
 731 AC_MSG_RESULT(${ENABLE_LSRA})
 732 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 733
 734 if test x"${ENABLE_LSRA}" = "xyes"; then
 735     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 736 fi
 737
 738
 739 dnl check if profiling should be supported
 740 AC_MSG_CHECKING(whether profiling should be supported)
 741 AC_ARG_ENABLE([profiling],
 742               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 743               [case "${enableval}" in
 744                    yes) ENABLE_PROFILING=yes;;
 745                    *) ENABLE_PROFILING=no;;
 746                esac],
 747               [ENABLE_PROFILING=no])
 748 AC_MSG_RESULT(${ENABLE_PROFILING})
 749 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 750
 751 if test x"${ENABLE_PROFILING}" = "xyes"; then
 752     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 753 fi
 754
 755
 756 dnl check for instruction scheduler
 757 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 758
 759 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 760 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 761         case "${ARCH_DIR}" in
 762                 xdspcore )
 763                         ;;
 764                 * )
 765                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 766                         ;;
 767         esac
 768
 769         AC_MSG_RESULT(yes)
 770         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 771         AM_CONDITIONAL([USE_SCHEDULER], [true])
 772 else
 773         AC_MSG_RESULT(no)
 774         AM_CONDITIONAL([USE_SCHEDULER], [false])
 775 fi
 776
 777
 778 dnl check if zlib should be used
 779 AC_MSG_CHECKING(whether ZIP/JAR archives should be supported)
 780 AC_ARG_ENABLE([zlib],
 781               [AS_HELP_STRING(--disable-zlib,disable ZIP/JAR archive support (needs zlib) [[default=yes]])],
 782               [case "${enableval}" in
 783                   no) ENABLE_ZLIB=no;;
 784                   *) ENABLE_ZLIB=yes;;
 785                esac],
 786               [ENABLE_ZLIB=yes])
 787 AC_MSG_RESULT(${ENABLE_ZLIB})
 788
 789 if test x"${ENABLE_ZLIB}" = "xyes"; then
 790     AC_CHECK_HEADERS([zconf.h],, [AC_MSG_ERROR(cannot find zconf.h)])
 791     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 792     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 793     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 794 fi
 795 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 796
 797
 798 dnl check for stuff to be built
 799 AC_CHECK_ENABLE_JNI
 800
 801
 802 dnl check if a libjvm.so should be built
 803 AC_MSG_CHECKING(whether to build a libjvm.so)
 804 AC_ARG_ENABLE([libjvm],
 805               [AS_HELP_STRING(--disable-libjvm,build a libjvm.so [[default=yes]])],
 806               [case "${enableval}" in
 807                   no) ENABLE_LIBJVM=no;;
 808                   *) ENABLE_LIBJVM=yes;;
 809                esac],
 810               [ENABLE_LIBJVM=yes])
 811 AC_MSG_RESULT(${ENABLE_LIBJVM})
 812 AM_CONDITIONAL([ENABLE_LIBJVM], test x"${ENABLE_LIBJVM}" = "xyes")
 813 AC_SUBST(ENABLE_LIBJVM)
 814
 815 if test x"${ENABLE_LIBJVM}" = "xyes"; then
 816     AC_DEFINE([ENABLE_LIBJVM], 1, [enable libjvm.so])
 817
 818     dnl set AC_ENABLE_SHARED and AC_DISABLE_STATIC properly
 819     enable_shared=yes
 820     enable_static=no
 821 else
 822     enable_shared=no
 823     enable_static=yes
 824 fi
 825
 826 dnl libtool stuff
 827 AC_LIBTOOL_DLOPEN
 828 AC_PROG_LIBTOOL
 829
 830
 831 dnl check if CACAO should be linked statically
 832 AC_MSG_CHECKING(whether to link CACAO statically)
 833 AC_ARG_ENABLE([staticvm],
 834               [AS_HELP_STRING(--enable-staticvm,link CACAO statically [[default=no]])],
 835               [case "${enableval}" in
 836                   yes) ENABLE_STATICVM=yes
 837                        AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 838                        ;;
 839                   *) ENABLE_STATICVM=no;;
 840                esac],
 841               [ENABLE_STATICVM=no])
 842 AC_MSG_RESULT(${ENABLE_STATICVM})
 843 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 844 AC_SUBST(ENABLE_STATICVM)
 845
 846
 847 dnl where is CACAO's vm.zip
 848 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 849 AC_ARG_WITH([vm-zip],
 850             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 851             [CACAO_VM_ZIP=${withval}],
 852             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 853 AC_MSG_RESULT(${CACAO_VM_ZIP})
 854 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 855 AC_SUBST(CACAO_VM_ZIP)
 856
 857
 858 dnl which Java core library are we using?
 859 AC_MSG_CHECKING(which Java core library to use)
 860 AC_ARG_WITH([classpath],
 861             [AS_HELP_STRING(--with-classpath=<type>,specifies which type of classpath to use as Java core library (gnu) [[default=gnu]])],
 862             [case "${withval}" in
 863                 cldc1.1)
 864                     WITH_CLASSPATH=cldc1.1
 865                     AC_DEFINE([WITH_CLASSPATH_CLDC1_1], 1, [use Sun's CLDC1.1 classes])
 866                     AC_SUBST(WITH_CLASSPATH_CLDC1_1)
 867                     ;;
 868                 gnu)
 869                     WITH_CLASSPATH=gnu
 870                     AC_DEFINE([WITH_CLASSPATH_GNU], 1, [use GNU Classpath])
 871                     AC_SUBST(WITH_CLASSPATH_GNU)
 872                     ;;
 873                 *)
 874                     AC_MSG_ERROR(unknown classpath ${withval})
 875                     ;;
 876              esac],
 877             [WITH_CLASSPATH=gnu
 878              AC_DEFINE([WITH_CLASSPATH_GNU], 1, [use GNU Classpath])
 879              AC_SUBST(WITH_CLASSPATH_GNU)])
 880 AC_MSG_RESULT(${WITH_CLASSPATH})
 881 AM_CONDITIONAL([WITH_CLASSPATH_CLDC1_1], test x"${WITH_CLASSPATH}" = "xcldc1.1")
 882 AM_CONDITIONAL([WITH_CLASSPATH_GNU], test x"${WITH_CLASSPATH}" = "xgnu")
 883
 884
 885 dnl where is Java core library installed?
 886 AC_MSG_CHECKING(where Java core library is installed)
 887 AC_ARG_WITH([classpath-prefix],
 888             [AS_HELP_STRING(--with-classpath-prefix=<dir>,installation directory of Java core library [[default=/usr/local/classpath]])],
 889             [CLASSPATH_PREFIX=${withval}],
 890             [CLASSPATH_PREFIX=/usr/local/classpath])
 891 AC_MSG_RESULT(${CLASSPATH_PREFIX})
 892 AC_DEFINE_UNQUOTED([CLASSPATH_PREFIX], "${CLASSPATH_PREFIX}", [Java core library installation directory])
 893 AC_SUBST(CLASSPATH_PREFIX)
 894
 895
 896 dnl where are Java core library classes installed?
 897 AC_MSG_CHECKING(where Java core library classes are installed)
 898 AC_ARG_WITH([classpath-classes],
 899             [AS_HELP_STRING(--with-classpath-classes=<path>,path to Java core library classes (includes the name of the file and may be flat) [[default=/usr/local/classpath/share/classpath/glibj.zip]])],
 900             [CLASSPATH_CLASSES=${withval}],
 901             [CLASSPATH_CLASSES=${CLASSPATH_PREFIX}/share/classpath/glibj.zip])
 902 AC_MSG_RESULT(${CLASSPATH_CLASSES})
 903 AC_DEFINE_UNQUOTED([CLASSPATH_CLASSES], "${CLASSPATH_CLASSES}", [Java core library classes])
 904 AC_SUBST(CLASSPATH_CLASSES)
 905
 906
 907 dnl where are Java core library native libraries installed?
 908 AC_MSG_CHECKING(where Java core library native libraries are installed)
 909 AC_ARG_WITH([classpath-libdir],
 910             [AS_HELP_STRING(--with-classpath-libdir=<dir>,installation directory of Java core library native libraries [[default=/usr/local/classpath/lib]])],
 911             [CLASSPATH_LIBDIR=${withval}],
 912             [CLASSPATH_LIBDIR=${CLASSPATH_PREFIX}/lib])
 913 AC_MSG_RESULT(${CLASSPATH_LIBDIR})
 914
 915 dnl expand CLASSPATH_LIBDIR to something that is usable in C code
 916 AS_AC_EXPAND([CLASSPATH_LIBDIR], ${CLASSPATH_LIBDIR})
 917 AC_DEFINE_UNQUOTED([CLASSPATH_LIBDIR], "${CLASSPATH_LIBDIR}", [Java core library native libraries installation directory])
 918 AC_SUBST(CLASSPATH_LIBDIR)
 919
 920
 921 dnl where are Java core library headers installed?
 922 AC_MSG_CHECKING(where Java core library headers are installed)
 923 AC_ARG_WITH([classpath-includedir],
 924             [AS_HELP_STRING(--with-classpath-includedir=<dir>,installation directory of Java core library headers [[default=/usr/local/classpath/include]])],
 925             [CLASSPATH_INCLUDEDIR=${withval}],
 926             [CLASSPATH_INCLUDEDIR=${CLASSPATH_PREFIX}/include])
 927 AC_MSG_RESULT(${CLASSPATH_INCLUDEDIR})
 928
 929 AC_CHECK_HEADER([${CLASSPATH_INCLUDEDIR}/jni.h],
 930                 [AC_DEFINE_UNQUOTED([CLASSPATH_JNI_H], "${CLASSPATH_INCLUDEDIR}/jni.h", [Java core library jni.h header])],
 931                 [AC_MSG_ERROR(cannot find jni.h)])
 932
 933
 934 dnl if we compile for a JRE-style directory layout
 935 AC_MSG_CHECKING(if we compile for a JRE-style directory layout)
 936 AC_ARG_WITH([jre-layout],
 937             [AS_HELP_STRING(--with-jre-layout,compile for JRE-style directory layout [[default=no]])],
 938             [case "${enableval}" in
 939                 yes) WITH_JRE_LAYOUT=yes
 940                      AC_DEFINE([WITH_JRE_LAYOUT], 1, [with JRE layout])
 941                      ;;
 942                 *) WITH_JRE_LAYOUT=no;;
 943              esac],
 944             [WITH_JRE_LAYOUT=no])
 945 AC_MSG_RESULT(${WITH_JRE_LAYOUT})
 946
 947
 948 dnl check if GNU Classpath should be linked statically into CACAO
 949 AC_MSG_CHECKING(whether to link GNU Classpath native libraries statically into CACAO)
 950 AC_ARG_WITH([static-classpath],
 951             [AS_HELP_STRING(--with-static-classpath,link GNU classpath native libraries statically into CACAO [[default=no]])],
 952             [case "${enableval}" in
 953                 yes) WITH_STATIC_CLASSPATH=yes;;
 954                 *) WITH_STATIC_CLASSPATH=no;;
 955              esac],
 956             [WITH_STATIC_CLASSPATH=no])
 957 AC_MSG_RESULT(${WITH_STATIC_CLASSPATH})
 958
 959 if test x"${WITH_STATIC_CLASSPATH}" = "xyes"; then
 960     AC_DEFINE([WITH_STATIC_CLASSPATH], 1, [link GNU classpath native libraries statically into CACAO])
 961
 962     dnl check for some classpath related stuff when we link statically
 963     AM_ICONV_LINK
 964 else
 965     dnl we need this check for --enable-staticvm, otherwise ltdl can't find dlopen
 966     if test x"${ENABLE_STATICVM}" = "xyes"; then
 967         AC_CHECK_LIB(dl, dlopen,, [AC_MSG_ERROR(cannot find libdl)])
 968     fi
 969
 970     AC_CHECK_HEADERS([ltdl.h],, [AC_MSG_ERROR(cannot find ltdl.h)])
 971     AC_CHECK_LIB(ltdl, lt_dlopen,, [AC_MSG_ERROR(cannot find libltdl)])
 972 fi
 973 AM_CONDITIONAL([WITH_STATIC_CLASSPATH], test x"${WITH_STATIC_CLASSPATH}" = "xyes")
 974 AC_SUBST(WITH_STATIC_CLASSPATH)
 975
 976
 977 dnl check for some programs we need
 978 AC_PROG_JAVAC
 979 AC_PROG_JAR
 980
 981
 982 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 983 CFLAGS=$OPT_CFLAGS
 984 AM_CFLAGS=$ARCH_CFLAGS
 985 AC_SUBST(AM_CFLAGS)
 986
 987
 988 AC_CONFIG_FILES([Makefile]
 989                 [contrib/Makefile]
 990                 [contrib/setenvinstalled]
 991                 [contrib/setenvsource]
 992                 [doc/Makefile]
 993                 [doc/handbook/Makefile]
 994                 [man/Makefile]
 995                 [src/Makefile]
 996                 [src/cacao/Makefile]
 997                 [src/cacaoh/Makefile]
 998                 [src/fdlibm/Makefile]
 999                 [src/lib/Makefile]
1000                 [src/mm/Makefile]
1001                 [src/mm/cacao-gc/Makefile]
1002                 [src/native/Makefile]
1003                 [src/native/include/Makefile]
1004                 [src/native/jvmti/Makefile]
1005                 [src/native/tools/Makefile]
1006                 [src/native/vm/Makefile]
1007                 [src/native/vm/cldc1.1/Makefile]
1008                 [src/native/vm/gnu/Makefile]
1009                 [src/scripts/Makefile]
1010                 [src/scripts/java]
1011                 [src/threads/Makefile]
1012                 [src/threads/native/Makefile]
1013                 [src/threads/none/Makefile]
1014                 [src/toolbox/Makefile]
1015                 [src/vm/Makefile]
1016                 [src/vm/jit/Makefile]
1017                 [src/vm/jit/allocator/Makefile]
1018                 [src/vm/jit/alpha/Makefile]
1019                 [src/vm/jit/alpha/freebsd/Makefile]
1020                 [src/vm/jit/alpha/linux/Makefile]
1021                 [src/vm/jit/arm/Makefile]
1022                 [src/vm/jit/arm/linux/Makefile]
1023                 [src/vm/jit/i386/Makefile]
1024                 [src/vm/jit/i386/cygwin/Makefile]
1025                 [src/vm/jit/i386/darwin/Makefile]
1026                 [src/vm/jit/i386/freebsd/Makefile]
1027                 [src/vm/jit/i386/linux/Makefile]
1028                 [src/vm/jit/intrp/Makefile]
1029                 [src/vm/jit/inline/Makefile]
1030                 [src/vm/jit/loop/Makefile]
1031                 [src/vm/jit/m68k/Makefile]
1032                 [src/vm/jit/m68k/linux/Makefile]
1033                 [src/vm/jit/mips/Makefile]
1034                 [src/vm/jit/mips/irix/Makefile]
1035                 [src/vm/jit/mips/linux/Makefile]
1036                 [src/vm/jit/optimizing/Makefile]
1037                 [src/vm/jit/parisc/Makefile]
1038                 [src/vm/jit/parisc/linux/Makefile]
1039                 [src/vm/jit/powerpc/Makefile]
1040                 [src/vm/jit/powerpc/darwin/Makefile]
1041                 [src/vm/jit/powerpc/linux/Makefile]
1042                 [src/vm/jit/powerpc/netbsd/Makefile]
1043                 [src/vm/jit/powerpc64/Makefile]
1044                 [src/vm/jit/powerpc64/linux/Makefile]
1045                 [src/vm/jit/s390/Makefile]
1046                 [src/vm/jit/schedule/Makefile]
1047                 [src/vm/jit/sparc64/Makefile]
1048                 [src/vm/jit/sparc64/linux/Makefile]
1049                 [src/vm/jit/sparc64/solaris/Makefile]
1050                 [src/vm/jit/tools/Makefile]
1051                 [src/vm/jit/verify/Makefile]
1052                 [src/vm/jit/x86_64/Makefile]
1053                 [src/vm/jit/x86_64/freebsd/Makefile]
1054                 [src/vm/jit/x86_64/linux/Makefile]
1055                 [src/vmcore/Makefile]
1056                 [tests/Makefile]
1057                 [tests/regression/Makefile]
1058                 [tests/regression/codepatching/Makefile]
1059                 [tests/regression/jasmin/Makefile]
1060                 [tests/regression/native/Makefile]
1061                 [tests/regression/resolving/Makefile]
1062                 [tests/regression/resolving/classes1/Makefile]
1063                 [tests/regression/resolving/classes2/Makefile]
1064                 [tests/regression/resolving/classes3/Makefile]
1065                 )
1066
1067
1068 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
1069 export OPT_CFLAGS
1070 export ARCH_CFLAGS
1071 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
1072
1073
1074 AC_OUTPUT
1075
1076
1077 ## Local variables:
1078 ## mode: m4
1079 ## indent-tabs-mode: t
1080 ## c-basic-offset: 4
1081 ## tab-width: 8
1082 ## compile-command: "automake --add-missing"
1083 ## End: