util/mkelfImage/kunzip_src/arch/alpha/lib/kunzip.lds

   1 PAGE_SIZE = 65536;
   2 BASIC_ALIGN = 8;
   3 OUTPUT_FORMAT("elf64-alpha")
   4 ENTRY(__start)
   5 SECTIONS
   6 {
   7         . = PAGE_SIZE;
   8         _start = .;
   9         /*
  10          * First we place the code and read only data (typically const declared).
  11          * This get placed in rom.
  12          */
  13         .text : {
  14                 _text = .;
  15                 *(.text)
  16                 _etext = .;
  17                 _rodata = .;
  18                 *(.rodata);
  19                 _erodata = .;
  20         }
  21         /* Global data */
  22         .data : {
  23                 _data = .;
  24                 *(.data)
  25                 CONSTRUCTORS
  26                 *(.got)
  27                 *(.sdata)
  28                 _edata = .;
  29         }
  30
  31         /* Important align _bss so bss may be zeroed with quadword access */
  32         . = ALIGN(BASIC_ALIGN);
  33         .bss : {
  34                 _bss = .;
  35                 *(.sbss)
  36                 *(.scommon)
  37                 *(.bss)
  38                 *(COMMON)
  39                 *(.heap)
  40                 *(.stack)
  41                 /* Important align _ebss so bss may be zeroed with quadword access */
  42                 . = ALIGN(BASIC_ALIGN);
  43                 _ebss = .;
  44         }
  45         _end = .;
  46
  47         /DISCARD/ : {
  48                 *(*)
  49         }
  50 }