+ .class nested private auto ansi beforefieldinit R1
+ extends [mscorlib]System.MarshalByRefObject
+ {
+ .field public int32 test_field
+
+ .method public hidebysig specialname rtspecialname
+ instance default void '.ctor' () cil managed
+ {
+ ret
+ }
+ }
+
+ .method public static hidebysig
+ default int32 return_0 () cil managed
+ {
+ ldc.i4.0
+ ret
+ }
+
+ .method public static hidebysig
+ default int32 test_1_volatile_marshalbyref_bug_432673 () cil managed
+ {
+ .locals init (
+ class Tests/R1 v_0
+ )
+
+ newobj instance void class Tests/R1::.ctor ()
+ stloc.0
+ ldloc.0
+ ldc.i4.0
+ volatile.
+ stfld int32 Tests/R1::test_field
+ call int32 class Tests::return_0 ()
+ ldc.i4.1
+ add
+ ret
+ }
+
+ .method public static default int32 return_2 () cil managed
+ {
+ // Prevent inlining
+ ldc.i4.s 16
+ localloc
+ pop
+ ldc.i4.s 2
+ ret
+ }
+
+ .method public static hidebysig
+ default int32 test_1_cmov_opt_regress_463357 () cil managed
+ {
+ call int32 class Tests::return_2 ()
+ ldc.i4.0
+ ceq
+ brfalse L1
+ ldc.i4.0
+ ret
+ br L2
+ L1: nop
+ L2: nop
+ ldc.i4.1
+ ret
+ }
+
+ .method public static hidebysig default int32 cmov_opt_regress_474718_inner (int32 A_1) cil managed
+ {
+ .maxstack 3
+ .locals init (int32 V_0, bool V_1, bool V_2)
+
+ ldc.i4.0
+ IL_000b: stloc.1
+ IL_000d: br IL_002f
+
+ ldc.i4.1
+ stloc.2
+ IL_001e: ldloc.2
+ IL_001f: brfalse IL_0036
+
+ IL_0024:
+ IL_002a: br IL_0041
+
+ IL_002f: ldloc.1
+ IL_0030: stloc.2
+ IL_0031: br IL_001e
+
+ IL_0036: ldc.i4 0
+ IL_003b: stloc.0
+ IL_003c: br IL_0041
+
+ IL_0041: ldloc.0
+ IL_0042: ret
+ }
+
+ .method public static default int32 test_0_cmov_opt_regress_474718 () cil managed
+ {
+ .maxstack 16
+ ldc.i4.1
+ call int32 Tests::cmov_opt_regress_474718_inner (int32)
+ ret
+ }
+
+ .method public static default int32 test_5_createarr_newobj () cil managed
+ {
+ .maxstack 16
+
+ ldc.i4 5
+ newobj void char[]::.ctor(int32)
+ ldlen
+ ret
+ }
+
+ .method public static default int32 test_0_initblk_3_regress_481458 () cil managed
+ {
+ .maxstack 16
+ .locals init (native int)
+
+ ldc.i4.s 10
+ localloc
+ stloc.0
+
+ // Set the first value to 3
+ ldloc.0
+ ldc.i4.0
+ add //addr
+ ldc.i4.3 //value
+ stind.i1
+
+ // Zero out the first 3 values
+ ldloc.0 //addr
+ ldc.i4.0 //value
+ ldc.i4.s 3 //size
+ initblk
+
+ // Load the first value
+ ldloc.0
+ ldc.i4.0
+ add
+ ldind.u1
+ conv.i4
+ ret
+ }
+
+ .method public static float32 GetFloat32() cil managed noinlining
+ {
+ .maxstack 8
+ ldc.r8 0.19975845134874831
+ ret
+ }
+
+/* Disabled until they can be fixed to run on amd64
+ .method public static default int32 test_0_implicit_float_to_double_conversion () cil managed
+ {
+ .maxstack 16
+
+ call float32 Tests::GetFloat32()
+ ldc.r8 0.19975845134874831
+ beq OK
+
+ ldc.i4.1
+ ret
+OK:
+ ldc.i4.0
+ ret
+ }
+*/
+
+ .field public static int32 shift1
+
+ .method public static int32 regress_497271_helper (int32 i) cil managed
+ {
+ ldarg.0
+ ret
+ }
+
+ .method public static int32 test_0_regalloc_regress_497271 () cil managed
+ {
+ .locals (int32 var)
+
+ ldc.i4 4
+ stsfld int32 Tests::shift1
+ ldsfld int32 Tests::shift1
+ stloc var
+ ldc.i4 4660
+ ldloc var
+ shr.un
+ ldc.i4 4660
+ ldc.i4 32
+ ldloc var
+ sub
+ shl
+ or
+ ldc.i4 1073742115
+ beq ?L10
+?L9:
+ ldc.i4 1
+ call int32 Tests::regress_497271_helper (int32)
+ ret
+?L10:
+ ldc.i4 0
+ call int32 Tests::regress_497271_helper (int32)
+ ret
+ }
+