configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.91)
   5 AM_MAINTAINER_MODE
   6
   7 dnl
   8 dnl libgc checks
   9 dnl
  10
  11 gc_headers=no
  12 gc=included
  13 use_included_gc=no
  14
  15 if test -d $srcdir/libgc ; then
  16   gc_default=included
  17 else
  18   gc_default=boehm
  19 fi
  20
  21 #
  22 # These are the flags that need to be stored in the mono.pc file for
  23 # compiling code that will embed Mono
  24 #
  25 libmono_cflags=""
  26 libmono_ldflags=""
  27 AC_SUBST(libmono_cflags)
  28 AC_SUBST(libmono_ldflags)
  29
  30 dnl if linker handles the version script
  31 no_version_script=no
  32
  33 # Thread configuration inspired by sleepycat's db
  34 AC_MSG_CHECKING([host platform characteristics])
  35 libgc_threads=no
  36 case "$host" in
  37         *-*-mingw*|*-*-cygwin*)
  38                 platform_win32=yes
  39                 AC_DEFINE(PLATFORM_WIN32)
  40                 CC="gcc -mno-cygwin"
  41                 HOST_CC="gcc"
  42 # latest libgc already defines GC_WIN32_THREADS
  43 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  44                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  45                 libdl=
  46                 libgc_threads=win32
  47                 gc_default=boehm
  48                 ;;
  49         *-*-*netbsd*)
  50                 platform_win32=no
  51                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  52                 libmono_cflags="-D_REENTRANT"
  53                 LDFLAGS="$LDFLAGS -pthread"
  54                 libmono_ldflags="-pthread"
  55                 AC_DEFINE(NEED_LINK_UNLINK)
  56                 libdl=
  57                 libgc_threads=pthreads
  58                 ;;
  59         *-*-*freebsd*|*-*-*openbsd*)
  60                 platform_win32=no
  61                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  62                 libmono_cflags="-D_THREAD_SAFE"
  63                 LDFLAGS="$LDFLAGS -pthread"
  64                 libmono_ldflags="-pthread"
  65                 AC_DEFINE(NEED_LINK_UNLINK)
  66                 AC_DEFINE(PTHREAD_POINTER_ID)
  67                 libdl=
  68                 libgc_threads=pthreads
  69                 ;;
  70         *-*-linux*)
  71                 platform_win32=no
  72                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -DMONO_USE_EXC_TABLES -D_GNU_SOURCE -D_REENTRANT -fexceptions"
  73                 libmono_cflags="-DMONO_USE_EXC_TABLES -fexceptions -D_REENTRANT"
  74                 libmono_ldflags="-lpthread"
  75                 libdl="-ldl"
  76                 libgc_threads=pthreads
  77                 ;;
  78         *-*-hpux*)
  79                 platform_win32=no
  80                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  81                 CFLAGS="$CFLAGS +ESdbgasm"
  82                 LDFLAGS="$LDFLAGS -z"
  83                 libmono_cflags="-D_REENTRANT"
  84                 libmono_ldflags="-lpthread"
  85                 libgc_threads=pthreads
  86                 AC_DEFINE(NEED_LINK_UNLINK)
  87                 ;;
  88         *-*-solaris*)
  89                 platform_win32=no
  90                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  91                 AC_DEFINE(NEED_LINK_UNLINK)
  92                 libmono_cflags="-D_REENTRANT"
  93                 libgc_threads=pthreads
  94                 ;;
  95         *-*-darwin*)
  96                 platform_win32=no
  97                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
  98                 libmono_cflags="-D_THREAD_SAFE"
  99                 LDFLAGS="$LDFLAGS -pthread"
 100                 libmono_ldflags="-pthread"
 101                 AC_DEFINE(NEED_LINK_UNLINK)
 102                 AC_DEFINE(PTHREAD_POINTER_ID)
 103                 AC_DEFINE(USE_MACH_SEMA)
 104                 no_version_script=yes
 105                 libdl=
 106                 libgc_threads=no
 107                 gc_default=none
 108                 ;;
 109         *)
 110                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 111                 platform_win32=no
 112                 libdl="-ldl"
 113                 ;;
 114 esac
 115 AC_MSG_RESULT(ok)
 116 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 117
 118 AC_CHECK_TOOL(CC, gcc, gcc)
 119 AC_PROG_CC
 120 AM_PROG_CC_STDC
 121 AC_PROG_INSTALL
 122 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 123 : ${CCAS='$(CC)'}
 124 # Set ASFLAGS if not already set.
 125 : ${CCASFLAGS='$(CFLAGS)'}
 126 AC_SUBST(CCAS)
 127 AC_SUBST(CCASFLAGS)
 128
 129 AC_CHECK_PROG(BISON, bison,yes,no)
 130 if test "x$BISON" = "xno";
 131 then
 132         AC_MSG_ERROR([You need to install bison])
 133 fi
 134
 135 dnl may require a specific autoconf version
 136 dnl AC_PROG_CC_FOR_BUILD
 137 dnl CC_FOR_BUILD not automatically detected
 138 CC_FOR_BUILD=$CC
 139 BUILD_EXEEXT=
 140 if test "x$cross_compiling" = "xyes"; then
 141         CC_FOR_BUILD=cc
 142         BUILD_EXEEXT=""
 143 fi
 144 AC_SUBST(CC_FOR_BUILD)
 145 AC_SUBST(HOST_CC)
 146 AC_SUBST(BUILD_EXEEXT)
 147
 148 # Set STDC_HEADERS
 149 AC_HEADER_STDC
 150 AC_LIBTOOL_WIN32_DLL
 151 AM_PROG_LIBTOOL
 152
 153 # Test whenever ld supports -version-script
 154 AC_PROG_LD
 155 AC_PROG_LD_GNU
 156 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 157    no_version_script=yes
 158 fi
 159
 160 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 161
 162 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 163
 164 # for mono/mini/tramp-x86.c
 165 AC_CHECK_HEADERS(valgrind/memcheck.h)
 166
 167 # for mono/metadata/debug-symfile.c
 168 AC_CHECK_HEADERS(elf.h)
 169
 170 # for mono/dis
 171 AC_CHECK_HEADERS(wchar.h)
 172
 173 # not 64 bit clean in cross-compile
 174 AC_CHECK_SIZEOF(void *, 4)
 175
 176 WARN=''
 177 if test x"$GCC" = xyes; then
 178         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 179                 # The runtime code does not respect ANSI C strict aliasing rules
 180                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 181 else
 182         # The Sun Forte compiler complains about inline functions that access static variables
 183         # so disable all inlining.
 184         case "$host" in
 185         *-*-solaris*)
 186                 CFLAGS="$CFLAGS -Dinline="
 187                 ;;
 188         esac
 189 fi
 190 CFLAGS="$CFLAGS -g $WARN"
 191
 192 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 193 if test "x$PKG_CONFIG" = "xno"; then
 194         AC_MSG_ERROR([You need to install pkg-config])
 195 fi
 196
 197 dnl for use on the build system
 198 dnl pkg-config is stupid
 199 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 200 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 201 AC_SUBST(BUILD_GLIB_CFLAGS)
 202 AC_SUBST(BUILD_GLIB_LIBS)
 203
 204 PKG_PATH=
 205 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 206         if test x$with_crosspkgdir = "x"; then
 207                 if test -s $PKG_CONFIG_PATH; then
 208                         PKG_PATH=$PKG_CONFIG_PATH
 209                 fi
 210         else
 211                 PKG_PATH=$with_crosspkgdir
 212                 PKG_CONFIG_PATH=$PKG_PATH
 213                 export PKG_CONFIG_PATH
 214         fi
 215 )
 216
 217 ## Versions of dependencies
 218 GLIB_REQUIRED_VERSION=1.3.11
 219
 220 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 221
 222 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 223 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 224 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 225 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 226
 227 AC_SUBST(GLIB_CFLAGS)
 228 AC_SUBST(GLIB_LIBS)
 229 AC_SUBST(GMODULE_CFLAGS)
 230 AC_SUBST(GMODULE_LIBS)
 231
 232 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 233
 234 # Enable support for NPTL only features like fast thread-local storage
 235 # We can't reliably detect nptl at compile & run time
 236 # so this option will stay until nptl becomes more widespread
 237 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 238
 239 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 240 # This does not work on some platforms (bug #55253)
 241 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 242
 243 # assembly bundle support, see metadata/make-bundle.pl for more info
 244 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 245         BUNDLE_FILE=$with_bundle
 246         AC_SUBST(BUNDLE_FILE)
 247         AC_DEFINE(WITH_BUNDLE)
 248 ],[with_bundle=no])
 249 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 250
 251 LIBGC_CFLAGS=
 252 LIBGC_LIBS=
 253 libgc_dir=
 254 case "x$gc" in
 255         xboehm|xbohem|xyes)
 256                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 257                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 258
 259                 if test "x$found_boehm" != "xyes"; then
 260                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 261                 fi
 262                 if test "x$gc_headers" != "xyes"; then
 263                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 264                 fi
 265
 266                 AC_DEFINE(HAVE_BOEHM_GC)
 267                 AC_SUBST(HAVE_BOEHM_GC)
 268                 LIBGC_LIBS="-lgc $libdl"
 269
 270                 # AC_CHECK_FUNCS does not work for some reason...
 271                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 272                 if test "x$found_gcj_malloc" = "xyes"; then
 273                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 274                 fi
 275                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 276                 if test "x$found_gc_enable" = "xyes"; then
 277                         AC_DEFINE(HAVE_GC_ENABLE)
 278                 fi
 279                 ;;
 280
 281         xincluded)
 282                 AC_CONFIG_SUBDIRS(libgc)
 283
 284                 found_boehm=yes
 285                 gc_headers=yes
 286                 use_included_gc=yes
 287                 libgc_dir=libgc
 288
 289                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 290                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 291
 292                 AC_DEFINE(HAVE_BOEHM_GC)
 293                 AC_SUBST(HAVE_BOEHM_GC)
 294
 295                 AC_DEFINE(HAVE_GC_H)
 296                 AC_DEFINE(USE_INCLUDED_LIBGC)
 297
 298                 # The included libgc contains GCJ support
 299                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 300                 AC_DEFINE(HAVE_GC_ENABLE)
 301                 ;;
 302
 303         xnone)
 304                 AC_MSG_WARN("Compiling mono without GC.")
 305                 ;;
 306         *)
 307                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 308                 ;;
 309 esac
 310
 311 we_are_embedded_in_mono=yes
 312 export we_are_embedded_in_mono
 313 export libgc_threads
 314
 315 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 316 AC_SUBST(LIBGC_CFLAGS)
 317 AC_SUBST(LIBGC_LIBS)
 318 AC_SUBST(libgc_dir)
 319
 320 dnl
 321 dnl End of libgc checks
 322 dnl
 323
 324 if test x$platform_win32 = xno; then
 325
 326         dnl ******************************************************************
 327         dnl *** Checks for the IKVM JNI interface library                  ***
 328         dnl ******************************************************************
 329         AC_ARG_WITH(ikvm-jni, [  --with-ikvm-jni=yes,no  build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
 330         AC_ARG_WITH(jdk, [  --with-jdk=DIRECTORY    Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
 331
 332         ikvm_jni_dir=
 333         if test x$with_ikvm_jni = xyes; then
 334                 AC_MSG_CHECKING([JDK headers])
 335
 336                 if test x$with_jdk_dir = x; then
 337                         # Try JAVA_HOME variable
 338                         if test x$JAVA_HOME != x; then
 339                                 with_jdk_dir=$JAVA_HOME
 340                         fi
 341                 fi
 342
 343                 jdk_platform=
 344                 if test -d $with_jdk_dir/include; then
 345                         jdk_headers_found=yes
 346
 347                         if test -d $with_jdk_dir/include/linux; then
 348                                 jdk_platform=linux
 349                         else
 350                         if test -d $with_jdk_dir/include/solaris; then
 351                                 jdk_platform=solaris
 352                         else
 353                         if test -f $with_jdk_dir/include/jni_md.h; then
 354                                 # GNU Classpath sources
 355                                 jdk_platform=
 356                         else
 357                                 jdk_headers_found=no
 358                         fi
 359                         fi
 360                         fi
 361                 else
 362                         jdk_headers_found=no
 363                 fi
 364
 365                 if test x$jdk_headers_found = xyes; then
 366                         AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
 367                 else
 368                         AC_MSG_RESULT(not found)
 369                 fi
 370
 371                 if test x$jdk_headers_found = xyes; then
 372                         ikvm_jni_dir=ikvm-jni
 373                         IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
 374                 fi
 375         fi
 376
 377         AC_SUBST(ikvm_jni_dir)
 378         AC_SUBST(IKVM_JNI_CFLAGS)
 379
 380         AC_CHECK_FUNCS(getgrgid_r)
 381         AC_CHECK_FUNCS(getgrnam_r)
 382         AC_CHECK_FUNCS(getpwnam_r)
 383         AC_CHECK_FUNCS(getpwuid_r)
 384         AC_CHECK_FUNCS(getresuid)
 385         AC_CHECK_FUNCS(setresuid)
 386
 387         dnl ******************************************************************
 388         dnl *** Check for large file support                               ***
 389         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 390         dnl ******************************************************************
 391
 392         # Check that off_t can represent 2**63 - 1 correctly, working around
 393         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 394         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 395         large_offt=no
 396         AC_DEFUN(LARGE_FILES, [
 397                 large_CPPFLAGS=$CPPFLAGS
 398                 CPPFLAGS="$CPPFLAGS $1"
 399                 AC_TRY_RUN([
 400                         #include <sys/types.h>
 401
 402                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 403
 404                         int main(void) {
 405                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 406                                                (BIG_OFF_T%2147483647==1));
 407                                 if(big_off_t) {
 408                                         exit(0);
 409                                 } else {
 410                                         exit(1);
 411                                 }
 412                         }
 413                 ], [
 414                         AC_MSG_RESULT(ok)
 415                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 416                         large_CPPFLAGS="$large_CPPFLAGS $1"
 417                         large_offt=yes
 418                 ], [
 419                         AC_MSG_RESULT(no)
 420                 ], "")
 421                 CPPFLAGS=$large_CPPFLAGS
 422         ])
 423
 424         AC_MSG_CHECKING(if off_t is 64 bits wide)
 425         LARGE_FILES("")
 426         if test $large_offt = no; then
 427                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 428                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 429         fi
 430         if test $large_offt = no; then
 431                 AC_MSG_WARN([No 64 bit file size support available])
 432         fi
 433
 434         dnl *****************************
 435         dnl *** Checks for libsocket  ***
 436         dnl *****************************
 437         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 438
 439         dnl *******************************
 440         dnl *** Checks for MSG_NOSIGNAL ***
 441         dnl *******************************
 442         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 443         AC_TRY_COMPILE([#include <sys/socket.h>], [
 444                 int f = MSG_NOSIGNAL;
 445         ], [
 446                 # Yes, we have it...
 447                 AC_MSG_RESULT(yes)
 448                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 449         ], [
 450                 # We'll have to use signals
 451                 AC_MSG_RESULT(no)
 452         ])
 453
 454         dnl *****************************
 455         dnl *** Checks for SOL_IP     ***
 456         dnl *****************************
 457         AC_MSG_CHECKING(for SOL_IP)
 458         AC_TRY_COMPILE([#include <netdb.h>], [
 459                 int level = SOL_IP;
 460         ], [
 461                 # Yes, we have it...
 462                 AC_MSG_RESULT(yes)
 463                 AC_DEFINE(HAVE_SOL_IP)
 464         ], [
 465                 # We'll have to use getprotobyname
 466                 AC_MSG_RESULT(no)
 467         ])
 468
 469         dnl *****************************
 470         dnl *** Checks for SOL_IPV6     ***
 471         dnl *****************************
 472         AC_MSG_CHECKING(for SOL_IPV6)
 473         AC_TRY_COMPILE([#include <netdb.h>], [
 474                 int level = SOL_IPV6;
 475         ], [
 476                 # Yes, we have it...
 477                 AC_MSG_RESULT(yes)
 478                 AC_DEFINE(HAVE_SOL_IPV6)
 479         ], [
 480                 # We'll have to use getprotobyname
 481                 AC_MSG_RESULT(no)
 482         ])
 483
 484         dnl *****************************
 485         dnl *** Checks for SOL_TCP    ***
 486         dnl *****************************
 487         AC_MSG_CHECKING(for SOL_TCP)
 488         AC_TRY_COMPILE([#include <netdb.h>], [
 489                 int level = SOL_TCP;
 490         ], [
 491                 # Yes, we have it...
 492                 AC_MSG_RESULT(yes)
 493                 AC_DEFINE(HAVE_SOL_TCP)
 494         ], [
 495                 # We'll have to use getprotobyname
 496                 AC_MSG_RESULT(no)
 497         ])
 498
 499         dnl *****************************
 500         dnl *** Checks for IP_PKTINFO ***
 501         dnl *****************************
 502         AC_MSG_CHECKING(for IP_PKTINFO)
 503         AC_TRY_COMPILE([#include <netdb.h>], [
 504                 int level = IP_PKTINFO;
 505         ], [
 506                 # Yes, we have it...
 507                 AC_MSG_RESULT(yes)
 508                 AC_DEFINE(HAVE_IP_PKTINFO)
 509         ], [
 510                 AC_MSG_RESULT(no)
 511         ])
 512
 513         dnl *********************************
 514         dnl *** Check for struct ip_mreqn ***
 515         dnl *********************************
 516         AC_MSG_CHECKING(for struct ip_mreqn)
 517         AC_TRY_COMPILE([#include <netinet/in.h>], [
 518                 struct ip_mreqn mreq;
 519                 mreq.imr_address.s_addr = 0;
 520         ], [
 521                 # Yes, we have it...
 522                 AC_MSG_RESULT(yes)
 523                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 524         ], [
 525                 # We'll just have to try and use struct ip_mreq
 526                 AC_MSG_RESULT(no)
 527                 AC_MSG_CHECKING(for struct ip_mreq)
 528                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 529                         struct ip_mreq mreq;
 530                         mreq.imr_interface.s_addr = 0;
 531                 ], [
 532                         # Yes, we have it...
 533                         AC_MSG_RESULT(yes)
 534                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 535                 ], [
 536                         # No multicast support
 537                         AC_MSG_RESULT(no)
 538                 ])
 539         ])
 540
 541         dnl **********************************
 542         dnl *** Check for gethostbyname2_r ***
 543         dnl **********************************
 544         AC_MSG_CHECKING(for gethostbyname2_r)
 545                 AC_TRY_LINK([#include <netdb.h>], [
 546                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 547         ], [
 548                 # Yes, we have it...
 549                 AC_MSG_RESULT(yes)
 550                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 551         ], [
 552                 AC_MSG_RESULT(no)
 553         ])
 554
 555         dnl *****************************
 556         dnl *** Checks for libnsl     ***
 557         dnl *****************************
 558         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 559
 560         AC_CHECK_FUNCS(inet_pton inet_aton)
 561
 562         dnl ***********************************************
 563         dnl *** Checks for size of sockaddr_un.sun_path ***
 564         dnl ***********************************************
 565         # AC_CHECK_SIZEOF can't cope with struct members :-(
 566         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 567         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 568                 [AC_TRY_RUN([
 569                         #include <sys/types.h>
 570                         #include <stdio.h>
 571                         #include <sys/un.h>
 572
 573                         int main(void) {
 574                                 struct sockaddr_un sock_un;
 575                                 FILE *f=fopen("conftestval", "w");
 576                                 if(!f) exit(1);
 577                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 578                                 exit(0);
 579                         }
 580                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 581                    cv_mono_sizeof_sunpath=0,
 582                    cv_mono_sizeof_sunpath=0)])dnl
 583         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 584         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 585
 586         dnl *************************************
 587         dnl *** Checks for zero length arrays ***
 588         dnl *************************************
 589         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 590         AC_TRY_COMPILE([
 591                 struct s {
 592                         int  length;
 593                         char data [0];
 594                 };
 595         ], [], [
 596                 AC_MSG_RESULT(yes)
 597                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 598         ], [
 599                 AC_MSG_RESULT(no)
 600                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 601         ])
 602
 603         dnl *****************************
 604         dnl *** Checks for libxnet    ***
 605         dnl *****************************
 606         case "${host}" in
 607                 *solaris* )
 608                         AC_MSG_CHECKING(for Solaris XPG4 support)
 609                         if test -f /usr/lib/libxnet.so; then
 610                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 611                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 612                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 613                                 LIBS="$LIBS -lxnet"
 614                                 AC_MSG_RESULT(yes)
 615                         else
 616                                 AC_MSG_RESULT(no)
 617                         fi
 618
 619                         if test "$GCC" = "yes"; then
 620                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 621                         fi
 622                 ;;
 623         esac
 624
 625         dnl *****************************
 626         dnl *** Checks for libpthread ***
 627         dnl *****************************
 628         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 629         AC_CHECK_HEADERS(pthread.h)
 630         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 631         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 632         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 633         AC_TRY_COMPILE([ #include <pthread.h>], [
 634                 pthread_mutexattr_t attr;
 635                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 636         ], [
 637                 AC_MSG_RESULT(ok)
 638         ], [
 639                 AC_MSG_RESULT(no)
 640                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 641                 AC_DEFINE(USE_MONO_MUTEX)
 642         ])
 643         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 644
 645         dnl ***********************************
 646         dnl *** Checks for working __thread ***
 647         dnl ***********************************
 648         AC_MSG_CHECKING(for working __thread)
 649         if test "x$with_nptl" != "xyes"; then
 650                 AC_MSG_RESULT(disabled)
 651         else
 652                 AC_TRY_RUN([
 653                         #include <pthread.h>
 654
 655                         __thread int i;
 656                         static int res1, res2;
 657
 658                         void thread_main (void *arg)
 659                         {
 660                                 i = arg;
 661                                 sleep (1);
 662                                 if (arg == 1)
 663                                         res1 = (i == arg);
 664                                 else
 665                                         res2 = (i == arg);
 666                         }
 667
 668                         int main () {
 669                                 pthread_t t1, t2;
 670
 671                                 i = 5;
 672
 673                                 pthread_create (&t1, NULL, thread_main, 1);
 674                                 pthread_create (&t2, NULL, thread_main, 2);
 675
 676                                 pthread_join (t1, NULL);
 677                                 pthread_join (t2, NULL);
 678
 679                                 return !(res1 + res2 == 2);
 680                         }
 681                 ], [
 682                                 AC_MSG_RESULT(yes)
 683                                 AC_DEFINE(HAVE_KW_THREAD)
 684                 ], [
 685                                 AC_MSG_RESULT(no)
 686                 ])
 687         fi
 688
 689         dnl **************************************
 690         dnl *** Checks for working sigaltstack ***
 691         dnl **************************************
 692         AC_MSG_CHECKING(for working sigaltstack)
 693         if test "x$with_sigaltstack" != "xyes"; then
 694                 AC_MSG_RESULT(disabled)
 695         else
 696                 AC_TRY_RUN([
 697                         #include <stdio.h>
 698                         #include <stdlib.h>
 699                         #include <unistd.h>
 700                         #include <signal.h>
 701                         #include <pthread.h>
 702                         #include <sys/wait.h>
 703
 704                         static void
 705                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 706                         {
 707                                 exit (0);
 708                         }
 709
 710                         static void *
 711                         loop (void *ignored)
 712                         {
 713                                 char *ptr = NULL;
 714
 715                                 *ptr = 0;
 716                                 return NULL;
 717                         }
 718
 719                         static void
 720                         child ()
 721                         {
 722                                 struct sigaction sa;
 723                                 struct sigaltstack sas;
 724                                 pthread_t id;
 725                                 pthread_attr_t attr;
 726
 727                                 sa.sa_sigaction = sigsegv_signal_handler;
 728                                 sigemptyset (&sa.sa_mask);
 729                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 730                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 731                                         perror ("lala");
 732                                         return;
 733                                 }
 734
 735                                 sas.ss_sp = malloc (SIGSTKSZ);
 736                                 sas.ss_size = SIGSTKSZ;
 737                                 sas.ss_flags = SS_ONSTACK;
 738                                 if (sigaltstack (&sas, NULL) == -1) {
 739                                         perror ("lala");
 740                                         return;
 741                                 }
 742
 743                                 pthread_attr_init (&attr);
 744                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 745                                         printf ("failed\n");
 746                                         return;
 747                                 }
 748
 749                                 sleep (100);
 750                         }
 751
 752                         int
 753                         main ()
 754                         {
 755                                 pid_t son;
 756                                 int status;
 757                                 int i;
 758
 759                                 son = fork ();
 760                                 if (son == -1) {
 761                                         return 1;
 762                                 }
 763
 764                                 if (son == 0) {
 765                                         child ();
 766                                         return 0;
 767                                 }
 768
 769                                 for (i = 0; i < 3; ++i) {
 770                                         sleep (1);
 771                                         waitpid (son, &status, WNOHANG);
 772                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 773                                                 return 0;
 774                                 }
 775
 776                                 kill (son, SIGKILL);
 777                                 return 1;
 778                         }
 779
 780                 ], [
 781                                 AC_MSG_RESULT(yes)
 782                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 783                 ], [
 784                                 with_sigaltstack=no
 785                                 AC_MSG_RESULT(no)
 786                 ])
 787         fi
 788
 789         dnl ********************************
 790         dnl *** Checks for semaphore lib ***
 791         dnl ********************************
 792         # 'Real Time' functions on Solaris
 793         # posix4 on Solaris 2.6
 794         # pthread (first!) on Linux
 795         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 796
 797         dnl ********************************
 798         dnl *** Checks for timezone stuff **
 799         dnl ********************************
 800         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 801                 AC_TRY_COMPILE([
 802                         #include <time.h>
 803                         ], [
 804                         struct tm tm;
 805                         tm.tm_gmtoff = 1;
 806                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 807         if test $ac_cv_struct_tm_gmtoff = yes; then
 808                 AC_DEFINE(HAVE_TM_GMTOFF)
 809         else
 810                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 811                         AC_TRY_COMPILE([
 812                                 #include <time.h>
 813                         ], [
 814                                 timezone = 1;
 815                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 816                 if test $ac_cv_var_timezone = yes; then
 817                         AC_DEFINE(HAVE_TIMEZONE)
 818                 else
 819                         AC_ERROR(unable to find a way to determine timezone)
 820                 fi
 821         fi
 822
 823         dnl *********************************
 824         dnl *** Checks for math functions ***
 825         dnl *********************************
 826         LIBS="$LIBS -lm";
 827         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 828                 AC_TRY_LINK([#include <math.h>],
 829                 [ finite(0.0); ],
 830                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 831                 AC_MSG_RESULT(no)))
 832         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 833                 AC_TRY_LINK([#include <math.h>],
 834                 [ isfinite(0.0); ],
 835                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 836                 AC_MSG_RESULT(no)))
 837
 838         dnl ****************************************************************
 839         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 840         dnl *** have it in the library (duh))                            ***
 841         dnl ****************************************************************
 842         AC_CHECK_FUNCS(poll)
 843
 844         dnl *************************
 845         dnl *** Check for signbit ***
 846         dnl *************************
 847         AC_MSG_CHECKING(for signbit)
 848         AC_TRY_LINK([#include <math.h>], [
 849                 int s = signbit(1.0);
 850         ], [
 851                 AC_MSG_RESULT(yes)
 852                 AC_DEFINE(HAVE_SIGNBIT)
 853         ], [
 854                 AC_MSG_RESULT(no)
 855         ])
 856
 857         dnl *********************
 858         dnl * Check for scandir *
 859         dnl *********************
 860         AC_CHECK_FUNCS(scandir)
 861
 862         dnl *********************
 863         dnl *** Check for AIO ***
 864         dnl *********************
 865         AC_MSG_CHECKING([for SIGEV_THREAD definition])
 866         dnl Some systems (FreeBSD at least) may have aio_read
 867         dnl but don't support/define SIGEV_THREAD.
 868         AC_TRY_COMPILE([
 869         #include <sys/signal.h>
 870         ],[
 871         int x = SIGEV_THREAD;
 872         ],[
 873                 ac_cv_c_sigev_thread=yes
 874                 AC_MSG_RESULT(yes)
 875         ],[
 876                 AC_MSG_RESULT(no)
 877         ])
 878
 879         if test "$ac_cv_c_sigev_thread" = "yes" ; then
 880                 AC_CHECK_HEADERS(aio.h sys/aio.h)
 881                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 882                 SIGVAL_PTR="undefined"
 883                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
 884                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
 885                                         #include <sys/signal.h>
 886                                         ])
 887                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
 888                                         #include <sys/signal.h>
 889                                         ])
 890                         if test "$SIGVAL_PTR" = "undefined" ; then
 891                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
 892                         fi
 893                 fi
 894                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
 895         fi
 896 else
 897         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 898         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 899 fi
 900
 901 dnl socklen_t check
 902 AC_MSG_CHECKING(for socklen_t)
 903 AC_TRY_COMPILE([
 904 #include <sys/types.h>
 905 #include <sys/socket.h>
 906 ],[
 907   socklen_t foo;
 908 ],[
 909 ac_cv_c_socklen_t=yes
 910         AC_DEFINE(HAVE_SOCKLEN_T)
 911         AC_MSG_RESULT(yes)
 912 ],[
 913         AC_MSG_RESULT(no)
 914 ])
 915
 916 AC_CHECK_FUNCS(truncl, , AC_MSG_CHECKING(for truncl in math.h)
 917         AC_TRY_LINK([#include <math.h>],
 918         [ truncl(0.0); ],
 919         [
 920                 AC_DEFINE(HAVE_TRUNCL)
 921                 AC_MSG_RESULT(yes)
 922                 ac_cv_truncl=yes
 923         ],
 924         AC_MSG_RESULT(no)))
 925
 926 if test "x$ac_cv_truncl" != "xyes"; then
 927    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 928 fi
 929
 930 dnl ****************************
 931 dnl *** Look for /dev/random ***
 932 dnl ****************************
 933
 934 AC_MSG_CHECKING([if usage of random device is requested])
 935 AC_ARG_ENABLE(dev-random,
 936 [  --disable-dev-random    disable the use of the random device],
 937 try_dev_random=$enableval, try_dev_random=yes)
 938 AC_MSG_RESULT($try_dev_random)
 939
 940 case "{$target}" in
 941     *-openbsd*)
 942     NAME_DEV_RANDOM="/dev/srandom"
 943     ;;
 944
 945 dnl Win32 does not have /dev/random, they have their own method...
 946
 947     *-*-mingw*|*-*-cygwin*)
 948     ac_cv_have_dev_random = no
 949     ;;
 950
 951 dnl Everywhere else, it's /dev/random
 952
 953     *)
 954     NAME_DEV_RANDOM="/dev/random"
 955     ;;
 956 esac
 957
 958 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 959
 960 dnl Now check if the device actually exists
 961
 962 if test "x$try_dev_random" = "xyes"; then
 963     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 964     [if test -r "$NAME_DEV_RANDOM" ; then
 965         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 966     if test "x$ac_cv_have_dev_random" = "xyes"; then
 967         AC_DEFINE(HAVE_CRYPT_RNG)
 968     fi
 969 else
 970     AC_MSG_CHECKING(for random device)
 971     ac_cv_have_dev_random=no
 972     AC_MSG_RESULT(has been disabled)
 973 fi
 974
 975 if test "x$platform_win32" = "xyes"; then
 976     AC_DEFINE(HAVE_CRYPT_RNG)
 977 fi
 978
 979 if test "x$ac_cv_have_dev_random" = "xno" \
 980     && test "x$platform_win32" = "xno"; then
 981     AC_MSG_WARN([[
 982 ***
 983 *** A system-provided entropy source was not found on this system.
 984 *** Because of this, the System.Security.Cryptography random number generator
 985 *** will throw a NotImplemented exception.
 986 ***
 987 *** If you are seeing this message, and you know your system DOES have an
 988 *** entropy collection in place, please contact <crichton@gimp.org> and
 989 *** provide information about the system and how to access the random device.
 990 ***
 991 *** Otherwise you can install either egd or prngd and set the environment
 992 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
 993 ***]])
 994 fi
 995
 996 AC_MSG_CHECKING([if inter-process shared handles are requested])
 997 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
 998 AC_MSG_RESULT($try_shared_handles)
 999 if test "x$try_shared_handles" != "xyes"; then
1000         AC_DEFINE(DISABLE_SHARED_HANDLES)
1001         AC_SUBST(DISABLE_SHARED_HANDLES)
1002 fi
1003
1004 #
1005 # ICU
1006 #
1007 ICU_CFLAGS=""
1008 ICU_LIBS=""
1009 enable_icu=no
1010
1011 probe_icu=true
1012 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1013         if test x$with_icu = xno; then
1014            probe_icu=false;
1015            AC_MSG_RESULT(Will not probe for ICU)
1016         fi
1017 )
1018
1019 if $probe_icu; then
1020         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1021         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1022                 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1023                 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1024         else
1025                 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1026                 AC_DEFINE(HAVE_ICU)
1027                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1028                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1029         fi
1030 fi
1031 AC_SUBST(ICU_CFLAGS)
1032 AC_SUBST(ICU_LIBS)
1033
1034 TARGET="unknown"
1035 ACCESS_UNALIGNED="yes"
1036
1037 JIT_SUPPORTED=no
1038 LIBC="libc.so.6"
1039
1040 jit_wanted=false
1041 case "$host" in
1042 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1043 #               TARGET=MIPS;
1044 #               ACCESS_UNALIGNED="no"
1045 #               ;;
1046         i*86-*-*)
1047                 TARGET=X86;
1048                 arch_target=x86;
1049                 JIT_SUPPORTED=yes
1050                 jit_wanted=true
1051                 ;;
1052         x86_64-*-* | amd64-*-*)
1053                 TARGET=AMD64;
1054                 arch_target=amd64;
1055                 JIT_SUPPORTED=no
1056                 ;;
1057         sparc*-*-*)
1058                 TARGET=SPARC;
1059                 arch_target=sparc;
1060                 JIT_SUPPORTED=yes
1061                 ACCESS_UNALIGNED="no"
1062                 LIBC="libc.so"
1063                 jit_wanted=true
1064                 ;;
1065 #       alpha*-*-linux* | alpha*-*-osf*)
1066 #               TARGET=ALPHA;
1067 #               ACCESS_UNALIGNED="no"
1068 #              ;;
1069 #       ia64-*-linux* | ia64-*-hpux*)
1070 #               TARGET=IA64;
1071 #               arch_target=ia64;
1072 #               JIT_SUPPORTED=no;
1073 #               ACCESS_UNALIGNED="no";
1074 #               case "$host_os" in
1075 #                       linux*) LIBC="libc.so.6.1";;
1076 #                       hpux*)  LIBC="libc.so.1";;
1077 #               esac
1078 #               ;;
1079 #       m68k-*-linux*)
1080 #               TARGET=M68K
1081 #               ;;
1082         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1083                 TARGET=HPPA;
1084                 arch_target=hppa;
1085                 ACCESS_UNALIGNED="no"
1086                 ;;
1087         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1088         powerpc-*-sysv* | powerpc-*-darwin*)
1089                 TARGET=POWERPC;
1090                 arch_target=ppc;
1091                 JIT_SUPPORTED=yes
1092                 jit_wanted=true
1093                 ;;
1094         arm-*-linux-* | armv4l-*-linux-*)
1095                 TARGET=ARM;
1096                 arch_target=arm;
1097                 ACCESS_UNALIGNED="no"
1098                 ;;
1099         s390-*-linux*)
1100                 TARGET=S390;
1101                 arch_target=s390;
1102                 ACCESS_UNALIGNED="no"
1103                 JIT_SUPPORTED=yes
1104                 ;;
1105 esac
1106
1107 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1108         jit_wanted=true
1109 ])
1110
1111 USEJIT=false
1112 if test x$JIT_SUPPORTED = xyes; then
1113    if $jit_wanted; then
1114       USEJIT=true
1115       jit_status="Building and using the JIT"
1116    else
1117       jit_status="Building the JIT, defaulting to the interpreter"
1118    fi
1119 else
1120    jit_status="interpreter"
1121 fi
1122
1123 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1124
1125 libsuffix=".so"
1126
1127 case "$host" in
1128      powerpc-*-darwin*)
1129         libsuffix=".dylib"
1130         LIBC="libc.dylib"
1131         ;;
1132 esac
1133 AC_SUBST(libsuffix)
1134
1135 if test ${TARGET} = ARM; then
1136         dnl ******************************************
1137         dnl *** Check to see what FPU is available ***
1138         dnl ******************************************
1139         AC_MSG_CHECKING(which FPU to use)
1140
1141         AC_TRY_COMPILE([], [
1142                 __asm__ ("ldfd f0, [r0]");
1143                 ], fpu=FPA, [
1144                         AC_TRY_COMPILE([], [
1145                                 __asm__ ("fldd d0, [r0]");
1146                         ], fpu=VFP, fpu=NONE)
1147                 ])
1148
1149         AC_MSG_RESULT($fpu)
1150         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1151         unset fpu
1152 fi
1153
1154 if test ${TARGET} = unknown; then
1155         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1156         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1157 fi
1158
1159 if test ${ACCESS_UNALIGNED} = no; then
1160         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1161 fi
1162
1163 PREVIEW=no
1164 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1165         if test x$with_preview = xyes; then
1166               PREVIEW=yes
1167         fi
1168 ])
1169
1170 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1171
1172 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1173 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1174 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1175 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1176 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1177 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1178 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1179 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1180 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1181 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1182 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1183 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1184
1185 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1186
1187 AC_SUBST(LIBC)
1188
1189 AC_SUBST(arch_target)
1190 AC_SUBST(CFLAGS)
1191 AC_SUBST(CPPFLAGS)
1192 AC_SUBST(LDFLAGS)
1193
1194 AC_OUTPUT([
1195 Makefile
1196 mint.pc
1197 mono.pc
1198 mono/Makefile
1199 mono/utils/Makefile
1200 mono/metadata/Makefile
1201 mono/dis/Makefile
1202 mono/cil/Makefile
1203 mono/arch/Makefile
1204 mono/os/Makefile
1205 mono/os/win32/Makefile
1206 mono/os/unix/Makefile
1207 mono/arch/x86/Makefile
1208 mono/arch/amd64/Makefile
1209 mono/arch/hppa/Makefile
1210 mono/arch/ppc/Makefile
1211 mono/arch/sparc/Makefile
1212 mono/arch/s390/Makefile
1213 mono/arch/arm/Makefile
1214 mono/arch/alpha/Makefile
1215 mono/interpreter/Makefile
1216 mono/tests/Makefile
1217 mono/tests/tests-config
1218 mono/benchmark/Makefile
1219 mono/monoburg/Makefile
1220 mono/monograph/Makefile
1221 mono/io-layer/Makefile
1222 mono/handles/Makefile
1223 mono/mini/Makefile
1224 mono/profiler/Makefile
1225 ikvm-jni/Makefile
1226 runtime/Makefile
1227 runtime/net_1_1/Makefile
1228 runtime/net_2_0/Makefile
1229 scripts/Makefile
1230 man/Makefile
1231 web/Makefile
1232 docs/Makefile
1233 data/Makefile
1234 samples/Makefile
1235 support/Makefile
1236 data/config
1237 mono.spec
1238 ])
1239
1240 echo "
1241
1242         GC:          $gc
1243         ICU:         $enable_icu
1244         NPTL:        $with_nptl
1245         SIGALTSTACK: $with_sigaltstack
1246         Engine:      $jit_status
1247         2.0 Alpha:   $PREVIEW
1248         JNI support: $jdk_headers_found
1249
1250 "