src/vm/jit/i386/asmpart.S

   1 /* src/vm/jit/i386/asmpart.S - Java-C interface functions for i386
   2
   3    Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25 */
  26
  27
  28 #include "config.h"
  29
  30 #include "md-asm.h"
  31
  32 #include "vm/jit/i386/arch.h"
  33 #include "vm/jit/i386/md-abi.h"
  34
  35 #include "vm/jit/abi-asm.h"
  36 #include "vm/jit/methodheader.h"
  37
  38
  39         .text
  40
  41
  42 /* export functions ***********************************************************/
  43
  44         .globl asm_md_init
  45
  46         .globl asm_vm_call_method
  47         .globl asm_vm_call_method_int
  48         .globl asm_vm_call_method_long
  49         .globl asm_vm_call_method_float
  50         .globl asm_vm_call_method_double
  51         .globl asm_vm_call_method_exception_handler
  52         .globl asm_vm_call_method_end
  53
  54         .globl asm_handle_nat_exception
  55         .globl asm_handle_exception
  56
  57         .globl asm_abstractmethoderror
  58
  59         .globl asm_builtin_f2i
  60         .globl asm_builtin_f2l
  61         .globl asm_builtin_d2i
  62         .globl asm_builtin_d2l
  63
  64         .globl asm_compare_and_swap
  65         .globl asm_memory_barrier
  66
  67         .globl asm_get_cycle_count
  68
  69
  70 /* asm_md_init *****************************************************************
  71
  72    Initialize machine dependent stuff.
  73
  74    See: http://www.srware.com/linux_numerics.txt
  75
  76    This puts the X86 FPU in 64-bit precision mode.  The default under
  77    Linux is to use 80-bit mode, which produces subtle differences from
  78    FreeBSD and other systems, eg, (int)(1000*atof("0.3")) is 300 in
  79    64-bit mode, 299 in 80-bit mode.
  80
  81    Fixes: http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=350729
  82
  83 *******************************************************************************/
  84
  85 asm_md_init:
  86         sub     $4,sp                       /* allocate space for the FPU state   */
  87         fnstcw  (sp)                        /* get the FPU state                  */
  88         mov     (sp),%eax
  89         and     $0xfcff,%ax                 /* remove the extended mode flag      */
  90         or      $0x0200,%ax                 /* put the double mode flag           */
  91         mov     %eax,(sp)                   /* store new FPU state                */
  92         fldcw   (sp)                        /* setup new FPU state                */
  93         add     $4,sp
  94         ret
  95
  96
  97 /********************* function asm_calljavafunction ***************************
  98 *                                                                              *
  99 *   This function calls a Java-method (which possibly needs compilation)       *
 100 *   with up to 4 address parameters.                                           *
 101 *                                                                              *
 102 *   This functions calls the JIT-compiler which eventually translates the      *
 103 *   method into machine code.                                                  *
 104 *                                                                              *
 105 *   C-prototype:                                                               *
 106 *    javaobject_header *asm_vm_call_method(methodinfo *m,                      *
 107 *         u4 count, u4 size, void *callblock);                                 *
 108 *                                                                              *
 109 *******************************************************************************/
 110
 111         .align  8
 112
 113         .long   0                           /* catch type all                     */
 114         .long   0                           /* handler pc                         */
 115         .long   0                           /* end pc                             */
 116         .long   0                           /* start pc                           */
 117         .long   1                           /* extable size                       */
 118         .long   0                           /* line number table start            */
 119         .long   0                           /* line number table size             */
 120         .long   0                           /* fltsave                            */
 121         .long   0                           /* intsave                            */
 122         .long   0                           /* isleaf                             */
 123         .long   0                           /* frame size                         */
 124         .long   0                           /* codeinfo pointer                   */
 125
 126 asm_vm_call_method:
 127 asm_vm_call_method_int:
 128 asm_vm_call_method_long:
 129 asm_vm_call_method_float:
 130 asm_vm_call_method_double:
 131         push    bp
 132         mov     sp,bp                       /* save stackptr                      */
 133         sub     $(4*4),sp                   /* create stackframe                  */
 134         and     $0xfffffff0,sp              /* align stack to 16-byte             */
 135
 136         mov     t0,0*4(sp)                  /* save registers                     */
 137         mov     s1,1*4(sp)
 138         mov     s2,2*4(sp)
 139
 140         mov     sp,s1                       /* save stack pointer                 */
 141
 142         mov     3*4(bp),t0                  /* address of data structure          */
 143         mov     4*4(bp),itmp1               /* number of stack arguments          */
 144
 145         cmp     $0,itmp1
 146         je      L_asm_vm_call_method_stack_copy_done
 147
 148         mov     itmp1,itmp2
 149         add     $1,itmp2                    /* keep stack 16-byte aligned         */
 150         and     $0xfffffffe,itmp2
 151         shl     $3,itmp2                    /* calculate stack size               */
 152         sub     itmp2,sp                    /* create stack frame                 */
 153         mov     sp,itmp2                    /* temporary stack pointer            */
 154
 155 L_asm_vm_call_method_stack_copy_loop:
 156         mov     0(t0),itmp3                 /* load argument                      */
 157         mov     itmp3,0(itmp2)              /* store argument on stack            */
 158         mov     4(t0),itmp3
 159         mov     itmp3,4(itmp2)
 160
 161         sub     $1,itmp1                    /* subtract 1 argument                */
 162         add     $8,t0                       /* set address of next argument       */
 163         add     $8,itmp2                    /* increase SP                        */
 164
 165         cmp     $0,itmp1
 166         jg      L_asm_vm_call_method_stack_copy_loop
 167
 168 L_asm_vm_call_method_stack_copy_done:
 169         lea     (2*4-256)(bp),mptr          /* We subtract 256 to force the next  */
 170                                             /* move instruction to have a 32-bit  */
 171                                             /* offset.                            */
 172
 173         mov     (0*4+256)(mptr),itmp3       /* method call as in Java             */
 174         call    *itmp3                      /* call JIT compiler                  */
 175
 176 L_asm_vm_call_method_return:
 177         mov     s1,sp                       /* restore stackpointer               */
 178
 179         mov     0*4(sp),t0                  /* restore registers                  */
 180         mov     1*4(sp),s1
 181         mov     2*4(sp),s2
 182
 183         leave
 184         ret
 185
 186 asm_vm_call_method_exception_handler:
 187         push    xptr                        /* pass exception pointer             */
 188         call    builtin_throw_exception
 189         add     $4,sp
 190 asm_vm_call_method_end:
 191         jmp     L_asm_vm_call_method_return
 192
 193
 194 /* asm_handle_exception ********************************************************
 195 *                                                                              *
 196 *   This function handles an exception. It does not use the usual calling      *
 197 *   conventions. The exception pointer is passed in REG_ITMP1 and the          *
 198 *   pc from the exception raising position is passed in REG_ITMP2. It searches *
 199 *   the local exception table for a handler. If no one is found, it unwinds    *
 200 *   stacks and continues searching the callers.                                *
 201 *                                                                              *
 202 *******************************************************************************/
 203
 204 asm_handle_nat_exception:
 205         add     $4,sp                       /* clear return address of native stub*/
 206
 207 asm_handle_exception:
 208 L_asm_handle_exception:                 /* required for PIC code              */
 209         sub     $((ARG_CNT+TMP_CNT+3)*4),sp /* keep stack 16-byte aligned         */
 210
 211         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 212         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 213
 214         mov     $((ARG_CNT+TMP_CNT+3)*4),itmp3 /* prepare a3 for handle_exception */
 215         mov     $1,t0                       /* set maybe-leaf flag                */
 216
 217 L_asm_handle_exception_stack_loop:
 218         sub     $(12*4),sp                  /* keep stack 16-byte aligned         */
 219         mov     xptr,4*4(sp)                /* save exception pointer             */
 220         mov     xpc,5*4(sp)                 /* save exception pc                  */
 221         add     sp,itmp3                    /* calculate Java sp into a3...       */
 222         add     $(12*4),itmp3
 223         mov     itmp3,7*4(sp)               /* ...and save it                     */
 224         mov     t0,8*4(sp)                  /* save maybe-leaf flag               */
 225
 226         mov     xpc,0*4(sp)                 /* pass exception pc                  */
 227         call    codegen_get_pv_from_pc
 228         mov     v0,6*4(sp)                  /* save data segment pointer          */
 229
 230         mov     4*4(sp),itmp3               /* pass exception pointer             */
 231         mov     itmp3,0*4(sp)
 232         mov     5*4(sp),itmp3               /* pass exception pc                  */
 233         mov     itmp3,1*4(sp)
 234         mov     v0,2*4(sp)                  /* pass data segment pointer          */
 235         mov     7*4(sp),itmp3               /* pass Java stack pointer            */
 236         mov     itmp3,3*4(sp)
 237         call    exceptions_handle_exception
 238
 239         test    v0,v0
 240         jz      L_asm_handle_exception_not_catched
 241
 242         mov     v0,xpc                      /* move handlerpc into xpc            */
 243         mov     4*4(sp),xptr                /* restore exception pointer          */
 244         mov     8*4(sp),t0                  /* get maybe-leaf flag                */
 245         add     $(12*4),sp                  /* free stackframe                    */
 246
 247         test    t0,t0                       /* test for maybe-leaf flag           */
 248         jz      L_asm_handle_exception_no_leaf
 249
 250         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 251         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 252
 253         add     $((ARG_CNT+TMP_CNT+3)*4),sp /* remove maybe-leaf stackframe       */
 254
 255 L_asm_handle_exception_no_leaf:
 256         jmp     *xpc                        /* jump to exception handler          */
 257
 258 L_asm_handle_exception_not_catched:
 259         mov     4*4(sp),xptr                /* restore exception pointer          */
 260         mov     6*4(sp),itmp3               /* restore data segment pointer       */
 261         mov     8*4(sp),t0                  /* get maybe-leaf flag                */
 262         add     $(12*4),sp                  /* free stackframe                    */
 263
 264         test    t0,t0
 265         jz      L_asm_handle_exception_no_leaf_stack
 266
 267         add     $((ARG_CNT+TMP_CNT+3)*4),sp /* remove maybe-leaf stackframe       */
 268         xor     t0,t0                       /* clear the maybe-leaf flag          */
 269
 270 L_asm_handle_exception_no_leaf_stack:
 271         mov     FrameSize(itmp3),itmp2      /* get frame size                     */
 272         add     sp,itmp2                    /* pointer to save area               */
 273
 274         push    xptr                        /* we are out of registers            */
 275
 276         mov     IntSave(itmp3),itmp1        /* itmp1 = saved int register count   */
 277         test    itmp1,itmp1
 278         je      noint
 279
 280         cmp     $1,itmp1
 281         je      int1
 282         cmp     $2,itmp1
 283         je      int2
 284
 285         mov     -3*8(itmp2),s0
 286 int2:
 287         mov     -2*8(itmp2),s1
 288 int1:
 289         mov     -1*8(itmp2),s2
 290
 291         shl     $2,itmp1                    /* multiply by 4 bytes                */
 292         sub     itmp1,itmp2
 293
 294 noint:
 295 #if 0
 296         mov     FltSave(itmp3),itmp1        /* itmp1 = saved flt register count   */
 297         test    itmp1,itmp1
 298         je      noflt
 299
 300         cmp     $1,itmp1
 301         je      flt1
 302         cmp     $2,itmp1
 303         je      flt2
 304         cmp     $3,itmp1
 305         je      flt3
 306
 307         fldl    -4*8(itmp2)
 308         fstp    %st(1)
 309 flt3:
 310         fldl    -3*8(itmp2)
 311         fstp    %st(2)
 312 flt2:
 313         fldl    -2*8(itmp2)
 314         fstp    %st(3)
 315 flt1:
 316         fldl    -1*8(itmp2)
 317         fstp    %st(4)
 318
 319 noflt:
 320 #endif
 321         pop     xptr                        /* restore exception pointer          */
 322         mov     FrameSize(itmp3),itmp2      /* get frame size                     */
 323         add     itmp2,sp                    /* unwind stack                       */
 324
 325         pop     xpc                         /* the new xpc is return address      */
 326         sub     $2,xpc                      /* subtract 2-bytes for call          */
 327
 328         xor     itmp3,itmp3                 /* prepare a3 for handle_exception    */
 329
 330         jmp     L_asm_handle_exception_stack_loop
 331
 332
 333 /* asm_abstractmethoderror *****************************************************
 334
 335    Creates and throws an AbstractMethodError.
 336
 337 *******************************************************************************/
 338
 339 asm_abstractmethoderror:
 340         sub     $(3*4),sp                   /* keep stack 16-byte aligned         */
 341         mov     sp,itmp1                    /* pass java sp                       */
 342         add     $((1+3)*4),itmp1
 343         mov     itmp1,0*4(sp)
 344         mov     3*4(sp),itmp2               /* pass exception address             */
 345         sub     $2,itmp2
 346         mov     itmp2,1*4(sp)
 347         call    exceptions_asm_new_abstractmethoderror
 348                                             /* exception pointer is return value  */
 349         add     $(3*4),sp                   /* remove stack frame                 */
 350
 351         pop     xpc                         /* get exception address              */
 352         sub     $2,xpc                      /* exception address is ra - 2        */
 353         jmp     L_asm_handle_exception
 354
 355
 356 /************************ function asm_builtin_x2x *****************************
 357 *                                                                              *
 358 *   Wrapper functions for corner cases                                         *
 359 *                                                                              *
 360 *******************************************************************************/
 361
 362 asm_builtin_f2i:
 363         sub     $(3*4),%esp
 364         fsts    (%esp)
 365         call    builtin_f2i
 366         add     $(3*4),%esp
 367         ret
 368
 369 asm_builtin_d2i:
 370         sub     $(3*4),%esp
 371         fstl    (%esp)
 372         call    builtin_d2i
 373         add     $(3*4),%esp
 374         ret
 375
 376 asm_builtin_f2l:
 377         sub     $(3*4),%esp
 378         fsts    (%esp)
 379         call    builtin_f2l
 380         add     $(3*4),%esp
 381         ret
 382
 383 asm_builtin_d2l:
 384         sub     $(3*4),%esp
 385         fstl    (%esp)
 386         call    builtin_d2l
 387         add     $(3*4),%esp
 388         ret
 389
 390
 391 /* asm_compare_and_swap ********************************************************
 392
 393    Does an atomic compare and swap.  Required for the lock
 394    implementation.
 395
 396    Atomically do the following: Check if the location still contains
 397    `oldval`. If so, replace it by `newval` and return `oldval`.
 398
 399    RETURN VALUE:
 400        the old value at *p
 401
 402    long compare_and_swap(volatile long *p, long oldval, long newval);
 403
 404 *******************************************************************************/
 405
 406 asm_compare_and_swap:
 407         mov     1*4(sp),%ecx            /* load p into a register                 */
 408         mov     2*4(sp),%eax            /* load oldval into return register       */
 409         mov     3*4(sp),%edx            /* load newval into a register            */
 410         lock; cmpxchgl %edx,0(%ecx)
 411         ret
 412
 413
 414 /* asm_memory_barrier **********************************************************
 415
 416    A memory barrier for the Java Memory Model.
 417
 418 *******************************************************************************/
 419
 420 asm_memory_barrier:
 421         lock; add $0,0(sp)
 422         ret
 423
 424
 425 /* asm_get_cycle_count *********************************************************
 426
 427    Get the current time-stamp counter from the CPU.
 428
 429 *******************************************************************************/
 430
 431 asm_get_cycle_count:
 432         rdtsc
 433         ret
 434
 435
 436 /* disable exec-stacks ********************************************************/
 437
 438 #if defined(__linux__) && defined(__ELF__)
 439         .section .note.GNU-stack,"",%progbits
 440 #endif
 441
 442
 443 /*
 444  * These are local overrides for various environment variables in Emacs.
 445  * Please do not remove this and leave it at the end of the file, where
 446  * Emacs will automagically detect them.
 447  * ---------------------------------------------------------------------
 448  * Local variables:
 449  * mode: asm
 450  * indent-tabs-mode: t
 451  * c-basic-offset: 4
 452  * tab-width: 4
 453  * End:
 454  * vim:noexpandtab:sw=4:ts=4:
 455  */