eglib/configure.ac

   1 #
   2 # Copyright 2012 Xamarin Inc
   3 #
   4 AC_INIT(eglib, [0.3],
   5         [http://bugzilla.xamarin.com/enter_bug.cgi?classification=Mono])
   6
   7 AC_CONFIG_SRCDIR([README])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_SYSTEM
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.9 dist-bzip2 tar-ustar no-dist-gzip foreign])
  13 AM_CONFIG_HEADER([config.h])
  14 AM_MAINTAINER_MODE
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_PROG_CC
  19 AM_PROG_LIBTOOL
  20 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
  21 DOLT
  22 GNUC_PRETTY=
  23 GNUC_UNUSED=
  24 BREAKPOINT="G_STMT_START { raise (SIGTRAP); } G_STMT_END"
  25 if test x$GCC = xyes; then
  26    GNUC_UNUSED='__attribute__((__unused__))'
  27    GNUC_NORETURN='__attribute__((__noreturn__))'
  28    case $host_cpu in
  29      i*86|x86_64) BREAKPOINT="G_STMT_START { __asm__ (\"int \$03\"); } G_STMT_END" ;;
  30    esac
  31 fi
  32 AC_SUBST(GNUC_PRETTY)
  33 AC_SUBST(GNUC_UNUSED)
  34 AC_SUBST(GNUC_NORETURN)
  35 AC_SUBST(BREAKPOINT)
  36
  37 # We use a separate variable to pass down CPPFLAGS and CFLAGS from the main mono
  38 # configure, because of autoconf brokeness
  39 if test "x$CPPFLAGS_FOR_EGLIB" != "x"; then
  40    CPPFLAGS=$CPPFLAGS_FOR_EGLIB
  41 fi
  42 if test "x$CFLAGS_FOR_EGLIB" != "x"; then
  43    CFLAGS=$CFLAGS_FOR_EGLIB
  44 fi
  45
  46 CFLAGS="$CFLAGS -g -D_GNU_SOURCE"
  47
  48 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
  49 AC_C_BIGENDIAN([ORDER=G_BIG_ENDIAN],[ORDER=G_LITTLE_ENDIAN])
  50
  51 platform_darwin=no
  52 platform_android=no
  53
  54 case $host in
  55 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  56     PATHSEP='\\'
  57     SEARCHSEP=';'
  58     OS="WIN32"
  59     PIDTYPE='void *'
  60     ;;
  61 *-*darwin*)
  62     platform_darwin=yes
  63     PATHSEP='/'
  64     SEARCHSEP=':'
  65     OS="UNIX"
  66     PIDTYPE='int'
  67     ;;
  68 *-*-linux-android*)
  69     platform_android=yes
  70         AC_DEFINE(PLATFORM_ANDROID,1,[Targeting the Android platform])
  71     PATHSEP='/'
  72     SEARCHSEP=':'
  73     OS="UNIX"
  74     PIDTYPE='int'
  75     ;;
  76 *)
  77     PATHSEP='/'
  78     SEARCHSEP=':'
  79     OS="UNIX"
  80     PIDTYPE='int'
  81     ;;
  82 esac
  83
  84 case $host in
  85         *-*-solaris*)
  86         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  87         ;;
  88 esac
  89
  90 case $target in
  91 arm*-darwin*)
  92     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE"
  93     ;;
  94 i*86-*-darwin*)
  95     ORDER=G_LITTLE_ENDIAN
  96     ;;
  97 *-*-openbsd*)
  98     CFLAGS="$CFLAGS -pthread"
  99     LDFLAGS="$LDFLAGS -pthread"
 100     ;;
 101 esac
 102
 103 AC_SUBST(ORDER)
 104 AC_SUBST(CFLAGS)
 105 AC_SUBST(PATHSEP)
 106 AC_SUBST(SEARCHSEP)
 107 AC_SUBST(OS)
 108 AC_SUBST(PIDTYPE)
 109 AM_CONDITIONAL(HOST_WIN32, test x$OS = xWIN32)
 110 AM_CONDITIONAL(TARGET_WIN32, test x$OS = xWIN32)
 111 AM_CONDITIONAL(PLATFORM_DARWIN, test x$platform_darwin = xyes)
 112 AM_CONDITIONAL(PLATFORM_ANDROID, test x$platform_android = xyes)
 113
 114 AC_CHECK_SIZEOF(int)
 115 AC_CHECK_SIZEOF(void *)
 116 AC_CHECK_SIZEOF(long)
 117 AC_CHECK_SIZEOF(long long)
 118 AC_CHECK_FUNCS(strndup strlcpy stpcpy getpwuid_r strtok_r rewinddir vasprintf)
 119 AM_CONDITIONAL(NEED_VASPRINTF, test x$have_vasprintf = x )
 120 AM_ICONV()
 121 AC_SEARCH_LIBS(sqrtf, m)
 122
 123 # nanosleep may not be part of libc, also search it in other libraries
 124 AC_SEARCH_LIBS(nanosleep, rt)
 125
 126 AC_SEARCH_LIBS(dlopen, dl)
 127 old_ldflags="${LDFLAGS}"
 128 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 129 AC_TRY_LINK(, [int i;], found_export_dynamic=yes, found_export_dynamic=no)
 130 if test $found_export_dynamic = no; then
 131         LDFLAGS="${old_ldflags}"
 132 fi
 133
 134 AC_MSG_CHECKING(for varargs macros)
 135 AC_TRY_COMPILE([],[
 136 int foo (int i, int j);
 137 #define bar(...) foo (1, __VA_ARGS__)
 138 void main () {
 139          bar (2);
 140 }
 141 ],have_iso_varargs=yes,have_iso_varargs=no)
 142 AC_MSG_RESULT($have_iso_varargs)
 143 G_HAVE_ISO_VARARGS=0
 144 if test "x$have_iso_varargs" = "xyes"; then
 145    G_HAVE_ISO_VARARGS=1
 146 fi
 147 AC_SUBST(G_HAVE_ISO_VARARGS)
 148
 149 AC_CHECK_HEADERS(getopt.h sys/time.h sys/wait.h pwd.h langinfo.h iconv.h localcharset.h sys/types.h)
 150 AC_CHECK_HEADER(alloca.h, [HAVE_ALLOCA_H=1], [HAVE_ALLOCA_H=0])
 151 AC_SUBST(HAVE_ALLOCA_H)
 152
 153 if test $ac_cv_sizeof_void_p = $ac_cv_sizeof_int; then
 154    GPOINTER_TO_INT="((gint) (ptr))"
 155    GPOINTER_TO_UINT="((guint) (ptr))"
 156    GINT_TO_POINTER="((gpointer) (v))"
 157    GUINT_TO_POINTER="((gpointer) (v))"
 158    GSIZE="int"
 159    GSIZE_FORMAT='"u"'
 160    G_GUINT64_FORMAT='"llu"'
 161    G_GINT64_FORMAT='"lld"'
 162    G_GUINT32_FORMAT='"lu"'
 163    G_GINT32_FORMAT='"ld"'
 164 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long; then
 165    GPOINTER_TO_INT="((gint)(long) (ptr))"
 166    GPOINTER_TO_UINT="((guint)(long) (ptr))"
 167    GINT_TO_POINTER="((gpointer)(glong) (v))"
 168    GUINT_TO_POINTER="((gpointer)(gulong) (v))"
 169    GSIZE="long"
 170    GSIZE_FORMAT='"lu"'
 171    G_GUINT64_FORMAT='"lu"'
 172    G_GINT64_FORMAT='"ld"'
 173    G_GUINT32_FORMAT='"u"'
 174    G_GINT32_FORMAT='"d"'
 175 elif test $ac_cv_sizeof_void_p = $ac_cv_sizeof_long_long; then
 176    GPOINTER_TO_INT="((gint)(long long) (ptr))"
 177    GPOINTER_TO_UINT="((guint)(unsigned long long) (ptr))"
 178    GINT_TO_POINTER="((gpointer)(long long) (v))"
 179    GUINT_TO_POINTER="((gpointer)(unsigned long long) (v))"
 180    GSIZE="long long"
 181    GSIZE_FORMAT='"I64u"'
 182    G_GUINT64_FORMAT='"I64u"'
 183    G_GINT64_FORMAT='"I64i"'
 184    G_GUINT32_FORMAT='"I32u"'
 185    G_GINT32_FORMAT='"I32i"'
 186 else
 187    AC_MSG_ERROR([unsupported pointer size])
 188 fi
 189
 190 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 191
 192 pkg_config_path=
 193 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir      Change pkg-config dir to custom dir],
 194         if test x$with_crosspkgdir = "x"; then
 195                 if test -s $PKG_CONFIG_PATH; then
 196                         pkg_config_path=$PKG_CONFIG_PATH
 197                 fi
 198         else
 199                 pkg_config_path=$with_crosspkgdir
 200                 PKG_CONFIG_PATH=$pkg_config_path
 201                 export PKG_CONFIG_PATH
 202         fi
 203 )
 204
 205 dnl
 206 dnl No, you can not replace the call below with a pkg.m4 macro
 207 dnl
 208 have_glib=false
 209 if test "x$PKG_CONFIG" != "xno"; then
 210     if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
 211         have_glib=true;
 212     else
 213         have_glib=false;
 214     fi
 215 fi
 216 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 217
 218 AC_SUBST(GPOINTER_TO_INT)
 219 AC_SUBST(GPOINTER_TO_UINT)
 220 AC_SUBST(GINT_TO_POINTER)
 221 AC_SUBST(GUINT_TO_POINTER)
 222 AC_SUBST(GSIZE)
 223 AC_SUBST(GSIZE_FORMAT)
 224 AC_SUBST(G_GUINT64_FORMAT)
 225 AC_SUBST(G_GINT64_FORMAT)
 226 AC_SUBST(G_GUINT32_FORMAT)
 227 AC_SUBST(G_GINT32_FORMAT)
 228
 229 AC_OUTPUT([
 230 Makefile
 231 m4/Makefile
 232 src/Makefile
 233 src/eglib-config.h
 234 test/Makefile
 235 ])