src/vm/jit/powerpc/asmpart.S

   1 /* src/vm/jit/powerpc/asmpart.S - Java-C interface functions for PowerPC
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software.text;  you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation;  either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY ;  without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program;  if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29             Stefan Ring
  30
  31    Changes: Christian Thalinger
  32             Edwin Steiner
  33
  34    $Id: asmpart.S 5233 2006-08-14 10:59:39Z twisti $
  35
  36 */
  37
  38
  39 #include "config.h"
  40
  41 #include "md-abi.h"
  42 #include "md-asm.h"
  43
  44 #include "vm/jit/abi-asm.h"
  45 #include "vm/jit/methodheader.h"
  46 #include "vm/jit/powerpc/offsets.h"
  47
  48
  49         .text
  50
  51         .align 2
  52
  53
  54 /* export functions ***********************************************************/
  55
  56         .globl asm_vm_call_method
  57         .globl asm_vm_call_method_int
  58         .globl asm_vm_call_method_long
  59         .globl asm_vm_call_method_float
  60         .globl asm_vm_call_method_double
  61
  62         .globl asm_vm_call_method_exception_handler
  63
  64         .globl asm_call_jit_compiler
  65
  66         .globl asm_handle_nat_exception
  67         .globl asm_handle_exception
  68
  69         .globl asm_abstractmethoderror
  70
  71         .globl asm_patcher_wrapper
  72
  73         .globl asm_replacement_out
  74         .globl asm_replacement_in
  75
  76         .globl asm_cacheflush
  77         .globl asm_criticalsections
  78         .globl asm_getclassvalues_atomic
  79
  80
  81 /* asm_vm_call_method **********************************************************
  82 *                                                                              *
  83 *   This function calls a Java-method (which possibly needs compilation)       *
  84 *   with up to 4 address parameters.                                           *
  85 *                                                                              *
  86 *   This functions calls the JIT-compiler which eventually translates the      *
  87 *   method into machine code.                                                  *
  88 *                                                                              *
  89 *   C-prototype:                                                               *
  90 *    javaobject_header *asm_calljavamethod (methodinfo *m,                     *
  91 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  92 *                                                                              *
  93 *******************************************************************************/
  94
  95         .align 2
  96
  97         .long   0                         /* catch type all                       */
  98         .long   0                         /* exception handler pc                 */
  99         .long   0                         /* end pc                               */
 100         .long   0                         /* start pc                             */
 101         .long   1                         /* extable size                         */
 102         .long   0                         /* line number table start              */
 103         .long   0                         /* line number table size               */
 104         .long   0                         /* fltsave                              */
 105         .long   0                         /* intsave                              */
 106         .long   0                         /* IsLeaf                               */
 107         .long   0                         /* IsSync                               */
 108         .long   0                         /* frame size                           */
 109         .long   0                         /* codeinfo pointer                     */
 110
 111 asm_vm_call_method:
 112 asm_vm_call_method_int:
 113 asm_vm_call_method_long:
 114 asm_vm_call_method_float:
 115 asm_vm_call_method_double:
 116         mflr    r0
 117         stw     r0,LA_LR_OFFSET(sp)
 118         stwu    sp,-40*4(sp)
 119
 120         stw     s0,8*4(sp)                /* save used callee saved registers     */
 121         stw     a0,9*4(sp)                /* save method pointer for compiler     */
 122
 123 #if defined(__DARWIN__)
 124         stw     itmp1,10*4(sp)            /* register r11 is callee saved         */
 125 #endif
 126         stw     pv,11*4(sp)               /* save PV register                     */
 127
 128         stw     itmp3,12*4(sp)            /* registers r14-r31 are callee saved   */
 129         stfd    ftmp1,14*4(sp)            /* registers f14-f31 are callee saved   */
 130         stfd    ftmp2,16*4(sp)
 131
 132 #if defined(__DARWIN__)
 133         stw     t1,18*4(sp)
 134         stw     t2,19*4(sp)
 135         stw     t3,20*4(sp)
 136         stw     t4,21*4(sp)
 137         stw     t5,22*4(sp)
 138         stw     t6,23*4(sp)
 139         stw     t7,24*4(sp)
 140
 141         stfd    ft0,26*4(sp)
 142         stfd    ft1,28*4(sp)
 143         stfd    ft2,30*4(sp)
 144         stfd    ft3,32*4(sp)
 145         stfd    ft4,34*4(sp)
 146         stfd    ft5,36*4(sp)
 147 #else
 148         SAVE_TEMPORARY_REGISTERS(18)      /* the offset has to be even            */
 149 #endif
 150
 151         mr      itmp2,a1                  /* arg count                            */
 152         mr      itmp1,a2                  /* pointer to arg block                 */
 153
 154         mr      t4,itmp2                  /* save argument count                  */
 155         mr      t5,itmp1                  /* save argument block pointer          */
 156
 157         mr      s0,sp                     /* save current sp to s0                */
 158
 159         addi    itmp1,itmp1,-sizevmarg    /* initialize pointer (smaller code)    */
 160         addi    itmp2,itmp2,1             /* initialize argument count            */
 161         li      t0,0                      /* initialize integer argument counter  */
 162         li      t1,0                      /* initialize float argument counter    */
 163         li      t6,0                      /* initialize integer register counter  */
 164 #if defined(__DARWIN__)
 165         li      t7,0                      /* initialize stack slot counter        */
 166 #endif
 167
 168         mflr    r0                        /* save link register (PIC code)        */
 169         bl      L_asm_vm_call_method_get_pc
 170 L_asm_vm_call_method_get_pc:
 171         mflr    t3                        /* t3 contains the current pc           */
 172         mtlr    r0
 173
 174 L_register_copy:
 175         addi    itmp1,itmp1,sizevmarg     /* goto next argument block             */
 176         addi    itmp2,itmp2,-1            /* argument count - 1                   */
 177         mr.     itmp2,itmp2
 178         beq     L_register_copy_done
 179
 180         lwz     itmp3,offvmargtype+4(itmp1)
 181         andi.   r0,itmp3,0x0002           /* is this a float/double type?         */
 182         bne     L_register_handle_float
 183
 184 L_register_handle_int:
 185         cmpwi   t6,INT_ARG_CNT            /* are we out of integer argument       */
 186         beq     L_register_copy           /* registers? yes, next loop            */
 187
 188         andi.   r0,itmp3,0x0001           /* is this a 2-word type?               */
 189         bne     L_register_handle_long
 190
 191 #if defined(__DARWIN__)
 192         addis   itmp3,t3,ha16(L_jumptable_int - L_asm_vm_call_method_get_pc)
 193         la      itmp3,lo16(L_jumptable_int - L_asm_vm_call_method_get_pc)(itmp3)
 194 #else
 195         lis     itmp3,L_jumptable_int@ha
 196         addi    itmp3,itmp3,L_jumptable_int@l
 197 #endif
 198
 199         slwi    t2,t6,2                   /* multiple of 4-bytes                  */
 200         add     itmp3,itmp3,t2            /* calculate address of jumptable       */
 201         lwz     itmp3,0(itmp3)            /* load function address                */
 202         mtctr   itmp3
 203         addi    t0,t0,1                   /* integer argument counter             */
 204         addi    t6,t6,1                   /* integer argument register counter    */
 205 #if defined(__DARWIN__)
 206         addi    t7,t7,1                   /* stack slot counter                   */
 207 #endif
 208         bctr
 209
 210 L_register_handle_long:
 211 #if defined(__DARWIN__)
 212         addis   itmp3,t3,ha16(L_jumptable_long - L_asm_vm_call_method_get_pc)
 213         la      itmp3,lo16(L_jumptable_long - L_asm_vm_call_method_get_pc)(itmp3)
 214 #else
 215         lis     itmp3,L_jumptable_long@ha
 216         addi    itmp3,itmp3,L_jumptable_long@l
 217 #endif
 218 #if !defined(__DARWIN__)
 219         addi    t6,t6,1                   /* align to even numbers                */
 220         andi.   t6,t6,0xfffe
 221 #endif
 222
 223         cmpwi   t6,(INT_ARG_CNT - 1)      /* are we out of integer argument       */
 224         blt     L_register_handle_long_continue /* registers?                     */
 225
 226         li      t6,INT_ARG_CNT            /* yes, set integer argument register   */
 227         b       L_register_copy           /* count to max and next loop           */
 228
 229 L_register_handle_long_continue:
 230         slwi    t2,t6,2                   /* multiple of 4-bytes                  */
 231         add     itmp3,itmp3,t2            /* calculate address of jumptable       */
 232         lwz     itmp3,0(itmp3)            /* load function address                */
 233         mtctr   itmp3
 234         addi    t0,t0,1                   /* integer argument counter             */
 235         addi    t6,t6,2                   /* integer argument register counter    */
 236 #if defined(__DARWIN__)
 237         addi    t7,t7,2                   /* stack slot counter                   */
 238 #endif
 239         bctr
 240
 241 L_register_handle_float:
 242         cmpwi   t1,FLT_ARG_CNT            /* are we out of float argument         */
 243         beq     L_register_copy           /* registers? yes, next loop            */
 244
 245         andi.   r0,itmp3,0x0001           /* is this a 2-word type?               */
 246         bne     L_register_handle_double
 247
 248 #if defined(__DARWIN__)
 249         addis   itmp3,t3,ha16(L_jumptable_float - L_asm_vm_call_method_get_pc)
 250         la      itmp3,lo16(L_jumptable_float - L_asm_vm_call_method_get_pc)(itmp3)
 251 #else
 252         lis     itmp3,L_jumptable_float@ha
 253         addi    itmp3,itmp3,L_jumptable_float@l
 254 #endif
 255
 256         slwi    t2,t1,2                   /* multiple of 4-bytes                  */
 257         add     itmp3,itmp3,t2            /* calculate address of jumptable       */
 258         lwz     itmp3,0(itmp3)            /* load function address                */
 259         mtctr   itmp3
 260         addi    t1,t1,1                   /* float argument counter               */
 261 #if defined(__DARWIN__)
 262         addi    t7,t7,1                   /* stack slot counter                   */
 263         addi    t6,t6,1                   /* skip 1 integer argument register     */
 264 #endif
 265         bctr
 266
 267 L_register_handle_double:
 268 #if defined(__DARWIN__)
 269         addis   itmp3,t3,ha16(L_jumptable_double - L_asm_vm_call_method_get_pc)
 270         la      itmp3,lo16(L_jumptable_double - L_asm_vm_call_method_get_pc)(itmp3)
 271 #else
 272         lis     itmp3,L_jumptable_double@ha
 273         addi    itmp3,itmp3,L_jumptable_double@l
 274 #endif
 275
 276         slwi    t2,t1,2                   /* multiple of 4-bytes                  */
 277         add     itmp3,itmp3,t2            /* calculate address of jumptable       */
 278         lwz     itmp3,0(itmp3)            /* load function address                */
 279         mtctr   itmp3
 280         addi    t1,t1,1                   /* float argument counter               */
 281 #if defined(__DARWIN__)
 282         addi    t7,t7,2                   /* stack slot counter                   */
 283         addi    t6,t6,2                   /* skip 2 integer argument registers    */
 284 #endif
 285         bctr
 286
 287 L_register_copy_done:
 288                                           /* calculate remaining arguments        */
 289         sub     itmp3,t4,t0               /* - integer arguments in registers     */
 290         sub     itmp3,itmp3,t1            /* - float arguments in registers       */
 291         mr.     itmp3,itmp3
 292         beq     L_stack_copy_done
 293
 294         mr      itmp2,t4                  /* restore argument count               */
 295         mr      itmp1,t5                  /* restore argument block pointer       */
 296
 297         slwi    t4,itmp3,3                /* XXX use 8-bytes slots for now        */
 298         addi    t4,t4,LA_SIZE             /* add size of linkage area             */
 299
 300 #if defined(__DARWIN__)
 301         slwi    t5,t7,2                   /* add stack space for arguments        */
 302         add     t4,t4,t5
 303 #endif
 304
 305         sub     sp,sp,t4
 306
 307         mr      t6,sp                     /* use t6 as temporary sp               */
 308         addi    t6,t6,LA_SIZE             /* skip linkage area                    */
 309 #if defined(__DARWIN__)
 310         add     t6,t6,t5                  /* skip stack space for arguments       */
 311 #endif
 312
 313         addi    itmp1,itmp1,-sizevmarg    /* initialize pointer (smaller code)    */
 314         addi    itmp2,itmp2,1             /* initialize argument count            */
 315
 316 L_stack_copy_loop:
 317         addi    itmp1,itmp1,sizevmarg     /* goto next argument block             */
 318         addi    itmp2,itmp2,-1            /* argument count - 1                   */
 319         mr.     itmp2,itmp2
 320         beq     L_stack_copy_done
 321
 322         lwz     itmp3,offvmargtype+4(itmp1)
 323         andi.   r0,itmp3,0x0002           /* is this a float/double type?         */
 324         bne     L_stack_handle_float
 325
 326 L_stack_handle_int:
 327         addi    t0,t0,-1                  /* arguments assigned to registers      */
 328         mr.     t0,t0
 329         bge     L_stack_copy_loop
 330
 331         andi.   r0,itmp3,0x0001           /* is this a 2-word type?               */
 332         bne     L_stack_handle_long
 333
 334         lwz     itmp3,offvmargdata+4(itmp1) /* get integer argument               */
 335         stw     itmp3,0(t6)               /* and store it on the stack            */
 336         addi    t6,t6,4                   /* increase temporary sp by 1 slot      */
 337         b       L_stack_copy_loop
 338
 339 L_stack_handle_long:
 340 #if !defined(__DARWIN__)
 341         addi    t6,t6,4                   /* align stack to 8-bytes               */
 342         rlwinm  t6,t6,0,30,28             /* clear lower 4-bits                   */
 343 #endif
 344
 345         lwz     itmp3,offvmargdata+0(itmp1) /* get long argument                  */
 346         stw     itmp3,0(t6)               /* and store it on the stack            */
 347         lwz     itmp3,offvmargdata+4(itmp1)
 348         stw     itmp3,4(t6)
 349         addi    t6,t6,8                   /* increase temporary sp by 2 slots     */
 350         b       L_stack_copy_loop
 351
 352 L_stack_handle_float:
 353         addi    t1,t1,-1                  /* arguments assigned to registers      */
 354         mr.     t1,t1
 355         bge     L_stack_copy_loop
 356
 357         andi.   r0,itmp3,0x0001           /* is this a 2-word type?               */
 358         bne     L_stack_handle_double
 359
 360         lfs     ftmp3,offvmargdata(itmp1) /* get float argument                   */
 361         stfs    ftmp3,0(t6)               /* and store it on the stack            */
 362         addi    t6,t6,4                   /* increase temporary sp by 1 slot      */
 363         b       L_stack_copy_loop
 364
 365 L_stack_handle_double:
 366 #if !defined(__DARWIN__)
 367         addi    t6,t6,4                   /* align stack to 8-bytes               */
 368         rlwinm  t6,t6,0,30,28             /* clear lower 4-bits                   */
 369 #endif
 370
 371         lfd     ftmp3,offvmargdata(itmp1) /* get double argument                  */
 372         stfd    ftmp3,0(t6)               /* and store it on the stack            */
 373         addi    t6,t6,8                   /* increase temporary sp by 2 slots     */
 374         b       L_stack_copy_loop
 375
 376 L_stack_copy_done:
 377         lwz     itmp1,9*4(s0)             /* pass method pointer via tmp1         */
 378
 379 #if defined(__DARWIN__)
 380         addis   mptr,t3,ha16(L_asm_call_jit_compiler - L_asm_vm_call_method_get_pc)
 381         la      mptr,lo16(L_asm_call_jit_compiler - L_asm_vm_call_method_get_pc)(mptr)
 382 #else
 383         lis     mptr,L_asm_call_jit_compiler@ha
 384         addi    mptr,mptr,L_asm_call_jit_compiler@l
 385 #endif
 386         stw     mptr,7*4(s0)
 387         addi    mptr,s0,7*4
 388
 389         lwz     pv,0*4(mptr)
 390         mtctr   pv
 391         bctrl
 392 1:
 393         mflr    itmp1
 394 #if defined(__DARWIN__)
 395         addi    pv,itmp1,lo16(asm_vm_call_method - 1b)
 396 #else
 397         addi    pv,itmp1,(asm_vm_call_method - 1b)@l
 398 #endif
 399
 400 L_asm_vm_call_method_return:
 401         mr      sp,s0                     /* restore the function's sp            */
 402
 403         lwz     s0,8*4(sp)                /* restore used callee saved registers  */
 404
 405 #if defined(__DARWIN__)
 406         lwz     itmp1,10*4(sp)            /* register r11 is callee saved         */
 407 #endif
 408         lwz     pv,11*4(sp)               /* save PV register                     */
 409
 410         lwz     itmp3,12*4(sp)
 411         lfd     ftmp1,14*4(sp)            /* registers f14-f31 are callee saved   */
 412         lfd     ftmp2,16*4(sp)
 413
 414 #if defined(__DARWIN__)
 415         lwz     t1,18*4(sp)
 416         lwz     t2,19*4(sp)
 417         lwz     t3,20*4(sp)
 418         lwz     t4,21*4(sp)
 419         lwz     t5,22*4(sp)
 420         lwz     t6,23*4(sp)
 421         lwz     t7,24*4(sp)
 422
 423         lfd     ft0,26*4(sp)
 424         lfd     ft1,28*4(sp)
 425         lfd     ft2,30*4(sp)
 426         lfd     ft3,32*4(sp)
 427         lfd     ft4,34*4(sp)
 428         lfd     ft5,36*4(sp)
 429 #else
 430         RESTORE_TEMPORARY_REGISTERS(18)   /* the offset has to be even            */
 431 #endif
 432
 433         lwz     r0,40*4+LA_LR_OFFSET(sp)
 434         mtlr    r0
 435         addi    sp,sp,40*4
 436         blr
 437
 438 asm_vm_call_method_exception_handler:
 439         mr      a0,itmp1
 440         bl      builtin_throw_exception
 441         b       L_asm_vm_call_method_return
 442
 443
 444         .data
 445         .align  2
 446
 447 L_jumptable_int:
 448         .long   L_handle_a0
 449         .long   L_handle_a1
 450         .long   L_handle_a2
 451         .long   L_handle_a3
 452         .long   L_handle_a4
 453         .long   L_handle_a5
 454         .long   L_handle_a6
 455         .long   L_handle_a7
 456
 457         .text
 458         .align  2
 459
 460 L_handle_a0:
 461         lwz     a0,offvmargdata+4(itmp1)
 462         b       L_register_copy
 463 L_handle_a1:
 464         lwz     a1,offvmargdata+4(itmp1)
 465         b       L_register_copy
 466 L_handle_a2:
 467         lwz     a2,offvmargdata+4(itmp1)
 468         b       L_register_copy
 469 L_handle_a3:
 470         lwz     a3,offvmargdata+4(itmp1)
 471         b       L_register_copy
 472 L_handle_a4:
 473         lwz     a4,offvmargdata+4(itmp1)
 474         b       L_register_copy
 475 L_handle_a5:
 476         lwz     a5,offvmargdata+4(itmp1)
 477         b       L_register_copy
 478 L_handle_a6:
 479         lwz     a6,offvmargdata+4(itmp1)
 480         b       L_register_copy
 481 L_handle_a7:
 482         lwz     a7,offvmargdata+4(itmp1)
 483         b       L_register_copy
 484
 485
 486         .data
 487         .align  2
 488
 489 L_jumptable_long:
 490 #if defined(__DARWIN__)
 491         .long   L_handle_a0_a1
 492         .long   L_handle_a1_a2
 493         .long   L_handle_a2_a3
 494         .long   L_handle_a3_a4
 495         .long   L_handle_a4_a5
 496         .long   L_handle_a5_a6
 497         .long   L_handle_a6_a7
 498 #else
 499         /* we have two entries here, so we get the even argument register
 500         alignment for linux */
 501
 502         .long   L_handle_a0_a1
 503         .long   0
 504         .long   L_handle_a2_a3
 505         .long   0
 506         .long   L_handle_a4_a5
 507         .long   0
 508         .long   L_handle_a6_a7
 509 #endif
 510
 511         .text
 512         .align  2
 513
 514 L_handle_a0_a1:
 515         lwz     a0,offvmargdata+0(itmp1)
 516         lwz     a1,offvmargdata+4(itmp1)
 517         b       L_register_copy
 518 #if defined(__DARWIN__)
 519 L_handle_a1_a2:
 520         lwz     a1,offvmargdata+0(itmp1)
 521         lwz     a2,offvmargdata+4(itmp1)
 522         b       L_register_copy
 523 #endif
 524 L_handle_a2_a3:
 525         lwz     a2,offvmargdata+0(itmp1)
 526         lwz     a3,offvmargdata+4(itmp1)
 527         b       L_register_copy
 528 #if defined(__DARWIN__)
 529 L_handle_a3_a4:
 530         lwz     a3,offvmargdata+0(itmp1)
 531         lwz     a4,offvmargdata+4(itmp1)
 532         b       L_register_copy
 533 #endif
 534 L_handle_a4_a5:
 535         lwz     a4,offvmargdata+0(itmp1)
 536         lwz     a5,offvmargdata+4(itmp1)
 537         b       L_register_copy
 538 #if defined(__DARWIN__)
 539 L_handle_a5_a6:
 540         lwz     a5,offvmargdata+0(itmp1)
 541         lwz     a6,offvmargdata+4(itmp1)
 542         b       L_register_copy
 543 #endif
 544 L_handle_a6_a7:
 545         lwz     a6,offvmargdata+0(itmp1)
 546         lwz     a7,offvmargdata+4(itmp1)
 547         b       L_register_copy
 548
 549
 550         .data
 551         .align  2
 552
 553 L_jumptable_float:
 554         .long   L_handle_fa0
 555         .long   L_handle_fa1
 556         .long   L_handle_fa2
 557         .long   L_handle_fa3
 558         .long   L_handle_fa4
 559         .long   L_handle_fa5
 560         .long   L_handle_fa6
 561         .long   L_handle_fa7
 562
 563 #if defined(__DARWIN__)
 564         .long   L_handle_fa8
 565         .long   L_handle_fa9
 566         .long   L_handle_fa10
 567         .long   L_handle_fa11
 568         .long   L_handle_fa12
 569 #endif
 570
 571         .text
 572         .align  2
 573
 574 L_handle_fa0:
 575         lfs     fa0,offvmargdata(itmp1)
 576         b       L_register_copy
 577 L_handle_fa1:
 578         lfs     fa1,offvmargdata(itmp1)
 579         b       L_register_copy
 580 L_handle_fa2:
 581         lfs     fa2,offvmargdata(itmp1)
 582         b       L_register_copy
 583 L_handle_fa3:
 584         lfs     fa3,offvmargdata(itmp1)
 585         b       L_register_copy
 586 L_handle_fa4:
 587         lfs     fa4,offvmargdata(itmp1)
 588         b       L_register_copy
 589 L_handle_fa5:
 590         lfs     fa5,offvmargdata(itmp1)
 591         b       L_register_copy
 592 L_handle_fa6:
 593         lfs     fa6,offvmargdata(itmp1)
 594         b       L_register_copy
 595 L_handle_fa7:
 596         lfs     fa7,offvmargdata(itmp1)
 597         b       L_register_copy
 598
 599 #if defined(__DARWIN__)
 600 L_handle_fa8:
 601         lfs     fa8,offvmargdata(itmp1)
 602         b       L_register_copy
 603 L_handle_fa9:
 604         lfs     fa9,offvmargdata(itmp1)
 605         b       L_register_copy
 606 L_handle_fa10:
 607         lfs     fa10,offvmargdata(itmp1)
 608         b       L_register_copy
 609 L_handle_fa11:
 610         lfs     fa11,offvmargdata(itmp1)
 611         b       L_register_copy
 612 L_handle_fa12:
 613         lfs     fa12,offvmargdata(itmp1)
 614         b       L_register_copy
 615 #endif
 616
 617
 618         .data
 619         .align  2
 620
 621 L_jumptable_double:
 622         .long   L_handle_fda0
 623         .long   L_handle_fda1
 624         .long   L_handle_fda2
 625         .long   L_handle_fda3
 626         .long   L_handle_fda4
 627         .long   L_handle_fda5
 628         .long   L_handle_fda6
 629         .long   L_handle_fda7
 630
 631 #if defined(__DARWIN__)
 632         .long   L_handle_fda8
 633         .long   L_handle_fda9
 634         .long   L_handle_fda10
 635         .long   L_handle_fda11
 636         .long   L_handle_fda12
 637 #endif
 638
 639         .text
 640         .align  2
 641
 642 L_handle_fda0:
 643         lfd     fa0,offvmargdata(itmp1)
 644         b       L_register_copy
 645 L_handle_fda1:
 646         lfd     fa1,offvmargdata(itmp1)
 647         b       L_register_copy
 648 L_handle_fda2:
 649         lfd     fa2,offvmargdata(itmp1)
 650         b       L_register_copy
 651 L_handle_fda3:
 652         lfd     fa3,offvmargdata(itmp1)
 653         b       L_register_copy
 654 L_handle_fda4:
 655         lfd     fa4,offvmargdata(itmp1)
 656         b       L_register_copy
 657 L_handle_fda5:
 658         lfd     fa5,offvmargdata(itmp1)
 659         b       L_register_copy
 660 L_handle_fda6:
 661         lfd     fa6,offvmargdata(itmp1)
 662         b       L_register_copy
 663 L_handle_fda7:
 664         lfd     fa7,offvmargdata(itmp1)
 665         b       L_register_copy
 666
 667 #if defined(__DARWIN__)
 668 L_handle_fda8:
 669         lfd     fa8,offvmargdata(itmp1)
 670         b       L_register_copy
 671 L_handle_fda9:
 672         lfd     fa9,offvmargdata(itmp1)
 673         b       L_register_copy
 674 L_handle_fda10:
 675         lfd     fa10,offvmargdata(itmp1)
 676         b       L_register_copy
 677 L_handle_fda11:
 678         lfd     fa11,offvmargdata(itmp1)
 679         b       L_register_copy
 680 L_handle_fda12:
 681         lfd     fa12,offvmargdata(itmp1)
 682         b       L_register_copy
 683 #endif
 684
 685
 686 /* asm_call_jit_compiler *******************************************************
 687
 688    Invokes the compiler for untranslated JavaVM methods.
 689
 690 *******************************************************************************/
 691
 692 asm_call_jit_compiler:
 693 L_asm_call_jit_compiler:                /* required for PIC code              */
 694         mflr    r0
 695         stw     r0,LA_LR_OFFSET(sp)         /* save return address                */
 696         stwu    sp,-(LA_SIZE + 5*4 + INT_ARG_CNT*4 + FLT_ARG_CNT*8)(sp)
 697
 698 #if defined(__DARWIN__)
 699         stw     a0,LA_SIZE+(5+0)*4(sp)
 700         stw     a1,LA_SIZE+(5+1)*4(sp)
 701         stw     a2,LA_SIZE+(5+2)*4(sp)
 702         stw     a3,LA_SIZE+(5+3)*4(sp)
 703         stw     a4,LA_SIZE+(5+4)*4(sp)
 704         stw     a5,LA_SIZE+(5+5)*4(sp)
 705         stw     a6,LA_SIZE+(5+6)*4(sp)
 706         stw     a7,LA_SIZE+(5+7)*4(sp)
 707
 708         stfd    fa0,LA_SIZE+(5+8)*4(sp)
 709         stfd    fa1,LA_SIZE+(5+10)*4(sp)
 710         stfd    fa2,LA_SIZE+(5+12)*4(sp)
 711         stfd    fa3,LA_SIZE+(5+14)*4(sp)
 712         stfd    fa4,LA_SIZE+(5+16)*4(sp)
 713         stfd    fa5,LA_SIZE+(5+18)*4(sp)
 714         stfd    fa6,LA_SIZE+(5+20)*4(sp)
 715         stfd    fa7,LA_SIZE+(5+22)*4(sp)
 716         stfd    fa8,LA_SIZE+(5+24)*4(sp)
 717         stfd    fa9,LA_SIZE+(5+26)*4(sp)
 718         stfd    fa10,LA_SIZE+(5+28)*4(sp)
 719         stfd    fa11,LA_SIZE+(5+30)*4(sp)
 720         stfd    fa12,LA_SIZE+(5+32)*4(sp)
 721 #else
 722         SAVE_ARGUMENT_REGISTERS(LA_SIZE_IN_POINTERS+1)
 723 #endif
 724
 725         mr      a0,itmp1
 726         mr      a1,mptr
 727         addi    a2,sp,(LA_SIZE + 5*4 + INT_ARG_CNT*4 + FLT_ARG_CNT*8)
 728         lwz     a3,(LA_SIZE + 5*4 + INT_ARG_CNT*4 + FLT_ARG_CNT*8)+LA_LR_OFFSET(sp)
 729         bl      jit_asm_compile
 730         mr      pv,v0                       /* move address to pv register        */
 731
 732 #if defined(__DARWIN__)
 733         lwz     a0,LA_SIZE+(5+0)*4(sp)
 734         lwz     a1,LA_SIZE+(5+1)*4(sp)
 735         lwz     a2,LA_SIZE+(5+2)*4(sp)
 736         lwz     a3,LA_SIZE+(5+3)*4(sp)
 737         lwz     a4,LA_SIZE+(5+4)*4(sp)
 738         lwz     a5,LA_SIZE+(5+5)*4(sp)
 739         lwz     a6,LA_SIZE+(5+6)*4(sp)
 740         lwz     a7,LA_SIZE+(5+7)*4(sp)
 741
 742         lfd     fa0,LA_SIZE+(5+8)*4(sp)
 743         lfd     fa1,LA_SIZE+(5+10)*4(sp)
 744         lfd     fa2,LA_SIZE+(5+12)*4(sp)
 745         lfd     fa3,LA_SIZE+(5+14)*4(sp)
 746         lfd     fa4,LA_SIZE+(5+16)*4(sp)
 747         lfd     fa5,LA_SIZE+(5+18)*4(sp)
 748         lfd     fa6,LA_SIZE+(5+20)*4(sp)
 749         lfd     fa7,LA_SIZE+(5+22)*4(sp)
 750         lfd     fa8,LA_SIZE+(5+24)*4(sp)
 751         lfd     fa9,LA_SIZE+(5+26)*4(sp)
 752         lfd     fa10,LA_SIZE+(5+28)*4(sp)
 753         lfd     fa11,LA_SIZE+(5+30)*4(sp)
 754         lfd     fa12,LA_SIZE+(5+32)*4(sp)
 755 #else
 756         RESTORE_ARGUMENT_REGISTERS(LA_SIZE_IN_POINTERS+1)
 757 #endif
 758
 759         lwz     itmp1,(LA_SIZE + 5*4 + INT_ARG_CNT*4 + FLT_ARG_CNT*8)+LA_LR_OFFSET(sp)
 760         mtlr    itmp1
 761
 762         addi    sp,sp,(LA_SIZE + 5*4 + INT_ARG_CNT*4 + FLT_ARG_CNT*8)
 763
 764         mr.     pv,pv                       /* test for exception                 */
 765         beq     L_asm_call_jit_compiler_exception
 766
 767         mtctr   pv                          /* move method address to control reg */
 768         bctr                                /* and call the Java method           */
 769
 770 L_asm_call_jit_compiler_exception:
 771         mflr    r0
 772         stw     r0,LA_LR_OFFSET(sp)
 773         stwu    sp,-LA_SIZE_ALIGNED(sp)     /* preserve linkage area              */
 774         bl      exceptions_get_and_clear_exception
 775         lwz     xpc,LA_SIZE_ALIGNED+LA_LR_OFFSET(sp)
 776         mtlr    xpc
 777         addi    sp,sp,LA_SIZE_ALIGNED
 778
 779         mr      xptr,v0                     /* get exception                      */
 780         addi    xpc,xpc,-4                  /* exception address is ra - 4        */
 781         b       L_asm_handle_nat_exception
 782
 783
 784 /********************* function asm_handle_exception ***************************
 785 *                                                                              *
 786 *   This function handles an exception. It does not use the usual calling      *
 787 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 788 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 789 *   the local exception table for a handler. If no one is found, it unwinds    *
 790 *   stacks and continues searching the callers.                                *
 791 *                                                                              *
 792 *   void asm_handle_exception (exceptionptr, exceptionpc);                     *
 793 *                                                                              *
 794 *******************************************************************************/
 795
 796 asm_handle_nat_exception:
 797 L_asm_handle_nat_exception:             /* required for PIC code              */
 798 #if 1
 799         mflr    a6
 800         lwz     itmp3,4(a6)
 801         extsh   itmp3,itmp3
 802         add     pv,itmp3,a6
 803         lwz     itmp3,8(a6)
 804         srwi    itmp3,itmp3,16
 805         cmpwi   itmp3,0x3dad
 806         bne     L_asm_handle_exception
 807         lwz     itmp3,8(a6)
 808         slwi    itmp3,itmp3,16
 809         add     pv,pv,itmp3
 810 #else
 811         mflr    r0
 812         addi    sp,sp,-(LA_SIZE+(6*4))      /* allocate stack                     */
 813         stw     xptr,LA_SIZE+0*8(sp)        /* save exception pointer             */
 814         stw     xpc,LA_SIZE+1*8(sp)         /* save exception pc                  */
 815         stw     r0,LA_SIZE+3*8(sp)          /* save return address                */
 816         stw     zero,LA_SIZE+4*8(sp)        /* save maybe-leaf flag (cleared)     */
 817
 818         mr      a0,r0                       /* pass return address                */
 819         bl      md_codegen_get_pv_from_pc   /* get PV from RA                     */
 820         stw     v0,LA_SIZE+2*8(sp)          /* save data segment pointer          */
 821
 822         lwz     a0,LA_SIZE+0*8(sp)          /* pass exception pointer             */
 823         lwz     a1,LA_SIZE+1*8(sp)          /* pass exception pc                  */
 824         mr      a2,v0                       /* pass data segment pointer          */
 825         addi    a3,sp,LA_SIZE+(6*4)         /* pass Java stack pointer            */
 826
 827         b       L_asm_handle_exception_continue
 828 #endif
 829
 830 asm_handle_exception:
 831 L_asm_handle_exception:                 /* required for PIC code              */
 832         addi    sp,sp,-(ARG_CNT+TMP_CNT)*8  /* create maybe-leaf stackframe       */
 833
 834 #if defined(__DARWIN__)
 835 #else
 836         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 837         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 838 #endif
 839
 840         li      a3,(ARG_CNT+TMP_CNT)*8      /* prepare a3 for handle_exception    */
 841         li      a4,1                        /* set maybe-leaf flag                */
 842
 843 L_asm_handle_exception_stack_loop:
 844         addi    sp,sp,-(LA_SIZE+(4+5)*4)    /* allocate stack                     */
 845         stw     xptr,LA_SIZE+4*4(sp)        /* save exception pointer             */
 846         stw     xpc,LA_SIZE+5*4(sp)         /* save exception pc                  */
 847         stw     pv,LA_SIZE+6*4(sp)          /* save data segment pointer          */
 848         mflr    r0                          /* save return address                */
 849         stw     r0,LA_SIZE+5*4(sp)
 850         add     a3,a3,sp                    /* calculate Java sp into a3...       */
 851         addi    a3,a3,LA_SIZE+(4+5)*4
 852         stw     a4,LA_SIZE+8*4(sp)          /* save maybe-leaf flag               */
 853
 854         mr      a0,xptr                     /* pass exception pointer             */
 855         mr      a1,xpc                      /* pass exception pc                  */
 856         mr      a2,pv                       /* pass data segment pointer          */
 857                                             /* a3 is still set                    */
 858         bl      exceptions_handle_exception
 859
 860         mr.     v0,v0
 861         beq     L_asm_handle_exception_not_catched
 862
 863         mr      xpc,v0                      /* move handlerpc into xpc            */
 864         lwz     xptr,LA_SIZE+4*4(sp)        /* restore exception pointer          */
 865         lwz     pv,LA_SIZE+6*4(sp)          /* restore data segment pointer       */
 866         lwz     r0,LA_SIZE+5*4(sp)          /* restore return address             */
 867         mtlr    r0
 868         lwz     a4,LA_SIZE+8*4(sp)          /* get maybe-leaf flag                */
 869         addi    sp,sp,LA_SIZE+(4+5)*4       /* free stack frame                   */
 870
 871         mr.     a4,a4
 872         beq     L_asm_handle_exception_no_leaf
 873
 874 #if defined(__DARWIN__)
 875 #else
 876         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 877         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 878 #endif
 879
 880         addi    sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 881
 882 L_asm_handle_exception_no_leaf:
 883         mtctr   xpc                         /* jump to the handler                */
 884         bctr
 885
 886 L_asm_handle_exception_not_catched:
 887         lwz     xptr,LA_SIZE+4*4(sp)        /* restore exception pointer          */
 888         lwz     pv,LA_SIZE+6*4(sp)          /* restore data segment pointer       */
 889         lwz     r0,LA_SIZE+5*4(sp)          /* restore return address             */
 890         mtlr    r0
 891         lwz     a4,LA_SIZE+8*4(sp)          /* get maybe-leaf flag                */
 892         addi    sp,sp,LA_SIZE+(4+5)*4       /* free stack frame                   */
 893
 894         mr.     a4,a4
 895         beq     L_asm_handle_exception_no_leaf_stack
 896
 897         addi    sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 898         li      a4,0                        /* clear the maybe-leaf flag          */
 899
 900 L_asm_handle_exception_no_leaf_stack:
 901         lwz     t0,FrameSize(pv)            /* get frame size                     */
 902         add     t0,sp,t0                    /* pointer to save area               */
 903
 904         lwz     t1,IsLeaf(pv)               /* is leaf procedure                  */
 905         mr.     t1,t1
 906         bne     L_asm_handle_exception_no_ra_restore
 907
 908         lwz     r0,LA_LR_OFFSET(t0)         /* restore ra                         */
 909         mtlr    r0
 910
 911 L_asm_handle_exception_no_ra_restore:
 912         mflr    xpc                         /* the new xpc is ra                  */
 913         lwz     t1,IntSave(pv)              /* t1 = saved int register count      */
 914         bl      ex_int1
 915 ex_int1:
 916         mflr    t2                          /* t2 = current pc                    */
 917 #if defined(__DARWIN__)
 918         addi    t2,t2,lo16(ex_int2-ex_int1)
 919 #else
 920         addi    t2,t2,(ex_int2-ex_int1)@l
 921 #endif
 922         slwi    t1,t1,2                     /* t1 = register count * 4            */
 923         subf    t2,t1,t2                    /* t2 = IntSave - t1                  */
 924         mtctr   t2
 925         bctr
 926
 927         lwz     s0,-10*4(t0)
 928         lwz     s1,-9*4(t0)
 929         lwz     s2,-8*4(t0)
 930         lwz     s3,-7*4(t0)
 931         lwz     s4,-6*4(t0)
 932         lwz     s5,-5*4(t0)
 933         lwz     s6,-4*4(t0)
 934         lwz     s7,-3*4(t0)
 935         lwz     s8,-2*4(t0)
 936         lwz     s9,-1*4(t0)
 937
 938 ex_int2:
 939         subf    t0,t1,t0                    /* t0 = t0 - register count * 4       */
 940
 941         lwz     t1,FltSave(pv)
 942         bl      ex_flt1
 943 ex_flt1:
 944         mflr    t2
 945 #if defined(__DARWIN__)
 946         addi    t2,t2,lo16(ex_flt2-ex_flt1)
 947 #else
 948         addi    t2,t2,(ex_flt2-ex_flt1)@l
 949 #endif
 950         slwi    t1,t1,2                     /* t1 = register count * 4            */
 951         subf    t2,t1,t2                    /* t2 = FltSave - t1                  */
 952         mtctr   t2
 953         bctr
 954
 955         lfd     fs0,-10*8(t0)
 956         lfd     fs1,-9*8(t0)
 957         lfd     fs2,-8*8(t0)
 958         lfd     fs3,-7*8(t0)
 959         lfd     fs4,-6*8(t0)
 960         lfd     fs5,-5*8(t0)
 961         lfd     fs6,-4*8(t0)
 962         lfd     fs7,-3*8(t0)
 963         lfd     fs8,-2*8(t0)
 964         lfd     fs9,-1*8(t0)
 965
 966 ex_flt2:
 967         lwz     t0,FrameSize(pv)            /* get frame size                     */
 968         add     sp,sp,t0                    /* unwind stack                       */
 969         li      a3,0                        /* prepare a3 for handle_exception    */
 970
 971         mtlr    xpc
 972         lwz     itmp3,4(xpc)
 973         extsh   itmp3,itmp3
 974         add     pv,itmp3,xpc
 975         lwz     itmp3,8(xpc)
 976         srwi    itmp3,itmp3,16
 977         cmpwi   itmp3,0x3dad
 978         bne     L_asm_handle_exception_stack_loop
 979         lwz     itmp3,8(xpc)
 980         slwi    itmp3,itmp3,16
 981         add     pv,pv,itmp3
 982
 983         b       L_asm_handle_exception_stack_loop
 984
 985
 986 /* asm_abstractmethoderror *****************************************************
 987
 988    Creates and throws an AbstractMethodError.
 989
 990 *******************************************************************************/
 991
 992 asm_abstractmethoderror:
 993         mflr    r0
 994         stw     r0,LA_LR_OFFSET(sp)
 995         stwu    sp,-LA_SIZE_ALIGNED(sp)     /* preserve linkage area              */
 996         addi    a0,sp,LA_SIZE_ALIGNED       /* pass java sp                       */
 997         mr      a1,r0                       /* pass exception address             */
 998         bl      exceptions_asm_new_abstractmethoderror
 999         lwz     r0,LA_SIZE_ALIGNED+LA_LR_OFFSET(sp)
1000         mtlr    r0                          /* restore return address             */
1001         addi    sp,sp,LA_SIZE_ALIGNED
1002
1003         mr      xptr,v0                     /* get exception pointer              */
1004         mr      xpc,r0                      /* we can't use r0 directly in addi   */
1005         addi    xpc,xpc,-4                  /* exception address is ra - 4        */
1006         b       L_asm_handle_nat_exception
1007
1008
1009 /* asm_patcher_wrapper *********************************************************
1010
1011    XXX
1012
1013    Stack layout:
1014      20   return address into JIT code (patch position)
1015      16   pointer to virtual java_objectheader
1016      12   machine code (which is patched back later)
1017       8   unresolved class/method/field reference
1018       4   data segment displacement from load instructions
1019       0   patcher function pointer to call (pv is saved here afterwards)
1020
1021 *******************************************************************************/
1022
1023 asm_patcher_wrapper:
1024         mflr    r0                    /* get Java return address (leaf)           */
1025         stw     r0,6*4(sp)            /* store it in the stub stackframe          */
1026                                       /* keep stack 16-bytes aligned: 6+1+37 = 44 */
1027         stwu    sp,-(LA_SIZE+(5+58)*4)(sp)
1028
1029 #if defined(__DARWIN__)
1030         stw     a0,LA_SIZE+(5+0)*4(sp)      /* save argument registers            */
1031         stw     a1,LA_SIZE+(5+1)*4(sp)      /* preserve linkage area (24 bytes)   */
1032         stw     a2,LA_SIZE+(5+2)*4(sp)      /* and 4 bytes for 4 argument         */
1033         stw     a3,LA_SIZE+(5+3)*4(sp)
1034         stw     a4,LA_SIZE+(5+4)*4(sp)
1035         stw     a5,LA_SIZE+(5+5)*4(sp)
1036         stw     a6,LA_SIZE+(5+6)*4(sp)
1037         stw     a7,LA_SIZE+(5+7)*4(sp)
1038
1039         stfd    fa0,LA_SIZE+(5+8)*4(sp)
1040         stfd    fa1,LA_SIZE+(5+10)*4(sp)
1041         stfd    fa2,LA_SIZE+(5+12)*4(sp)
1042         stfd    fa3,LA_SIZE+(5+14)*4(sp)
1043         stfd    fa4,LA_SIZE+(5+16)*4(sp)
1044         stfd    fa5,LA_SIZE+(5+18)*4(sp)
1045         stfd    fa6,LA_SIZE+(5+20)*4(sp)
1046         stfd    fa7,LA_SIZE+(5+22)*4(sp)
1047         stfd    fa8,LA_SIZE+(5+24)*4(sp)
1048         stfd    fa9,LA_SIZE+(5+26)*4(sp)
1049         stfd    fa10,LA_SIZE+(5+28)*4(sp)
1050         stfd    fa11,LA_SIZE+(5+30)*4(sp)
1051         stfd    fa12,LA_SIZE+(5+32)*4(sp)
1052
1053         stw     t0,LA_SIZE+(5+33)*4(sp)
1054         stw     t1,LA_SIZE+(5+34)*4(sp)
1055         stw     t2,LA_SIZE+(5+35)*4(sp)
1056         stw     t3,LA_SIZE+(5+36)*4(sp)
1057         stw     t4,LA_SIZE+(5+37)*4(sp)
1058         stw     t5,LA_SIZE+(5+38)*4(sp)
1059         stw     t6,LA_SIZE+(5+39)*4(sp)
1060         stw     t7,LA_SIZE+(5+40)*4(sp)
1061
1062         stfd    ft0,LA_SIZE+(5+42)*4(sp)
1063         stfd    ft1,LA_SIZE+(5+44)*4(sp)
1064         stfd    ft2,LA_SIZE+(5+46)*4(sp)
1065         stfd    ft3,LA_SIZE+(5+48)*4(sp)
1066         stfd    ft4,LA_SIZE+(5+50)*4(sp)
1067         stfd    ft5,LA_SIZE+(5+52)*4(sp)
1068 #else
1069         /* save 8 int/8 float arguments */
1070         SAVE_ARGUMENT_REGISTERS(LA_SIZE_IN_POINTERS+1)
1071         SAVE_TEMPORARY_REGISTERS(LA_SIZE_IN_POINTERS+1+24)
1072 #endif
1073
1074         stw     itmp1,LA_SIZE+(5+54)*4(sp)
1075         stw     itmp2,LA_SIZE+(5+55)*4(sp)
1076         stw     pv,LA_SIZE+(5+56)*4(sp)
1077
1078         addi    a0,sp,LA_SIZE+(5+58)*4      /* pass SP of patcher stub            */
1079         mr      a1,pv                       /* pass PV                            */
1080         mr      a2,r0                       /* pass RA (correct for leafs)        */
1081         bl      patcher_wrapper
1082         stw     v0,LA_SIZE+(5+57)*4(sp)     /* save return value                  */
1083
1084 #if defined(__DARWIN__)
1085         lwz     a0,LA_SIZE+(5+0)*4(sp)
1086         lwz     a1,LA_SIZE+(5+1)*4(sp)
1087         lwz     a2,LA_SIZE+(5+2)*4(sp)
1088         lwz     a3,LA_SIZE+(5+3)*4(sp)
1089         lwz     a4,LA_SIZE+(5+4)*4(sp)
1090         lwz     a5,LA_SIZE+(5+5)*4(sp)
1091         lwz     a6,LA_SIZE+(5+6)*4(sp)
1092         lwz     a7,LA_SIZE+(5+7)*4(sp)
1093
1094         lfd     fa0,LA_SIZE+(5+8)*4(sp)
1095         lfd     fa1,LA_SIZE+(5+10)*4(sp)
1096         lfd     fa2,LA_SIZE+(5+12)*4(sp)
1097         lfd     fa3,LA_SIZE+(5+14)*4(sp)
1098         lfd     fa4,LA_SIZE+(5+16)*4(sp)
1099         lfd     fa5,LA_SIZE+(5+18)*4(sp)
1100         lfd     fa6,LA_SIZE+(5+20)*4(sp)
1101         lfd     fa7,LA_SIZE+(5+22)*4(sp)
1102         lfd     fa8,LA_SIZE+(5+24)*4(sp)
1103         lfd     fa9,LA_SIZE+(5+26)*4(sp)
1104         lfd     fa10,LA_SIZE+(5+28)*4(sp)
1105         lfd     fa11,LA_SIZE+(5+30)*4(sp)
1106         lfd     fa12,LA_SIZE+(5+32)*4(sp)
1107
1108         lwz     t0,LA_SIZE+(5+33)*4(sp)
1109         lwz     t1,LA_SIZE+(5+34)*4(sp)
1110         lwz     t2,LA_SIZE+(5+35)*4(sp)
1111         lwz     t3,LA_SIZE+(5+36)*4(sp)
1112         lwz     t4,LA_SIZE+(5+37)*4(sp)
1113         lwz     t5,LA_SIZE+(5+38)*4(sp)
1114         lwz     t6,LA_SIZE+(5+39)*4(sp)
1115         lwz     t7,LA_SIZE+(5+40)*4(sp)
1116
1117         lfd     ft0,LA_SIZE+(5+42)*4(sp)
1118         lfd     ft1,LA_SIZE+(5+44)*4(sp)
1119         lfd     ft2,LA_SIZE+(5+46)*4(sp)
1120         lfd     ft3,LA_SIZE+(5+48)*4(sp)
1121         lfd     ft4,LA_SIZE+(5+50)*4(sp)
1122         lfd     ft5,LA_SIZE+(5+52)*4(sp)
1123 #else
1124         /* restore 8 int/8 float arguments */
1125         RESTORE_ARGUMENT_REGISTERS(LA_SIZE_IN_POINTERS+1)
1126         RESTORE_TEMPORARY_REGISTERS(LA_SIZE_IN_POINTERS+1+24)
1127 #endif
1128
1129         lwz     itmp1,LA_SIZE+(5+54)*4(sp)
1130         lwz     itmp2,LA_SIZE+(5+55)*4(sp)
1131         lwz     pv,LA_SIZE+(5+56)*4(sp)
1132         lwz     itmp3,LA_SIZE+(5+57)*4(sp)  /* restore return value into temp reg.*/
1133
1134         lwz     r0,6*4+LA_SIZE+(5+58)*4(sp) /* restore RA                         */
1135         mtlr    r0
1136
1137         mr.     itmp3,itmp3           /* check for an exception                   */
1138         bne     L_asm_patcher_wrapper_exception
1139
1140                                       /* get return address (into JIT code)       */
1141         lwz     itmp3,5*4+LA_SIZE+(5+58)*4(sp)
1142
1143                                       /* remove stack frame + patcher stub stack  */
1144         addi    sp,sp,8*4+LA_SIZE+(5+58)*4
1145
1146         mtctr   itmp3
1147         bctr                          /* jump to new patched code                 */
1148
1149 L_asm_patcher_wrapper_exception:
1150         mr      xptr,itmp3                  /* get exception                      */
1151         lwz     xpc,5*4+LA_SIZE+(5+58)*4(sp)
1152         addi    sp,sp,8*4+LA_SIZE+(5+58)*4
1153         b       L_asm_handle_exception
1154
1155
1156 /* asm_replacement_out *********************************************************
1157
1158    This code is jumped to from the replacement-out stubs that are executed
1159    when a thread reaches an activated replacement point.
1160
1161    The purpose of asm_replacement_out is to read out the parts of the
1162    execution state that cannot be accessed from C code, store this state,
1163    and then call the C function replace_me.
1164
1165    Stack layout:
1166       16                start of stack inside method to replace
1167       0   rplpoint *    info on the replacement point that was reached
1168
1169    NOTE: itmp3 has been clobbered by the replacement-out stub!
1170
1171 *******************************************************************************/
1172
1173 /* some room to accomodate changes of the stack frame size during replacement */
1174         /* XXX we should find a cleaner solution here */
1175 #define REPLACEMENT_ROOM  512
1176
1177 asm_replacement_out:
1178     /* create stack frame */
1179         addi    sp,sp,-(sizeexecutionstate + REPLACEMENT_ROOM) /* XXX align */
1180
1181         /* save link register */
1182         mflr    itmp3
1183
1184         /* save registers in execution state */
1185         stw     r0 ,( 0*8+offes_intregs)(sp)
1186         stw     r1 ,( 1*8+offes_intregs)(sp)
1187         stw     r2 ,( 2*8+offes_intregs)(sp)
1188         stw     r3 ,( 3*8+offes_intregs)(sp)
1189         stw     r4 ,( 4*8+offes_intregs)(sp)
1190         stw     r5 ,( 5*8+offes_intregs)(sp)
1191         stw     r6 ,( 6*8+offes_intregs)(sp)
1192         stw     r7 ,( 7*8+offes_intregs)(sp)
1193         stw     r8 ,( 8*8+offes_intregs)(sp)
1194         stw     r9 ,( 9*8+offes_intregs)(sp)
1195         stw     r10,(10*8+offes_intregs)(sp)
1196         stw     r11,(11*8+offes_intregs)(sp)
1197         stw     r12,(12*8+offes_intregs)(sp)
1198         stw     r13,(13*8+offes_intregs)(sp)
1199         stw     r14,(14*8+offes_intregs)(sp)
1200         stw     r15,(15*8+offes_intregs)(sp)
1201         stw     r16,(16*8+offes_intregs)(sp) /* link register */
1202         stw     r17,(17*8+offes_intregs)(sp)
1203         stw     r18,(18*8+offes_intregs)(sp)
1204         stw     r19,(19*8+offes_intregs)(sp)
1205         stw     r20,(20*8+offes_intregs)(sp)
1206         stw     r21,(21*8+offes_intregs)(sp)
1207         stw     r22,(22*8+offes_intregs)(sp)
1208         stw     r23,(23*8+offes_intregs)(sp)
1209         stw     r24,(24*8+offes_intregs)(sp)
1210         stw     r25,(25*8+offes_intregs)(sp)
1211         stw     r26,(26*8+offes_intregs)(sp)
1212         stw     r27,(27*8+offes_intregs)(sp)
1213         stw     r28,(28*8+offes_intregs)(sp)
1214         stw     r29,(29*8+offes_intregs)(sp)
1215         stw     r30,(30*8+offes_intregs)(sp)
1216         stw     r31,(31*8+offes_intregs)(sp)
1217
1218         stfd    fr0 ,( 0*8+offes_fltregs)(sp)
1219         stfd    fr1 ,( 1*8+offes_fltregs)(sp)
1220         stfd    fr2 ,( 2*8+offes_fltregs)(sp)
1221         stfd    fr3 ,( 3*8+offes_fltregs)(sp)
1222         stfd    fr4 ,( 4*8+offes_fltregs)(sp)
1223         stfd    fr5 ,( 5*8+offes_fltregs)(sp)
1224         stfd    fr6 ,( 6*8+offes_fltregs)(sp)
1225         stfd    fr7 ,( 7*8+offes_fltregs)(sp)
1226         stfd    fr8 ,( 8*8+offes_fltregs)(sp)
1227         stfd    fr9 ,( 9*8+offes_fltregs)(sp)
1228         stfd    fr10,(10*8+offes_fltregs)(sp)
1229         stfd    fr11,(11*8+offes_fltregs)(sp)
1230         stfd    fr12,(12*8+offes_fltregs)(sp)
1231         stfd    fr13,(13*8+offes_fltregs)(sp)
1232         stfd    fr14,(14*8+offes_fltregs)(sp)
1233         stfd    fr15,(15*8+offes_fltregs)(sp)
1234         stfd    fr16,(16*8+offes_fltregs)(sp)
1235         stfd    fr17,(17*8+offes_fltregs)(sp)
1236         stfd    fr18,(18*8+offes_fltregs)(sp)
1237         stfd    fr19,(19*8+offes_fltregs)(sp)
1238         stfd    fr20,(20*8+offes_fltregs)(sp)
1239         stfd    fr21,(21*8+offes_fltregs)(sp)
1240         stfd    fr22,(22*8+offes_fltregs)(sp)
1241         stfd    fr23,(23*8+offes_fltregs)(sp)
1242         stfd    fr24,(24*8+offes_fltregs)(sp)
1243         stfd    fr25,(25*8+offes_fltregs)(sp)
1244         stfd    fr26,(26*8+offes_fltregs)(sp)
1245         stfd    fr27,(27*8+offes_fltregs)(sp)
1246         stfd    fr28,(28*8+offes_fltregs)(sp)
1247         stfd    fr29,(29*8+offes_fltregs)(sp)
1248         stfd    fr30,(30*8+offes_fltregs)(sp)
1249         stfd    fr31,(31*8+offes_fltregs)(sp)
1250
1251         /* calculate sp of method */
1252         addi    itmp1,sp,(sizeexecutionstate + REPLACEMENT_ROOM + 4*4)
1253         stw     itmp1,(offes_sp)(sp)
1254
1255         /* store pv */
1256         stw     pv,(offes_pv)(sp)
1257
1258         /* call replace_me */
1259         lwz     a0,-(4*4)(itmp1)            /* arg0: rplpoint *                   */
1260         mr      a1,sp                       /* arg1: execution state              */
1261         addi    sp,sp,-(LA_SIZE_ALIGNED)
1262         b       replace_me                  /* call C function replace_me         */
1263
1264 /* asm_replacement_in **********************************************************
1265
1266    This code writes the given execution state and jumps to the replacement
1267    code.
1268
1269    This function never returns!
1270
1271    NOTE: itmp3 is not restored!
1272
1273    C prototype:
1274       void asm_replacement_in(executionstate *es);
1275
1276 *******************************************************************************/
1277
1278 asm_replacement_in:
1279         /* a0 == executionstate *es */
1280
1281         /* set new sp and pv */
1282         lwz     sp,(offes_sp)(a0)
1283         lwz     pv,(offes_pv)(a0)
1284
1285         /* copy registers from execution state */
1286         lwz     r0 ,( 0*8+offes_intregs)(a0)
1287         /* r1 is sp                       */
1288         /* r2 is reserved                 */
1289         /* a0 is loaded below             */
1290         lwz     r4 ,( 4*8+offes_intregs)(a0)
1291         lwz     r5 ,( 5*8+offes_intregs)(a0)
1292         lwz     r6 ,( 6*8+offes_intregs)(a0)
1293         lwz     r7 ,( 7*8+offes_intregs)(a0)
1294         lwz     r8 ,( 8*8+offes_intregs)(a0)
1295         lwz     r9 ,( 9*8+offes_intregs)(a0)
1296         lwz     r10,(10*8+offes_intregs)(a0)
1297         lwz     r11,(11*8+offes_intregs)(a0)
1298         lwz     r12,(12*8+offes_intregs)(a0)
1299         /* r13 is pv                      */
1300         lwz     r14,(14*8+offes_intregs)(a0)
1301         lwz     r15,(15*8+offes_intregs)(a0)
1302         lwz     r16,(16*8+offes_intregs)(a0) /* link register */
1303         lwz     r17,(17*8+offes_intregs)(a0)
1304         lwz     r18,(18*8+offes_intregs)(a0)
1305         lwz     r19,(19*8+offes_intregs)(a0)
1306         lwz     r20,(20*8+offes_intregs)(a0)
1307         lwz     r21,(21*8+offes_intregs)(a0)
1308         lwz     r22,(22*8+offes_intregs)(a0)
1309         lwz     r23,(23*8+offes_intregs)(a0)
1310         lwz     r24,(24*8+offes_intregs)(a0)
1311         lwz     r25,(25*8+offes_intregs)(a0)
1312         lwz     r26,(26*8+offes_intregs)(a0)
1313         lwz     r27,(27*8+offes_intregs)(a0)
1314         lwz     r28,(28*8+offes_intregs)(a0)
1315         lwz     r29,(29*8+offes_intregs)(a0)
1316         lwz     r30,(30*8+offes_intregs)(a0)
1317         lwz     r31,(31*8+offes_intregs)(a0)
1318
1319         lfd     fr0 ,( 0*8+offes_fltregs)(a0)
1320         lfd     fr1 ,( 1*8+offes_fltregs)(a0)
1321         lfd     fr2 ,( 2*8+offes_fltregs)(a0)
1322         lfd     fr3 ,( 3*8+offes_fltregs)(a0)
1323         lfd     fr4 ,( 4*8+offes_fltregs)(a0)
1324         lfd     fr5 ,( 5*8+offes_fltregs)(a0)
1325         lfd     fr6 ,( 6*8+offes_fltregs)(a0)
1326         lfd     fr7 ,( 7*8+offes_fltregs)(a0)
1327         lfd     fr8 ,( 8*8+offes_fltregs)(a0)
1328         lfd     fr9 ,( 9*8+offes_fltregs)(a0)
1329         lfd     fr10,(10*8+offes_fltregs)(a0)
1330         lfd     fr11,(11*8+offes_fltregs)(a0)
1331         lfd     fr12,(12*8+offes_fltregs)(a0)
1332         lfd     fr13,(13*8+offes_fltregs)(a0)
1333         lfd     fr14,(14*8+offes_fltregs)(a0)
1334         lfd     fr15,(15*8+offes_fltregs)(a0)
1335         lfd     fr16,(16*8+offes_fltregs)(a0)
1336         lfd     fr17,(17*8+offes_fltregs)(a0)
1337         lfd     fr18,(18*8+offes_fltregs)(a0)
1338         lfd     fr19,(19*8+offes_fltregs)(a0)
1339         lfd     fr20,(20*8+offes_fltregs)(a0)
1340         lfd     fr21,(21*8+offes_fltregs)(a0)
1341         lfd     fr22,(22*8+offes_fltregs)(a0)
1342         lfd     fr23,(23*8+offes_fltregs)(a0)
1343         lfd     fr24,(24*8+offes_fltregs)(a0)
1344         lfd     fr25,(25*8+offes_fltregs)(a0)
1345         lfd     fr26,(26*8+offes_fltregs)(a0)
1346         lfd     fr27,(27*8+offes_fltregs)(a0)
1347         lfd     fr28,(28*8+offes_fltregs)(a0)
1348         lfd     fr29,(29*8+offes_fltregs)(a0)
1349         lfd     fr30,(30*8+offes_fltregs)(a0)
1350         lfd     fr31,(31*8+offes_fltregs)(a0)
1351
1352         /* restore link register */
1353
1354         mtlr    itmp3
1355
1356         /* load new pc */
1357
1358         lwz     itmp3,offes_pc(a0)
1359
1360         /* load a0 */
1361
1362         lwz     a0,(3*8+offes_intregs)(a0)
1363
1364         /* jump to new code */
1365
1366         mtctr   itmp3
1367         bctr
1368
1369 /*********************************************************************/
1370
1371 asm_cacheflush:
1372         add     a1,a0,a1
1373         rlwinm  a0,a0,0,0,26
1374         addi    a1,a1,31
1375         rlwinm  a1,a1,0,0,26
1376         mr      a2,a0
1377 1:
1378         cmplw   a0,a1
1379         bge     0f
1380         dcbst   0,a0
1381         addi    a0,a0,32
1382         b       1b
1383 0:
1384         sync
1385 1:
1386         cmplw   a2,a1
1387         bge     0f
1388         icbi    0,a2
1389         addi    a2,a2,32
1390         b       1b
1391 0:
1392         sync
1393         isync
1394         blr
1395
1396
1397 asm_getclassvalues_atomic:
1398 _crit_restart:
1399 _crit_begin:
1400         lwz     a3,offbaseval(a0)
1401         lwz     a4,offdiffval(a0)
1402         lwz     a5,offbaseval(a1)
1403 _crit_end:
1404         stw     a3,offcast_super_baseval(a2)
1405         stw     a4,offcast_super_diffval(a2)
1406         stw     a5,offcast_sub_baseval(a2)
1407         blr
1408
1409         .data
1410
1411 asm_criticalsections:
1412 #if defined(ENABLE_THREADS)
1413         .long   _crit_begin
1414         .long   _crit_end
1415         .long   _crit_restart
1416 #endif
1417         .long 0
1418
1419
1420 #if defined(__DARWIN__)
1421
1422 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1423         .align 2
1424 L_builtin_throw_exception$stub:
1425         .indirect_symbol _builtin_throw_exception
1426         mflr r0
1427         bcl 20,31,L00$_builtin_throw_exception
1428 L00$_builtin_throw_exception:
1429         mflr r11
1430         addis r11,r11,ha16(L_builtin_throw_exception$lazy_ptr - L00$_builtin_throw_exception)
1431         mtlr r0
1432         lwzu r12,lo16(L_builtin_throw_exception$lazy_ptr - L00$_builtin_throw_exception)(r11)
1433         mtctr r12
1434         bctr
1435 .data
1436 .lazy_symbol_pointer
1437 L_builtin_throw_exception$lazy_ptr:
1438         .indirect_symbol _builtin_throw_exception
1439         .long dyld_stub_binding_helper
1440
1441
1442 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1443         .align 2
1444 L_exceptions_handle_exception$stub:
1445         .indirect_symbol _exceptions_handle_exception
1446         mflr r0
1447         bcl 20,31,L00$_exceptions_handle_exception
1448 L00$_exceptions_handle_exception:
1449         mflr r11
1450         addis r11,r11,ha16(L_exceptions_handle_exception$lazy_ptr - L00$_exceptions_handle_exception)
1451         mtlr r0
1452         lwzu r12,lo16(L_exceptions_handle_exception$lazy_ptr - L00$_exceptions_handle_exception)(r11)
1453         mtctr r12
1454         bctr
1455 .data
1456 .lazy_symbol_pointer
1457 L_exceptions_handle_exception$lazy_ptr:
1458         .indirect_symbol _exceptions_handle_exception
1459         .long dyld_stub_binding_helper
1460
1461
1462 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1463         .align 2
1464 L_stacktrace_create_extern_stackframeinfo$stub:
1465         .indirect_symbol _stacktrace_create_extern_stackframeinfo
1466         mflr r0
1467         bcl 20,31,L00$_stacktrace_create_extern_stackframeinfo
1468 L00$_stacktrace_create_extern_stackframeinfo:
1469         mflr r11
1470         addis r11,r11,ha16(L_stacktrace_create_extern_stackframeinfo$lazy_ptr - L00$_stacktrace_create_extern_stackframeinfo)
1471         mtlr r0
1472         lwzu r12,lo16(L_stacktrace_create_extern_stackframeinfo$lazy_ptr - L00$_stacktrace_create_extern_stackframeinfo)(r11)
1473         mtctr r12
1474         bctr
1475 .data
1476 .lazy_symbol_pointer
1477 L_stacktrace_create_extern_stackframeinfo$lazy_ptr:
1478         .indirect_symbol _stacktrace_create_extern_stackframeinfo
1479         .long dyld_stub_binding_helper
1480
1481
1482 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1483         .align 2
1484 L_jit_asm_compile$stub:
1485         .indirect_symbol _jit_asm_compile
1486         mflr r0
1487         bcl 20,31,L00$_jit_asm_compile
1488 L00$_jit_asm_compile:
1489         mflr r11
1490         addis r11,r11,ha16(L_jit_asm_compile$lazy_ptr - L00$_jit_asm_compile)
1491         mtlr r0
1492         lwzu r12,lo16(L_jit_asm_compile$lazy_ptr - L00$_jit_asm_compile)(r11)
1493         mtctr r12
1494         bctr
1495 .data
1496 .lazy_symbol_pointer
1497 L_jit_asm_compile$lazy_ptr:
1498         .indirect_symbol _jit_asm_compile
1499         .long dyld_stub_binding_helper
1500
1501
1502 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1503         .align 2
1504 L_stacktrace_remove_stackframeinfo$stub:
1505         .indirect_symbol _stacktrace_remove_stackframeinfo
1506         mflr r0
1507         bcl 20,31,L00$_stacktrace_remove_stackframeinfo
1508 L00$_stacktrace_remove_stackframeinfo:
1509         mflr r11
1510         addis r11,r11,ha16(L_stacktrace_remove_stackframeinfo$lazy_ptr - L00$_stacktrace_remove_stackframeinfo)
1511         mtlr r0
1512         lwzu r12,lo16(L_stacktrace_remove_stackframeinfo$lazy_ptr - L00$_stacktrace_remove_stackframeinfo)(r11)
1513         mtctr r12
1514         bctr
1515 .data
1516 .lazy_symbol_pointer
1517 L_stacktrace_remove_stackframeinfo$lazy_ptr:
1518         .indirect_symbol _stacktrace_remove_stackframeinfo
1519         .long dyld_stub_binding_helper
1520
1521
1522 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1523         .align 2
1524 L_exceptions_get_and_clear_exception$stub:
1525         .indirect_symbol _exceptions_get_and_clear_exception
1526         mflr r0
1527         bcl 20,31,L00$_exceptions_get_and_clear_exception
1528 L00$_exceptions_get_and_clear_exception:
1529         mflr r11
1530         addis r11,r11,ha16(L_exceptions_get_and_clear_exception$lazy_ptr - L00$_exceptions_get_and_clear_exception)
1531         mtlr r0
1532         lwzu r12,lo16(L_exceptions_get_and_clear_exception$lazy_ptr - L00$_exceptions_get_and_clear_exception)(r11)
1533         mtctr r12
1534         bctr
1535 .data
1536 .lazy_symbol_pointer
1537 L_exceptions_get_and_clear_exception$lazy_ptr:
1538         .indirect_symbol _exceptions_get_and_clear_exception
1539         .long dyld_stub_binding_helper
1540
1541
1542 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1543         .align 2
1544 L_exceptions_asm_new_abstractmethoderror$stub:
1545         .indirect_symbol _exceptions_asm_new_abstractmethoderror
1546         mflr r0
1547         bcl 20,31,L00$_exceptions_asm_new_abstractmethoderror
1548 L00$_exceptions_asm_new_abstractmethoderror:
1549         mflr r11
1550         addis r11,r11,ha16(L_exceptions_asm_new_abstractmethoderror$lazy_ptr - L00$_exceptions_asm_new_abstractmethoderror)
1551         mtlr r0
1552         lwzu r12,lo16(L_exceptions_asm_new_abstractmethoderror$lazy_ptr - L00$_exceptions_asm_new_abstractmethoderror)(r11)
1553         mtctr r12
1554         bctr
1555 .data
1556 .lazy_symbol_pointer
1557 L_exceptions_asm_new_abstractmethoderror$lazy_ptr:
1558         .indirect_symbol _exceptions_asm_new_abstractmethoderror
1559         .long dyld_stub_binding_helper
1560
1561
1562 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1563         .align 2
1564 L_patcher_wrapper$stub:
1565         .indirect_symbol _patcher_wrapper
1566         mflr r0
1567         bcl 20,31,L00$_patcher_wrapper
1568 L00$_patcher_wrapper:
1569         mflr r11
1570         addis r11,r11,ha16(L_patcher_wrapper$lazy_ptr - L00$_patcher_wrapper)
1571         mtlr r0
1572         lwzu r12,lo16(L_patcher_wrapper$lazy_ptr - L00$_patcher_wrapper)(r11)
1573         mtctr r12
1574         bctr
1575 .data
1576 .lazy_symbol_pointer
1577 L_patcher_wrapper$lazy_ptr:
1578         .indirect_symbol _patcher_wrapper
1579         .long dyld_stub_binding_helper
1580
1581
1582 .section __TEXT,__picsymbolstub1,symbol_stubs,pure_instructions,32
1583         .align 2
1584 L_replace_me$stub:
1585         .indirect_symbol _replace_me
1586         mflr r0
1587         bcl 20,31,L00$_replace_me
1588 L00$_replace_me:
1589         mflr r11
1590         addis r11,r11,ha16(L_replace_me$lazy_ptr - L00$_replace_me)
1591         mtlr r0
1592         lwzu r12,lo16(L_replace_me$lazy_ptr - L00$_replace_me)(r11)
1593         mtctr r12
1594         bctr
1595 .data
1596 .lazy_symbol_pointer
1597 L_replace_me$lazy_ptr:
1598         .indirect_symbol _replace_me
1599         .long dyld_stub_binding_helper
1600
1601 #endif /* defined(__DARWIN__) */
1602
1603
1604 /* Disable exec-stacks, required for Gentoo ***********************************/
1605
1606 #if defined(__GCC__) && defined(__ELF__)
1607         .section .note.GNU-stack,"",@progbits
1608 #endif
1609
1610
1611 /*
1612  * These are local overrides for various environment variables in Emacs.
1613  * Please do not remove this and leave it at the end of the file, where
1614  * Emacs will automagically detect them.
1615  * ---------------------------------------------------------------------
1616  * Local variables:
1617  * mode: asm
1618  * indent-tabs-mode: t
1619  * c-basic-offset: 4
1620  * tab-width: 4
1621  * End:
1622  * vim:noexpandtab:sw=4:ts=4:
1623  */