# $Id: PKGBUILD 26024 2010-09-12 16:06:47Z tdziedzic $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: shild <shildv@gmail.com>

pkgname=xmonad
pkgver=0.9.1
pkgrel=8
pkgdesc="A lightweight X11 tiled window manager written in Haskell"
arch=('i686' 'x86_64' 'ppc')
url="http://xmonad.org/"
license=('BSD')
depends=('ghc=6.12.3' 'gmp' 'libxinerama' 'haskell-x11=1.5.0.0' 'sh' 'haskell-mtl=1.1.0.2' 'haskell-utf8-string=0.3.6')
install='xmonad.install'
source=(http://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz xmonad.desktop xmonad.svg)
md5sums=('3d0dd5cf77768b10e1b7f3a47e32b09e'
         'f61961459f190b6d948f1f2782afa7a7'
         '72bfa5e62e4e44fe7fa59b6a7593d993')

build() {
  cd $srcdir/$pkgname-$pkgver

  runhaskell Setup.lhs configure --ghc --prefix=/usr \
             --libsubdir=\$compiler/site-local/\$pkgid || return 1

  runhaskell Setup.lhs build || return 1

  runhaskell Setup.lhs register --gen-script
  runhaskell Setup.lhs unregister --gen-script

  install -D -m744 register.sh $pkgdir/usr/share/haskell/$pkgname/register.sh
  install -m744 unregister.sh $pkgdir/usr/share/haskell/$pkgname/unregister.sh
  runhaskell Setup.lhs copy --destdir=$pkgdir || return 1
#  runhaskell util/GenerateManpage.hs || return 1

  install -D -m644 man/xmonad.1 $pkgdir/usr/share/man/man1/xmonad.1 || return 1

  install -d -m755 $pkgdir/usr/share/xmonad && \
  install -D LICENSE $pkgdir/usr/share/licenses/xmonad/LICENSE || return 1

  install -D -m644 $srcdir/xmonad.desktop $pkgdir/usr/share/applications/xmonad.desktop && \
  mkdir -p $pkgdir/etc/X11/sessions/ && \
  ln -s /usr/share/applications/xmonad.desktop $pkgdir/etc/X11/sessions/xmonad.desktop && \
  install -D -m644 $srcdir/xmonad.svg $pkgdir/usr/share/pixmaps/xmonad.svg
}