# Maintainer: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>
_hkgname=text
pkgname=haskell-text
pkgver=0.10.0.0
pkgrel=1
pkgdesc="An efficient packed Unicode text type."
url="http://hackage.haskell.org/package/text"
license=('custom:BSD3')
arch=('i686' 'x86_64' 'ppc')
depends=('ghc=6.12.3' sh 'haskell-deepseq>=1.1.0.0')
options=('strip')
source=(http://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
install=${pkgname}.install
md5sums=('453cf09bae3d6aafdd8a4510ddff1fa5')

build() {
    cd ${srcdir}/${_hkgname}-${pkgver}
	ghc --make Setup.lhs
    ./Setup configure -O -p --enable-split-objs --prefix=/usr --docdir=/usr/share/doc/${pkgname}
    ./Setup build
    ./Setup haddock
    ./Setup register   --gen-script
    ./Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd ${srcdir}/${_hkgname}-${pkgver}
    install -D -m744 register.sh   ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
    install    -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
    install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
    ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
    ./Setup copy --destdir=${pkgdir}
    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    rm -f ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
}