src/vm/jit/mips/asmpart.S

   1 /* src/vm/jit/mips/asmpart.S - Java-C interface functions for MIPS
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28
  29    Changes: Christian Thalinger
  30             Edwin Steiner
  31
  32    $Id: asmpart.S 4921 2006-05-15 14:24:36Z twisti $
  33
  34 */
  35
  36
  37 #include "config.h"
  38
  39 #include "vm/jit/mips/md-abi.h"
  40 #include "vm/jit/mips/md-asm.h"
  41 #include "vm/jit/mips/offsets.h"
  42
  43 #include "vm/jit/abi-asm.h"
  44 #include "vm/jit/methodheader.h"
  45
  46
  47         .text
  48         .set    noat
  49
  50
  51 /* export functions ***********************************************************/
  52
  53         .globl asm_vm_call_method
  54         .globl asm_vm_call_method_int
  55         .globl asm_vm_call_method_long
  56         .globl asm_vm_call_method_float
  57         .globl asm_vm_call_method_double
  58         .globl asm_vm_call_method_exception_handler
  59
  60         .globl asm_call_jit_compiler
  61         .globl asm_handle_exception
  62         .globl asm_handle_nat_exception
  63
  64         .globl asm_wrapper_patcher
  65
  66         .globl asm_replacement_out
  67         .globl asm_replacement_in
  68
  69         .globl asm_perform_threadswitch
  70         .globl asm_initialize_thread_stack
  71         .globl asm_switchstackandcall
  72         .globl asm_getclassvalues_atomic
  73         .globl asm_criticalsections
  74
  75         .globl compare_and_swap
  76
  77
  78 /********************* function asm_calljavafunction ***************************
  79 *                                                                              *
  80 *   This function calls a Java-method (which possibly needs compilation)       *
  81 *   with up to 4 address parameters.                                           *
  82 *                                                                              *
  83 *   This functions calls the JIT-compiler which eventually translates the      *
  84 *   method into machine code.                                                  *
  85 *                                                                              *
  86 *   A possibly throwed exception will be returned to the caller as function    *
  87 *   return value, so the java method cannot return a fucntion value (this      *
  88 *   function usually calls 'main' and '<clinit>' which do not return a         *
  89 *   function value).                                                           *
  90 *                                                                              *
  91 *   C-prototype:                                                               *
  92 *    javaobject_header *asm_calljavafunction (methodinfo *m,                   *
  93 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  94 *                                                                              *
  95 *******************************************************************************/
  96
  97         .ent    asm_vm_call_method
  98
  99         .align  3
 100
 101         .dword  0                           /* catch type all                     */
 102         .dword  0                           /* handler pc                         */
 103         .dword  0                           /* end pc                             */
 104         .dword  0                           /* start pc                           */
 105         .word   1                           /* extable size                       */
 106         .word   0                           /* 4-byte ALIGNMENT PADDING           */
 107         .dword  0                           /* line number table start            */
 108         .dword  0                           /* line number table size             */
 109         .word   0                           /* 4-byte ALIGNMENT PADDING           */
 110         .word   0                           /* fltsave                            */
 111         .word   0                           /* intsave                            */
 112         .word   0                           /* isleaf                             */
 113         .word   0                           /* IsSync                             */
 114         .word   0                           /* frame size                         */
 115         .dword  0                           /* method pointer (pointer to name)   */
 116
 117 asm_vm_call_method:
 118 asm_vm_call_method_int:
 119 asm_vm_call_method_long:
 120 asm_vm_call_method_float:
 121 asm_vm_call_method_double:
 122         .set    noreorder                 /* XXX we need to recompute pv          */
 123
 124         aaddiu  sp,sp,-12*8               /* allocate stack space (only 11 needed)*/
 125         ast     ra,0(sp)                  /* save return address                  */
 126
 127         bal     L_asm_vm_call_method_compute_pv
 128         ast     pv,1*8(sp)                /* procedure vector                     */
 129 L_asm_vm_call_method_compute_pv:
 130         aaddiu  pv,ra,-4*4
 131         ast     s7,3*8(sp)
 132
 133         sdc1    fss0,5*8(sp)              /* save non JavaABI saved flt registers */
 134         sdc1    fss1,6*8(sp)
 135         sdc1    fss2,7*8(sp)
 136         sdc1    fss3,8*8(sp)
 137         sdc1    fss4,9*8(sp)
 138         sdc1    fss5,10*8(sp)
 139
 140         ast     a0,4*8(sp)                /* save method pointer for compiler     */
 141
 142         move    t0,a2
 143         move    s7,a1
 144         blez    s7,calljava_argsloaded
 145         nop
 146
 147         ald     a0,offvmargdata(t0)
 148         ldc1    fa0,offvmargdata(t0)
 149         daddi   s7,s7,-1
 150         blez    s7,calljava_argsloaded
 151         nop
 152
 153         ald     a1,offvmargdata+sizevmarg*1(t0)
 154         ldc1    fa1,offvmargdata+sizevmarg*1(t0)
 155         daddi   s7,s7,-1
 156         blez    s7,calljava_argsloaded
 157         nop
 158
 159         ald     a2,offvmargdata+sizevmarg*2(t0)
 160         ldc1    fa2,offvmargdata+sizevmarg*2(t0)
 161         daddi   s7,s7,-1
 162         blez    s7,calljava_argsloaded
 163         nop
 164
 165         ald     a3,offvmargdata+sizevmarg*3(t0)
 166         ldc1    fa3,offvmargdata+sizevmarg*3(t0)
 167         daddi   s7,s7,-1
 168         blez    s7,calljava_argsloaded
 169         nop
 170
 171         ald     a4,offvmargdata+sizevmarg*4(t0)
 172         ldc1    fa4,offvmargdata+sizevmarg*4(t0)
 173         daddi   s7,s7,-1
 174         blez    s7,calljava_argsloaded
 175         nop
 176
 177         ald     a5,offvmargdata+sizevmarg*5(t0)
 178         ldc1    fa5,offvmargdata+sizevmarg*5(t0)
 179         daddi   s7,s7,-1
 180         blez    s7,calljava_argsloaded
 181         nop
 182
 183         ald     a6,offvmargdata+sizevmarg*6(t0)
 184         ldc1    fa6,offvmargdata+sizevmarg*6(t0)
 185         daddi   s7,s7,-1
 186         blez    s7,calljava_argsloaded
 187         nop
 188
 189         ald     a7,offvmargdata+sizevmarg*7(t0)
 190         ldc1    fa7,offvmargdata+sizevmarg*7(t0)
 191         daddi   s7,s7,-1
 192
 193 calljava_argsloaded:
 194         move    t8,sp                      /* save stack pointer                  */
 195         blez    s7,calljava_nocopy
 196         nop
 197         subu    t1,zero,s7
 198         sll     t2,t1,3
 199         aaddu   sp,sp,t2
 200         aaddu   t2,t2,t8
 201
 202 calljava_copyloop:
 203     ald     t3,offvmargdata+sizevmarg*8(t0)
 204         ast     t3,0(t2)
 205         ala     t1,1(t1)
 206         ala     t0,sizevmarg(t0)
 207         ala     t2,8(t2)
 208         bnez    t1,calljava_copyloop
 209         nop
 210
 211 calljava_nocopy:
 212         ald     itmp1,4*8(t8)             /* pass method pointer via itmp1        */
 213
 214         ala     mptr,asm_call_jit_compiler/* fake virtual function call (2 instr) */
 215         ast     mptr,2*8(t8)              /* store function address               */
 216         ala     mptr,1*8(t8)              /* set method pointer                   */
 217
 218         ald     pv,1*8(mptr)              /* method call as in Java               */
 219         jalr    pv                        /* call JIT compiler                    */
 220         nop
 221 L_asm_vm_call_method_recompute_pv:
 222 /*      aaddiu  pv,ra,(asm_vm_call_method - L_asm_vm_call_method_recompute_pv)*/
 223         aaddiu  pv,ra,-76*4               /* recompute procedure vector           */
 224
 225         .set    reorder                   /* XXX we need to recompute pv          */
 226
 227 calljava_return2:
 228         ald     ra,0(sp)                  /* restore return address               */
 229         ald     pv,8(sp)                  /* restore procedure vector             */
 230         ald     s7,3*8(sp)
 231
 232         ldc1    fss0,5*8(sp)              /* restore non JavaABI saved flt regs   */
 233         ldc1    fss1,6*8(sp)
 234         ldc1    fss2,7*8(sp)
 235         ldc1    fss3,8*8(sp)
 236         ldc1    fss4,9*8(sp)
 237         ldc1    fss5,10*8(sp)
 238
 239         aaddiu  sp,sp,12*8                /* free stack space                     */
 240         j       ra                        /* return                               */
 241
 242 asm_vm_call_method_exception_handler:
 243         asll    s7,s7,3
 244         aaddu   sp,s7,sp
 245         move    a0,itmp1
 246         jal     builtin_throw_exception
 247         b       calljava_return2
 248
 249         .end    asm_vm_call_method
 250
 251
 252 /****************** function asm_call_jit_compiler *****************************
 253 *                                                                              *
 254 *   invokes the compiler for untranslated JavaVM methods.                      *
 255 *                                                                              *
 256 *   Register REG_ITEMP1 contains a pointer to the method info structure        *
 257 *   (prepared by createcompilerstub). Using the return address in R31 and the  *
 258 *   offset in the LDA instruction or using the value in methodptr R25 the      *
 259 *   patching address for storing the method address can be computed:           *
 260 *                                                                              *
 261 *   method address was either loaded using                                     *
 262 *   M_ALD (REG_PV, REG_PV, a)        ; invokestatic/special    ($28)           *
 263 *   M_JSR (REG_RA, REG_PV);                                                    *
 264 *   M_NOP                                                                      *
 265 *   M_LDA (REG_PV, REG_RA, val)                                                *
 266 *   or                                                                         *
 267 *   M_ALD (REG_PV, REG_METHODPTR, m) ; invokevirtual/interface ($25)           *
 268 *   M_JSR (REG_RA, REG_PV);                                                    *
 269 *   M_NOP                                                                      *
 270 *   in the static case the method pointer can be computed using the            *
 271 *   return address and the lda function following the jmp instruction          *
 272 *                                                                              *
 273 *******************************************************************************/
 274
 275
 276         .ent    asm_call_jit_compiler
 277
 278 asm_call_jit_compiler:
 279         aaddiu  sp,sp,-(ARG_CNT+2)*8  /* allocate stack space                     */
 280
 281         ast     ra,0*8(sp)            /* save return address                      */
 282
 283         SAVE_ARGUMENT_REGISTERS(1)
 284
 285         move    a0,itmp1              /* pass methodinfo pointer                  */
 286         move    a1,mptr               /* pass method pointer                      */
 287         aaddiu  a2,sp,(ARG_CNT+2)*8   /* pass java sp                             */
 288         move    a3,ra
 289         jal     jit_asm_compile       /* call jit compiler                        */
 290         move    pv,v0
 291
 292         ald     ra,0*8(sp)            /* restore return address                   */
 293
 294         RESTORE_ARGUMENT_REGISTERS(1)
 295
 296         aaddiu  sp,sp,(ARG_CNT+2)*8   /* remove stack frame                       */
 297
 298         beqz    pv,L_asm_call_jit_compiler_exception
 299
 300         jr      pv                    /* and call method. The method returns      */
 301                                       /* directly to the caller (ra).             */
 302
 303 L_asm_call_jit_compiler_exception:
 304 #if defined(ENABLE_THREADS)
 305         aaddiu  sp,sp,-2*8
 306         ast     ra,0*8(sp)
 307         jal     builtin_asm_get_exceptionptrptr
 308         ald     ra,0*8(sp)
 309         aaddiu  sp,sp,2*8
 310 #else
 311         la      v0,_exceptionptr
 312 #endif
 313         ald     xptr,0(v0)            /* get the exception pointer                */
 314         ast     zero,0(v0)            /* clear the exception pointer              */
 315
 316         aaddiu  xpc,ra,-4             /* faulting address is return adress - 4    */
 317         b       asm_handle_nat_exception
 318
 319         .end    asm_call_jit_compiler
 320
 321
 322 /* asm_handle_exception ********************************************************
 323
 324    This function handles an exception. It does not use the usual calling
 325    conventions. The exception pointer is passed in REG_ITMP1 and the
 326    pc from the exception raising position is passed in REG_ITMP2. It searches
 327    the local exception table for a handler. If no one is found, it unwinds
 328    stacks and continues searching the callers.
 329
 330 *******************************************************************************/
 331
 332         .ent    asm_handle_nat_exception
 333
 334 asm_handle_nat_exception:
 335 L_asm_handle_exception_stack_loop:
 336         aaddiu  sp,sp,-6*8                  /* allocate stack                     */
 337         ast     xptr,0*8(sp)                /* save exception pointer             */
 338         ast     xpc,1*8(sp)                 /* save exception pc                  */
 339         ast     ra,3*8(sp)                  /* save return address                */
 340         ast     zero,4*8(sp)                /* save maybe-leaf flag (cleared)     */
 341
 342         move    a0,ra                       /* pass return address                */
 343         jal     md_codegen_findmethod       /* get PV from RA                     */
 344         ast     v0,2*8(sp)                  /* save data segment pointer          */
 345
 346         ald     a0,0*8(sp)                  /* pass exception pointer             */
 347         ald     a1,1*8(sp)                  /* pass exception pc                  */
 348         move    a2,v0                       /* pass data segment pointer          */
 349         aaddiu  a3,sp,6*8                   /* pass Java stack pointer            */
 350
 351         b       L_asm_handle_exception_continue
 352
 353         .aent    asm_handle_exception
 354
 355 asm_handle_exception:
 356         aaddiu  sp,sp,-(ARG_CNT+TMP_CNT)*8  /* create maybe-leaf stackframe       */
 357
 358         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 359         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 360
 361         aaddiu  sp,sp,-6*8                  /* allocate stack                     */
 362         ast     xptr,0*8(sp)                /* save exception pointer             */
 363         ast     xpc,1*8(sp)                 /* save exception pc                  */
 364         ast     pv,2*8(sp)                  /* save data segment pointer          */
 365         ast     ra,3*8(sp)                  /* save return address                */
 366         addu    t0,zero,1                   /* set maybe-leaf flag                */
 367         ast     t0,4*8(sp)                  /* save maybe-leaf flag               */
 368
 369         move    a0,xptr                     /* pass exception pointer             */
 370         move    a1,xpc                      /* pass exception pc                  */
 371         move    a2,pv                       /* pass data segment pointer          */
 372         aaddiu  a3,sp,(ARG_CNT+TMP_CNT+6)*8 /* pass Java stack pointer            */
 373
 374 L_asm_handle_exception_continue:
 375         jal     exceptions_handle_exception
 376
 377         beqz    v0,L_asm_handle_exception_not_catched
 378
 379         move    xpc,v0                      /* move handlerpc into xpc            */
 380         ald     xptr,0*8(sp)                /* restore exception pointer          */
 381         ald     pv,2*8(sp)                  /* restore data segment pointer       */
 382         ald     ra,3*8(sp)                  /* restore return address             */
 383         ald     t0,4*8(sp)                  /* get maybe-leaf flag                */
 384         aaddiu  sp,sp,6*8                   /* free stackframe                    */
 385
 386         beqz    t0,L_asm_handle_exception_no_leaf
 387
 388         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 389         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 390
 391         aaddiu  sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 392
 393 L_asm_handle_exception_no_leaf:
 394         jr      xpc                         /* jump to the handler                */
 395
 396 L_asm_handle_exception_not_catched:
 397         ald     xptr,0*8(sp)                /* restore exception pointer          */
 398         ald     pv,2*8(sp)                  /* restore data segment pointer       */
 399         ald     ra,3*8(sp)                  /* restore return address             */
 400         ald     t0,4*8(sp)                  /* get maybe-leaf flag                */
 401         aaddiu  sp,sp,6*8                   /* free stackframe                    */
 402
 403         beqz    t0,L_asm_handle_exception_no_leaf_stack
 404
 405         aaddiu  sp,sp,(ARG_CNT+TMP_CNT)*8   /* remove maybe-leaf stackframe       */
 406         move    t0,zero                     /* clear the maybe-leaf flag          */
 407
 408 L_asm_handle_exception_no_leaf_stack:
 409         lw      t1,FrameSize(pv)            /* get frame size                     */
 410         aaddu   t1,sp,t1                    /* pointer to save area               */
 411
 412         lw      t2,IsLeaf(pv)               /* is leaf procedure                  */
 413         bnez    t2,L_asm_handle_exception_no_ra_restore
 414
 415         ald     ra,-1*8(t1)                 /* restore ra                         */
 416         aaddiu  t1,t1,-8                    /* t1--                               */
 417
 418 L_asm_handle_exception_no_ra_restore:
 419         move    xpc,ra                      /* the new xpc is ra                  */
 420         lw      t2,IntSave(pv)              /* t1 = saved int register count      */
 421         ala     t3,ex_int2                  /* t3 = current pc                    */
 422         sll     t2,t2,2                     /* t2 = register count * 4            */
 423         asubu   t3,t3,t2                    /* t3 = IntSave - 4 * register count  */
 424         jr      t3                          /* jump to save position              */
 425
 426         ald     s0,-8*8(t1)
 427         ald     s1,-7*8(t1)
 428         ald     s2,-6*8(t1)
 429         ald     s3,-5*8(t1)
 430         ald     s4,-4*8(t1)
 431         ald     s5,-3*8(t1)
 432         ald     s6,-2*8(t1)
 433         ald     s7,-1*8(t1)
 434 ex_int2:
 435         sll     t2,t2,1               /* t2 = register count * 4 * 2              */
 436         asubu   t1,t1,t2              /* t1 = t0 - 8 * register count             */
 437
 438         lw      t2,FltSave(pv)        /* t2 = saved flt register count            */
 439         ala     t3,ex_flt2            /* t3 = current pc                          */
 440         sll     t2,t2,2               /* t2 = register count * 4                  */
 441         asubu   t3,t3,t2              /* t3 = ex_int_sav - 4 * register count     */
 442         jr      t3                          /* jump to save position              */
 443
 444         ldc1    fs0,-4*8(t1)
 445         ldc1    fs1,-3*8(t1)
 446         ldc1    fs2,-2*8(t1)
 447         ldc1    fs3,-1*8(t1)
 448
 449 ex_flt2:
 450         lw      t1,FrameSize(pv)            /* get frame size                     */
 451         aaddu   sp,sp,t1                    /* unwind stack                       */
 452         b       L_asm_handle_exception_stack_loop
 453
 454         .end    asm_handle_nat_exception
 455
 456
 457 /* asm_wrapper_patcher *********************************************************
 458
 459    XXX
 460
 461    Stack layout:
 462      40   return address into JIT code (patch position)
 463      32   pointer to virtual java_objectheader
 464      24   machine code (which is patched back later)
 465      16   unresolved class/method/field reference
 466       8   data segment displacement from load instructions
 467       0   patcher function pointer to call
 468
 469 *******************************************************************************/
 470
 471     .ent    asm_wrapper_patcher
 472
 473 asm_wrapper_patcher:
 474         aaddiu  sp,sp,-((2+16+22+4)*8+sizestackframeinfo) /* create stack frame   */
 475
 476         SAVE_RETURN_REGISTERS(0)      /* save 1 int/1 float return registers      */
 477         SAVE_ARGUMENT_REGISTERS(2)    /* save 8 int/8 float argument registers    */
 478         SAVE_TEMPORARY_REGISTERS(18)  /* save 5 int/16 float temporary registers  */
 479
 480         ast     itmp1,(2+16+22+0)*8(sp) /* save itmp1                             */
 481         ast     itmp2,(2+16+22+1)*8(sp) /* save itmp2                             */
 482         ast     ra,(2+16+22+2)*8(sp)  /* save method return address (for leafs)   */
 483         ast     pv,(2+16+22+3)*8(sp)  /* save pv of calling java function         */
 484
 485         aaddiu  a0,sp,(2+16+22+4)*8   /* create stackframe info                   */
 486         move    a1,pv                 /* pass java pv                             */
 487         aaddiu  a2,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* pass java sp        */
 488         move    a3,ra                 /* this is correct for leafs                */
 489         ald     a4,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* pass xpc           */
 490         jal     stacktrace_create_extern_stackframeinfo
 491
 492         aaddiu  a0,sp,((0+2+16+22+4)*8+sizestackframeinfo) /* pass sp             */
 493         ald     itmp3,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* get function    */
 494         ald     itmp1,(2+16+22+3)*8(sp) /* save pv to the position of fp          */
 495         ast     itmp1,((0+2+16+22+4)*8+sizestackframeinfo)(sp)
 496         jalr    itmp3
 497         ast     v0,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* save return value  */
 498
 499         aaddiu  a0,sp,(2+16+22+4)*8   /* remove stackframe info                   */
 500         jal     stacktrace_remove_stackframeinfo
 501
 502         RESTORE_RETURN_REGISTERS(0)   /* restore 1 int/1 float return registers   */
 503         RESTORE_ARGUMENT_REGISTERS(2) /* restore 8 int/8 float argument registers */
 504         RESTORE_TEMPORARY_REGISTERS(18) /* restore 5 int/16 float temporary reg.  */
 505
 506         ald     itmp1,(2+16+22+0)*8(sp) /* restore itmp1                          */
 507         ald     itmp2,(2+16+22+1)*8(sp) /* restore itmp2                          */
 508         ald     ra,(2+16+22+2)*8(sp)  /* restore method return address (for leafs)*/
 509         ald     pv,(2+16+22+3)*8(sp)  /* restore pv of calling java function      */
 510
 511         ald     itmp3,((0+2+16+22+4)*8+sizestackframeinfo)(sp) /* get return value*/
 512         beqz    itmp3,L_asm_wrapper_patcher_exception
 513
 514         ald     itmp3,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* get RA to JIT   */
 515         aaddiu  sp,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* remove stack frame  */
 516
 517         jr      itmp3                 /* jump to new patched code                 */
 518
 519 L_asm_wrapper_patcher_exception:
 520         ald     xpc,((5+2+16+22+4)*8+sizestackframeinfo)(sp) /* RA to JIT is xpc  */
 521         aaddiu  sp,sp,((6+2+16+22+4)*8+sizestackframeinfo) /* remove stack frame  */
 522
 523 #if defined(ENABLE_THREADS)
 524         daddiu  sp,sp,-4*8
 525         sd      xpc,0*8(sp)
 526         sd      ra,1*8(sp)
 527         sd      pv,2*8(sp)
 528         jal     builtin_asm_get_exceptionptrptr
 529         ld      xpc,0*8(sp)
 530         ld      ra,1*8(sp)
 531         ld      pv,2*8(sp)
 532         daddiu  sp,sp,4*8
 533 #else
 534         la      v0,_exceptionptr
 535 #endif
 536         ld      xptr,0(v0)            /* get the exception pointer                */
 537         sd      zero,0(v0)            /* clear the exception pointer              */
 538         b       asm_handle_exception
 539
 540         .end    asm_wrapper_patcher
 541
 542
 543 /* asm_replacement_out *********************************************************
 544
 545    This code is jumped to from the replacement-out stubs that are executed
 546    when a thread reaches an activated replacement point.
 547
 548    The purpose of asm_replacement_out is to read out the parts of the
 549    execution state that cannot be accessed from C code, store this state,
 550    and then call the C function replace_me.
 551
 552    Stack layout:
 553      16                 start of stack inside method to replace
 554       0   rplpoint *    info on the replacement point that was reached
 555
 556    NOTE: itmp3 has been clobbered by the replacement-out stub!
 557
 558 *******************************************************************************/
 559
 560 /* some room to accomodate changes of the stack frame size during replacement */
 561         /* XXX we should find a cleaner solution here */
 562 #define REPLACEMENT_ROOM  512
 563
 564 #define REPLACEMENT_STACK_OFFSET ((sizeexecutionstate + REPLACEMENT_ROOM + 0xf) & ~0xf)
 565
 566         .ent asm_replacement_out
 567
 568 asm_replacement_out:
 569     /* create stack frame */
 570         daddiu  sp,sp,-REPLACEMENT_STACK_OFFSET
 571
 572         /* save registers in execution state */
 573         sd      $0 ,( 0*8+offes_intregs)(sp)
 574         sd      $1 ,( 1*8+offes_intregs)(sp)
 575         sd      $2 ,( 2*8+offes_intregs)(sp)
 576         sd      $3 ,( 3*8+offes_intregs)(sp)
 577         sd      $4 ,( 4*8+offes_intregs)(sp)
 578         sd      $5 ,( 5*8+offes_intregs)(sp)
 579         sd      $6 ,( 6*8+offes_intregs)(sp)
 580         sd      $7 ,( 7*8+offes_intregs)(sp)
 581         sd      $8 ,( 8*8+offes_intregs)(sp)
 582         sd      $9 ,( 9*8+offes_intregs)(sp)
 583         sd      $10,(10*8+offes_intregs)(sp)
 584         sd      $11,(11*8+offes_intregs)(sp)
 585         sd      $12,(12*8+offes_intregs)(sp)
 586         sd      $13,(13*8+offes_intregs)(sp)
 587         sd      $14,(14*8+offes_intregs)(sp)
 588         sd      $15,(15*8+offes_intregs)(sp)
 589         sd      $16,(16*8+offes_intregs)(sp)
 590         sd      $17,(17*8+offes_intregs)(sp)
 591         sd      $18,(18*8+offes_intregs)(sp)
 592         sd      $19,(19*8+offes_intregs)(sp)
 593         sd      $20,(20*8+offes_intregs)(sp)
 594         sd      $21,(21*8+offes_intregs)(sp)
 595         sd      $22,(22*8+offes_intregs)(sp)
 596         sd      $23,(23*8+offes_intregs)(sp)
 597         sd      $24,(24*8+offes_intregs)(sp)
 598         sd      $25,(25*8+offes_intregs)(sp)
 599         sd      $26,(26*8+offes_intregs)(sp)
 600         sd      $27,(27*8+offes_intregs)(sp)
 601         sd      $28,(28*8+offes_intregs)(sp)
 602         sd      $29,(29*8+offes_intregs)(sp)
 603         sd      $30,(30*8+offes_intregs)(sp)
 604         sd      $31,(31*8+offes_intregs)(sp)
 605
 606         sdc1    $f0 ,( 0*8+offes_fltregs)(sp)
 607         sdc1    $f1 ,( 1*8+offes_fltregs)(sp)
 608         sdc1    $f2 ,( 2*8+offes_fltregs)(sp)
 609         sdc1    $f3 ,( 3*8+offes_fltregs)(sp)
 610         sdc1    $f4 ,( 4*8+offes_fltregs)(sp)
 611         sdc1    $f5 ,( 5*8+offes_fltregs)(sp)
 612         sdc1    $f6 ,( 6*8+offes_fltregs)(sp)
 613         sdc1    $f7 ,( 7*8+offes_fltregs)(sp)
 614         sdc1    $f8 ,( 8*8+offes_fltregs)(sp)
 615         sdc1    $f9 ,( 9*8+offes_fltregs)(sp)
 616         sdc1    $f10,(10*8+offes_fltregs)(sp)
 617         sdc1    $f11,(11*8+offes_fltregs)(sp)
 618         sdc1    $f12,(12*8+offes_fltregs)(sp)
 619         sdc1    $f13,(13*8+offes_fltregs)(sp)
 620         sdc1    $f14,(14*8+offes_fltregs)(sp)
 621         sdc1    $f15,(15*8+offes_fltregs)(sp)
 622         sdc1    $f16,(16*8+offes_fltregs)(sp)
 623         sdc1    $f17,(17*8+offes_fltregs)(sp)
 624         sdc1    $f18,(18*8+offes_fltregs)(sp)
 625         sdc1    $f19,(19*8+offes_fltregs)(sp)
 626         sdc1    $f20,(20*8+offes_fltregs)(sp)
 627         sdc1    $f21,(21*8+offes_fltregs)(sp)
 628         sdc1    $f22,(22*8+offes_fltregs)(sp)
 629         sdc1    $f23,(23*8+offes_fltregs)(sp)
 630         sdc1    $f24,(24*8+offes_fltregs)(sp)
 631         sdc1    $f25,(25*8+offes_fltregs)(sp)
 632         sdc1    $f26,(26*8+offes_fltregs)(sp)
 633         sdc1    $f27,(27*8+offes_fltregs)(sp)
 634         sdc1    $f28,(28*8+offes_fltregs)(sp)
 635         sdc1    $f29,(29*8+offes_fltregs)(sp)
 636         sdc1    $f30,(30*8+offes_fltregs)(sp)
 637         sdc1    $f31,(31*8+offes_fltregs)(sp)
 638
 639         /* calculate sp of method */
 640         daddiu  itmp1,sp,(REPLACEMENT_STACK_OFFSET + 2*8)
 641         sd      itmp1,(offes_sp)(sp)
 642
 643         /* store pv */
 644         sd      pv,(offes_pv)(sp)
 645
 646         /* call replace_me */
 647         ld      a0,-(2*8)(itmp1)            /* arg0: rplpoint *                   */
 648     move    a1,sp                       /* arg1: execution state              */
 649     jal     replace_me                  /* call C function replace_me         */
 650         jal     abort                       /* NEVER REACHED                      */
 651
 652         .end asm_replacement_out
 653
 654 /* asm_replacement_in **********************************************************
 655
 656    This code writes the given execution state and jumps to the replacement
 657    code.
 658
 659    This function never returns!
 660
 661    NOTE: itmp3 is not restored!
 662
 663    C prototype:
 664       void asm_replacement_in(executionstate *es);
 665
 666 *******************************************************************************/
 667
 668         .ent asm_replacement_in
 669
 670 asm_replacement_in:
 671         /* a0 == executionstate *es */
 672
 673         /* set new sp and pv */
 674         ld      sp,(offes_sp)(a0)
 675         ld      pv,(offes_pv)(a0)
 676
 677         /* copy registers from execution state */
 678         /* $0 is zero                     */
 679         ld      $1 ,( 1*8+offes_intregs)(a0)
 680         ld      $2 ,( 2*8+offes_intregs)(a0)
 681         ld      $3 ,( 2*8+offes_intregs)(a0)
 682         /* a0 is loaded below             */
 683         ld      $5 ,( 5*8+offes_intregs)(a0)
 684         ld      $6 ,( 6*8+offes_intregs)(a0)
 685         ld      $7 ,( 7*8+offes_intregs)(a0)
 686         ld      $8 ,( 8*8+offes_intregs)(a0)
 687         ld      $9 ,( 9*8+offes_intregs)(a0)
 688         ld      $10,(10*8+offes_intregs)(a0)
 689         ld      $11,(11*8+offes_intregs)(a0)
 690         ld      $12,(12*8+offes_intregs)(a0)
 691         ld      $13,(13*8+offes_intregs)(a0)
 692         ld      $14,(14*8+offes_intregs)(a0)
 693         ld      $15,(15*8+offes_intregs)(a0)
 694         ld      $16,(16*8+offes_intregs)(a0)
 695         ld      $17,(17*8+offes_intregs)(a0)
 696         ld      $18,(18*8+offes_intregs)(a0)
 697         ld      $19,(19*8+offes_intregs)(a0)
 698         ld      $20,(20*8+offes_intregs)(a0)
 699         ld      $21,(21*8+offes_intregs)(a0)
 700         ld      $22,(22*8+offes_intregs)(a0)
 701         ld      $23,(23*8+offes_intregs)(a0)
 702         ld      $24,(24*8+offes_intregs)(a0)
 703         ld      $25,(25*8+offes_intregs)(a0)
 704         ld      $26,(26*8+offes_intregs)(a0)
 705         ld      $27,(27*8+offes_intregs)(a0)
 706         ld      $28,(28*8+offes_intregs)(a0)
 707         /* $29 is sp                      */
 708         /* $30 is pv                      */
 709         ld      $31,(31*8+offes_intregs)(a0)
 710
 711         ldc1    $f0 ,( 0*8+offes_fltregs)(a0)
 712         ldc1    $f1 ,( 1*8+offes_fltregs)(a0)
 713         ldc1    $f2 ,( 2*8+offes_fltregs)(a0)
 714         ldc1    $f3 ,( 3*8+offes_fltregs)(a0)
 715         ldc1    $f4 ,( 4*8+offes_fltregs)(a0)
 716         ldc1    $f5 ,( 5*8+offes_fltregs)(a0)
 717         ldc1    $f6 ,( 6*8+offes_fltregs)(a0)
 718         ldc1    $f7 ,( 7*8+offes_fltregs)(a0)
 719         ldc1    $f8 ,( 8*8+offes_fltregs)(a0)
 720         ldc1    $f9 ,( 9*8+offes_fltregs)(a0)
 721         ldc1    $f10,(10*8+offes_fltregs)(a0)
 722         ldc1    $f11,(11*8+offes_fltregs)(a0)
 723         ldc1    $f12,(12*8+offes_fltregs)(a0)
 724         ldc1    $f13,(13*8+offes_fltregs)(a0)
 725         ldc1    $f14,(14*8+offes_fltregs)(a0)
 726         ldc1    $f15,(15*8+offes_fltregs)(a0)
 727         ldc1    $f16,(16*8+offes_fltregs)(a0)
 728         ldc1    $f17,(17*8+offes_fltregs)(a0)
 729         ldc1    $f18,(18*8+offes_fltregs)(a0)
 730         ldc1    $f19,(19*8+offes_fltregs)(a0)
 731         ldc1    $f20,(20*8+offes_fltregs)(a0)
 732         ldc1    $f21,(21*8+offes_fltregs)(a0)
 733         ldc1    $f22,(22*8+offes_fltregs)(a0)
 734         ldc1    $f23,(23*8+offes_fltregs)(a0)
 735         ldc1    $f24,(24*8+offes_fltregs)(a0)
 736         ldc1    $f25,(25*8+offes_fltregs)(a0)
 737         ldc1    $f26,(26*8+offes_fltregs)(a0)
 738         ldc1    $f27,(27*8+offes_fltregs)(a0)
 739         ldc1    $f28,(28*8+offes_fltregs)(a0)
 740         ldc1    $f29,(29*8+offes_fltregs)(a0)
 741         ldc1    $f30,(30*8+offes_fltregs)(a0)
 742         ldc1    $f31,(31*8+offes_fltregs)(a0)
 743
 744         /* load new pc */
 745
 746         ld      itmp3,offes_pc(a0)
 747
 748         /* load a0 */
 749
 750         ld      a0,(4*8+offes_intregs)(a0)
 751
 752         /* jump to new code */
 753
 754         jr      itmp3
 755
 756         .end asm_replacement_in
 757
 758 /******************* function asm_initialize_thread_stack **********************
 759 *                                                                              *
 760 *   u1* asm_initialize_thread_stack (void *func, u1 *stack);                   *
 761 *                                                                              *
 762 *   initialize a thread stack                                                  *
 763 *                                                                              *
 764 *******************************************************************************/
 765
 766         .ent    asm_initialize_thread_stack
 767
 768 asm_initialize_thread_stack:
 769         aaddiu  a1,a1,-14*8     /* allocate save area                             */
 770         sd      zero, 0*8(a1)   /* s0 initalize thread area                       */
 771         sd      zero, 1*8(a1)   /* s1                                             */
 772         sd      zero, 2*8(a1)   /* s2                                             */
 773         sd      zero, 3*8(a1)   /* s3                                             */
 774         sd      zero, 4*8(a1)   /* s4                                             */
 775         sd      zero, 5*8(a1)   /* s5                                             */
 776         sd      zero, 6*8(a1)   /* s6                                             */
 777         sd      zero, 7*8(a1)   /* s7                                             */
 778         sd      zero, 8*8(a1)   /* s8                                             */
 779         sd      zero, 9*8(a1)   /* fs0                                            */
 780         sd      zero,10*8(a1)   /* fs1                                            */
 781         sd      zero,11*8(a1)   /* fs2                                            */
 782         sd      zero,12*8(a1)   /* fs3                                            */
 783         sd      a0, 13*8(a1)
 784         move    v0,a1
 785         j       ra              /* return                                         */
 786
 787         .end    asm_initialize_thread_stack
 788
 789
 790 /******************* function asm_perform_threadswitch *************************
 791 *                                                                              *
 792 *   void asm_perform_threadswitch (u1 **from, u1 **to, u1 **stackTop);         *
 793 *                                                                              *
 794 *   performs a threadswitch                                                    *
 795 *                                                                              *
 796 *******************************************************************************/
 797
 798         .ent    asm_perform_threadswitch
 799
 800 asm_perform_threadswitch:
 801         aaddiu  sp,sp,-14*8     /* allocate new stack                             */
 802         sd      s0,  0*8(sp)    /* save saved registers of old thread             */
 803         sd      s1,  1*8(sp)
 804         sd      s2,  2*8(sp)
 805         sd      s3,  3*8(sp)
 806         sd      s4,  4*8(sp)
 807         sd      s5,  5*8(sp)
 808         sd      s6,  6*8(sp)
 809         sd      s7,  7*8(sp)
 810         sd      s8,  8*8(sp)
 811         sdc1    fs0, 9*8(sp)
 812         sdc1    fs1,10*8(sp)
 813         sdc1    fs2,11*8(sp)
 814         sdc1    fs3,12*8(sp)
 815         sd      ra, 13*8(sp)
 816         ast     sp,0(a0)        /* save old stack pointer                         */
 817         ast     sp,0(a2)        /* stackTop = old stack pointer                   */
 818         ald     sp,0(a1)        /* load new stack pointer                         */
 819         ld      s0,  0*8(sp)    /* load saved registers of new thread             */
 820         ld      s1,  1*8(sp)
 821         ld      s2,  2*8(sp)
 822         ld      s3,  3*8(sp)
 823         ld      s4,  4*8(sp)
 824         ld      s5,  5*8(sp)
 825         ld      s6,  6*8(sp)
 826         ld      s7,  7*8(sp)
 827         ld      s8,  8*8(sp)
 828         ldc1    fs0, 9*8(sp)
 829         ldc1    fs1,10*8(sp)
 830         ldc1    fs2,11*8(sp)
 831         ldc1    fs3,12*8(sp)
 832         ld      ra, 13*8(sp)
 833         aaddiu  sp,sp,14*8      /* deallocate new stack                           */
 834         move    itmp3, ra
 835         j       ra              /* return                                         */
 836
 837         .end    asm_perform_threadswitch
 838
 839
 840 /********************* function asm_switchstackandcall *************************
 841 *                                                                              *
 842 *  void asm_switchstackandcall (void *stack, void *func, void **stacktopsave); *
 843 *                                                                              *
 844 *   Switches to a new stack, calls a function and switches back.               *
 845 *       a0      new stack pointer                                              *
 846 *       a1      function pointer                                               *
 847 *               a2              pointer to variable where stack top should be stored           *
 848 *                                                                              *
 849 *******************************************************************************/
 850
 851         .ent    asm_switchstackandcall
 852
 853 asm_switchstackandcall:
 854         aaddiu  a0,a0,-16       /* allocate new stack                             */
 855         sd      ra,0(a0)        /* save return address on new stack               */
 856         sd      sp,8(a0)        /* save old stack pointer on new stack            */
 857         sd      sp,0(a2)        /* save old stack pointer to variable             */
 858         move    sp,a0           /* switch to new stack                            */
 859
 860         move    itmp3,a1
 861         move    a0,a3
 862         jalr    itmp3           /* and call function                              */
 863
 864         ld      ra,0(sp)        /* load return address                            */
 865         ld      sp,8(sp)        /* switch to old stack                            */
 866
 867         j       ra              /* return                                         */
 868
 869         .end    asm_switchstackandcall
 870
 871
 872         .ent    asm_getclassvalues_atomic
 873
 874 asm_getclassvalues_atomic:
 875 _crit_restart:
 876 _crit_begin:
 877         lw      t0,offbaseval(a0)
 878         lw      t1,offdiffval(a0)
 879         lw      t2,offbaseval(a1)
 880 _crit_end:
 881         sw      t0,offcast_super_baseval(a2)
 882         sw      t1,offcast_super_diffval(a2)
 883         sw      t2,offcast_sub_baseval(a2)
 884         j       ra
 885
 886         .end    asm_getclassvalues_atomic
 887
 888     .data
 889
 890 asm_criticalsections:
 891 #if defined(ENABLE_THREADS)
 892     .dword  _crit_begin
 893     .dword  _crit_end
 894     .dword  _crit_restart
 895 #endif
 896     .dword  0
 897
 898
 899         .text
 900
 901         .ent    compare_and_swap
 902
 903 compare_and_swap:
 904 1:
 905         all     v0,0(a0)
 906         bne     v0,a1,2f
 907         move    t0,a2
 908         asc     t0,0(a0)
 909         beqz    t0,1b
 910 2:
 911         sync
 912         j       ra
 913
 914         .end    compare_and_swap
 915
 916
 917 /* Disable exec-stacks, required for Gentoo ***********************************/
 918
 919 #if defined(__GCC__) && defined(__ELF__)
 920         .section .note.GNU-stack,"",@progbits
 921 #endif
 922
 923
 924 /*
 925  * These are local overrides for various environment variables in Emacs.
 926  * Please do not remove this and leave it at the end of the file, where
 927  * Emacs will automagically detect them.
 928  * ---------------------------------------------------------------------
 929  * Local variables:
 930  * mode: asm
 931  * indent-tabs-mode: t
 932  * c-basic-offset: 4
 933  * tab-width: 4
 934  * End:
 935  * vim:noexpandtab:sw=4:ts=4:
 936  */