# Maintainer: Vesa Kaihlavirta <vegai@iki.fi>
# Contributor: Arch Haskell Team <arch-haskell@haskell.org>
_hkgname=mmap
pkgname=haskell-mmap
pkgver=0.5.7
pkgrel=1
pkgdesc="Memory mapped files for POSIX and Windows"
url="http://hackage.haskell.org/package/mmap"
license=('custom:BSD3')
arch=('i686' 'x86_64' 'ppc')
depends=('ghc=6.12.3' sh)
options=('strip')
source=(http://hackage.haskell.org/packages/archive/mmap/$pkgver/mmap-$pkgver.tar.gz)
install=haskell-mmap.install
md5sums=('1f74b3f59617332b06e277f5212423c1')

build() {
    cd ${srcdir}/mmap-$pkgver
	ghc --make Setup.hs
    ./Setup configure --prefix=/usr -p --enable-split-objs --docdir=/usr/share/doc/${pkgname}
    ./Setup build
    ./Setup haddock
    ./Setup register   --gen-script
    ./Setup unregister --gen-script
}

package() {
    cd ${srcdir}/mmap-${pkgver}
    install -D -m744 register.sh   ${pkgdir}/usr/share/haskell/${pkgname}/register.sh
    install    -m744 unregister.sh ${pkgdir}/usr/share/haskell/${pkgname}/unregister.sh
    install -d -m755 ${pkgdir}/usr/share/doc/ghc/html/libraries
    ln -s /usr/share/doc/${pkgname}/html ${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}
    ./Setup copy --destdir=${pkgdir}
    install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
    rm -f ${pkgdir}/usr/share/doc/${pkgname}/LICENSE
}