# Maintainer: Vesa Kaihlavirta <vesa@archlinux.org>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>
_hkgname=regex-posix
pkgname=haskell-regex-posix
pkgver=0.94.2
pkgrel=1.1
pkgdesc="The posix regex backend for regex-base"
url="http://hackage.haskell.org/cgi-bin/hackage-scripts/package/regex-posix"
license=('custom:BSD3')
arch=('i686' 'x86_64' 'ppc')
depends=(ghc=6.12.3 sh 'haskell-regex-base=0.93.2')
options=('strip')
source=(http://hackage.haskell.org/packages/archive/regex-posix/$pkgver/regex-posix-$pkgver.tar.gz)
install=haskell-regex-posix.install
md5sums=('e3ebbd6b66fdb2f8c4f0ad95c4580852')

build() {
    cd ${srcdir}/${_hkgname}-$pkgver
	ghc --make Setup.hs
    ./Setup configure -O -p --enable-split-objs --prefix=/usr --docdir=/usr/share/doc/${pkgname}
    ./Setup build
    ./Setup haddock
    ./Setup register   --gen-script
    ./Setup unregister --gen-script
    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

package() {
    cd ${srcdir}/${_hkgname}-${pkgver}
    install -D -m744 register.sh   ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
    install    -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
    install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
    ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
    ./Setup copy --destdir=${pkgdir}
    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    rm -f ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
}