1 /* src/vm/jit/alpha/asmpart.S - Java-C interface functions for alpha
3 Copyright (C) 1996-2005, 2006 R. Grafl, A. Krall, C. Kruegel,
4 C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
5 E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
6 J. Wenninger, Institut f. Computersprachen - TU Wien
8 This file is part of CACAO.
10 This program is free software; you can redistribute it and/or
11 modify it under the terms of the GNU General Public License as
12 published by the Free Software Foundation; either version 2, or (at
13 your option) any later version.
15 This program is distributed in the hope that it will be useful, but
16 WITHOUT ANY WARRANTY; without even the implied warranty of
17 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
18 General Public License for more details.
20 You should have received a copy of the GNU General Public License
21 along with this program; if not, write to the Free Software
22 Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
25 Contact: cacao@cacaojvm.org
27 Authors: Andreas Krall
30 Changes: Joseph Wenninger
34 $Id: asmpart.S 5272 2006-08-23 15:55:38Z twisti $
41 #include "vm/jit/alpha/md-abi.h"
42 #include "vm/jit/alpha/md-asm.h"
43 #include "vm/jit/alpha/offsets.h"
45 #include "vm/jit/abi-asm.h"
46 #include "vm/jit/methodheader.h"
54 /* export functions ***********************************************************/
56 .globl asm_vm_call_method
57 .globl asm_vm_call_method_int
58 .globl asm_vm_call_method_long
59 .globl asm_vm_call_method_float
60 .globl asm_vm_call_method_double
61 .globl asm_vm_call_method_exception_handler
63 .globl asm_call_jit_compiler
65 .globl asm_handle_exception
66 .globl asm_handle_nat_exception
68 .globl asm_abstractmethoderror
70 .globl asm_patcher_wrapper
72 .globl asm_replacement_out
73 .globl asm_replacement_in
75 .globl asm_criticalsections
76 .globl asm_getclassvalues_atomic
82 /* asm_vm_call_method **********************************************************
84 * This function calls a Java-method (which possibly needs compilation) *
85 * with up to 4 address parameters. *
87 * This functions calls the JIT-compiler which eventually translates the *
88 * method into machine code. *
91 * javaobject_header *asm_calljavafunction (methodinfo *m, *
92 * void *arg1, void *arg2, void *arg3, void *arg4); *
94 *******************************************************************************/
96 .ent asm_vm_call_method
100 .quad 0 /* catch type all */
101 .quad 0 /* handler pc */
103 .quad 0 /* start pc */
104 .long 1 /* extable size */
105 .long 0 /* ALIGNMENT PADDING */
106 .quad 0 /* line number table start */
107 .quad 0 /* line number table size */
108 .long 0 /* ALIGNMENT PADDING */
109 .long 0 /* fltsave */
110 .long 1 /* intsave */
113 .long 0 /* frame size */
114 .quad 0 /* codeinfo pointer */
117 asm_vm_call_method_int:
118 asm_vm_call_method_long:
119 asm_vm_call_method_float:
120 asm_vm_call_method_double:
122 lda sp,-5*8(sp) /* allocate stack space */
123 stq ra,0*8(sp) /* save return address */
124 stq gp,1*8(sp) /* save global pointer */
127 stq a0,4*8(sp) /* save method pointer for compiler */
129 mov a2,t0 /* pointer to arg block */
130 mov a1,s6 /* arg count */
132 ble s6,calljava_argsloaded
134 ldq a0,offvmargdata(t0)
135 ldt $f16,offvmargdata(t0)
136 ble s6,calljava_argsloaded
139 ldq a1,offvmargdata+sizevmarg*1(t0)
140 ldt $f17,offvmargdata+sizevmarg*1(t0)
141 ble s6,calljava_argsloaded
144 ldq a2,offvmargdata+sizevmarg*2(t0)
145 ldt $f18,offvmargdata+sizevmarg*2(t0)
146 ble s6,calljava_argsloaded
149 ldq a3,offvmargdata+sizevmarg*3(t0)
150 ldt $f19,offvmargdata+sizevmarg*3(t0)
151 ble s6,calljava_argsloaded
154 ldq a4,offvmargdata+sizevmarg*4(t0)
155 ldt $f20,offvmargdata+sizevmarg*4(t0)
156 ble s6,calljava_argsloaded
159 ldq a5,offvmargdata+sizevmarg*5(t0)
160 ldt $f21,offvmargdata+sizevmarg*5(t0)
163 ble s6,calljava_nocopy
169 ldq t3,offvmargdata+sizevmarg*6(t0)
174 bne t1,calljava_copyloop
177 ldq itmp1,4*8(t4) /* pass method pointer via itmp1 */
179 lda mptr,asm_call_jit_compiler/* fake virtual function call (2 instr) */
180 stq mptr,2*8(t4) /* store function address */
181 lda mptr,1*8(t4) /* set method pointer */
183 ldq pv,1*8(mptr) /* method call as in Java */
184 jmp ra,(pv) /* call JIT compiler */
186 lda pv,(asm_vm_call_method - calljava_jit2)(ra)
190 ldq ra,0*8(sp) /* restore return address */
191 ldq gp,1*8(sp) /* restore global pointer */
193 lda sp,5*8(sp) /* free stack space */
198 asm_vm_call_method_exception_handler:
200 ldq gp,1*8(sp) /* restore global pointer */
202 jsr ra,builtin_throw_exception
203 ldq ra,0*8(sp) /* restore return address */
205 lda sp,5*8(sp) /* free stack space */
208 .end asm_vm_call_method
211 /* asm_call_jit_compiler *******************************************************
213 Invokes the compiler for untranslated Java methods.
215 *******************************************************************************/
217 .ent asm_call_jit_compiler
219 asm_call_jit_compiler:
221 lda sp,-(ARG_CNT+2)*8(sp) /* +2: keep stack 16-byte aligned */
223 stq ra,0*8(sp) /* save return address */
225 SAVE_ARGUMENT_REGISTERS(1) /* save 6 int/6 float argument registers */
227 mov itmp1,a0 /* pass methodinfo pointer */
228 mov mptr,a1 /* pass method pointer */
229 lda a2,(ARG_CNT+2)*8(sp) /* pass java sp */
231 jsr ra,jit_asm_compile /* call jit compiler */
234 ldq ra,0*8(sp) /* load return address */
236 RESTORE_ARGUMENT_REGISTERS(1) /* restore 6 int/6 float argument registers */
238 lda sp,(ARG_CNT+2)*8(sp) /* remove stack frame */
240 beq pv,L_asm_call_jit_compiler_exception
242 jmp zero,(pv) /* and call method, the method returns */
243 /* directly to the caller (ra). */
245 L_asm_call_jit_compiler_exception:
247 stq ra,0*8(sp) /* save return address (xpc) */
248 jsr ra,exceptions_get_and_clear_exception
249 ldq ra,0*8(sp) /* restore return address (xpc) */
252 mov v0,xptr /* get exception */
253 subq ra,4,xpc /* exception address is ra - 4 */
254 br L_asm_handle_nat_exception
256 .end asm_call_jit_compiler
259 /* asm_handle_exception ********************************************************
261 This function handles an exception. It does not use the usual calling
262 conventions. The exception pointer is passed in REG_ITMP1 and the
263 pc from the exception raising position is passed in REG_ITMP2. It searches
264 the local exception table for a handler. If no one is found, it unwinds
265 stacks and continues searching the callers.
267 ATTENTION: itmp3 == gp!
269 *******************************************************************************/
271 .ent asm_handle_nat_exception
273 asm_handle_nat_exception:
274 L_asm_handle_nat_exception: /* required for PIC code */
275 L_asm_handle_exception_stack_loop:
276 lda sp,-6*8(sp) /* keep stack 16-byte aligned */
277 stq xptr,0*8(sp) /* save xptr */
278 stq xpc,1*8(sp) /* save xpc */
279 stq ra,3*8(sp) /* save RA */
280 stq zero,4*8(sp) /* save maybe-leaf flag (cleared) */
282 mov ra,a0 /* pass RA */
284 br ra,L_asm_handle_exception_load_gp
285 L_asm_handle_exception_load_gp:
286 ldgp gp,0(ra) /* load gp */
288 jsr ra,md_codegen_get_pv_from_pc/* get PV from RA */
289 stq v0,2*8(sp) /* save PV */
291 ldq a0,0*8(sp) /* pass xptr */
292 ldq a1,1*8(sp) /* pass xpc */
293 mov v0,a2 /* pass PV */
294 addq sp,6*8,a3 /* pass Java SP */
296 br L_asm_handle_exception_continue
298 .aent asm_handle_exception
300 asm_handle_exception:
301 L_asm_handle_exception: /* required for PIC code */
302 lda sp,-(ARG_CNT+TMP_CNT)*8(sp) /* create maybe-leaf stackframe */
304 SAVE_ARGUMENT_REGISTERS(0) /* we save arg and temp registers in */
305 SAVE_TEMPORARY_REGISTERS(ARG_CNT) /* case this is a leaf method */
307 lda sp,-6*8(sp) /* keep stack 16-byte aligned */
308 stq xptr,0*8(sp) /* save xptr */
309 stq pv,2*8(sp) /* save PV */
310 stq ra,3*8(sp) /* save RA */
311 lda t0,1(zero) /* set maybe-leaf flag */
312 stq t0,4*8(sp) /* save maybe-leaf flag */
314 br ra,L_asm_handle_exception_load_gp_2
315 L_asm_handle_exception_load_gp_2:
316 ldgp gp,0(ra) /* load gp */
318 mov xptr,a0 /* pass xptr */
319 mov xpc,a1 /* pass xpc */
320 mov pv,a2 /* pass PV */
321 lda a3,(ARG_CNT+TMP_CNT+6)*8(sp)/* pass Java SP */
323 L_asm_handle_exception_continue:
324 jsr ra,exceptions_handle_exception
326 beq v0,L_asm_handle_exception_not_catched
328 mov v0,xpc /* move handlerpc into xpc */
329 ldq xptr,0*8(sp) /* restore xptr */
330 ldq pv,2*8(sp) /* restore PV */
331 ldq ra,3*8(sp) /* restore RA */
332 ldq t0,4*8(sp) /* get maybe-leaf flag */
333 lda sp,6*8(sp) /* free stack frame */
335 beq t0,L_asm_handle_exception_no_leaf
337 RESTORE_ARGUMENT_REGISTERS(0) /* if this is a leaf method, we have */
338 RESTORE_TEMPORARY_REGISTERS(ARG_CNT)/* to restore arg and temp registers */
340 lda sp,(ARG_CNT+TMP_CNT)*8(sp) /* remove maybe-leaf stackframe */
342 L_asm_handle_exception_no_leaf:
343 jmp zero,(xpc) /* jump to the handler */
345 L_asm_handle_exception_not_catched:
346 ldq xptr,0*8(sp) /* restore xptr */
347 ldq pv,2*8(sp) /* restore PV */
348 ldq ra,3*8(sp) /* restore RA */
349 ldq t0,4*8(sp) /* get maybe-leaf flag */
352 beq t0,L_asm_handle_exception_no_leaf_stack
354 lda sp,(ARG_CNT+TMP_CNT)*8(sp) /* remove maybe-leaf stackframe */
355 mov zero,t0 /* clear the maybe-leaf flag */
357 L_asm_handle_exception_no_leaf_stack:
358 ldl t1,FrameSize(pv) /* get frame size */
359 addq t1,sp,t1 /* pointer to save area */
361 ldl t2,IsLeaf(pv) /* is leaf procedure */
362 bne t2,L_asm_handle_exception_no_ra_restore
364 ldq ra,-1*8(t1) /* restore ra */
365 subq t1,8,t1 /* t1-- */
367 L_asm_handle_exception_no_ra_restore:
368 mov ra,xpc /* the new xpc is ra */
369 ldl t2,IntSave(pv) /* t2 = saved int register count */
370 br t3,ex_int1 /* t3 = current pc */
372 lda t3,(ex_int2 - ex_int1)(t3)
373 negl t2,t2 /* negate register count */
374 s4addq t2,t3,t3 /* t2 = IntSave - register count * 4 */
375 jmp zero,(t3) /* jump to save position */
386 s8addq t2,t1,t1 /* t1 = t1 - 8 * register count */
388 ldl t2,FltSave(pv) /* t2 = saved flt register count */
389 br t3,ex_flt1 /* t3 = current pc */
391 lda t3,(ex_flt2 - ex_flt1)(t3)
392 negl t2,t2 /* negate register count */
393 s4addq t2,t3,t3 /* t2 = FltSave - 4 * register count */
394 jmp zero,(t3) /* jump to save position */
406 ldl t1,FrameSize(pv) /* get frame size */
407 addq sp,t1,sp /* unwind stack */
408 br L_asm_handle_exception_stack_loop
410 .end asm_handle_nat_exception
413 /* asm_abstractmethoderror *****************************************************
415 Creates and throws an AbstractMethodError.
417 *******************************************************************************/
419 .ent asm_abstractmethoderror
421 asm_abstractmethoderror:
422 subq sp,2*8,sp /* create stackframe */
423 stq ra,0*8(sp) /* save return address */
424 addq sp,2*8,a0 /* pass java sp */
425 mov ra,a1 /* pass exception address */
426 jsr ra,exceptions_asm_new_abstractmethoderror
427 ldq ra,0*8(sp) /* restore return address */
428 addq sp,2*8,sp /* remove stackframe */
430 mov v0,xptr /* get exception pointer */
431 subq ra,4,xpc /* exception address is ra - 4 */
432 br L_asm_handle_nat_exception
434 .end asm_abstractmethoderror
437 /* asm_patcher_wrapper *********************************************************
442 40 return address into JIT code (patch position)
443 32 pointer to virtual java_objectheader
444 24 machine code (which is patched back later)
445 16 unresolved class/method/field reference
446 8 data segment displacement from load instructions
447 0 patcher function pointer to call (pv afterwards)
449 ATTENTION: itmp3 == gp! But we don't need gp do call the patcher function.
451 *******************************************************************************/
453 .ent asm_patcher_wrapper
456 lda sp,-((2+12+27+4)*8)(sp) /* create stack frame */
458 SAVE_RETURN_REGISTERS(0) /* save 1 int/1 float return registers */
459 SAVE_ARGUMENT_REGISTERS(2) /* save 6 int/6 float argument registers */
460 SAVE_TEMPORARY_REGISTERS(14) /* save 11 int/16 float temporary registers */
462 stq itmp1,(2+12+27+0)*8(sp) /* save itmp1 */
463 stq itmp2,(2+12+27+1)*8(sp) /* save itmp2 */
464 stq ra,(2+12+27+2)*8(sp) /* save method return address (for leafs) */
465 stq pv,(2+12+27+3)*8(sp) /* save pv of calling java function */
467 br ra,L_asm_patcher_wrapper_load_gp
468 L_asm_patcher_wrapper_load_gp:
469 ldgp gp,0(ra) /* load gp (it's not set correctly in jit) */
471 lda a0,(2+12+27+4)*8(sp) /* pass SP of patcher stub */
472 mov pv,a1 /* pass PV */
473 ldq a2,(2+12+27+2)*8(sp) /* pass RA (correct for leafs) */
474 jsr ra,patcher_wrapper
476 stq v0,(0+2+12+27+4)*8(sp) /* save return value */
478 RESTORE_RETURN_REGISTERS(0) /* restore 1 int/1 float return registers */
479 RESTORE_ARGUMENT_REGISTERS(2) /* restore 6 int/6 float argument registers */
480 RESTORE_TEMPORARY_REGISTERS(14) /* restore 11 integer temporary registers */
482 ldq itmp1,(2+12+27+0)*8(sp) /* restore itmp1 */
483 ldq itmp2,(2+12+27+1)*8(sp) /* restore itmp2 */
484 ldq ra,(2+12+27+2)*8(sp) /* restore method return address (for leafs)*/
485 ldq pv,(2+12+27+3)*8(sp) /* restore pv of calling java function */
487 ldq itmp3,(0+2+12+27+4)*8(sp) /* get return value */
488 bne itmp3,L_asm_patcher_wrapper_exception
490 ldq itmp3,(5+2+12+27+4)*8(sp) /* get RA to JIT */
491 lda sp,(6+2+12+27+4)*8(sp) /* remove stack frame */
493 jmp zero,(itmp3) /* jump to new patched code */
495 L_asm_patcher_wrapper_exception:
496 mov itmp3,xptr /* get exception */
497 ldq xpc,(5+2+12+27+4)*8(sp) /* RA is xpc */
498 lda sp,(6+2+12+27+4)*8(sp) /* remove stack frame */
499 br L_asm_handle_exception
501 .end asm_patcher_wrapper
504 /* asm_replacement_out *********************************************************
506 This code is jumped to from the replacement-out stubs that are executed
507 when a thread reaches an activated replacement point.
509 The purpose of asm_replacement_out is to read out the parts of the
510 execution state that cannot be accessed from C code, store this state,
511 and then call the C function replace_me.
514 16 start of stack inside method to replace
515 0 rplpoint * info on the replacement point that was reached
517 NOTE: itmp3 has been clobbered by the replacement-out stub!
519 *******************************************************************************/
521 /* some room to accomodate changes of the stack frame size during replacement */
522 /* XXX we should find a cleaner solution here */
523 #define REPLACEMENT_ROOM 512
525 #define REPLACEMENT_STACK_OFFSET ((sizeexecutionstate + REPLACEMENT_ROOM + 0xf) & ~0xf)
527 .ent asm_replacement_out
530 /* create stack frame */
531 lda sp,-(REPLACEMENT_STACK_OFFSET)(sp)
533 /* save registers in execution state */
534 stq $0 ,( 0*8+offes_intregs)(sp)
535 stq $1 ,( 1*8+offes_intregs)(sp)
536 stq $2 ,( 2*8+offes_intregs)(sp)
537 stq $3 ,( 3*8+offes_intregs)(sp)
538 stq $4 ,( 4*8+offes_intregs)(sp)
539 stq $5 ,( 5*8+offes_intregs)(sp)
540 stq $6 ,( 6*8+offes_intregs)(sp)
541 stq $7 ,( 7*8+offes_intregs)(sp)
542 stq $8 ,( 8*8+offes_intregs)(sp)
543 stq $9 ,( 9*8+offes_intregs)(sp)
544 stq $10,(10*8+offes_intregs)(sp)
545 stq $11,(11*8+offes_intregs)(sp)
546 stq $12,(12*8+offes_intregs)(sp)
547 stq $13,(13*8+offes_intregs)(sp)
548 stq $14,(14*8+offes_intregs)(sp)
549 stq $15,(15*8+offes_intregs)(sp)
550 stq $16,(16*8+offes_intregs)(sp)
551 stq $17,(17*8+offes_intregs)(sp)
552 stq $18,(18*8+offes_intregs)(sp)
553 stq $19,(19*8+offes_intregs)(sp)
554 stq $20,(20*8+offes_intregs)(sp)
555 stq $21,(21*8+offes_intregs)(sp)
556 stq $22,(22*8+offes_intregs)(sp)
557 stq $23,(23*8+offes_intregs)(sp)
558 stq $24,(24*8+offes_intregs)(sp)
559 stq $25,(25*8+offes_intregs)(sp)
560 stq $26,(26*8+offes_intregs)(sp)
561 stq $27,(27*8+offes_intregs)(sp)
562 stq $28,(28*8+offes_intregs)(sp)
563 stq $29,(29*8+offes_intregs)(sp)
564 stq $30,(30*8+offes_intregs)(sp)
565 stq $31,(31*8+offes_intregs)(sp)
567 stt $f0 ,( 0*8+offes_fltregs)(sp)
568 stt $f1 ,( 1*8+offes_fltregs)(sp)
569 stt $f2 ,( 2*8+offes_fltregs)(sp)
570 stt $f3 ,( 3*8+offes_fltregs)(sp)
571 stt $f4 ,( 4*8+offes_fltregs)(sp)
572 stt $f5 ,( 5*8+offes_fltregs)(sp)
573 stt $f6 ,( 6*8+offes_fltregs)(sp)
574 stt $f7 ,( 7*8+offes_fltregs)(sp)
575 stt $f8 ,( 8*8+offes_fltregs)(sp)
576 stt $f9 ,( 9*8+offes_fltregs)(sp)
577 stt $f10,(10*8+offes_fltregs)(sp)
578 stt $f11,(11*8+offes_fltregs)(sp)
579 stt $f12,(12*8+offes_fltregs)(sp)
580 stt $f13,(13*8+offes_fltregs)(sp)
581 stt $f14,(14*8+offes_fltregs)(sp)
582 stt $f15,(15*8+offes_fltregs)(sp)
583 stt $f16,(16*8+offes_fltregs)(sp)
584 stt $f17,(17*8+offes_fltregs)(sp)
585 stt $f18,(18*8+offes_fltregs)(sp)
586 stt $f19,(19*8+offes_fltregs)(sp)
587 stt $f20,(20*8+offes_fltregs)(sp)
588 stt $f21,(21*8+offes_fltregs)(sp)
589 stt $f22,(22*8+offes_fltregs)(sp)
590 stt $f23,(23*8+offes_fltregs)(sp)
591 stt $f24,(24*8+offes_fltregs)(sp)
592 stt $f25,(25*8+offes_fltregs)(sp)
593 stt $f26,(26*8+offes_fltregs)(sp)
594 stt $f27,(27*8+offes_fltregs)(sp)
595 stt $f28,(28*8+offes_fltregs)(sp)
596 stt $f29,(29*8+offes_fltregs)(sp)
597 stt $f30,(30*8+offes_fltregs)(sp)
598 stt $f31,(31*8+offes_fltregs)(sp)
600 /* calculate sp of method */
601 lda itmp1,(REPLACEMENT_STACK_OFFSET + 2*8)(sp)
602 stq itmp1,(offes_sp)(sp)
604 br ra,L_asm_replacement_out_load_gp
605 L_asm_replacement_out_load_gp:
606 ldgp gp,0(ra) /* load gp */
609 stq pv,(offes_pv)(sp)
611 /* call replace_me */
612 ldq a0,-(2*8)(itmp1) /* arg0: rplpoint * */
613 mov sp,a1 /* arg1: execution state */
614 jmp zero,replace_me /* call C function replace_me */
615 jmp zero,abort /* NEVER REACHED */
617 .end asm_replacement_out
619 /* asm_replacement_in **********************************************************
621 This code writes the given execution state and jumps to the replacement
624 This function never returns!
626 NOTE: itmp3 is not restored!
629 void asm_replacement_in(executionstate *es);
631 *******************************************************************************/
633 .ent asm_replacement_in
636 /* a0 == executionstate *es */
638 /* set new sp and pv */
639 ldq sp,(offes_sp)(a0)
640 ldq pv,(offes_pv)(a0)
642 /* copy registers from execution state */
643 ldq $0 ,( 0*8+offes_intregs)(a0)
644 ldq $1 ,( 1*8+offes_intregs)(a0)
645 ldq $2 ,( 2*8+offes_intregs)(a0)
646 ldq $3 ,( 3*8+offes_intregs)(a0)
647 ldq $4 ,( 4*8+offes_intregs)(a0)
648 ldq $5 ,( 5*8+offes_intregs)(a0)
649 ldq $6 ,( 6*8+offes_intregs)(a0)
650 ldq $7 ,( 7*8+offes_intregs)(a0)
651 ldq $8 ,( 8*8+offes_intregs)(a0)
652 ldq $9 ,( 9*8+offes_intregs)(a0)
653 ldq $10,(10*8+offes_intregs)(a0)
654 ldq $11,(11*8+offes_intregs)(a0)
655 ldq $12,(12*8+offes_intregs)(a0)
656 ldq $13,(13*8+offes_intregs)(a0)
657 ldq $14,(14*8+offes_intregs)(a0)
658 ldq $15,(15*8+offes_intregs)(a0)
659 /* a0 is loaded below */
660 ldq $17,(17*8+offes_intregs)(a0)
661 ldq $18,(18*8+offes_intregs)(a0)
662 ldq $19,(19*8+offes_intregs)(a0)
663 ldq $20,(20*8+offes_intregs)(a0)
664 ldq $21,(21*8+offes_intregs)(a0)
665 ldq $22,(22*8+offes_intregs)(a0)
666 ldq $23,(23*8+offes_intregs)(a0)
667 ldq $24,(24*8+offes_intregs)(a0)
668 ldq $25,(25*8+offes_intregs)(a0)
669 ldq $26,(26*8+offes_intregs)(a0)
671 ldq $28,(28*8+offes_intregs)(a0)
672 ldq $29,(29*8+offes_intregs)(a0)
676 ldt $f0 ,( 0*8+offes_fltregs)(a0)
677 ldt $f1 ,( 1*8+offes_fltregs)(a0)
678 ldt $f2 ,( 2*8+offes_fltregs)(a0)
679 ldt $f3 ,( 3*8+offes_fltregs)(a0)
680 ldt $f4 ,( 4*8+offes_fltregs)(a0)
681 ldt $f5 ,( 5*8+offes_fltregs)(a0)
682 ldt $f6 ,( 6*8+offes_fltregs)(a0)
683 ldt $f7 ,( 7*8+offes_fltregs)(a0)
684 ldt $f8 ,( 8*8+offes_fltregs)(a0)
685 ldt $f9 ,( 9*8+offes_fltregs)(a0)
686 ldt $f10,(10*8+offes_fltregs)(a0)
687 ldt $f11,(11*8+offes_fltregs)(a0)
688 ldt $f12,(12*8+offes_fltregs)(a0)
689 ldt $f13,(13*8+offes_fltregs)(a0)
690 ldt $f14,(14*8+offes_fltregs)(a0)
691 ldt $f15,(15*8+offes_fltregs)(a0)
692 ldt $f16,(16*8+offes_fltregs)(a0)
693 ldt $f17,(17*8+offes_fltregs)(a0)
694 ldt $f18,(18*8+offes_fltregs)(a0)
695 ldt $f19,(19*8+offes_fltregs)(a0)
696 ldt $f20,(20*8+offes_fltregs)(a0)
697 ldt $f21,(21*8+offes_fltregs)(a0)
698 ldt $f22,(22*8+offes_fltregs)(a0)
699 ldt $f23,(23*8+offes_fltregs)(a0)
700 ldt $f24,(24*8+offes_fltregs)(a0)
701 ldt $f25,(25*8+offes_fltregs)(a0)
702 ldt $f26,(26*8+offes_fltregs)(a0)
703 ldt $f27,(27*8+offes_fltregs)(a0)
704 ldt $f28,(28*8+offes_fltregs)(a0)
705 ldt $f29,(29*8+offes_fltregs)(a0)
706 ldt $f30,(30*8+offes_fltregs)(a0)
707 ldt $f31,(31*8+offes_fltregs)(a0)
711 ldq itmp3,offes_pc(a0)
715 ldq a0,(16*8+offes_intregs)(a0)
717 /* jump to new code */
721 .end asm_replacement_in
724 .ent asm_getclassvalues_atomic
726 asm_getclassvalues_atomic:
729 ldl t0,offbaseval(a0)
730 ldl t1,offdiffval(a0)
731 ldl t2,offbaseval(a1)
733 stl t0,offcast_super_baseval(a2)
734 stl t1,offcast_super_diffval(a2)
735 stl t2,offcast_sub_baseval(a2)
738 .end asm_getclassvalues_atomic
743 asm_criticalsections:
744 #if defined(ENABLE_THREADS)
752 /* asm_md_init *****************************************************************
754 Initialize machine dependent stuff.
756 Determines if the byte support instruction set (21164a and higher)
759 *******************************************************************************/
764 .long 0x47e03c20 /* amask 1,v0 */
765 jmp zero,(ra) /* return */
770 /* asm_cacheflush **************************************************************
774 *******************************************************************************/
779 call_pal PAL_imb /* synchronize instruction cache */
785 /* Disable exec-stacks, required for Gentoo ***********************************/
787 #if defined(__GCC__) && defined(__ELF__)
788 .section .note.GNU-stack,"",@progbits
793 * These are local overrides for various environment variables in Emacs.
794 * Please do not remove this and leave it at the end of the file, where
795 * Emacs will automagically detect them.
796 * ---------------------------------------------------------------------
799 * indent-tabs-mode: t
803 * vim:noexpandtab:sw=4:ts=4: