1 /* src/vm/jit/alpha/asmpart.S - Java-C interface functions for alpha
3 Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
4 C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
5 E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
6 J. Wenninger, Institut f. Computersprachen - TU Wien
8 This file is part of CACAO.
10 This program is free software; you can redistribute it and/or
11 modify it under the terms of the GNU General Public License as
12 published by the Free Software Foundation; either version 2, or (at
13 your option) any later version.
15 This program is distributed in the hope that it will be useful, but
16 WITHOUT ANY WARRANTY; without even the implied warranty of
17 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
18 General Public License for more details.
20 You should have received a copy of the GNU General Public License
21 along with this program; if not, write to the Free Software
22 Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
25 Contact: cacao@cacaojvm.org
27 Authors: Andreas Krall
30 Changes: Joseph Wenninger
34 $Id: asmpart.S 5072 2006-07-03 14:06:05Z twisti $
41 #include "vm/jit/alpha/md-abi.h"
42 #include "vm/jit/alpha/md-asm.h"
43 #include "vm/jit/alpha/offsets.h"
45 #include "vm/jit/abi-asm.h"
46 #include "vm/jit/methodheader.h"
54 /* export functions ***********************************************************/
56 .globl asm_vm_call_method
57 .globl asm_vm_call_method_int
58 .globl asm_vm_call_method_long
59 .globl asm_vm_call_method_float
60 .globl asm_vm_call_method_double
61 .globl asm_vm_call_method_exception_handler
63 .globl asm_call_jit_compiler
65 .globl asm_handle_exception
66 .globl asm_handle_nat_exception
68 .globl asm_abstractmethoderror
70 .globl asm_wrapper_patcher
72 .globl asm_replacement_out
73 .globl asm_replacement_in
75 .globl asm_criticalsections
76 .globl asm_getclassvalues_atomic
82 /* asm_vm_call_method **********************************************************
84 * This function calls a Java-method (which possibly needs compilation) *
85 * with up to 4 address parameters. *
87 * This functions calls the JIT-compiler which eventually translates the *
88 * method into machine code. *
91 * javaobject_header *asm_calljavafunction (methodinfo *m, *
92 * void *arg1, void *arg2, void *arg3, void *arg4); *
94 *******************************************************************************/
96 .ent asm_vm_call_method
100 .quad 0 /* catch type all */
101 .quad 0 /* handler pc */
103 .quad 0 /* start pc */
104 .long 1 /* extable size */
105 .long 0 /* ALIGNMENT PADDING */
106 .quad 0 /* line number table start */
107 .quad 0 /* line number table size */
108 .long 0 /* ALIGNMENT PADDING */
109 .long 0 /* fltsave */
110 .long 1 /* intsave */
113 .long 0 /* frame size */
114 .quad 0 /* codeinfo pointer */
117 asm_vm_call_method_int:
118 asm_vm_call_method_long:
119 asm_vm_call_method_float:
120 asm_vm_call_method_double:
122 lda sp,-5*8(sp) /* allocate stack space */
123 stq ra,0*8(sp) /* save return address */
124 stq gp,1*8(sp) /* save global pointer */
127 stq a0,4*8(sp) /* save method pointer for compiler */
129 mov a2,t0 /* pointer to arg block */
130 mov a1,s6 /* arg count */
132 ble s6,calljava_argsloaded
134 ldq a0,offvmargdata(t0)
135 ldt $f16,offvmargdata(t0)
136 ble s6,calljava_argsloaded
139 ldq a1,offvmargdata+sizevmarg*1(t0)
140 ldt $f17,offvmargdata+sizevmarg*1(t0)
141 ble s6,calljava_argsloaded
144 ldq a2,offvmargdata+sizevmarg*2(t0)
145 ldt $f18,offvmargdata+sizevmarg*2(t0)
146 ble s6,calljava_argsloaded
149 ldq a3,offvmargdata+sizevmarg*3(t0)
150 ldt $f19,offvmargdata+sizevmarg*3(t0)
151 ble s6,calljava_argsloaded
154 ldq a4,offvmargdata+sizevmarg*4(t0)
155 ldt $f20,offvmargdata+sizevmarg*4(t0)
156 ble s6,calljava_argsloaded
159 ldq a5,offvmargdata+sizevmarg*5(t0)
160 ldt $f21,offvmargdata+sizevmarg*5(t0)
163 ble s6,calljava_nocopy
169 ldq t3,offvmargdata+sizevmarg*6(t0)
174 bne t1,calljava_copyloop
177 ldq itmp1,4*8(t4) /* pass method pointer via itmp1 */
179 lda mptr,asm_call_jit_compiler/* fake virtual function call (2 instr) */
180 stq mptr,2*8(t4) /* store function address */
181 lda mptr,1*8(t4) /* set method pointer */
183 ldq pv,1*8(mptr) /* method call as in Java */
184 jmp ra,(pv) /* call JIT compiler */
186 lda pv,(asm_vm_call_method - calljava_jit2)(ra)
190 ldq ra,0*8(sp) /* restore return address */
191 ldq gp,1*8(sp) /* restore global pointer */
193 lda sp,5*8(sp) /* free stack space */
198 asm_vm_call_method_exception_handler:
200 ldq gp,1*8(sp) /* restore global pointer */
202 jsr ra,builtin_throw_exception
203 ldq ra,0*8(sp) /* restore return address */
205 lda sp,5*8(sp) /* free stack space */
208 .end asm_vm_call_method
211 /* asm_call_jit_compiler *******************************************************
213 Invokes the compiler for untranslated Java methods.
215 *******************************************************************************/
217 .ent asm_call_jit_compiler
219 asm_call_jit_compiler:
221 lda sp,-(ARG_CNT+2)*8(sp) /* +2: keep stack 16-byte aligned */
223 stq ra,0*8(sp) /* save return address */
225 SAVE_ARGUMENT_REGISTERS(1) /* save 6 int/6 float argument registers */
227 mov itmp1,a0 /* pass methodinfo pointer */
228 mov mptr,a1 /* pass method pointer */
229 lda a2,(ARG_CNT+2)*8(sp) /* pass java sp */
231 jsr ra,jit_asm_compile /* call jit compiler */
234 ldq ra,0*8(sp) /* load return address */
236 RESTORE_ARGUMENT_REGISTERS(1) /* restore 6 int/6 float argument registers */
238 lda sp,(ARG_CNT+2)*8(sp) /* remove stack frame */
240 beq pv,L_asm_call_jit_compiler_exception
242 jmp zero,(pv) /* and call method, the method returns */
243 /* directly to the caller (ra). */
245 L_asm_call_jit_compiler_exception:
247 stq ra,0*8(sp) /* save return address (xpc) */
248 jsr ra,exceptions_get_and_clear_exception
249 ldq ra,0*8(sp) /* restore return address (xpc) */
252 mov v0,xptr /* get exception */
253 subq ra,4,xpc /* exception address is ra - 4 */
254 br L_asm_handle_nat_exception
256 .end asm_call_jit_compiler
259 /* asm_handle_exception ********************************************************
261 This function handles an exception. It does not use the usual calling
262 conventions. The exception pointer is passed in REG_ITMP1 and the
263 pc from the exception raising position is passed in REG_ITMP2. It searches
264 the local exception table for a handler. If no one is found, it unwinds
265 stacks and continues searching the callers.
267 ATTENTION: itmp3 == gp!
269 *******************************************************************************/
271 .ent asm_handle_nat_exception
273 asm_handle_nat_exception:
274 L_asm_handle_nat_exception: /* required for PIC code */
275 ldl t0,0(ra) /* load instruction LDA PV,xxx(RA) */
277 sra t0,48,t0 /* isolate offset */
278 addq t0,ra,pv /* compute update address */
279 ldl t0,4(ra) /* load instruction LDAH PV,xxx(PV) */
280 srl t0,16,t0 /* isolate instruction code */
281 lda t0,-0x177b(t0) /* test for LDAH */
282 bne t0,L_asm_handle_exception
283 ldl t0,4(ra) /* load instruction LDAH PV,xxx(PV) */
284 sll t0,16,t0 /* compute high offset */
285 addl t0,0,t0 /* sign extend high offset */
286 addq t0,pv,pv /* compute update address */
288 .aent asm_handle_exception
290 asm_handle_exception:
291 L_asm_handle_exception: /* required for PIC code */
292 lda sp,-(ARG_CNT+TMP_CNT)*8(sp) /* create maybe-leaf stackframe */
294 SAVE_ARGUMENT_REGISTERS(0) /* we save arg and temp registers in */
295 SAVE_TEMPORARY_REGISTERS(ARG_CNT) /* case this is a leaf method */
297 lda a3,(ARG_CNT+TMP_CNT)*8(zero)/* prepare a3 for handle_exception */
298 lda a4,1(zero) /* set maybe-leaf flag */
300 L_asm_handle_exception_stack_loop:
301 lda sp,-5*8(sp) /* allocate stack */
302 stq xptr,0*8(sp) /* save exception pointer */
303 stq xpc,1*8(sp) /* save exception pc */
304 stq pv,2*8(sp) /* save data segment pointer */
305 stq ra,3*8(sp) /* save return address */
306 addq a3,sp,a3 /* calculate Java sp into a3... */
308 stq a4,4*8(sp) /* save maybe-leaf flag */
310 br ra,L_asm_handle_exception_load_gp /* set ra for gp loading */
311 L_asm_handle_exception_load_gp:
312 ldgp gp,0(ra) /* load gp */
314 mov xptr,a0 /* pass exception pointer */
315 mov xpc,a1 /* pass exception pc */
316 mov pv,a2 /* pass data segment pointer */
317 /* a3 is still set */
318 jsr ra,exceptions_handle_exception
320 beq v0,L_asm_handle_exception_not_catched
322 mov v0,xpc /* move handlerpc into xpc */
323 ldq xptr,0*8(sp) /* restore exception pointer */
324 ldq pv,2*8(sp) /* restore data segment pointer */
325 ldq ra,3*8(sp) /* restore return address */
326 ldq a4,4*8(sp) /* get maybe-leaf flag */
327 lda sp,5*8(sp) /* free stack frame */
329 beq a4,L_asm_handle_exception_no_leaf
331 RESTORE_ARGUMENT_REGISTERS(0) /* if this is a leaf method, we have */
332 RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers */
334 lda sp,(ARG_CNT+TMP_CNT)*8(sp) /* remove maybe-leaf stackframe */
336 L_asm_handle_exception_no_leaf:
337 jmp zero,(xpc) /* jump to the handler */
339 L_asm_handle_exception_not_catched:
340 ldq xptr,0*8(sp) /* restore exception pointer */
341 ldq pv,2*8(sp) /* restore data segment pointer */
342 ldq ra,3*8(sp) /* restore return address */
343 ldq a4,4*8(sp) /* get maybe-leaf flag */
346 beq a4,L_asm_handle_exception_no_leaf_stack
348 lda sp,(ARG_CNT+TMP_CNT)*8(sp) /* remove maybe-leaf stackframe */
349 mov zero,a4 /* clear the maybe-leaf flag */
351 L_asm_handle_exception_no_leaf_stack:
352 ldl t0,FrameSize(pv) /* get frame size */
353 addq t0,sp,t0 /* pointer to save area */
355 ldl t1,IsLeaf(pv) /* is leaf procedure */
356 bne t1,L_asm_handle_exception_no_ra_restore
358 ldq ra,-1*8(t0) /* restore ra */
359 subq t0,8,t0 /* t0-- */
361 L_asm_handle_exception_no_ra_restore:
362 mov ra,xpc /* the new xpc is ra */
363 ldl t1,IntSave(pv) /* t1 = saved int register count */
364 br t2,ex_int1 /* t2 = current pc */
366 lda t2,(ex_int2-ex_int1)(t2)
367 negl t1,t1 /* negate register count */
368 s4addq t1,t2,t2 /* t2 = IntSave - register count * 4 */
369 jmp zero,(t2) /* jump to save position */
380 s8addq t1,t0,t0 /* t0 = t0 - 8 * register count */
382 ldl t1,FltSave(pv) /* t1 = saved flt register count */
383 br t2,ex_flt1 /* t2 = current pc */
385 lda t2,(ex_flt2-ex_flt1)(t2)
386 negl t1,t1 /* negate register count */
387 s4addq t1,t2,t2 /* t2 = FltSave - 4 * register count */
388 jmp zero,(t2) /* jump to save position */
400 ldl t0,FrameSize(pv) /* get frame size */
401 addq sp,t0,sp /* unwind stack */
402 mov zero,a3 /* prepare a3 for handle_exception */
404 ldl t0,0(ra) /* load instruction LDA PV,xxx(RA) */
406 sra t0,48,t0 /* isolate offset */
407 addq t0,ra,pv /* compute update address */
408 ldl t0,4(ra) /* load instruction LDAH PV,xxx(PV) */
409 srl t0,16,t0 /* isolate instruction code */
410 lda t0,-0x177b(t0) /* test for LDAH */
411 bne t0,L_asm_handle_exception_stack_loop
412 ldl t0,4(ra) /* load instruction LDAH PV,xxx(RA) */
413 sll t0,16,t0 /* compute high offset */
414 addl t0,0,t0 /* sign extend high offset */
415 addq t0,pv,pv /* compute update address */
417 br L_asm_handle_exception_stack_loop
419 .end asm_handle_nat_exception
422 /* asm_abstractmethoderror *****************************************************
424 Creates and throws an AbstractMethodError.
426 *******************************************************************************/
428 .ent asm_abstractmethoderror
430 asm_abstractmethoderror:
431 subq sp,2*8,sp /* create stackframe */
432 stq ra,0*8(sp) /* save return address */
433 addq sp,2*8,a0 /* pass java sp */
434 mov ra,a1 /* pass exception address */
435 jsr ra,exceptions_asm_new_abstractmethoderror
436 ldq ra,0*8(sp) /* restore return address */
437 addq sp,2*8,sp /* remove stackframe */
439 mov v0,xptr /* get exception pointer */
440 subq ra,4,xpc /* exception address is ra - 4 */
441 br L_asm_handle_nat_exception
443 .end asm_abstractmethoderror
446 /* asm_wrapper_patcher *********************************************************
451 40 return address into JIT code (patch position)
452 32 pointer to virtual java_objectheader
453 24 machine code (which is patched back later)
454 16 unresolved class/method/field reference
455 8 data segment displacement from load instructions
456 0 patcher function pointer to call (pv afterwards)
458 ATTENTION: itmp3 == gp! But we don't need gp do call the patcher function.
460 *******************************************************************************/
462 .ent asm_wrapper_patcher
465 lda sp,-((2+12+27+4)*8+sizestackframeinfo)(sp) /* create stack frame */
467 SAVE_RETURN_REGISTERS(0) /* save 1 int/1 float return registers */
468 SAVE_ARGUMENT_REGISTERS(2) /* save 6 int/6 float argument registers */
469 SAVE_TEMPORARY_REGISTERS(14) /* save 11 int/16 float temporary registers */
471 stq itmp1,(2+12+27+0)*8(sp) /* save itmp1 */
472 stq itmp2,(2+12+27+1)*8(sp) /* save itmp2 */
473 stq ra,(2+12+27+2)*8(sp) /* save method return address (for leafs) */
474 stq pv,(2+12+27+3)*8(sp) /* save pv of calling java function */
476 br ra,L_asm_wrapper_patcher_load_gp
477 L_asm_wrapper_patcher_load_gp:
478 ldgp gp,0(ra) /* load gp (it's not set correctly in jit) */
480 lda a0,(2+12+27+4)*8(sp) /* create stackframe info */
481 mov pv,a1 /* pass java pv */
482 lda a2,((6+2+12+27+4)*8+sizestackframeinfo)(sp) /* pass java sp */
483 ldq a3,(2+12+27+2)*8(sp) /* this is correct for leafs */
484 ldq a4,((5+2+12+27+4)*8+sizestackframeinfo)(sp) /* pass xpc */
485 jsr ra,stacktrace_create_extern_stackframeinfo
488 lda a0,((0+2+12+27+4)*8+sizestackframeinfo)(sp) /* pass sp */
489 ldq pv,((0+2+12+27+4)*8+sizestackframeinfo)(sp) /* get function */
490 ldq itmp1,(2+12+27+3)*8(sp) /* save pv to the position of fp */
491 stq itmp1,((0+2+12+27+4)*8+sizestackframeinfo)(sp)
492 jmp ra,(pv) /* call the patcher function */
494 stq v0,((0+2+12+27+4)*8+sizestackframeinfo)(sp) /* save return value */
496 lda a0,(2+12+27+4)*8(sp) /* remove stackframe info */
497 jsr ra,stacktrace_remove_stackframeinfo
500 RESTORE_RETURN_REGISTERS(0) /* restore 1 int/1 float return registers */
501 RESTORE_ARGUMENT_REGISTERS(2) /* restore 6 int/6 float argument registers */
502 RESTORE_TEMPORARY_REGISTERS(14) /* restore 11 integer temporary registers */
504 ldq itmp1,(2+12+27+0)*8(sp) /* restore itmp1 */
505 ldq itmp2,(2+12+27+1)*8(sp) /* restore itmp2 */
506 ldq ra,(2+12+27+2)*8(sp) /* restore method return address (for leafs)*/
507 ldq pv,(2+12+27+3)*8(sp) /* restore pv of calling java function */
509 ldq itmp3,((0+2+12+27+4)*8+sizestackframeinfo)(sp) /* get return value*/
510 beq itmp3,L_asm_wrapper_patcher_exception
512 ldq itmp3,((5+2+12+27+4)*8+sizestackframeinfo)(sp)/* get RA to JIT */
513 lda sp,((6+2+12+27+4)*8+sizestackframeinfo)(sp) /* remove stack frame */
515 jmp zero,(itmp3) /* jump to new patched code */
517 L_asm_wrapper_patcher_exception:
518 ldq xpc,((5+2+12+27+4)*8+sizestackframeinfo)(sp) /* RA is xpc */
519 lda sp,((6+2+12+27+4)*8+sizestackframeinfo)(sp) /* remove stack frame */
521 br itmp1,L_asm_wrapper_patcher_exception_load_gp
522 L_asm_wrapper_patcher_exception_load_gp:
523 ldgp gp,0(itmp1) /* itmp3 == gp, load the current gp */
526 stq xpc,0*8(sp) /* save return address (xpc) */
529 jsr ra,exceptions_get_and_clear_exception
530 ldq xpc,0*8(sp) /* restore return address (xpc) */
535 mov v0,xptr /* get exception */
536 br L_asm_handle_exception/* we have the pv of the calling java func. */
538 .end asm_wrapper_patcher
541 /* asm_replacement_out *********************************************************
543 This code is jumped to from the replacement-out stubs that are executed
544 when a thread reaches an activated replacement point.
546 The purpose of asm_replacement_out is to read out the parts of the
547 execution state that cannot be accessed from C code, store this state,
548 and then call the C function replace_me.
551 16 start of stack inside method to replace
552 0 rplpoint * info on the replacement point that was reached
554 NOTE: itmp3 has been clobbered by the replacement-out stub!
556 *******************************************************************************/
558 /* some room to accomodate changes of the stack frame size during replacement */
559 /* XXX we should find a cleaner solution here */
560 #define REPLACEMENT_ROOM 512
562 #define REPLACEMENT_STACK_OFFSET ((sizeexecutionstate + REPLACEMENT_ROOM + 0xf) & ~0xf)
564 .ent asm_replacement_out
567 /* create stack frame */
568 lda sp,-(REPLACEMENT_STACK_OFFSET)(sp)
570 /* save registers in execution state */
571 stq $0 ,( 0*8+offes_intregs)(sp)
572 stq $1 ,( 1*8+offes_intregs)(sp)
573 stq $2 ,( 2*8+offes_intregs)(sp)
574 stq $3 ,( 3*8+offes_intregs)(sp)
575 stq $4 ,( 4*8+offes_intregs)(sp)
576 stq $5 ,( 5*8+offes_intregs)(sp)
577 stq $6 ,( 6*8+offes_intregs)(sp)
578 stq $7 ,( 7*8+offes_intregs)(sp)
579 stq $8 ,( 8*8+offes_intregs)(sp)
580 stq $9 ,( 9*8+offes_intregs)(sp)
581 stq $10,(10*8+offes_intregs)(sp)
582 stq $11,(11*8+offes_intregs)(sp)
583 stq $12,(12*8+offes_intregs)(sp)
584 stq $13,(13*8+offes_intregs)(sp)
585 stq $14,(14*8+offes_intregs)(sp)
586 stq $15,(15*8+offes_intregs)(sp)
587 stq $16,(16*8+offes_intregs)(sp)
588 stq $17,(17*8+offes_intregs)(sp)
589 stq $18,(18*8+offes_intregs)(sp)
590 stq $19,(19*8+offes_intregs)(sp)
591 stq $20,(20*8+offes_intregs)(sp)
592 stq $21,(21*8+offes_intregs)(sp)
593 stq $22,(22*8+offes_intregs)(sp)
594 stq $23,(23*8+offes_intregs)(sp)
595 stq $24,(24*8+offes_intregs)(sp)
596 stq $25,(25*8+offes_intregs)(sp)
597 stq $26,(26*8+offes_intregs)(sp)
598 stq $27,(27*8+offes_intregs)(sp)
599 stq $28,(28*8+offes_intregs)(sp)
600 stq $29,(29*8+offes_intregs)(sp)
601 stq $30,(30*8+offes_intregs)(sp)
602 stq $31,(31*8+offes_intregs)(sp)
604 stt $f0 ,( 0*8+offes_fltregs)(sp)
605 stt $f1 ,( 1*8+offes_fltregs)(sp)
606 stt $f2 ,( 2*8+offes_fltregs)(sp)
607 stt $f3 ,( 3*8+offes_fltregs)(sp)
608 stt $f4 ,( 4*8+offes_fltregs)(sp)
609 stt $f5 ,( 5*8+offes_fltregs)(sp)
610 stt $f6 ,( 6*8+offes_fltregs)(sp)
611 stt $f7 ,( 7*8+offes_fltregs)(sp)
612 stt $f8 ,( 8*8+offes_fltregs)(sp)
613 stt $f9 ,( 9*8+offes_fltregs)(sp)
614 stt $f10,(10*8+offes_fltregs)(sp)
615 stt $f11,(11*8+offes_fltregs)(sp)
616 stt $f12,(12*8+offes_fltregs)(sp)
617 stt $f13,(13*8+offes_fltregs)(sp)
618 stt $f14,(14*8+offes_fltregs)(sp)
619 stt $f15,(15*8+offes_fltregs)(sp)
620 stt $f16,(16*8+offes_fltregs)(sp)
621 stt $f17,(17*8+offes_fltregs)(sp)
622 stt $f18,(18*8+offes_fltregs)(sp)
623 stt $f19,(19*8+offes_fltregs)(sp)
624 stt $f20,(20*8+offes_fltregs)(sp)
625 stt $f21,(21*8+offes_fltregs)(sp)
626 stt $f22,(22*8+offes_fltregs)(sp)
627 stt $f23,(23*8+offes_fltregs)(sp)
628 stt $f24,(24*8+offes_fltregs)(sp)
629 stt $f25,(25*8+offes_fltregs)(sp)
630 stt $f26,(26*8+offes_fltregs)(sp)
631 stt $f27,(27*8+offes_fltregs)(sp)
632 stt $f28,(28*8+offes_fltregs)(sp)
633 stt $f29,(29*8+offes_fltregs)(sp)
634 stt $f30,(30*8+offes_fltregs)(sp)
635 stt $f31,(31*8+offes_fltregs)(sp)
637 /* calculate sp of method */
638 lda itmp1,(REPLACEMENT_STACK_OFFSET + 2*8)(sp)
639 stq itmp1,(offes_sp)(sp)
641 br ra,L_asm_replacement_out_load_gp
642 L_asm_replacement_out_load_gp:
643 ldgp gp,0(ra) /* load gp */
646 stq pv,(offes_pv)(sp)
648 /* call replace_me */
649 ldq a0,-(2*8)(itmp1) /* arg0: rplpoint * */
650 mov sp,a1 /* arg1: execution state */
651 jmp zero,replace_me /* call C function replace_me */
652 jmp zero,abort /* NEVER REACHED */
654 .end asm_replacement_out
656 /* asm_replacement_in **********************************************************
658 This code writes the given execution state and jumps to the replacement
661 This function never returns!
663 NOTE: itmp3 is not restored!
666 void asm_replacement_in(executionstate *es);
668 *******************************************************************************/
670 .ent asm_replacement_in
673 /* a0 == executionstate *es */
675 /* set new sp and pv */
676 ldq sp,(offes_sp)(a0)
677 ldq pv,(offes_pv)(a0)
679 /* copy registers from execution state */
680 ldq $0 ,( 0*8+offes_intregs)(a0)
681 ldq $1 ,( 1*8+offes_intregs)(a0)
682 ldq $2 ,( 2*8+offes_intregs)(a0)
683 ldq $3 ,( 3*8+offes_intregs)(a0)
684 ldq $4 ,( 4*8+offes_intregs)(a0)
685 ldq $5 ,( 5*8+offes_intregs)(a0)
686 ldq $6 ,( 6*8+offes_intregs)(a0)
687 ldq $7 ,( 7*8+offes_intregs)(a0)
688 ldq $8 ,( 8*8+offes_intregs)(a0)
689 ldq $9 ,( 9*8+offes_intregs)(a0)
690 ldq $10,(10*8+offes_intregs)(a0)
691 ldq $11,(11*8+offes_intregs)(a0)
692 ldq $12,(12*8+offes_intregs)(a0)
693 ldq $13,(13*8+offes_intregs)(a0)
694 ldq $14,(14*8+offes_intregs)(a0)
695 ldq $15,(15*8+offes_intregs)(a0)
696 /* a0 is loaded below */
697 ldq $17,(17*8+offes_intregs)(a0)
698 ldq $18,(18*8+offes_intregs)(a0)
699 ldq $19,(19*8+offes_intregs)(a0)
700 ldq $20,(20*8+offes_intregs)(a0)
701 ldq $21,(21*8+offes_intregs)(a0)
702 ldq $22,(22*8+offes_intregs)(a0)
703 ldq $23,(23*8+offes_intregs)(a0)
704 ldq $24,(24*8+offes_intregs)(a0)
705 ldq $25,(25*8+offes_intregs)(a0)
706 ldq $26,(26*8+offes_intregs)(a0)
708 ldq $28,(28*8+offes_intregs)(a0)
709 ldq $29,(29*8+offes_intregs)(a0)
713 ldt $f0 ,( 0*8+offes_fltregs)(a0)
714 ldt $f1 ,( 1*8+offes_fltregs)(a0)
715 ldt $f2 ,( 2*8+offes_fltregs)(a0)
716 ldt $f3 ,( 3*8+offes_fltregs)(a0)
717 ldt $f4 ,( 4*8+offes_fltregs)(a0)
718 ldt $f5 ,( 5*8+offes_fltregs)(a0)
719 ldt $f6 ,( 6*8+offes_fltregs)(a0)
720 ldt $f7 ,( 7*8+offes_fltregs)(a0)
721 ldt $f8 ,( 8*8+offes_fltregs)(a0)
722 ldt $f9 ,( 9*8+offes_fltregs)(a0)
723 ldt $f10,(10*8+offes_fltregs)(a0)
724 ldt $f11,(11*8+offes_fltregs)(a0)
725 ldt $f12,(12*8+offes_fltregs)(a0)
726 ldt $f13,(13*8+offes_fltregs)(a0)
727 ldt $f14,(14*8+offes_fltregs)(a0)
728 ldt $f15,(15*8+offes_fltregs)(a0)
729 ldt $f16,(16*8+offes_fltregs)(a0)
730 ldt $f17,(17*8+offes_fltregs)(a0)
731 ldt $f18,(18*8+offes_fltregs)(a0)
732 ldt $f19,(19*8+offes_fltregs)(a0)
733 ldt $f20,(20*8+offes_fltregs)(a0)
734 ldt $f21,(21*8+offes_fltregs)(a0)
735 ldt $f22,(22*8+offes_fltregs)(a0)
736 ldt $f23,(23*8+offes_fltregs)(a0)
737 ldt $f24,(24*8+offes_fltregs)(a0)
738 ldt $f25,(25*8+offes_fltregs)(a0)
739 ldt $f26,(26*8+offes_fltregs)(a0)
740 ldt $f27,(27*8+offes_fltregs)(a0)
741 ldt $f28,(28*8+offes_fltregs)(a0)
742 ldt $f29,(29*8+offes_fltregs)(a0)
743 ldt $f30,(30*8+offes_fltregs)(a0)
744 ldt $f31,(31*8+offes_fltregs)(a0)
748 ldq itmp3,offes_pc(a0)
752 ldq a0,(16*8+offes_intregs)(a0)
754 /* jump to new code */
758 .end asm_replacement_in
761 .ent asm_getclassvalues_atomic
763 asm_getclassvalues_atomic:
766 ldl t0,offbaseval(a0)
767 ldl t1,offdiffval(a0)
768 ldl t2,offbaseval(a1)
770 stl t0,offcast_super_baseval(a2)
771 stl t1,offcast_super_diffval(a2)
772 stl t2,offcast_sub_baseval(a2)
775 .end asm_getclassvalues_atomic
780 asm_criticalsections:
781 #if defined(ENABLE_THREADS)
789 /* asm_md_init *****************************************************************
791 Initialize machine dependent stuff.
793 Determines if the byte support instruction set (21164a and higher)
796 *******************************************************************************/
801 .long 0x47e03c20 /* amask 1,v0 */
802 jmp zero,(ra) /* return */
807 /* asm_cacheflush **************************************************************
811 *******************************************************************************/
816 call_pal PAL_imb /* synchronize instruction cache */
822 /* Disable exec-stacks, required for Gentoo ***********************************/
824 #if defined(__GCC__) && defined(__ELF__)
825 .section .note.GNU-stack,"",@progbits
830 * These are local overrides for various environment variables in Emacs.
831 * Please do not remove this and leave it at the end of the file, where
832 * Emacs will automagically detect them.
833 * ---------------------------------------------------------------------
836 * indent-tabs-mode: t
840 * vim:noexpandtab:sw=4:ts=4: