src/vm/jit/alpha/asmpart.S

   1 /* src/vm/jit/alpha/asmpart.S - Java-C interface functions for alpha
   2
   3    Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
   4    C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5    E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6    J. Wenninger, Institut f. Computersprachen - TU Wien
   7
   8    This file is part of CACAO.
   9
  10    This program is free software; you can redistribute it and/or
  11    modify it under the terms of the GNU General Public License as
  12    published by the Free Software Foundation; either version 2, or (at
  13    your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful, but
  16    WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18    General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23    02110-1301, USA.
  24
  25    Contact: cacao@cacaojvm.org
  26
  27    Authors: Andreas Krall
  28             Reinhard Grafl
  29
  30    Changes: Joseph Wenninger
  31             Christian Thalinger
  32                 Edwin Steiner
  33
  34    $Id: asmpart.S 6147 2006-12-07 23:54:40Z edwin $
  35
  36 */
  37
  38
  39 #include "config.h"
  40
  41 #include "vm/jit/alpha/md-abi.h"
  42 #include "vm/jit/alpha/md-asm.h"
  43 #include "vm/jit/alpha/offsets.h"
  44
  45 #include "vm/jit/abi-asm.h"
  46 #include "vm/jit/methodheader.h"
  47
  48
  49         .text
  50         .set    noat
  51         .set    noreorder
  52
  53
  54 /* export functions ***********************************************************/
  55
  56         .globl asm_vm_call_method
  57         .globl asm_vm_call_method_int
  58         .globl asm_vm_call_method_long
  59         .globl asm_vm_call_method_float
  60         .globl asm_vm_call_method_double
  61         .globl asm_vm_call_method_exception_handler
  62
  63         .globl asm_call_jit_compiler
  64
  65         .globl asm_handle_exception
  66         .globl asm_handle_nat_exception
  67
  68         .globl asm_abstractmethoderror
  69
  70         .globl asm_patcher_wrapper
  71
  72         .globl asm_replacement_out
  73         .globl asm_replacement_in
  74
  75         .globl asm_criticalsections
  76         .globl asm_getclassvalues_atomic
  77
  78         .globl asm_md_init
  79         .globl asm_cacheflush
  80
  81
  82 /* asm_vm_call_method **********************************************************
  83 *                                                                              *
  84 *   This function calls a Java-method (which possibly needs compilation)       *
  85 *   with up to 4 address parameters.                                           *
  86 *                                                                              *
  87 *   This functions calls the JIT-compiler which eventually translates the      *
  88 *   method into machine code.                                                  *
  89 *                                                                              *
  90 *   C-prototype:                                                               *
  91 *    javaobject_header *asm_calljavafunction (methodinfo *m,                   *
  92 *         void *arg1, void *arg2, void *arg3, void *arg4);                     *
  93 *                                                                              *
  94 *******************************************************************************/
  95
  96         .ent    asm_vm_call_method
  97
  98         .align  3
  99
 100         .quad   0                           /* catch type all                     */
 101         .quad   0                           /* handler pc                         */
 102         .quad   0                           /* end pc                             */
 103         .quad   0                           /* start pc                           */
 104         .long   1                           /* extable size                       */
 105         .long   0                           /* ALIGNMENT PADDING                  */
 106         .quad   0                           /* line number table start            */
 107         .quad   0                           /* line number table size             */
 108         .long   0                           /* ALIGNMENT PADDING                  */
 109         .long   0                           /* fltsave                            */
 110         .long   1                           /* intsave                            */
 111         .long   0                           /* isleaf                             */
 112         .long   0                           /* IsSync                             */
 113         .long   0                           /* frame size                         */
 114         .quad   0                           /* codeinfo pointer                   */
 115
 116 asm_vm_call_method:
 117 asm_vm_call_method_int:
 118 asm_vm_call_method_long:
 119 asm_vm_call_method_float:
 120 asm_vm_call_method_double:
 121         ldgp    gp,0(pv)
 122         lda     sp,-5*8(sp)               /* allocate stack space                 */
 123         stq     ra,0*8(sp)                /* save return address                  */
 124         stq     gp,1*8(sp)                /* save global pointer                  */
 125         stq     s6,3*8(sp)
 126
 127         stq     a0,4*8(sp)                /* save method pointer for compiler     */
 128
 129         mov     a2,t0                     /* pointer to arg block                 */
 130         mov     a1,s6                     /* arg count                            */
 131
 132         ble     s6,calljava_argsloaded
 133         lda     s6,-1(s6)
 134         ldq     a0,offvmargdata(t0)
 135         ldt     $f16,offvmargdata(t0)
 136         ble     s6,calljava_argsloaded
 137
 138         lda     s6,-1(s6)
 139         ldq     a1,offvmargdata+sizevmarg*1(t0)
 140         ldt     $f17,offvmargdata+sizevmarg*1(t0)
 141         ble     s6,calljava_argsloaded
 142
 143         lda     s6,-1(s6)
 144         ldq     a2,offvmargdata+sizevmarg*2(t0)
 145         ldt     $f18,offvmargdata+sizevmarg*2(t0)
 146         ble     s6,calljava_argsloaded
 147
 148         lda     s6,-1(s6)
 149         ldq     a3,offvmargdata+sizevmarg*3(t0)
 150         ldt     $f19,offvmargdata+sizevmarg*3(t0)
 151         ble     s6,calljava_argsloaded
 152
 153         lda     s6,-1(s6)
 154         ldq     a4,offvmargdata+sizevmarg*4(t0)
 155         ldt     $f20,offvmargdata+sizevmarg*4(t0)
 156         ble     s6,calljava_argsloaded
 157
 158         lda     s6,-1(s6)
 159         ldq     a5,offvmargdata+sizevmarg*5(t0)
 160         ldt     $f21,offvmargdata+sizevmarg*5(t0)
 161 calljava_argsloaded:
 162         mov     sp,t4
 163         ble     s6,calljava_nocopy
 164         negq    s6,t1
 165         s8addq  t1,sp,sp
 166         s8addq  t1,t4,t2
 167
 168 calljava_copyloop:
 169         ldq     t3,offvmargdata+sizevmarg*6(t0)
 170         stq     t3,0(t2)
 171         lda     t1,1(t1)
 172         lda     t0,sizevmarg(t0)
 173         lda     t2,8(t2)
 174         bne     t1,calljava_copyloop
 175
 176 calljava_nocopy:
 177         ldq     itmp1,4*8(t4)             /* pass method pointer via itmp1        */
 178
 179         lda     mptr,asm_call_jit_compiler/* fake virtual function call (2 instr) */
 180         stq     mptr,2*8(t4)              /* store function address               */
 181         lda     mptr,1*8(t4)              /* set method pointer                   */
 182
 183         ldq     pv,1*8(mptr)              /* method call as in Java               */
 184         jmp     ra,(pv)                   /* call JIT compiler                    */
 185 calljava_jit2:
 186         lda     pv,(asm_vm_call_method - calljava_jit2)(ra)
 187
 188         s8addq  s6,sp,sp
 189 calljava_return2:
 190         ldq     ra,0*8(sp)                /* restore return address               */
 191         ldq     gp,1*8(sp)                /* restore global pointer               */
 192         ldq     s6,3*8(sp)
 193         lda     sp,5*8(sp)                /* free stack space                     */
 194
 195 calljava_ret2:
 196         jmp     zero,(ra)
 197
 198 asm_vm_call_method_exception_handler:
 199         s8addq  s6,sp,sp
 200         ldq     gp,1*8(sp)                /* restore global pointer               */
 201         mov     itmp1,a0
 202         jsr     ra,builtin_throw_exception
 203         ldq     ra,0*8(sp)                /* restore return address               */
 204         ldq     s6,3*8(sp)
 205         lda     sp,5*8(sp)                /* free stack space                     */
 206         jmp     zero,(ra)
 207
 208         .end    asm_vm_call_method
 209
 210
 211 /* asm_call_jit_compiler *******************************************************
 212
 213    Invokes the compiler for untranslated Java methods.
 214
 215 *******************************************************************************/
 216
 217         .ent    asm_call_jit_compiler
 218
 219 asm_call_jit_compiler:
 220         ldgp    gp,0(pv)
 221         lda     sp,-(ARG_CNT+2)*8(sp) /* +2: keep stack 16-byte aligned           */
 222
 223         stq     ra,0*8(sp)            /* save return address                      */
 224
 225         SAVE_ARGUMENT_REGISTERS(1)    /* save 6 int/6 float argument registers    */
 226
 227         mov     itmp1,a0              /* pass methodinfo pointer                  */
 228         mov     mptr,a1               /* pass method pointer                      */
 229         lda     a2,(ARG_CNT+2)*8(sp)  /* pass java sp                             */
 230         mov     ra,a3
 231         jsr     ra,jit_asm_compile    /* call jit compiler                        */
 232         mov     v0,pv
 233
 234         ldq     ra,0*8(sp)            /* load return address                      */
 235
 236         RESTORE_ARGUMENT_REGISTERS(1) /* restore 6 int/6 float argument registers */
 237
 238         lda     sp,(ARG_CNT+2)*8(sp)  /* remove stack frame                       */
 239
 240         beq     pv,L_asm_call_jit_compiler_exception
 241
 242         jmp     zero,(pv)             /* and call method, the method returns      */
 243                                       /* directly to the caller (ra).             */
 244
 245 L_asm_call_jit_compiler_exception:
 246         subq    sp,2*8,sp
 247         stq     ra,0*8(sp)            /* save return address (xpc)                */
 248         jsr     ra,exceptions_get_and_clear_exception
 249         ldq     ra,0*8(sp)            /* restore return address (xpc)             */
 250         addq    sp,2*8,sp
 251
 252         mov     v0,xptr               /* get exception                            */
 253         subq    ra,4,xpc              /* exception address is ra - 4              */
 254         br      L_asm_handle_nat_exception
 255
 256         .end    asm_call_jit_compiler
 257
 258
 259 /* asm_handle_exception ********************************************************
 260
 261    This function handles an exception. It does not use the usual calling
 262    conventions. The exception pointer is passed in REG_ITMP1 and the
 263    pc from the exception raising position is passed in REG_ITMP2. It searches
 264    the local exception table for a handler. If no one is found, it unwinds
 265    stacks and continues searching the callers.
 266
 267    ATTENTION: itmp3 == gp!
 268
 269 *******************************************************************************/
 270
 271         .ent    asm_handle_nat_exception
 272
 273 asm_handle_nat_exception:
 274 L_asm_handle_nat_exception:       /* required for PIC code                    */
 275 L_asm_handle_exception_stack_loop:
 276         lda     sp,-6*8(sp)                 /* keep stack 16-byte aligned         */
 277         stq     xptr,0*8(sp)                /* save xptr                          */
 278         stq     xpc,1*8(sp)                 /* save xpc                           */
 279         stq     ra,3*8(sp)                  /* save RA                            */
 280         stq     zero,4*8(sp)                /* save maybe-leaf flag (cleared)     */
 281
 282         mov     ra,a0                       /* pass RA                            */
 283
 284         br      ra,L_asm_handle_exception_load_gp
 285 L_asm_handle_exception_load_gp:
 286         ldgp    gp,0(ra)                    /* load gp                            */
 287
 288         jsr     ra,md_codegen_get_pv_from_pc/* get PV from RA                     */
 289         stq     v0,2*8(sp)                  /* save PV                            */
 290
 291         ldq     a0,0*8(sp)                  /* pass xptr                          */
 292         ldq     a1,1*8(sp)                  /* pass xpc                           */
 293         mov     v0,a2                       /* pass PV                            */
 294         addq    sp,6*8,a3                   /* pass Java SP                       */
 295
 296         br      L_asm_handle_exception_continue
 297
 298         .aent    asm_handle_exception
 299
 300 asm_handle_exception:
 301 L_asm_handle_exception:                 /* required for PIC code              */
 302         lda     sp,-(ARG_CNT+TMP_CNT)*8(sp) /* create maybe-leaf stackframe       */
 303
 304         SAVE_ARGUMENT_REGISTERS(0)          /* we save arg and temp registers in  */
 305         SAVE_TEMPORARY_REGISTERS(ARG_CNT)   /* case this is a leaf method         */
 306
 307         lda     sp,-6*8(sp)                 /* keep stack 16-byte aligned         */
 308         stq     xptr,0*8(sp)                /* save xptr                          */
 309         stq     pv,2*8(sp)                  /* save PV                            */
 310         stq     ra,3*8(sp)                  /* save RA                            */
 311         lda     t0,1(zero)                  /* set maybe-leaf flag                */
 312         stq     t0,4*8(sp)                  /* save maybe-leaf flag               */
 313
 314         br      ra,L_asm_handle_exception_load_gp_2
 315 L_asm_handle_exception_load_gp_2:
 316         ldgp    gp,0(ra)                    /* load gp                            */
 317
 318         mov     xptr,a0                     /* pass xptr                          */
 319         mov     xpc,a1                      /* pass xpc                           */
 320         mov     pv,a2                       /* pass PV                            */
 321         lda     a3,(ARG_CNT+TMP_CNT+6)*8(sp)/* pass Java SP                       */
 322
 323 L_asm_handle_exception_continue:
 324         jsr     ra,exceptions_handle_exception
 325
 326         beq     v0,L_asm_handle_exception_not_catched
 327
 328         mov     v0,xpc                      /* move handlerpc into xpc            */
 329         ldq     xptr,0*8(sp)                /* restore xptr                       */
 330         ldq     pv,2*8(sp)                  /* restore PV                         */
 331         ldq     ra,3*8(sp)                  /* restore RA                         */
 332         ldq     t0,4*8(sp)                  /* get maybe-leaf flag                */
 333         lda     sp,6*8(sp)                  /* free stack frame                   */
 334
 335         beq     t0,L_asm_handle_exception_no_leaf
 336
 337         RESTORE_ARGUMENT_REGISTERS(0)       /* if this is a leaf method, we have  */
 338         RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers  */
 339
 340         lda     sp,(ARG_CNT+TMP_CNT)*8(sp)  /* remove maybe-leaf stackframe       */
 341
 342 L_asm_handle_exception_no_leaf:
 343         jmp     zero,(xpc)                  /* jump to the handler                */
 344
 345 L_asm_handle_exception_not_catched:
 346         ldq     xptr,0*8(sp)                /* restore xptr                       */
 347         ldq     pv,2*8(sp)                  /* restore PV                         */
 348         ldq     ra,3*8(sp)                  /* restore RA                         */
 349         ldq     t0,4*8(sp)                  /* get maybe-leaf flag                */
 350         lda     sp,6*8(sp)
 351
 352         beq     t0,L_asm_handle_exception_no_leaf_stack
 353
 354         lda     sp,(ARG_CNT+TMP_CNT)*8(sp)  /* remove maybe-leaf stackframe       */
 355         mov     zero,t0                     /* clear the maybe-leaf flag          */
 356
 357 L_asm_handle_exception_no_leaf_stack:
 358         ldl     t1,FrameSize(pv)            /* get frame size                     */
 359         addq    t1,sp,t1                    /* pointer to save area               */
 360
 361         ldl     t2,IsLeaf(pv)               /* is leaf procedure                  */
 362         bne     t2,L_asm_handle_exception_no_ra_restore
 363
 364         ldq     ra,-1*8(t1)                 /* restore ra                         */
 365         subq    t1,8,t1                     /* t1--                               */
 366
 367 L_asm_handle_exception_no_ra_restore:
 368         mov     ra,xpc                      /* the new xpc is ra                  */
 369         ldl     t2,IntSave(pv)              /* t2 = saved int register count      */
 370         br      t3,ex_int1                  /* t3 = current pc                    */
 371 ex_int1:
 372         lda     t3,(ex_int2 - ex_int1)(t3)
 373         negl    t2,t2                       /* negate register count              */
 374         s4addq  t2,t3,t3                    /* t2 = IntSave - register count * 4  */
 375         jmp     zero,(t3)                   /* jump to save position              */
 376
 377         ldq     s0,-7*8(t1)
 378         ldq     s1,-6*8(t1)
 379         ldq     s2,-5*8(t1)
 380         ldq     s3,-4*8(t1)
 381         ldq     s4,-3*8(t1)
 382         ldq     s5,-2*8(t1)
 383         ldq     s6,-1*8(t1)
 384
 385 ex_int2:
 386         s8addq  t2,t1,t1                    /* t1 = t1 - 8 * register count       */
 387
 388         ldl     t2,FltSave(pv)              /* t2 = saved flt register count      */
 389         br      t3,ex_flt1                  /* t3 = current pc                    */
 390 ex_flt1:
 391         lda     t3,(ex_flt2 - ex_flt1)(t3)
 392         negl    t2,t2                       /* negate register count              */
 393         s4addq  t2,t3,t3                    /* t2 = FltSave - 4 * register count  */
 394         jmp     zero,(t3)                   /* jump to save position              */
 395
 396         ldt     fs0,-8*8(t1)
 397         ldt     fs1,-7*8(t1)
 398         ldt     fs2,-6*8(t1)
 399         ldt     fs3,-5*8(t1)
 400         ldt     fs4,-4*8(t1)
 401         ldt     fs5,-3*8(t1)
 402         ldt     fs6,-2*8(t1)
 403         ldt     fs7,-1*8(t1)
 404
 405 ex_flt2:
 406         ldl     t1,FrameSize(pv)            /* get frame size                     */
 407         addq    sp,t1,sp                    /* unwind stack                       */
 408         br      L_asm_handle_exception_stack_loop
 409
 410         .end    asm_handle_nat_exception
 411
 412
 413 /* asm_abstractmethoderror *****************************************************
 414
 415    Creates and throws an AbstractMethodError.
 416
 417 *******************************************************************************/
 418
 419         .ent    asm_abstractmethoderror
 420
 421 asm_abstractmethoderror:
 422         subq    sp,2*8,sp                   /* create stackframe                  */
 423         stq     ra,0*8(sp)                  /* save return address                */
 424         addq    sp,2*8,a0                   /* pass java sp                       */
 425         mov     ra,a1                       /* pass exception address             */
 426         jsr     ra,exceptions_asm_new_abstractmethoderror
 427         ldq     ra,0*8(sp)                  /* restore return address             */
 428         addq    sp,2*8,sp                   /* remove stackframe                  */
 429
 430         mov     v0,xptr                     /* get exception pointer              */
 431         subq    ra,4,xpc                    /* exception address is ra - 4        */
 432         br      L_asm_handle_nat_exception
 433
 434         .end    asm_abstractmethoderror
 435
 436
 437 /* asm_patcher_wrapper *********************************************************
 438
 439    XXX
 440
 441    Stack layout:
 442      40   return address into JIT code (patch position)
 443      32   pointer to virtual java_objectheader
 444      24   machine code (which is patched back later)
 445      16   unresolved class/method/field reference
 446       8   data segment displacement from load instructions
 447       0   patcher function pointer to call (pv afterwards)
 448
 449    ATTENTION: itmp3 == gp! But we don't need gp do call the patcher function.
 450
 451 *******************************************************************************/
 452
 453         .ent    asm_patcher_wrapper
 454
 455 asm_patcher_wrapper:
 456         lda     sp,-((2+12+27+4)*8)(sp) /* create stack frame                     */
 457
 458         SAVE_RETURN_REGISTERS(0)      /* save 1 int/1 float return registers      */
 459         SAVE_ARGUMENT_REGISTERS(2)    /* save 6 int/6 float argument registers    */
 460         SAVE_TEMPORARY_REGISTERS(14)  /* save 11 int/16 float temporary registers */
 461
 462         stq     itmp1,(2+12+27+0)*8(sp) /* save itmp1                             */
 463         stq     itmp2,(2+12+27+1)*8(sp) /* save itmp2                             */
 464         stq     ra,(2+12+27+2)*8(sp)  /* save method return address (for leafs)   */
 465         stq     pv,(2+12+27+3)*8(sp)  /* save pv of calling java function         */
 466
 467         br      ra,L_asm_patcher_wrapper_load_gp
 468 L_asm_patcher_wrapper_load_gp:
 469         ldgp    gp,0(ra)              /* load gp (it's not set correctly in jit)  */
 470
 471         lda     a0,(2+12+27+4)*8(sp)  /* pass SP of patcher stub                  */
 472         mov     pv,a1                 /* pass PV                                  */
 473         ldq     a2,(2+12+27+2)*8(sp)  /* pass RA (correct for leafs)              */
 474         jsr     ra,patcher_wrapper
 475         ldgp    gp,0(ra)
 476         stq     v0,(0+2+12+27+4)*8(sp) /* save return value                       */
 477
 478         RESTORE_RETURN_REGISTERS(0)   /* restore 1 int/1 float return registers   */
 479         RESTORE_ARGUMENT_REGISTERS(2) /* restore 6 int/6 float argument registers */
 480         RESTORE_TEMPORARY_REGISTERS(14) /* restore 11 integer temporary registers */
 481
 482         ldq     itmp1,(2+12+27+0)*8(sp) /* restore itmp1                          */
 483         ldq     itmp2,(2+12+27+1)*8(sp) /* restore itmp2                          */
 484         ldq     ra,(2+12+27+2)*8(sp)  /* restore method return address (for leafs)*/
 485         ldq     pv,(2+12+27+3)*8(sp)  /* restore pv of calling java function      */
 486
 487         ldq     itmp3,(0+2+12+27+4)*8(sp) /* get return value                     */
 488         bne     itmp3,L_asm_patcher_wrapper_exception
 489
 490         ldq     itmp3,(5+2+12+27+4)*8(sp) /* get RA to JIT                        */
 491         lda     sp,(6+2+12+27+4)*8(sp) /* remove stack frame                      */
 492
 493         jmp     zero,(itmp3)          /* jump to new patched code                 */
 494
 495 L_asm_patcher_wrapper_exception:
 496         mov     itmp3,xptr            /* get exception                            */
 497         ldq     xpc,(5+2+12+27+4)*8(sp) /* RA is xpc                              */
 498         lda     sp,(6+2+12+27+4)*8(sp) /* remove stack frame                      */
 499         br      L_asm_handle_exception
 500
 501         .end    asm_patcher_wrapper
 502
 503
 504 /* asm_replacement_out *********************************************************
 505
 506    This code is jumped to from the replacement-out stubs that are executed
 507    when a thread reaches an activated replacement point.
 508
 509    The purpose of asm_replacement_out is to read out the parts of the
 510    execution state that cannot be accessed from C code, store this state,
 511    and then call the C function replace_me.
 512
 513    Stack layout:
 514      16                 start of stack inside method to replace
 515       0   rplpoint *    info on the replacement point that was reached
 516
 517    NOTE: itmp3 has been clobbered by the replacement-out stub!
 518
 519 *******************************************************************************/
 520
 521 /* some room to accomodate changes of the stack frame size during replacement */
 522         /* XXX we should find a cleaner solution here */
 523 #define REPLACEMENT_ROOM  512
 524
 525 #define REPLACEMENT_STACK_OFFSET ((sizeexecutionstate + REPLACEMENT_ROOM + 0xf) & ~0xf)
 526
 527         .ent asm_replacement_out
 528
 529 asm_replacement_out:
 530     /* create stack frame */
 531         lda     sp,-(REPLACEMENT_STACK_OFFSET)(sp)
 532
 533         /* save registers in execution state */
 534         stq     $0 ,( 0*8+offes_intregs)(sp)
 535         stq     $1 ,( 1*8+offes_intregs)(sp)
 536         stq     $2 ,( 2*8+offes_intregs)(sp)
 537         stq     $3 ,( 3*8+offes_intregs)(sp)
 538         stq     $4 ,( 4*8+offes_intregs)(sp)
 539         stq     $5 ,( 5*8+offes_intregs)(sp)
 540         stq     $6 ,( 6*8+offes_intregs)(sp)
 541         stq     $7 ,( 7*8+offes_intregs)(sp)
 542         stq     $8 ,( 8*8+offes_intregs)(sp)
 543         stq     $9 ,( 9*8+offes_intregs)(sp)
 544         stq     $10,(10*8+offes_intregs)(sp)
 545         stq     $11,(11*8+offes_intregs)(sp)
 546         stq     $12,(12*8+offes_intregs)(sp)
 547         stq     $13,(13*8+offes_intregs)(sp)
 548         stq     $14,(14*8+offes_intregs)(sp)
 549         stq     $15,(15*8+offes_intregs)(sp)
 550         stq     $16,(16*8+offes_intregs)(sp)
 551         stq     $17,(17*8+offes_intregs)(sp)
 552         stq     $18,(18*8+offes_intregs)(sp)
 553         stq     $19,(19*8+offes_intregs)(sp)
 554         stq     $20,(20*8+offes_intregs)(sp)
 555         stq     $21,(21*8+offes_intregs)(sp)
 556         stq     $22,(22*8+offes_intregs)(sp)
 557         stq     $23,(23*8+offes_intregs)(sp)
 558         stq     $24,(24*8+offes_intregs)(sp)
 559         stq     $25,(25*8+offes_intregs)(sp)
 560         stq     $26,(26*8+offes_intregs)(sp)
 561         stq     $27,(27*8+offes_intregs)(sp)
 562         stq     $28,(28*8+offes_intregs)(sp)
 563         stq     $29,(29*8+offes_intregs)(sp)
 564         stq     $30,(30*8+offes_intregs)(sp)
 565         stq     $31,(31*8+offes_intregs)(sp)
 566
 567         stt     $f0 ,( 0*8+offes_fltregs)(sp)
 568         stt     $f1 ,( 1*8+offes_fltregs)(sp)
 569         stt     $f2 ,( 2*8+offes_fltregs)(sp)
 570         stt     $f3 ,( 3*8+offes_fltregs)(sp)
 571         stt     $f4 ,( 4*8+offes_fltregs)(sp)
 572         stt     $f5 ,( 5*8+offes_fltregs)(sp)
 573         stt     $f6 ,( 6*8+offes_fltregs)(sp)
 574         stt     $f7 ,( 7*8+offes_fltregs)(sp)
 575         stt     $f8 ,( 8*8+offes_fltregs)(sp)
 576         stt     $f9 ,( 9*8+offes_fltregs)(sp)
 577         stt     $f10,(10*8+offes_fltregs)(sp)
 578         stt     $f11,(11*8+offes_fltregs)(sp)
 579         stt     $f12,(12*8+offes_fltregs)(sp)
 580         stt     $f13,(13*8+offes_fltregs)(sp)
 581         stt     $f14,(14*8+offes_fltregs)(sp)
 582         stt     $f15,(15*8+offes_fltregs)(sp)
 583         stt     $f16,(16*8+offes_fltregs)(sp)
 584         stt     $f17,(17*8+offes_fltregs)(sp)
 585         stt     $f18,(18*8+offes_fltregs)(sp)
 586         stt     $f19,(19*8+offes_fltregs)(sp)
 587         stt     $f20,(20*8+offes_fltregs)(sp)
 588         stt     $f21,(21*8+offes_fltregs)(sp)
 589         stt     $f22,(22*8+offes_fltregs)(sp)
 590         stt     $f23,(23*8+offes_fltregs)(sp)
 591         stt     $f24,(24*8+offes_fltregs)(sp)
 592         stt     $f25,(25*8+offes_fltregs)(sp)
 593         stt     $f26,(26*8+offes_fltregs)(sp)
 594         stt     $f27,(27*8+offes_fltregs)(sp)
 595         stt     $f28,(28*8+offes_fltregs)(sp)
 596         stt     $f29,(29*8+offes_fltregs)(sp)
 597         stt     $f30,(30*8+offes_fltregs)(sp)
 598         stt     $f31,(31*8+offes_fltregs)(sp)
 599
 600         /* calculate sp of method */
 601         lda     itmp1,(REPLACEMENT_STACK_OFFSET + 2*8)(sp)
 602         stq     itmp1,(offes_sp)(sp)
 603
 604         br      ra,L_asm_replacement_out_load_gp
 605 L_asm_replacement_out_load_gp:
 606         ldgp    gp,0(ra)                    /* load gp                            */
 607
 608         /* store pv */
 609         stq     pv,(offes_pv)(sp)
 610
 611         /* call replace_me */
 612         ldq     a0,-(2*8)(itmp1)            /* arg0: rplpoint *                   */
 613     mov     sp,a1                       /* arg1: execution state              */
 614     jmp     zero,replace_me             /* call C function replace_me         */
 615     jmp     zero,abort                  /* NEVER REACHED                      */
 616
 617         .end asm_replacement_out
 618
 619 /* asm_replacement_in **********************************************************
 620
 621    This code writes the given execution state and jumps to the replacement
 622    code.
 623
 624    This function never returns!
 625
 626    NOTE: itmp3 is not restored!
 627
 628    C prototype:
 629       void asm_replacement_in(executionstate *es, replace_safestack_t *st);
 630
 631 *******************************************************************************/
 632
 633         .ent asm_replacement_in
 634
 635 asm_replacement_in:
 636         /* a0 == executionstate *es */
 637
 638         /* get arguments */
 639         mov     a1,s1                       /* replace_safestack_t *st            */
 640         mov     a0,s2                       /* executionstate *es == safe stack   */
 641
 642         /* switch to the safe stack */
 643         mov     s2,sp
 644
 645         /* call replace_build_execution_state(st) */
 646         mov             s1,a0
 647         jsr             ra,replace_build_execution_state
 648
 649         /* set new sp */
 650         ldq             sp,(offes_sp)(s2)
 651
 652         /* build stack frame */
 653         lda     sp,(-sizeexecutionstate)(sp)
 654
 655         /* call replace_free_safestack(st,& of allocated executionstate_t) */
 656         mov             sp,a1 /* tmpes */
 657         mov             s1,a0 /* st    */
 658         jsr             ra,replace_free_safestack
 659
 660         /* set new pv */
 661         ldq     pv,(offes_pv)(sp)
 662
 663         /* copy registers from execution state */
 664         ldq     $0 ,( 0*8+offes_intregs)(sp)
 665         ldq     $1 ,( 1*8+offes_intregs)(sp)
 666         ldq     $2 ,( 2*8+offes_intregs)(sp)
 667         ldq     $3 ,( 3*8+offes_intregs)(sp)
 668         ldq     $4 ,( 4*8+offes_intregs)(sp)
 669         ldq     $5 ,( 5*8+offes_intregs)(sp)
 670         ldq     $6 ,( 6*8+offes_intregs)(sp)
 671         ldq     $7 ,( 7*8+offes_intregs)(sp)
 672         ldq     $8 ,( 8*8+offes_intregs)(sp)
 673         ldq     $9 ,( 9*8+offes_intregs)(sp)
 674         ldq     $10,(10*8+offes_intregs)(sp)
 675         ldq     $11,(11*8+offes_intregs)(sp)
 676         ldq     $12,(12*8+offes_intregs)(sp)
 677         ldq     $13,(13*8+offes_intregs)(sp)
 678         ldq     $14,(14*8+offes_intregs)(sp)
 679         ldq     $15,(15*8+offes_intregs)(sp)
 680         ldq     a0, (16*8+offes_intregs)(sp)
 681         ldq     $17,(17*8+offes_intregs)(sp)
 682         ldq     $18,(18*8+offes_intregs)(sp)
 683         ldq     $19,(19*8+offes_intregs)(sp)
 684         ldq     $20,(20*8+offes_intregs)(sp)
 685         ldq     $21,(21*8+offes_intregs)(sp)
 686         ldq     $22,(22*8+offes_intregs)(sp)
 687         ldq     $23,(23*8+offes_intregs)(sp)
 688         ldq     $24,(24*8+offes_intregs)(sp)
 689         ldq     $25,(25*8+offes_intregs)(sp)
 690         ldq     $26,(26*8+offes_intregs)(sp)
 691         /* $27 is pv                    */
 692         ldq     $28,(28*8+offes_intregs)(sp)
 693         ldq     $29,(29*8+offes_intregs)(sp)
 694         /* $30 is sp                      */
 695         /* $31 is zero                    */
 696
 697         ldt     $f0 ,( 0*8+offes_fltregs)(sp)
 698         ldt     $f1 ,( 1*8+offes_fltregs)(sp)
 699         ldt     $f2 ,( 2*8+offes_fltregs)(sp)
 700         ldt     $f3 ,( 3*8+offes_fltregs)(sp)
 701         ldt     $f4 ,( 4*8+offes_fltregs)(sp)
 702         ldt     $f5 ,( 5*8+offes_fltregs)(sp)
 703         ldt     $f6 ,( 6*8+offes_fltregs)(sp)
 704         ldt     $f7 ,( 7*8+offes_fltregs)(sp)
 705         ldt     $f8 ,( 8*8+offes_fltregs)(sp)
 706         ldt     $f9 ,( 9*8+offes_fltregs)(sp)
 707         ldt     $f10,(10*8+offes_fltregs)(sp)
 708         ldt     $f11,(11*8+offes_fltregs)(sp)
 709         ldt     $f12,(12*8+offes_fltregs)(sp)
 710         ldt     $f13,(13*8+offes_fltregs)(sp)
 711         ldt     $f14,(14*8+offes_fltregs)(sp)
 712         ldt     $f15,(15*8+offes_fltregs)(sp)
 713         ldt     $f16,(16*8+offes_fltregs)(sp)
 714         ldt     $f17,(17*8+offes_fltregs)(sp)
 715         ldt     $f18,(18*8+offes_fltregs)(sp)
 716         ldt     $f19,(19*8+offes_fltregs)(sp)
 717         ldt     $f20,(20*8+offes_fltregs)(sp)
 718         ldt     $f21,(21*8+offes_fltregs)(sp)
 719         ldt     $f22,(22*8+offes_fltregs)(sp)
 720         ldt     $f23,(23*8+offes_fltregs)(sp)
 721         ldt     $f24,(24*8+offes_fltregs)(sp)
 722         ldt     $f25,(25*8+offes_fltregs)(sp)
 723         ldt     $f26,(26*8+offes_fltregs)(sp)
 724         ldt     $f27,(27*8+offes_fltregs)(sp)
 725         ldt     $f28,(28*8+offes_fltregs)(sp)
 726         ldt     $f29,(29*8+offes_fltregs)(sp)
 727         ldt     $f30,(30*8+offes_fltregs)(sp)
 728         ldt     $f31,(31*8+offes_fltregs)(sp)
 729
 730         /* load new pc */
 731
 732         ldq     itmp3,offes_pc(sp)
 733
 734         /* remove stack frame */
 735
 736         lda             sp,(sizeexecutionstate)(sp)
 737
 738         /* jump to new code */
 739
 740         jmp     zero,(itmp3)
 741
 742         .end asm_replacement_in
 743
 744
 745         .ent    asm_getclassvalues_atomic
 746
 747 asm_getclassvalues_atomic:
 748 _crit_restart:
 749 _crit_begin:
 750         ldl     t0,offbaseval(a0)
 751         ldl     t1,offdiffval(a0)
 752         ldl     t2,offbaseval(a1)
 753 _crit_end:
 754         stl     t0,offcast_super_baseval(a2)
 755         stl     t1,offcast_super_diffval(a2)
 756         stl     t2,offcast_sub_baseval(a2)
 757         jmp     zero,(ra)
 758
 759         .end    asm_getclassvalues_atomic
 760
 761
 762     .data
 763
 764 asm_criticalsections:
 765 #if defined(ENABLE_THREADS)
 766     .quad   _crit_begin
 767     .quad   _crit_end
 768     .quad   _crit_restart
 769 #endif
 770     .quad   0
 771
 772
 773 /* asm_md_init *****************************************************************
 774
 775    Initialize machine dependent stuff.
 776
 777    Determines if the byte support instruction set (21164a and higher)
 778    is available.
 779
 780 *******************************************************************************/
 781
 782         .ent    asm_md_init
 783
 784 asm_md_init:
 785         .long   0x47e03c20                  /* amask   1,v0                       */
 786         jmp     zero,(ra)                   /* return                             */
 787
 788         .end    asm_md_init
 789
 790
 791 /* asm_cacheflush **************************************************************
 792
 793    XXX
 794
 795 *******************************************************************************/
 796
 797         .ent    asm_cacheflush
 798
 799 asm_cacheflush:
 800         call_pal PAL_imb              /* synchronize instruction cache            */
 801         jmp     zero,(ra)
 802
 803         .end    asm_cacheflush
 804
 805
 806 /* Disable exec-stacks, required for Gentoo ***********************************/
 807
 808 #if defined(__GCC__) && defined(__ELF__)
 809         .section .note.GNU-stack,"",@progbits
 810 #endif
 811
 812
 813 /*
 814  * These are local overrides for various environment variables in Emacs.
 815  * Please do not remove this and leave it at the end of the file, where
 816  * Emacs will automagically detect them.
 817  * ---------------------------------------------------------------------
 818  * Local variables:
 819  * mode: asm
 820  * indent-tabs-mode: t
 821  * c-basic-offset: 4
 822  * tab-width: 4
 823  * End:
 824  * vim:noexpandtab:sw=4:ts=4:
 825  */