eglib/configure.ac

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 AM_CONFIG_HEADER(config.h)
   5 AM_INIT_AUTOMAKE(eglib,0.3)
   6 AM_MAINTAINER_MODE
   7
   8 AC_PROG_CC
   9 AM_PROG_LIBTOOL
  10 CFLAGS="$CFLAGS -g -O0 -D_GNU_SOURCE"
  11 GNUC_PRETTY=
  12 GNUC_UNUSED=
  13 BREAKPOINT="G_STMT_START { raise (SIGTRAP); } G_STMT_END"
  14 if test x$GCC = xyes; then
  15    GNUC_UNUSED='__attribute__((__unused__))'
  16    GNUC_NORETURN='__attribute__((__noreturn__))'
  17    echo target_cpu=$target_cpu
  18    case $target_cpu in
  19      i*86) BREAKPOINT="G_STMT_START { __asm__ (\"int \$03\"); } G_STMT_END" ;;
  20    esac
  21 fi
  22 AC_SUBST(GNUC_PRETTY)
  23 AC_SUBST(GNUC_UNUSED)
  24 AC_SUBST(GNUC_NORETURN)
  25 AC_SUBST(BREAKPOINT)
  26
  27 # We use a separate variable to pass down CPPFLAGS and CFLAGS from the main mono
  28 # configure, because of autoconf brokeness
  29 if test "x$CPPFLAGS_FOR_EGLIB" != "x"; then
  30    CPPFLAGS=$CPPFLAGS_FOR_EGLIB
  31 fi
  32 if test "x$CFLAGS_FOR_EGLIB" != "x"; then
  33    CFLAGS=$CFLAGS_FOR_EGLIB
  34 fi
  35
  36 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
  37 AC_C_BIGENDIAN([ORDER=G_BIG_ENDIAN],[ORDER=G_LITTLE_ENDIAN])
  38
  39 case $host in
  40 *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  41     PATHSEP='\\'
  42     SEARCHSEP=';'
  43     OS="WIN32"
  44     ;;
  45 *)
  46     PATHSEP='/'
  47     SEARCHSEP=':'
  48     OS="UNIX"
  49     ;;
  50 esac
  51
  52 case $target in
  53 arm*-darwin*)
  54     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE"
  55     ;;
  56 i*86-*-darwin*)
  57     ORDER=G_LITTLE_ENDIAN
  58     ;;
  59 esac
  60
  61 AC_SUBST(ORDER)
  62 AC_SUBST(CFLAGS)
  63 AC_SUBST(PATHSEP)
  64 AC_SUBST(SEARCHSEP)
  65 AC_SUBST(OS)
  66 AM_CONDITIONAL(HOST_WIN32, test x$OS = xWIN32)
  67 AM_CONDITIONAL(TARGET_WIN32, test x$OS = xWIN32)
  68
  69 AC_CHECK_SIZEOF(int)
  70 AC_CHECK_SIZEOF(void *)
  71 AC_CHECK_FUNCS(strndup strlcpy getpwent_r strtok_r rewinddir)
  72 AC_CHECK_LIB(iconv, libiconv_open, LIBS="$LIBS -liconv")
  73 old_ldflags="${LDFLAGS}"
  74 LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
  75 AC_TRY_LINK(, [int i;], found_export_dynamic=yes, found_export_dynamic=no)
  76 if test $found_export_dynamic = no; then
  77         LDFLAGS="${old_ldflags}"
  78 fi
  79
  80 AC_CHECK_HEADERS(getopt.h sys/time.h sys/wait.h pwd.h langinfo.h iconv.h)
  81
  82 if test $ac_cv_sizeof_void_p != $ac_cv_sizeof_int; then
  83    GPOINTER_TO_INT="((gint)(long) (ptr))"
  84    GPOINTER_TO_UINT="((guint)(long) (ptr))"
  85    GINT_TO_POINTER="((gpointer)(glong) (v))"
  86    GUINT_TO_POINTER="((gpointer)(gulong) (v))"
  87    GSIZE="long"
  88    GSIZE_FORMAT='"lu"'
  89    G_GUINT64_FORMAT='"lu"'
  90 else
  91    GPOINTER_TO_INT="((gint) (ptr))"
  92    GPOINTER_TO_UINT="((guint) (ptr))"
  93    GINT_TO_POINTER="((gpointer) (v))"
  94    GUINT_TO_POINTER="((gpointer) (v))"
  95    GSIZE="int"
  96    GSIZE_FORMAT='"u"'
  97    G_GUINT64_FORMAT='"llu"'
  98 fi
  99
 100 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 101 if test "x$PKG_CONFIG" = "xno"; then
 102         AC_MSG_ERROR([You need to install pkg-config])
 103 fi
 104
 105 pkg_config_path=
 106 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir      Change pkg-config dir to custom dir],
 107         if test x$with_crosspkgdir = "x"; then
 108                 if test -s $PKG_CONFIG_PATH; then
 109                         pkg_config_path=$PKG_CONFIG_PATH
 110                 fi
 111         else
 112                 pkg_config_path=$with_crosspkgdir
 113                 PKG_CONFIG_PATH=$pkg_config_path
 114                 export PKG_CONFIG_PATH
 115         fi
 116 )
 117
 118 dnl
 119 dnl No, you can not replace the call below with a pkg.m4 macro
 120 dnl
 121 if $PKG_CONFIG --atleast-version=$GLIB_REQUIRED_VERSION glib-2.0; then
 122     have_glib=true;
 123 else
 124     have_glib=false;
 125 fi
 126 AM_CONDITIONAL(HAVE_GLIB, $have_glib)
 127
 128 AC_SUBST(GPOINTER_TO_INT)
 129 AC_SUBST(GPOINTER_TO_UINT)
 130 AC_SUBST(GINT_TO_POINTER)
 131 AC_SUBST(GUINT_TO_POINTER)
 132 AC_SUBST(GSIZE)
 133 AC_SUBST(GSIZE_FORMAT)
 134 AC_SUBST(G_GUINT64_FORMAT)
 135
 136 AC_OUTPUT([
 137 Makefile
 138 src/Makefile
 139 src/eglib-config.h
 140 test/Makefile
 141 ])