eglib/configure.ac

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 AM_CONFIG_HEADER(config.h)
   5 AM_INIT_AUTOMAKE(eglib,0.3)
   6 AM_MAINTAINER_MODE
   7
   8 AC_PROG_CC
   9 AM_PROG_LIBTOOL
  10 CFLAGS="$CFLAGS -g -O0 -D_GNU_SOURCE"
  11 GNUC_PRETTY=
  12 GNUC_UNUSED=
  13 BREAKPOINT="G_STMT_START { raise (SIGTRAP); } G_STMT_END"
  14 if test x$GCC = xyes; then
  15    GNUC_UNUSED='__attribute__((__unused__))'
  16    GNUC_NORETURN='__attribute__((__noreturn__))'
  17    echo target_cpu=$target_cpu
  18    case $target_cpu in
  19      i*86) BREAKPOINT="G_STMT_START { __asm__ (\"int \$03\"); } G_STMT_END" ;;
  20    esac
  21 fi
  22 AC_SUBST(GNUC_PRETTY)
  23 AC_SUBST(GNUC_UNUSED)
  24 AC_SUBST(GNUC_NORETURN)
  25 AC_SUBST(BREAKPOINT)
  26
  27 # We use a separate variable to pass down CPPFLAGS and CFLAGS from the main mono
  28 # configure, because of autoconf brokeness
  29 if test "x$CPPFLAGS_FOR_EGLIB" != "x"; then
  30    CPPFLAGS=$CPPFLAGS_FOR_EGLIB
  31 fi
  32 if test "x$CFLAGS_FOR_EGLIB" != "x"; then
  33    CFLAGS=$CFLAGS_FOR_EGLIB
  34 fi
  35
  36 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
  37 AC_C_BIGENDIAN([ORDER=G_BIG_ENDIAN],[ORDER=G_LITTLE_ENDIAN])
  38
  39 case $host in
  40 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  41     PATHSEP='\\'
  42     SEARCHSEP=';'
  43     OS="WIN32"
  44     ;;
  45 *)
  46     PATHSEP='/'
  47     SEARCHSEP=':'
  48     OS="UNIX"
  49     ;;
  50 esac
  51
  52 case $target in
  53 arm*-darwin*)
  54     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE"
  55     ;;
  56 i*86-*-darwin*)
  57     ORDER=G_LITTLE_ENDIAN
  58     ;;
  59 esac
  60
  61 AC_SUBST(ORDER)
  62 AC_SUBST(CFLAGS)
  63 AC_SUBST(PATHSEP)
  64 AC_SUBST(SEARCHSEP)
  65 AC_SUBST(OS)
  66 AM_CONDITIONAL(HOST_WIN32, test x$OS = xWIN32)
  67 AM_CONDITIONAL(TARGET_WIN32, test x$OS = xWIN32)
  68
  69 AC_CHECK_SIZEOF(int)
  70 AC_CHECK_SIZEOF(void *)
  71 AC_CHECK_FUNCS(strndup strlcpy getpwent_r strtok_r rewinddir)
  72 AC_CHECK_LIB(iconv, libiconv_open, LIBS="$LIBS -liconv")
  73 old_ldflags="${LDFLAGS}"
  74 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
  75 AC_TRY_LINK(, [int i;], found_export_dynamic=yes, found_export_dynamic=no)
  76 if test $found_export_dynamic = no; then
  77         LDFLAGS="${old_ldflags}"
  78 fi
  79
  80 AC_MSG_CHECKING(for varargs macros)
  81 AC_TRY_COMPILE([],[
  82 int foo (int i, int j);
  83 #define bar(...) foo (1, __VA_ARGS__)
  84 void main () {
  85          bar (2);
  86 }
  87 ],have_iso_varargs=yes,have_iso_varargs=no)
  88 AC_MSG_RESULT($have_iso_varargs)
  89 G_HAVE_ISO_VARARGS=0
  90 if test "x$have_iso_varargs" = "xyes"; then
  91    G_HAVE_ISO_VARARGS=1
  92 fi
  93 AC_SUBST(G_HAVE_ISO_VARARGS)
  94
  95 AC_CHECK_HEADERS(getopt.h sys/time.h sys/wait.h pwd.h langinfo.h iconv.h)
  96
  97 if test $ac_cv_sizeof_void_p != $ac_cv_sizeof_int; then
  98    GPOINTER_TO_INT="((gint)(long) (ptr))"
  99    GPOINTER_TO_UINT="((guint)(long) (ptr))"
 100    GINT_TO_POINTER="((gpointer)(glong) (v))"
 101    GUINT_TO_POINTER="((gpointer)(gulong) (v))"
 102    GSIZE="long"
 103    GSIZE_FORMAT='"lu"'
 104    G_GUINT64_FORMAT='"lu"'
 105 else
 106    GPOINTER_TO_INT="((gint) (ptr))"
 107    GPOINTER_TO_UINT="((guint) (ptr))"
 108    GINT_TO_POINTER="((gpointer) (v))"
 109    GUINT_TO_POINTER="((gpointer) (v))"
 110    GSIZE="int"
 111    GSIZE_FORMAT='"u"'
 112    G_GUINT64_FORMAT='"llu"'
 113 fi
 114
 115 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 116 if test "x$PKG_CONFIG" = "xno"; then
 117         AC_MSG_ERROR([You need to install pkg-config])
 118 fi
 119
 120 pkg_config_path=
 121 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir      Change pkg-config dir to custom dir],
 122         if test x$with_crosspkgdir = "x"; then
 123                 if test -s $PKG_CONFIG_PATH; then
 124                         pkg_config_path=$PKG_CONFIG_PATH
 125                 fi
 126         else
 127                 pkg_config_path=$with_crosspkgdir
 128                 PKG_CONFIG_PATH=$pkg_config_path
 129                 export PKG_CONFIG_PATH
 130         fi
 131 )
 132
 133 dnl
 134 dnl No, you can not replace the call below with a pkg.m4 macro
 135 dnl
 136 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
 137     have_glib=true;
 138 else
 139     have_glib=false;
 140 fi
 141 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 142
 143 AC_SUBST(GPOINTER_TO_INT)
 144 AC_SUBST(GPOINTER_TO_UINT)
 145 AC_SUBST(GINT_TO_POINTER)
 146 AC_SUBST(GUINT_TO_POINTER)
 147 AC_SUBST(GSIZE)
 148 AC_SUBST(GSIZE_FORMAT)
 149 AC_SUBST(G_GUINT64_FORMAT)
 150
 151 AC_OUTPUT([
 152 Makefile
 153 src/Makefile
 154 src/eglib-config.h
 155 test/Makefile
 156 ])