configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 0.98+svn, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl set optimization and debugging for all architectures and systems
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-O0 -g3"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 dnl system type
  46 case "$host_cpu" in
  47 alpha | alphaev56 | alphapca56 )
  48     ARCH_DIR="alpha"
  49     ARCH_CFLAGS="-mieee -D__ALPHA__"
  50     JAVA_ARCH="alpha"
  51     ;;
  52
  53 arm | armv4 | armv4tl | armv5b | armv5l )
  54     ARCH_DIR="arm"
  55     ARCH_CFLAGS="-D__ARM__"
  56     JAVA_ARCH="arm"
  57     ;;
  58
  59 hppa2.0 )
  60     ARCH_DIR="parisc"
  61     ARCH_CFLAGS="-D__PARISC__"
  62     JAVA_ARCH="hppa"
  63     ;;
  64
  65 i386 | i486 | i586 | i686 )
  66     ARCH_DIR="i386"
  67     ARCH_CFLAGS="-D__I386__"
  68     JAVA_ARCH="i386"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     JAVA_ARCH="m68k"
  75     ;;
  76
  77 mips | mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_CFLAGS="-D__MIPS__"
  80     dnl Is this correct for mipsel?
  81     JAVA_ARCH="mips"
  82     ;;
  83
  84 powerpc )
  85     ARCH_DIR="powerpc"
  86     ARCH_CFLAGS="-D__POWERPC__"
  87     JAVA_ARCH="ppc"
  88     ;;
  89
  90 powerpc64 )
  91     ARCH_DIR="powerpc64"
  92     ARCH_CFLAGS="-D__POWERPC64__"
  93     JAVA_ARCH="ppc64"
  94     ;;
  95
  96 s390 )
  97     ARCH_DIR="s390"
  98     ARCH_CFLAGS="-D__S390__"
  99     JAVA_ARCH="s390"
 100     ;;
 101
 102 sparc | sparc64 )
 103     ARCH_DIR="sparc64"
 104     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 105     dnl Is this correct for 64-bits?
 106     JAVA_ARCH="sparc"
 107     ;;
 108
 109 x86_64 )
 110     ARCH_DIR="x86_64"
 111     ARCH_CFLAGS="-D__X86_64__"
 112     JAVA_ARCH="amd64"
 113     ;;
 114
 115 xdspcore )
 116     ARCH_DIR="xdspcore"
 117     ENABLE_STATICVM="yes"
 118     ARCH_CFLAGS="-D__XDSPCORE__"
 119     USE_SCHEDULER="1"
 120     ;;
 121
 122 * )
 123     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 124     ;;
 125 esac
 126
 127 dnl host type
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 132     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 138     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 139     ;;
 140
 141 *freebsd* )
 142     OS_DIR="freebsd"
 143     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 144     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 145     ;;
 146
 147 *irix* )
 148     OS_DIR="irix"
 149     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 150     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 151     ;;
 152
 153 *kfreebsd*-gnu)
 154     OS_DIR="freebsd"
 155     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 156     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 157     ;;
 158
 159 dnl must be before *linux*
 160 *uclinux | *elf )
 161     OS_DIR="uclinux"
 162     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 163     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     ;;
 165
 166 *linux* | *Linux* )
 167     OS_DIR="linux"
 168     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 169     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     ;;
 171
 172 *netbsd* )
 173     OS_DIR="netbsd"
 174     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 175     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     ;;
 177
 178 *solaris* )
 179     OS_DIR="solaris"
 180         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 181         dnl therefore we add them here
 182     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 183     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 184     ;;
 185
 186 * )
 187     ;;
 188 esac
 189
 190
 191 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 192 dnl we set it properly at the end of this file
 193 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 194
 195 dnl set interpreter flags
 196 AC_SUBST(INTRP_CFLAGS)
 197
 198 dnl define and substitute some architecture specific variables
 199 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 200 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 201 AC_SUBST(ARCH_DIR)
 202 AC_SUBST(OS_DIR)
 203 AC_SUBST(USE_SCHEDULER)
 204
 205
 206 dnl Checks for programs.
 207 AC_PROG_CC
 208 AM_PROG_AS
 209 AC_PROG_LD
 210 AC_PROG_LD_GNU
 211 AC_PROG_RANLIB
 212 AC_PROG_LN_S
 213 AC_PROG_MAKE_SET
 214 AM_PROG_MKDIR_P
 215
 216 dnl Checks for header files.
 217 AC_HEADER_DIRENT
 218 AC_HEADER_STDC
 219
 220 dnl keep them alpha-sorted!
 221 AC_CHECK_HEADERS([assert.h])
 222 AC_CHECK_HEADERS([errno.h])
 223 AC_CHECK_HEADERS([fcntl.h])
 224 AC_CHECK_HEADERS([libgen.h])
 225 AC_CHECK_HEADERS([netdb.h])
 226 AC_CHECK_HEADERS([stdlib.h])
 227 AC_CHECK_HEADERS([string.h])
 228 AC_CHECK_HEADERS([time.h])
 229 AC_CHECK_HEADERS([ucontext.h])
 230 AC_CHECK_HEADERS([unistd.h])
 231 AC_CHECK_HEADERS([sys/ioctl.h])
 232 AC_CHECK_HEADERS([sys/mman.h])
 233 AC_CHECK_HEADERS([sys/resource.h])
 234 AC_CHECK_HEADERS([sys/select.h])
 235 AC_CHECK_HEADERS([sys/socket.h])
 236 AC_CHECK_HEADERS([sys/stat.h])
 237 AC_CHECK_HEADERS([sys/time.h])
 238 AC_CHECK_HEADERS([sys/types.h])
 239
 240 dnl this is for fdlibm
 241 AC_CHECK_HEADERS([stdint.h])
 242 AC_CHECK_HEADERS([inttypes.h])
 243 AC_CHECK_HEADERS([sys/config.h])
 244 AC_CHECK_HEADERS([sys/types.h])
 245 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 246 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 247 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 248 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 249
 250 dnl Checks for typedefs, structures, and compiler characteristics.
 251 AC_C_CONST
 252 AC_C_INLINE
 253 AC_C_ATTRIBUTE
 254 AC_TYPE_OFF_T
 255 AC_TYPE_SIZE_T
 256 AC_HEADER_TIME
 257 AC_STRUCT_TM
 258
 259 dnl Checks for libraries (NOTE: Should be done before function checks,
 260 dnl as some functions may be in libraries we check for).
 261 AC_CHECK_LIB(dl, dlopen,,)
 262
 263 dnl Checks for library functions.
 264 AC_PROG_GCC_TRADITIONAL
 265 AC_TYPE_SIGNAL
 266 AC_FUNC_MEMCMP
 267 AC_FUNC_MMAP
 268
 269 dnl keep them alpha-sorted!
 270 AC_CHECK_FUNCS([abort])
 271 AC_CHECK_FUNCS([accept])
 272 AC_CHECK_FUNCS([access])
 273 AC_CHECK_FUNCS([atoi])
 274 AC_CHECK_FUNCS([atol])
 275 AC_CHECK_FUNCS([calloc])
 276 AC_CHECK_FUNCS([close])
 277 AC_CHECK_FUNCS([confstr])
 278 AC_CHECK_FUNCS([connect])
 279 AC_CHECK_FUNCS([dirname])
 280 AC_CHECK_FUNCS([fclose])
 281 AC_CHECK_FUNCS([fflush])
 282 AC_CHECK_FUNCS([fopen])
 283 AC_CHECK_FUNCS([fprintf])
 284 AC_CHECK_FUNCS([fread])
 285 AC_CHECK_FUNCS([free])
 286 AC_CHECK_FUNCS([fstat])
 287 AC_CHECK_FUNCS([fsync])
 288 AC_CHECK_FUNCS([ftruncate])
 289 AC_CHECK_FUNCS([getcwd])
 290 AC_CHECK_FUNCS([gethostbyname])
 291 AC_CHECK_FUNCS([gethostname])
 292 AC_CHECK_FUNCS([getpagesize])
 293 AC_CHECK_FUNCS([getrusage])
 294 AC_CHECK_FUNCS([getsockname])
 295 AC_CHECK_FUNCS([getsockopt])
 296 AC_CHECK_FUNCS([gettimeofday])
 297 AC_CHECK_FUNCS([htons])
 298 AC_CHECK_FUNCS([ioctl])
 299 AC_CHECK_FUNCS([isnan])
 300 AC_CHECK_FUNCS([listen])
 301 AC_CHECK_FUNCS([localtime])
 302 AC_CHECK_FUNCS([localtime_r])
 303 AC_CHECK_FUNCS([lseek])
 304 AC_CHECK_FUNCS([malloc])
 305 AC_CHECK_FUNCS([memcpy])
 306 AC_CHECK_FUNCS([memset])
 307 AC_CHECK_FUNCS([mmap])
 308 AC_CHECK_FUNCS([mprotect])
 309 AC_CHECK_FUNCS([open])
 310 AC_CHECK_FUNCS([read])
 311 AC_CHECK_FUNCS([readlink])
 312 AC_CHECK_FUNCS([realloc])
 313 AC_CHECK_FUNCS([recv])
 314 AC_CHECK_FUNCS([scandir])
 315 AC_CHECK_FUNCS([select])
 316 AC_CHECK_FUNCS([send])
 317 AC_CHECK_FUNCS([setsockopt])
 318 AC_CHECK_FUNCS([shutdown])
 319 AC_CHECK_FUNCS([socket])
 320 AC_CHECK_FUNCS([stat])
 321 AC_CHECK_FUNCS([strchr])
 322 AC_CHECK_FUNCS([strdup])
 323 AC_CHECK_FUNCS([strerror])
 324 AC_CHECK_FUNCS([strlen])
 325 AC_CHECK_FUNCS([strncmp])
 326 AC_CHECK_FUNCS([strstr])
 327 AC_CHECK_FUNCS([time])
 328 AC_CHECK_FUNCS([write])
 329
 330
 331 dnl Checks for libraries.
 332
 333 dnl Checking sizeof void *
 334 AC_CHECK_SIZEOF(void *)
 335 AC_C_BIGENDIAN
 336
 337
 338 dnl define install prefix
 339 if test "x$prefix" = "xNONE"; then
 340     CACAO_PREFIX=$ac_default_prefix
 341 else
 342     CACAO_PREFIX=$prefix
 343 fi
 344 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 345 AC_SUBST(CACAO_PREFIX)
 346
 347 dnl define libdir prefix
 348 if test "x$libdir" = "xNONE"; then
 349     CACAO_LIBDIR=$ac_default_libdir
 350 else
 351     CACAO_LIBDIR=$libdir
 352 fi
 353 dnl expand CACAO_LIBDIR to something that is usable in C code
 354 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 355 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 356 AC_SUBST(CACAO_LIBDIR)
 357
 358
 359 AC_CHECK_ENABLE_LTDL
 360
 361 AC_CHECK_ENABLE_JAVA
 362
 363 AC_CHECK_ENABLE_JIT
 364 AC_CHECK_ENABLE_INTRP
 365
 366 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 367     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 368 fi
 369
 370 AC_CHECK_SOFTFLOAT
 371 AC_CHECK_SOFT_FLOAT_CMP
 372 AC_CHECK_SOFT_DOUBLE_CMP
 373
 374 AC_CHECK_ENABLE_GC
 375 AC_CHECK_ENABLE_DEBUG
 376 AC_CHECK_ENABLE_DUMP
 377
 378
 379 dnl check for memcheck support
 380 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 381 AC_ARG_ENABLE([memcheck],
 382               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 383               [case "${enableval}" in
 384                    yes) ENABLE_MEMCHECK=yes;;
 385                    *) ENABLE_MEMCHECK=no;;
 386                esac],
 387               [ENABLE_MEMCHECK=no])
 388 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 389 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 390
 391 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 392     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 393 fi
 394
 395
 396 dnl check for handles (indirection cells) support
 397 AC_MSG_CHECKING(whether handles (indirection cells) should be enabled)
 398 AC_ARG_ENABLE([handles],
 399               [AS_HELP_STRING(--enable-handles,enable handles (indirection cells) [[default=no]])],
 400               [case "${enableval}" in
 401                    yes) ENABLE_HANDLES=yes;;
 402                    *) ENABLE_HANDLES=no;;
 403                esac],
 404               [ENABLE_HANDLES=no])
 405 AC_MSG_RESULT(${ENABLE_HANDLES})
 406 AM_CONDITIONAL([ENABLE_HANDLES], test x"${ENABLE_HANDLES}" = "xyes")
 407
 408 if test x"${ENABLE_HANDLES}" = "xyes"; then
 409     AC_DEFINE([ENABLE_HANDLES], 1, [enable handles (indirection cells)])
 410 fi
 411
 412
 413 dnl check for vmlog support
 414 AC_MSG_CHECKING(whether vmlog tracing should be enabled)
 415 AC_ARG_ENABLE([vmlog],
 416               [AS_HELP_STRING(--enable-vmlog,enable vmlog tracing [[default=no]])],
 417               [case "${enableval}" in
 418                    yes) ENABLE_VMLOG=yes;;
 419                    *) ENABLE_VMLOG=no;;
 420                esac],
 421               [ENABLE_VMLOG=no])
 422 AC_MSG_RESULT(${ENABLE_VMLOG})
 423 AM_CONDITIONAL([ENABLE_VMLOG], test x"${ENABLE_VMLOG}" = "xyes")
 424
 425 if test x"${ENABLE_VMLOG}" = "xyes"; then
 426     AC_DEFINE([ENABLE_VMLOG], 1, [enable vmlog tracing code])
 427 fi
 428
 429
 430 dnl check for disassembler support
 431 AC_MSG_CHECKING(whether disassembler should be enabled)
 432 AC_ARG_ENABLE([disassembler],
 433               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 434               [case "${enableval}" in
 435                    yes) ENABLE_DISASSEMBLER=yes;;
 436                    *) ENABLE_DISASSEMBLER=no;;
 437                esac],
 438               [ENABLE_DISASSEMBLER=no])
 439 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 440 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 441
 442 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 443     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 444
 445     dnl check for binutils headers and libraries on some architectures for the
 446     dnl disassembler
 447     case "${ARCH_DIR}" in
 448         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 449             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 450             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 451             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 452             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 453
 454             case "${OS_DIR}" in
 455                 cygwin | darwin | netbsd | solaris)
 456                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 457                      ;;
 458             esac
 459
 460             case "${OS_DIR}" in
 461                 solaris)
 462                                          AC_CHECK_LIB(rt, sem_init,, [AC_MSG_ERROR(cannot find librt)])
 463                      ;;
 464             esac
 465
 466
 467             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 468             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 469             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 470             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 471             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 472             ;;
 473         * )
 474             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 475             ;;
 476     esac
 477 else
 478     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 479 fi
 480
 481
 482 dnl check for statistics
 483 AC_MSG_CHECKING(whether statistics generation should be enabled)
 484 AC_ARG_ENABLE([statistics],
 485               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 486               [case "${enableval}" in
 487                    yes) ENABLE_STATISTICS=yes;;
 488                    *) ENABLE_STATISTICS=no;;
 489                esac],
 490               [ENABLE_STATISTICS=no])
 491 AC_MSG_RESULT(${ENABLE_STATISTICS})
 492 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 493
 494 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 495     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 496 fi
 497
 498
 499 dnl check for verifier
 500 AC_MSG_CHECKING(whether classfile verification should be enabled)
 501 AC_ARG_ENABLE([verifier],
 502               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=enabled]])],
 503               [case "${enableval}" in
 504                    no) ENABLE_VERIFIER=no;;
 505                    *) ENABLE_VERIFIER=yes;;
 506                esac],
 507               [ENABLE_VERIFIER=yes])
 508 AC_MSG_RESULT(${ENABLE_VERIFIER})
 509 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 510
 511 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 512     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 513 fi
 514
 515
 516 dnl check for compiler timing
 517 AC_MSG_CHECKING(whether real-time timing should be enabled)
 518 AC_ARG_ENABLE([rt-timing],
 519               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 520               [case "${enableval}" in
 521                    yes) ENABLE_RT_TIMING=yes;;
 522                    *) ENABLE_RT_TIMING=no;;
 523                esac],
 524               [ENABLE_RT_TIMING=no])
 525 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 526 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 527
 528 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 529     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 530 fi
 531
 532
 533 dnl check for cycle count statistics
 534 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 535 AC_ARG_ENABLE([cycles-stats],
 536               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 537               [case "${enableval}" in
 538                    yes) ENABLE_CYCLES_STATS=yes;;
 539                    *) ENABLE_CYCLES_STATS=no;;
 540                esac],
 541               [ENABLE_CYCLES_STATS=no])
 542 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 543 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 544
 545 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 546     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 547 fi
 548
 549
 550 dnl check for JVMTI
 551 AC_MSG_CHECKING(whether to compile JVMTI support)
 552 AC_ARG_ENABLE([jvmti],
 553               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 554               [case "${enableval}" in
 555                    yes) ENABLE_JVMTI=yes;;
 556                    *) ENABLE_JVMTI=no;;
 557                esac],
 558               [ENABLE_JVMTI=no])
 559 AC_MSG_RESULT(${ENABLE_JVMTI})
 560 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 561
 562 if test x"${ENABLE_JVMTI}" = "xyes"; then
 563     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 564 fi
 565
 566
 567 AC_CHECK_ENABLE_THREADS
 568
 569
 570 dnl check if if-conversion should be supported
 571 AC_MSG_CHECKING(whether if-conversion should be supported)
 572 AC_ARG_ENABLE([ifconv],
 573               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=enabled]])],
 574               [case "${enableval}" in
 575                    no) ENABLE_IFCONV=no;;
 576                    *) ENABLE_IFCONV=yes;;
 577                esac],
 578               [ENABLE_IFCONV=yes])
 579 AC_MSG_RESULT(${ENABLE_IFCONV})
 580 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 581
 582 if test x"${ENABLE_IFCONV}" = "xyes"; then
 583     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 584 fi
 585
 586
 587 dnl check for inlining
 588 AC_MSG_CHECKING(whether method inlining should be supported)
 589 AC_ARG_ENABLE([inlining],
 590               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 591               [case "${enableval}" in
 592                    yes) ENABLE_INLINING=yes;;
 593                    *) ENABLE_INLINING=no;;
 594                esac],
 595               [ENABLE_INLINING=no])
 596 AC_MSG_RESULT(${ENABLE_INLINING})
 597 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 598
 599 if test x"${ENABLE_INLINING}" = "xyes"; then
 600     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 601 fi
 602
 603
 604 dnl check for inlining debug options
 605 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 606 AC_ARG_ENABLE([inlining-debug],
 607               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 608               [case "${enableval}" in
 609                    yes) ENABLE_INLINING_DEBUG=yes;;
 610                    *) ENABLE_INLINING_DEBUG=no;;
 611                esac],
 612               [ENABLE_INLINING_DEBUG=no])
 613 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 614 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 615
 616 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 617     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 618 fi
 619
 620
 621 dnl check for replacement
 622 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 623 AC_ARG_ENABLE([replacement],
 624               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 625               [case "${enableval}" in
 626                    yes) ENABLE_REPLACEMENT=yes;;
 627                    *) ENABLE_REPLACEMENT=no;;
 628                esac],
 629               [ENABLE_REPLACEMENT=no])
 630 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 631 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 632
 633 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 634     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 635 fi
 636
 637
 638 dnl check for loop optimization
 639 AC_MSG_CHECKING(whether loop optimization should be supported)
 640 AC_ARG_ENABLE([loop],
 641               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 642               [case "${enableval}" in
 643                    yes) ENABLE_LOOP=yes;;
 644                    *) ENABLE_LOOP=no;;
 645                esac],
 646               [ENABLE_LOOP=no])
 647 AC_MSG_RESULT(${ENABLE_LOOP})
 648 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 649
 650 if test x"${ENABLE_LOOP}" = "xyes"; then
 651     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 652 fi
 653
 654
 655 dnl check if linear scan register allocator(lsra) with SSA should be used
 656 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 657 AC_ARG_ENABLE([ssa],
 658               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 659               [case "${enableval}" in
 660                    no) ENABLE_SSA=no;;
 661                    *) ENABLE_SSA=yes;;
 662                esac],
 663               [ENABLE_SSA=no])
 664 AC_MSG_RESULT(${ENABLE_SSA})
 665 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 666
 667 if test x"${ENABLE_SSA}" = "xyes"; then
 668     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 669     ENABLE_LSRA="no"
 670 fi
 671
 672
 673 dnl check if linear scan register allocator(lsra) should be used
 674 AC_MSG_CHECKING(whether lsra should be supported)
 675 AC_ARG_ENABLE([lsra],
 676               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 677               [case "${enableval}" in
 678                    yes) ENABLE_LSRA=yes;;
 679                    *) ENABLE_LSRA=no;;
 680                esac],
 681               [ENABLE_LSRA=no])
 682
 683 if test x"${ENABLE_LSRA}" = "xyes"; then
 684     if test x"${ENABLE_SSA}" = "xyes"; then
 685         ENABLE_LSRA="no"
 686     fi
 687 fi
 688 AC_MSG_RESULT(${ENABLE_LSRA})
 689 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 690
 691 if test x"${ENABLE_LSRA}" = "xyes"; then
 692     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 693 fi
 694
 695
 696 dnl check if profiling should be supported
 697 AC_MSG_CHECKING(whether profiling should be supported)
 698 AC_ARG_ENABLE([profiling],
 699               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 700               [case "${enableval}" in
 701                    yes) ENABLE_PROFILING=yes;;
 702                    *) ENABLE_PROFILING=no;;
 703                esac],
 704               [ENABLE_PROFILING=no])
 705 AC_MSG_RESULT(${ENABLE_PROFILING})
 706 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 707
 708 if test x"${ENABLE_PROFILING}" = "xyes"; then
 709     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 710 fi
 711
 712
 713 dnl check for instruction scheduler
 714 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 715
 716 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 717 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 718         case "${ARCH_DIR}" in
 719                 xdspcore )
 720                         ;;
 721                 * )
 722                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 723                         ;;
 724         esac
 725
 726         AC_MSG_RESULT(yes)
 727         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 728         AM_CONDITIONAL([USE_SCHEDULER], [true])
 729 else
 730         AC_MSG_RESULT(no)
 731         AM_CONDITIONAL([USE_SCHEDULER], [false])
 732 fi
 733
 734
 735 AC_CHECK_ENABLE_ZLIB
 736
 737 dnl check for stuff to be built
 738 AC_CHECK_ENABLE_JNI
 739 AC_CHECK_ENABLE_LIBJVM
 740
 741 dnl ATTENTION: These check must be after setting
 742 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 743 dnl because libtool uses them to build the correct libraries.
 744 AC_LIBTOOL_DLOPEN
 745 AC_PROG_LIBTOOL
 746
 747 AC_CHECK_ENABLE_STATICVM
 748 AC_CHECK_ENABLE_ANNOTATIONS
 749 AC_CHECK_ENABLE_ASSERTION
 750
 751
 752 dnl where is CACAO's vm.zip
 753 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 754 AC_ARG_WITH([vm-zip],
 755             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 756             [CACAO_VM_ZIP=${withval}],
 757             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 758 AC_MSG_RESULT(${CACAO_VM_ZIP})
 759 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 760 AC_SUBST(CACAO_VM_ZIP)
 761
 762
 763 AC_CHECK_WITH_CACAOH
 764 AC_CHECK_WITH_CLASSPATH
 765
 766 dnl Now we check for jre-layout so we can skip some checks that are
 767 dnl not required.
 768 AC_CHECK_WITH_JRE_LAYOUT
 769
 770 AC_CHECK_WITH_CLASSPATH_PREFIX
 771 AC_CHECK_WITH_CLASSPATH_CLASSES
 772
 773 if test x"${WITH_JRE_LAYOUT}" = "xno"; then
 774    AC_CHECK_WITH_CLASSPATH_LIBDIR
 775 fi
 776
 777 dnl The check for jni_md.h must be before jni.h.
 778 AC_CHECK_WITH_JNI_MD_H
 779 AC_CHECK_WITH_JNI_H
 780
 781
 782 dnl check for some programs we need
 783
 784 case "${WITH_CLASSPATH}" in
 785     cldc1.1 | gnu)
 786         AC_PROG_JAVAC
 787         AC_PROG_JAR
 788         ;;
 789     sun)
 790         ;;
 791     *)
 792         AC_MSG_ERROR(unknown classpath configuration ${WITH_CLASSPATH})
 793         ;;
 794 esac
 795
 796
 797 AC_CHECK_HEADERS(
 798         [regex.h],
 799         [
 800                 dnl If debug build and regex.h available, enable debug filter
 801                 if test x"${NDEBUG}" = "xno"; then
 802                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 803                 fi
 804                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 805                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 806         ],
 807         [
 808                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 809         ]
 810 )
 811
 812 dnl python
 813
 814 AZ_PYTHON_DEFAULT
 815 AZ_PYTHON_ENABLE
 816 AZ_PYTHON_WITH
 817 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 818 AZ_PYTHON_CSPEC
 819 AZ_PYTHON_LSPEC
 820
 821
 822 dnl define some stuff required for --fullversion
 823 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 824 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 825 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS $CPPFLAGS", [CFLAGS used])
 826
 827
 828 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 829 CFLAGS="$OPT_CFLAGS"
 830 AM_CFLAGS=$ARCH_CFLAGS
 831 AM_CPPFLAGS="$CPPFLAGS"
 832 AC_SUBST(AM_CFLAGS)
 833 AC_SUBST(AM_CPPFLAGS)
 834
 835
 836 AC_CONFIG_FILES([Makefile]
 837                 [contrib/Makefile]
 838                 [contrib/setenvinstalled]
 839                 [contrib/setenvsource]
 840                 [contrib/vmlog/Makefile]
 841                 [contrib/vmlog/t/Makefile]
 842                 [doc/Makefile]
 843                 [doc/handbook/Makefile]
 844                 [man/Makefile]
 845                 [src/Makefile]
 846                 [src/cacao/Makefile]
 847                 [src/cacaoh/Makefile]
 848                 [src/classes/Makefile]
 849                 [src/fdlibm/Makefile]
 850                 [src/mm/Makefile]
 851                 [src/mm/cacao-gc/Makefile]
 852                 [src/native/Makefile]
 853                 [src/native/include/Makefile]
 854                 [src/native/jvmti/Makefile]
 855                 [src/native/vm/Makefile]
 856                 [src/native/vm/cldc1.1/Makefile]
 857                 [src/native/vm/gnu/Makefile]
 858                 [src/native/vm/sun/Makefile]
 859                 [src/scripts/Makefile]
 860                 [src/scripts/java]
 861                 [src/threads/Makefile]
 862                 [src/threads/native/Makefile]
 863                 [src/threads/none/Makefile]
 864                 [src/toolbox/Makefile]
 865                 [src/vm/Makefile]
 866                 [src/vm/jit/Makefile]
 867                 [src/vm/jit/allocator/Makefile]
 868                 [src/vm/jit/alpha/Makefile]
 869                 [src/vm/jit/alpha/freebsd/Makefile]
 870                 [src/vm/jit/alpha/linux/Makefile]
 871                 [src/vm/jit/arm/Makefile]
 872                 [src/vm/jit/arm/linux/Makefile]
 873                 [src/vm/jit/i386/Makefile]
 874                 [src/vm/jit/i386/cygwin/Makefile]
 875                 [src/vm/jit/i386/darwin/Makefile]
 876                 [src/vm/jit/i386/freebsd/Makefile]
 877                 [src/vm/jit/i386/linux/Makefile]
 878                 [src/vm/jit/intrp/Makefile]
 879                 [src/vm/jit/inline/Makefile]
 880                 [src/vm/jit/ir/Makefile]
 881                 [src/vm/jit/loop/Makefile]
 882                 [src/vm/jit/m68k/Makefile]
 883                 [src/vm/jit/m68k/linux/Makefile]
 884                 [src/vm/jit/mips/Makefile]
 885                 [src/vm/jit/mips/irix/Makefile]
 886                 [src/vm/jit/mips/linux/Makefile]
 887                 [src/vm/jit/mips/uclinux/Makefile]
 888                 [src/vm/jit/optimizing/Makefile]
 889                 [src/vm/jit/parisc/Makefile]
 890                 [src/vm/jit/parisc/linux/Makefile]
 891                 [src/vm/jit/powerpc/Makefile]
 892                 [src/vm/jit/powerpc/darwin/Makefile]
 893                 [src/vm/jit/powerpc/linux/Makefile]
 894                 [src/vm/jit/powerpc/netbsd/Makefile]
 895                 [src/vm/jit/powerpc64/Makefile]
 896                 [src/vm/jit/powerpc64/linux/Makefile]
 897                 [src/vm/jit/s390/Makefile]
 898                 [src/vm/jit/schedule/Makefile]
 899                 [src/vm/jit/sparc64/Makefile]
 900                 [src/vm/jit/sparc64/linux/Makefile]
 901                 [src/vm/jit/sparc64/solaris/Makefile]
 902                 [src/vm/jit/verify/Makefile]
 903                 [src/vm/jit/x86_64/Makefile]
 904                 [src/vm/jit/x86_64/freebsd/Makefile]
 905                 [src/vm/jit/x86_64/linux/Makefile]
 906                 [src/vmcore/Makefile]
 907                 [tests/Makefile]
 908                 [tests/regression/Makefile]
 909                 [tests/regression/bugzilla/Makefile]
 910                 [tests/regression/codepatching/Makefile]
 911                 [tests/regression/assertion/Makefile]
 912                 [tests/regression/jasmin/Makefile]
 913                 [tests/regression/native/Makefile]
 914                 [tests/regression/resolving/Makefile]
 915                 [tests/regression/resolving/classes1/Makefile]
 916                 [tests/regression/resolving/classes2/Makefile]
 917                 [tests/regression/resolving/classes3/Makefile]
 918 )
 919
 920
 921 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
 922 export OPT_CFLAGS
 923 export ARCH_CFLAGS
 924 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 925
 926
 927 AC_OUTPUT
 928
 929
 930 ## Local variables:
 931 ## mode: m4
 932 ## indent-tabs-mode: t
 933 ## c-basic-offset: 4
 934 ## tab-width: 8
 935 ## compile-command: "automake --add-missing"
 936 ## End: