src/vm/jit/sparc64/asmpart.S

   1 /* src/vm/jit/sparc64/asmpart.S - Java-C interface functions for Sparc64
   2
   3    Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    $Id: asmpart.S 4749 2006-04-11 10:20:18Z twisti $
  26
  27 */
  28
  29
  30 #include "config.h"
  31
  32 #include "vm/jit/sparc64/md-abi.h"
  33 #include "offsets.h"
  34 #include "md-asm.h"
  35
  36         .register %g2,#scratch                         /* define as scratch       */
  37         .register %g3,#scratch                    /* XXX  reserve for application */
  38         .text
  39
  40 /* export functions ***********************************************************/
  41
  42         .global asm_vm_call_method
  43         .global asm_vm_call_method_int
  44         .global asm_vm_call_method_long
  45         .global asm_vm_call_method_float
  46         .global asm_vm_call_method_double
  47         .global asm_vm_call_method_exception_handler
  48         .global asm_vm_call_method_end
  49
  50         .global asm_call_jit_compiler
  51
  52         .global asm_handle_exception
  53         .global asm_handle_nat_exception
  54
  55         .global asm_patcher_wrapper
  56
  57         .global asm_abstractmethoderror
  58
  59         .global asm_criticalsections
  60         .global asm_getclassvalues_atomic
  61
  62         .global asm_store_fp_state_reg
  63         .global asm_load_fp_state_reg
  64
  65
  66 /* asm_vm_call_method ******************************************************
  67  *                                                                         *
  68  * This function calls a Java-method (which possibly needs compilation)    *
  69  *
  70  * C-prototype:
  71  *  java_objectheader *asm_vm_call_method(methodinfo *m, s4 vmargscount,
  72  *                                               vm_arg *vmargs);
  73  **************************************************************************/
  74
  75         .align 8        /* v9: All data types are aligned to their size */
  76
  77         .xword 0                         /* catch type all */
  78         .xword 0                         /* handler pc */
  79         .xword 0                         /* end pc */
  80         .xword 0                         /* start pc */
  81         .word  1                         /* extable size */
  82         .word  0                         /* ALIGNMENT PADDING */
  83         .xword 0                         /* line number table start */
  84         .xword 0                         /* line number table size */
  85         .word  0                         /* ALIGNMENT PADDING */
  86         .word  0                         /* fltsave */
  87         .word  1                         /* intsave */
  88         .word  0                         /* isleaf */
  89         .word  0                         /* IsSync */
  90         .word  0                         /* frame size */
  91         .xword 0                         /* method pointer (pointer to name)*/
  92
  93 asm_vm_call_method:
  94 asm_vm_call_method_int:
  95 asm_vm_call_method_long:
  96 asm_vm_call_method_float:
  97 asm_vm_call_method_double:
  98
  99         save %sp,-((JITSTACK_CNT+2)*8),%sp
 100         add %sp,JITSTACK,%l1               /* right above window save area */
 101
 102
 103         /* %i1 not needed after _nocopy -> calculate in branch delay */
 104
 105         brlez %i1, calljava_nocopy
 106
 107         dec %i1   /* branch delay */
 108         ldx [%i2 + offvmargdata],%o0
 109         ldd [%i2 + offvmargdata],fa0
 110         brlez %i1,calljava_nocopy
 111
 112         dec %i1   /* branch delay */
 113         ldx [%i2 + (offvmargdata+sizevmarg*1)],%o1
 114         ldd [%i2 + (offvmargdata+sizevmarg*1)],fa1
 115         brlez %i1,calljava_nocopy
 116
 117         dec %i1
 118         ldx [%i2 + (offvmargdata+sizevmarg*2)],%o2
 119         ldd [%i2 + (offvmargdata+sizevmarg*2)],fa2
 120         brlez %i1,calljava_nocopy
 121
 122         dec %i1
 123         ldx [%i2 + (offvmargdata+sizevmarg*3)],%o3
 124         ldd [%i2 + (offvmargdata+sizevmarg*3)],fa3
 125         brlez %i1,calljava_nocopy
 126
 127         dec %i1
 128         ldx [%i2 + (offvmargdata+sizevmarg*4)],%o4
 129         ldd [%i2 + (offvmargdata+sizevmarg*4)],fa4
 130
 131 calljava_argsloaded:
 132         brlez %i1, calljava_nocopy
 133         nop
 134         sllx %i1,3,%l0                     /* remaining args * 8           */
 135         sub %sp,%l0,%sp                    /* allocate more stack space    */
 136         add %sp,JITSTACK,%l1               /* adjust stack begin pointer   */
 137
 138 calljava_copyloop:
 139         ldx [%i2 + (offvmargdata+sizevmarg*5)],%l0
 140         stx %l0,[%l1]
 141         inc sizevmarg,%i2                  /* src++                        */
 142         subcc %i1,1,%i1                    /* arg_count--                  */
 143         bnz %xcc, calljava_copyloop        /* use cc from previous instr   */
 144         inc 8,%l1                          /* dst++ (delay)                */
 145
 146
 147 calljava_nocopy:
 148         /* set pv, like a java method does */
 149         /*      add  ra_caller,(asm_vm_call_method - calljava_nocopy + 8),pv_callee */
 150         setx  asm_vm_call_method,%l0,pv_callee
 151
 152         mov   %i0,itmp1         /* pass method info pointer via itmp1 */
 153
 154         setx  asm_call_jit_compiler,%l0,mptr_itmp2  /* fake virtual function call (2 instr) */
 155         stx   mptr_itmp2,[%l1 + 1*8]        /* store function address               */
 156         mov   %l1,mptr_itmp2            /* set method pointer                   */
 157
 158         ldx  [1*8 + mptr_itmp2], pv_caller          /* method call as in Java               */
 159         jmpl pv_caller,ra_caller                      /* call JIT compiler          */
 160         nop
 161 calljava_jit2:
 162         /* pretend to restore pv */
 163         add  ra_caller,(asm_vm_call_method - calljava_jit2 + 8),zero
 164
 165 calljava_return:
 166         mov %o0, %i0            /* pass on the return value     */
 167         return %i7 + 8          /* implicit window restore */
 168         nop
 169
 170
 171 asm_vm_call_method_exception_handler:
 172
 173         /* so far this function did not call any c functions */
 174         /* but now we need ABI compliant argslots on the stack */
 175         sub   %sp,6*8,%sp
 176
 177         mov             xptr_itmp2,%o0
 178         call    builtin_throw_exception
 179         nop
 180         return  %i7 + 8                          /* implicit window restore */
 181 asm_vm_call_method_end:
 182         nop
 183
 184
 185
 186 /****************** function asm_call_jit_compiler *****************************
 187 *                                                                              *
 188 *   invokes the compiler for untranslated JavaVM methods.                      *
 189 *                                                                              *
 190 *   Register R0 contains a pointer to the method info structure (prepared      *
 191 *   by createcompilerstub). Using the return address in R26 and the            *
 192 *   offset in the LDA instruction or using the value in methodptr R28 the      *
 193 *   patching address for storing the method address can be computed:           *
 194 *                                                                              *
 195 *   method address was either loaded using                                     *
 196 *   M_LDQ (REG_PV, REG_PV, a)        ; invokestatic/special    ($27)           *
 197 *   M_LDA (REG_PV, REG_RA, low)                                                *
 198 *   M_LDAH(REG_PV, REG_RA, high)     ; optional                                *
 199 *   or                                                                         *
 200 *   M_LDQ (REG_PV, REG_METHODPTR, m) ; invokevirtual/interface ($28)           *
 201 *   in the static case the method pointer can be computed using the            *
 202 *   return address and the lda function following the jmp instruction          *
 203 *                                                                              *
 204 *******************************************************************************/
 205
 206 asm_call_jit_compiler:
 207
 208         /* stacksave for regsave(16) + argslots(6) + float args  */
 209         /* Note: +1 to keep stack 16-byte aligned                */
 210         save    %sp,-((16+6+FLT_ARG_CNT+1)*8),%sp
 211
 212         SAVE_FLOAT_ARGUMENT_REGISTERS(22)
 213
 214         mov     itmp1,%o0             /* pass methodinfo pointer                  */
 215         mov     mptr_itmp2,%o1        /* pass method pointer                      */
 216         mov     %fp,%o2                           /* pass java sp (==fp)                          */
 217         mov     ra_callee,%o3         /* pass Java ra                             */
 218         mov     %o3,%o4               /* xpc is equal to ra                       */
 219         call    jit_asm_compile       /* call jit compiler                        */
 220         nop
 221
 222         RESTORE_FLOAT_ARGUMENT_REGISTERS(22)
 223
 224         brz     %o0,L_asm_call_jit_compiler_exception
 225         nop
 226
 227         restore %o0,%g0,pv_caller     /* restore the callers window               */
 228                                       /* the source o0 references the old window  */
 229                                       /* pv_caller references the new window      */
 230
 231
 232         /* synchronise instruction cache moved somewhere else           */
 233
 234         jmpl    pv_caller,zero        /* and call method, the method returns      */
 235                                       /* directly to the caller (ra).             */
 236         nop
 237
 238 L_asm_call_jit_compiler_exception:
 239         /* window still open, ra_callee valid, pv_callee undefined      */
 240
 241         call    exceptions_get_and_clear_exception
 242         nop
 243
 244         mov     %o0,xptr_itmp2        /* get exception                            */
 245         mov     ra_callee,xpc_itmp3  /* exception address is address of call      */
 246
 247         /* restore the window of the calling function */
 248         restore
 249
 250         b      L_asm_handle_nat_exception
 251         nop
 252
 253
 254
 255 /* asm_handle_exception ********************************************************
 256
 257    This function handles an exception. It does not use the usual calling
 258    conventions. The exception pointer is passed in REG_ITMP2 and the
 259    pc from the exception raising position is passed in REG_ITMP3. It searches
 260    the local exception table for a handler. If no one is found, it unwinds
 261    stacks and continues searching the callers.
 262
 263 *******************************************************************************/
 264
 265
 266 asm_handle_nat_exception:
 267 L_asm_handle_nat_exception:       /* required for PIC code                    */
 268 L_asm_handle_exception_stack_loop:
 269         /* exception handling assumes that the current java method saved       */
 270         /* the caller's window, and has a valid pv                             */
 271
 272         /* get ra and pv before saving the window */
 273         mov     ra_callee,itmp1
 274         mov     pv_callee,%g4
 275
 276         save    %sp,-176,%sp
 277         mov     xptr_itmp2,%l0              /* save exception pointer             */
 278         mov     xpc_itmp3,%l1               /* save exception pc                  */
 279         mov     zero,%l2                    /* save maybe-leaf flag (cleared)     */
 280
 281         mov     %l0,%o0                     /* pass xptr                          */
 282         mov     %l1,%o1                     /* pass xpc                           */
 283         mov     %g4,%o2                     /* pass PV                            */
 284         mov     %fp,%o3                     /* pass Java SP                       */
 285
 286         b       L_asm_handle_exception_continue
 287         nop
 288
 289 asm_handle_exception:
 290         mov     pv_callee,%g4
 291
 292         /* save bigger stack frame for float args and temps */
 293         save    %sp,-((FLT_ARG_CNT+FLT_TMP_CNT+CSTACK_CNT)*8),%sp
 294
 295         SAVE_FLOAT_ARGUMENT_REGISTERS(CSTACK_CNT)
 296         SAVE_FLOAT_TEMPORARY_REGISTERS(CSTACK_CNT+FLT_ARG_CNT)
 297
 298         mov     xptr_itmp2,%l0              /* save exception pointer             */
 299         add     zero,1,%l2                  /* set maybe-leaf flag                */
 300
 301         mov     %l0,%o0                     /* pass xptr                          */
 302         mov     xpc_itmp3,%o1               /* pass xpc                           */
 303         mov     %g4,%o2                     /* pass PV                            */
 304         mov     %fp,%o3                     /* pass Java SP                       */
 305
 306 L_asm_handle_exception_continue:
 307         call    exceptions_handle_exception
 308         nop
 309
 310         brz     %o0,L_asm_handle_exception_not_caught
 311         nop
 312
 313         mov     %o0,xpc_itmp3               /* move handlerpc into xpc            */
 314         mov     %l0,xptr_itmp2              /* restore exception pointer          */
 315
 316         brz     %l2,L_asm_handle_exception_no_leaf
 317         nop
 318
 319         RESTORE_FLOAT_ARGUMENT_REGISTERS(CSTACK_CNT)
 320         RESTORE_FLOAT_TEMPORARY_REGISTERS(CSTACK_CNT+FLT_ARG_CNT)
 321
 322 L_asm_handle_exception_no_leaf:
 323         /* restore java window and stackframe (ra and pv are in there) */
 324         restore
 325         jmpl    xpc_itmp3, zero             /* jump to the handler                */
 326         nop
 327
 328 L_asm_handle_exception_not_caught:
 329         mov     %l0,xptr_itmp2              /* restore xptr                       */
 330         restore                             /* free our stackframe and window     */
 331         /* maybe leaf flag gets cleared after branch to _loop */
 332
 333         restore                             /* unwind stack and window            */
 334         ba      L_asm_handle_exception_stack_loop
 335         mov     ra_caller,xpc_itmp3         /* the new xpc is ra (delay)          */
 336
 337
 338
 339
 340 /* asm_abstractmethoderror *****************************************************
 341
 342    Creates and throws an AbstractMethodError.
 343
 344 *******************************************************************************/
 345
 346 asm_abstractmethoderror:
 347         /* do a window save */
 348         save %sp,-192,%sp
 349
 350         mov     %fp,%o0                     /* pass java sp(==fp)                 */
 351         mov     ra_callee,%o1               /* pass exception address             */
 352         call    exceptions_asm_new_abstractmethoderror
 353         nop
 354
 355         mov     %o0,xptr_itmp2              /* get exception pointer              */
 356         sub     ra_callee,4,xpc_itmp3       /* exception address is ra - 4        */
 357         ba      L_asm_handle_nat_exception
 358         nop
 359
 360         /* XXX: leave the register window open for handle_exception ??? */
 361
 362 /* asm_patcher_wrapper *********************************************************
 363
 364    XXX
 365
 366    Stack layout, when called from patcher stub
 367      40   return address into JIT code (patch position)
 368      32   pointer to virtual java_objectheader
 369      24   machine code (which is patched back later)
 370      16   unresolved class/method/field reference
 371       8   data segment displacement from load instructions
 372       0   patcher function pointer to call
 373    -128   WINSAVE REGS (current SP)
 374
 375 *******************************************************************************/
 376
 377
 378 asm_patcher_wrapper:
 379         /* get pv and ra, since the emit code is not passing it on */
 380         mov     ra_callee,ra_caller
 381         mov     pv_callee,pv_caller
 382
 383         /* create window and stack frame              */
 384         save  %sp,-((FLT_ARG_CNT+FLT_TMP_CNT+CSTACK_CNT+4)*8),%sp
 385
 386         SAVE_FLOAT_ARGUMENT_REGISTERS(CSTACK_CNT)
 387         SAVE_FLOAT_TEMPORARY_REGISTERS(CSTACK_CNT+FLT_ARG_CNT)
 388
 389         mov     itmp1,%l0               /* save itmp1                             */
 390         mov     itmp2,%l1               /* save itmp2                             */
 391
 392         add     %fp,JITSTACK,%o0      /* pass pseudo SP                           */
 393         mov     pv_callee,%o1         /* pass PV                                  */
 394         mov     ra_callee,%o2         /* pass RA (correct for leafs)              */
 395         call    patcher_wrapper
 396         nop
 397
 398         RESTORE_FLOAT_ARGUMENT_REGISTERS(CSTACK_CNT)
 399         RESTORE_FLOAT_TEMPORARY_REGISTERS(CSTACK_CNT+FLT_ARG_CNT)
 400
 401         mov     %l0,itmp1               /* restore itmp1                          */
 402         mov     %l1,itmp2               /* restore itmp2                          */
 403
 404         brnz    %o0,L_asm_patcher_wrapper_exception
 405         nop
 406
 407         /* load RA (patch position from patcher data on the stack */
 408         ldx     [%fp+JITSTACK+5*8],itmp3
 409
 410         /* remove window and stack frame (and stack space allocated in the stub code */
 411         restore  %fp,6*8,%sp /* (source regs refer to old window, rd to new window)  */
 412
 413         jmpl     itmp3,zero              /* jump to newly patched code               */
 414         nop
 415
 416 L_asm_patcher_wrapper_exception:
 417         mov      %o0,xptr_itmp2        /* get exception                            */
 418         ldx      [%fp+JITSTACK+5*8],xpc_itmp3 /* xpc is RA                         */
 419         restore  %fp,6*8,%sp           /* remove stack frame                       */
 420         ba       asm_handle_exception
 421         nop
 422
 423
 424
 425 /* asm_store_fp_state_reg **************************************************
 426  *                                                                         *
 427  * This function stores the 64-bit floating point state register to a      *
 428  * memory location. (which needs to be 8-byte aligned)                     *
 429  *                                                                         *
 430  * C-prototype:                                                            *
 431  *  void asm_store_fp_state_reg(u8 *mem);                                  *
 432  *                                                                             *
 433  **************************************************************************/
 434
 435 asm_store_fp_state_reg:
 436         stx %fsr,[%o0]
 437         retl  /* return from leaf */
 438         nop
 439
 440 /* asm_load_fp_state_reg ***************************************************
 441  *                                                                         *
 442  * This function loades the 64-bit floating point state register from a    *
 443  * memory location. (which needs to be 8-byte aligned)                     *
 444  *                                                                         *
 445  * C-prototype:                                                            *
 446  *  void asm_load_fp_state_reg(u8 *mem);                                   *
 447  *                                                                             *
 448  **************************************************************************/
 449
 450 asm_load_fp_state_reg:
 451         ldx [%o0],%fsr
 452         retl  /* return from leaf */
 453         nop
 454
 455
 456
 457
 458 asm_getclassvalues_atomic:
 459 _crit_restart:
 460 _crit_begin:
 461 /* not doing a window save, using the global temporary registers */
 462         ldsw    [offbaseval+%o0],itmp1
 463         ldsw    [offdiffval+%o0],itmp2
 464         ldsw    [offbaseval+%o1],itmp3
 465 _crit_end:
 466         stw     itmp1,[offcast_super_baseval+%o2]
 467         stw     itmp2,[offcast_super_diffval+%o2]
 468         stw     itmp3,[offcast_sub_baseval+%o2]
 469         jmpl    ra_caller+8,zero  /* caller's ra, b/c no window save */
 470         nop
 471
 472
 473     .data
 474
 475 asm_criticalsections:
 476 #if defined(ENABLE_THREADS)
 477     .xword   _crit_begin
 478     .xword   _crit_end
 479     .xword   _crit_restart
 480 #endif
 481     .xword   0
 482
 483
 484 /* disable exec-stacks ********************************************************/
 485
 486 #if defined(__linux__) && defined(__ELF__)
 487         .section .note.GNU-stack,"",%progbits
 488 #endif
 489
 490
 491 /*
 492  * These are local overrides for various environment variables in Emacs.
 493  * Please do not remove this and leave it at the end of the file, where
 494  * Emacs will automagically detect them.
 495  * ---------------------------------------------------------------------
 496  * Local variables:
 497  * mode: asm
 498  * indent-tabs-mode: t
 499  * c-basic-offset: 4
 500  * tab-width: 4
 501  * End:
 502  * vim:noexpandtab:sw=4:ts=4:
 503  */